configure.ac

   1 AC_PREREQ(2.60)
   2
   3 m4_define([webkit_major_version], [1])
   4 m4_define([webkit_minor_version], [11])
   5 m4_define([webkit_micro_version], [2])
   6
   7 # This is the version we'll be using as part of our User-Agent string
   8 # e.g., AppleWebKit/$(webkit_user_agent_version) ...
   9 #
  10 # Sourced from Source/WebCore/Configurations/Version.xcconfig
  11 m4_define([webkit_user_agent_major_version], [537])
  12 m4_define([webkit_user_agent_minor_version], [20])
  13
  14 AC_INIT([WebKitGTK],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
  15
  16 AC_CONFIG_MACRO_DIR([Source/autotools])
  17 AC_CONFIG_AUX_DIR([Source/autotools])
  18 AC_SUBST(ACLOCAL_AMFLAGS, "-I Source/autotools")
  19
  20 AC_CONFIG_HEADERS([autotoolsconfig.h])
  21 AC_CANONICAL_HOST
  22
  23 WEBKIT_MAJOR_VERSION=webkit_major_version
  24 WEBKIT_MINOR_VERSION=webkit_minor_version
  25 WEBKIT_MICRO_VERSION=webkit_micro_version
  26 WEBKIT_USER_AGENT_MAJOR_VERSION=webkit_user_agent_major_version
  27 WEBKIT_USER_AGENT_MINOR_VERSION=webkit_user_agent_minor_version
  28 AC_SUBST(WEBKIT_MAJOR_VERSION)
  29 AC_SUBST(WEBKIT_MINOR_VERSION)
  30 AC_SUBST(WEBKIT_MICRO_VERSION)
  31 AC_SUBST(WEBKIT_USER_AGENT_MAJOR_VERSION)
  32 AC_SUBST(WEBKIT_USER_AGENT_MINOR_VERSION)
  33
  34 AC_CONFIG_SRCDIR([Source/WebCore/config.h])
  35
  36 dnl # Libtool library version, not to confuse with API version
  37 dnl # see http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  38 LIBWEBKITGTK_VERSION=17:1:17
  39 AC_SUBST([LIBWEBKITGTK_VERSION])
  40
  41 LIBJAVASCRIPTCOREGTK_VERSION=13:7:13
  42 AC_SUBST([LIBJAVASCRIPTCOREGTK_VERSION])
  43
  44 LIBWEBKIT2GTK_VERSION=19:0:19
  45 AC_SUBST([LIBWEBKIT2GTK_VERSION])
  46
  47 AM_INIT_AUTOMAKE([foreign subdir-objects dist-xz no-dist-gzip tar-ustar])
  48
  49 # Use AM_SILENT_RULES if present
  50 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  51
  52 # host checking - inspired by the GTK+ configure.in
  53 # TODO: move these to webkit.m4?
  54 AC_MSG_CHECKING([for native Win32])
  55 case "$host" in
  56      *-*-mingw*)
  57        os_win32=yes
  58        ;;
  59      *)
  60        os_win32=no
  61        ;;
  62 esac
  63 AC_MSG_RESULT([$os_win32])
  64
  65 case "$host" in
  66      *-*-linux*)
  67        os_linux=yes
  68        ;;
  69      *-*-freebsd*)
  70        os_freebsd=yes
  71        ;;
  72      *-*-darwin*)
  73        os_darwin=yes
  74        ;;
  75 esac
  76
  77 case "$host_os" in
  78      gnu* | linux* | k*bsd*-gnu)
  79        os_gnu=yes
  80        ;;
  81      *)
  82        os_gnu=no
  83        ;;
  84 esac
  85
  86 # If CFLAGS and CXXFLAGS are unset, default to empty.
  87 # This is to tell automake not to include '-g' if C{XX,}FLAGS is not set
  88 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
  89 if test -z "$CXXFLAGS"; then
  90    CXXFLAGS=""
  91 fi
  92 if test -z "$CFLAGS"; then
  93    CFLAGS=""
  94 fi
  95
  96 PKG_PROG_PKG_CONFIG
  97
  98 AC_PATH_PROG(PERL, perl)
  99 if test -z "$PERL"; then
 100    AC_MSG_ERROR([You need 'perl' to compile WebKit])
 101 fi
 102
 103 AC_PATH_PROG(PYTHON, python)
 104 if test -z "$PYTHON"; then
 105    AC_MSG_ERROR([You need 'python' to compile WebKit])
 106 fi
 107
 108 AC_PATH_PROG(RUBY, ruby)
 109 if test -z "$RUBY"; then
 110    AC_MSG_ERROR([You need 'ruby' to compile WebKit])
 111 fi
 112
 113 AC_PATH_PROG(BISON, bison)
 114 if test -z "$BISON"; then
 115    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
 116 fi
 117
 118 AC_PATH_PROG(MV, mv)
 119 if test -z "$MV"; then
 120    AC_MSG_ERROR([You need 'mv' to compile WebKit])
 121 fi
 122
 123 AC_PROG_CC
 124 AC_PROG_CXX
 125 AM_PROG_CC_C_O
 126 AC_PROG_INSTALL
 127 AC_SYS_LARGEFILE
 128
 129 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
 130 # doesn't exist)
 131 AC_LANG_PUSH([C++])
 132 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
 133 AC_LANG_POP([C++])
 134
 135 # C/C++ Language Features
 136 AC_C_CONST
 137 AC_C_INLINE
 138 AC_C_VOLATILE
 139
 140 # C/C++ Headers
 141 AC_HEADER_STDC
 142 AC_HEADER_STDBOOL
 143
 144 # Linker
 145 AC_DISABLE_STATIC
 146 AC_LIBTOOL_WIN32_DLL
 147 AC_PROG_LIBTOOL
 148 # use dolt to speedup the build
 149 DOLT
 150
 151 AC_PATH_PROG(FLEX, flex)
 152 if test -z "$FLEX"; then
 153    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
 154 else
 155    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
 156    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
 157       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
 158 fi
 159
 160 AC_PATH_PROG(GPERF, gperf)
 161 if test -z "$GPERF"; then
 162    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
 163 fi
 164
 165 # check for -fvisibility=hidden compiler support (GCC >= 4)
 166 saved_CFLAGS="$CFLAGS"
 167 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
 168 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
 169 AC_COMPILE_IFELSE([AC_LANG_SOURCE([char foo;])],
 170       [ AC_MSG_RESULT([yes])
 171         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
 172         AC_MSG_RESULT([no]))
 173 CFLAGS="$saved_CFLAGS"
 174 AC_SUBST(SYMBOL_VISIBILITY)
 175 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
 176
 177 # Disable C++0x compat warnings for GCC >= 4.6.0 until we build
 178 # cleanly with that.
 179 AC_LANG_PUSH(C++)
 180 TMPCXXFLAGS=$CXXFLAGS
 181 CXXFLAGS="-Wall -Werror"
 182 AC_MSG_CHECKING([if we have to disable C++0x compat warnings for GCC >= 4.6.0])
 183 AC_TRY_COMPILE([
 184 namespace std {
 185     class nullptr_t { };
 186 }
 187 extern std::nullptr_t nullptr;
 188 ], [return 0;],
 189 disable_cxx0x_compat=no,
 190 disable_cxx0x_compat=yes)
 191 AC_MSG_RESULT($disable_cxx0x_compat)
 192 if test "$disable_cxx0x_compat" = yes; then
 193   CXXFLAGS="$TMPCXXFLAGS -Wno-c++0x-compat"
 194 else
 195   CXXFLAGS="$TMPCXXFLAGS"
 196 fi
 197 AC_LANG_POP(C++)
 198
 199 # pthread (not needed on Windows)
 200 if test "$os_win32" = "no"; then
 201 AC_CHECK_HEADERS([pthread.h],
 202                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
 203                  AC_MSG_ERROR([pthread support is required to build WebKit]))
 204 AC_CHECK_LIB(pthread, pthread_rwlock_init,
 205                  AC_DEFINE([HAVE_PTHREAD_RWLOCK],[1],[Define if pthread rwlock is present]),
 206                  AC_MSG_WARN([pthread rwlock support is not available]))
 207 fi
 208
 209 # check for libjpeg the way Gtk does it.
 210 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 211                    jpeg_ok=yes, jpeg_ok=no
 212                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
 213 if test "$jpeg_ok" = yes; then
 214    AC_MSG_CHECKING([for jpeglib])
 215    AC_TRY_CPP(
 216 [#include <stdio.h>
 217 #undef PACKAGE
 218 #undef VERSION
 219 #undef HAVE_STDLIB_H
 220 #include <jpeglib.h>],
 221          jpeg_ok=yes,
 222          jpeg_ok=no)
 223    AC_MSG_RESULT($jpeg_ok)
 224    if test "$jpeg_ok" = yes; then
 225       JPEG_LIBS="-ljpeg"
 226       # should we check for progressive JPEG like GTK+ as well?
 227    else
 228       AC_MSG_ERROR([JPEG library (libjpeg) not found])
 229    fi
 230 fi
 231 AC_SUBST([JPEG_LIBS])
 232
 233 # Check for libpng the way Gtk+ does it
 234 for l in libpng libpng14 libpng12; do
 235   AC_MSG_CHECKING(for $l)
 236   if $PKG_CONFIG --exists $l ; then
 237     AC_MSG_RESULT(yes)
 238     PNG_LIBS=`$PKG_CONFIG --libs $l`
 239     png_ok=yes
 240     break
 241   else
 242     AC_MSG_RESULT(no)
 243     png_ok=no
 244   fi
 245 done
 246 if test "$png_ok" != yes; then
 247   AC_CHECK_LIB(png, png_read_info,
 248     [AC_CHECK_HEADER(png.h,
 249       png_ok=yes,
 250       png_ok=no)],
 251     AC_MSG_ERROR([PNG library (libpng) not found]), -lz -lm)
 252   if test "$png_ok" = yes; then
 253     AC_MSG_CHECKING([for png_structp in png.h])
 254     AC_TRY_COMPILE([#include <png.h>],
 255       [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 256       png_ok=yes,
 257       png_ok=no)
 258     AC_MSG_RESULT($png_ok)
 259     if test "$png_ok" = yes; then
 260       PNG_LIBS='-lpng -lz'
 261     else
 262       AC_MSG_ERROR([PNG library (libpng) not found])
 263     fi
 264   else
 265     AC_MSG_ERROR([PNG library (libpng) not found])
 266   fi
 267 fi
 268 AC_SUBST([PNG_LIBS])
 269
 270 # Check for WEBP Image support
 271 AC_CHECK_HEADERS([webp/decode.h], [WEBP_LIBS='-lwebp'], [AC_MSG_ERROR([WebP library (libwebp) not found])])
 272 AC_SUBST([WEBP_LIBS])
 273
 274 if test "$os_win32" = "yes"; then
 275   WINMM_LIBS=-lwinmm
 276   SHLWAPI_LIBS=-lshlwapi
 277   OLE32_LIBS=-lole32
 278 fi
 279 AC_SUBST([WINMM_LIBS])
 280 AC_SUBST([SHLWAPI_LIBS])
 281 AC_SUBST([OLE32_LIBS])
 282
 283
 284 # determine the GTK+ version to use
 285 AC_MSG_CHECKING([the GTK+ version to use])
 286 AC_ARG_WITH([gtk],
 287         [AS_HELP_STRING([--with-gtk=2.0|3.0], [the GTK+ version to use (default: 3.0)])],
 288         [case "$with_gtk" in
 289         2.0|3.0) ;;
 290         *) AC_MSG_ERROR([invalid GTK+ version specified]) ;;
 291         esac],
 292         [with_gtk=3.0])
 293 AC_MSG_RESULT([$with_gtk])
 294
 295 GTK2_REQUIRED_VERSION=2.10
 296 GAIL2_REQUIRED_VERSION=1.8
 297 GTK3_REQUIRED_VERSION=3.4.0
 298 GAIL3_REQUIRED_VERSION=3.0
 299
 300 case "$with_gtk" in
 301      2.0) GTK_REQUIRED_VERSION=$GTK2_REQUIRED_VERSION
 302           GTK_API_VERSION=2.0
 303           WEBKITGTK_API_MAJOR_VERSION=1
 304           WEBKITGTK_API_MINOR_VERSION=0
 305           WEBKITGTK_API_VERSION=1.0
 306           WEBKITGTK_PC_NAME=webkit
 307           GAIL_PC_NAME=gail
 308           GAIL_REQUIRED_VERSION=$GAIL2_REQUIRED_VERSION
 309           ;;
 310      3.0) GTK_REQUIRED_VERSION=$GTK3_REQUIRED_VERSION
 311           GTK_API_VERSION=3.0
 312           WEBKITGTK_API_MAJOR_VERSION=3
 313           WEBKITGTK_API_MINOR_VERSION=0
 314           WEBKITGTK_API_VERSION=3.0
 315           WEBKITGTK_PC_NAME=webkitgtk
 316           GAIL_PC_NAME=gail-3.0
 317           GAIL_REQUIRED_VERSION=$GAIL3_REQUIRED_VERSION
 318           ;;
 319 esac
 320
 321 AC_SUBST([WEBKITGTK_API_MAJOR_VERSION])
 322 AC_SUBST([WEBKITGTK_API_MINOR_VERSION])
 323 AC_SUBST([WEBKITGTK_API_VERSION])
 324 AC_SUBST([WEBKITGTK_PC_NAME])
 325 AC_SUBST([GTK_API_VERSION])
 326 AM_CONDITIONAL([GTK_API_VERSION_2],[test "$GTK_API_VERSION" = "2.0"])
 327
 328 # determine the GDK/GTK+ target
 329 AC_MSG_CHECKING([the target windowing system])
 330 AC_ARG_WITH(target,
 331             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
 332                            [Select webkit target [default=x11]]),
 333             [],[with_target="x11"])
 334
 335 case "$with_target" in
 336      x11|win32|quartz|directfb) ;;
 337      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
 338 esac
 339
 340 AC_MSG_RESULT([$with_target])
 341
 342 # minimum base dependencies
 343 CAIRO_REQUIRED_VERSION=1.10
 344 FONTCONFIG_REQUIRED_VERSION=2.4
 345 FREETYPE2_REQUIRED_VERSION=9.0
 346 GLIB_REQUIRED_VERSION=2.32.0
 347 LIBSOUP_REQUIRED_VERSION=2.40.0
 348 LIBXML_REQUIRED_VERSION=2.6
 349 PANGO_REQUIRED_VERSION=1.21.0
 350
 351 # optional modules
 352 LIBXSLT_REQUIRED_VERSION=1.1.7
 353 SQLITE_REQUIRED_VERSION=3.0
 354 ENCHANT_REQUIRED_VERSION=0.22
 355 CLUTTER_REQUIRED_VERSION=1.8.2
 356 CLUTTER_GTK_REQUIRED_VERSION=1.0.2
 357 ATSPI2_REQUIRED_VERSION=2.2.1
 358
 359 # Check for glib and required utilities
 360 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :, :, gmodule gobject gthread gio)
 361 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
 362    AC_MSG_ERROR([You need the GLib dev tools in your path])
 363 fi
 364
 365 # GResources
 366 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
 367 AC_SUBST(GLIB_COMPILE_RESOURCES)
 368
 369 GLIB_GSETTINGS
 370
 371 # Check and identify which unicode backend to use
 372 AC_MSG_CHECKING([which Unicode backend to use])
 373 AC_ARG_WITH(unicode_backend,
 374             AC_HELP_STRING([--with-unicode-backend=@<:@icu/glib@:>@],
 375                            [Select Unicode backend (WARNING: the glib-based backend is slow, and incomplete) [default=icu]]),
 376             [],[with_unicode_backend="icu"])
 377
 378 case "$with_unicode_backend" in
 379      icu|glib) ;;
 380      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu or glib.]) ;;
 381 esac
 382
 383 AC_MSG_RESULT([$with_unicode_backend])
 384
 385 if test "$with_unicode_backend" = "icu"; then
 386     # TODO: use pkg-config (after CFLAGS in their .pc files are cleaned up)
 387     case "$host" in
 388         *-*-darwin*)
 389             UNICODE_CFLAGS="-I$srcdir/Source/JavaScriptCore/icu -I$srcdir/Source/WebCore/icu"
 390             UNICODE_LIBS="-licucore"
 391             ;;
 392         *-*-mingw*)
 393             UNICODE_CFLAGS=""
 394             UNICODE_LIBS="-licui18n -licuuc"
 395             ;;
 396         *)
 397             AC_PATH_PROG(icu_config, icu-config, no)
 398             if test "$icu_config" = "no"; then
 399                 AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
 400             fi
 401
 402             # We don't use --cflags as this gives us a lot of things that we don't
 403             # necessarily want, like debugging and optimization flags
 404             # See man (1) icu-config for more info.
 405             UNICODE_CFLAGS=`$icu_config --cppflags`
 406             UNICODE_LIBS=`$icu_config --ldflags-libsonly`
 407             ;;
 408     esac
 409 fi
 410
 411 if test "$with_unicode_backend" = "glib"; then
 412     PKG_CHECK_MODULES([UNICODE], [glib-2.0 pango >= $PANGO_REQUIRED_VERSION])
 413 fi
 414
 415 AC_SUBST([UNICODE_CFLAGS])
 416 AC_SUBST([UNICODE_LIBS])
 417
 418 PKG_CHECK_MODULES([ZLIB], [zlib])
 419 AC_SUBST([ZLIB_CFLAGS])
 420 AC_SUBST([ZLIB_LIBS])
 421
 422 GETTEXT_PACKAGE=$PACKAGE-$GTK_API_VERSION
 423 AC_SUBST(GETTEXT_PACKAGE)
 424 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
 425                    [The gettext catalog name])
 426
 427 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED_VERSION)
 428 AC_SUBST(LIBXML_CFLAGS)
 429 AC_SUBST(LIBXML_LIBS)
 430
 431 PKG_CHECK_MODULES(PANGO,
 432                   [pango >= $PANGO_REQUIRED_VERSION
 433                    pangoft2])
 434 AC_SUBST(PANGO_CFLAGS)
 435 AC_SUBST(PANGO_LIBS)
 436
 437 AC_MSG_CHECKING([whether to enable spellcheck support])
 438 AC_ARG_ENABLE([spellcheck],
 439   [AS_HELP_STRING([--enable-spellcheck],[enable support for spellcheck])],
 440   [],[enable_spellcheck="yes"])
 441 AC_MSG_RESULT([$enable_spellcheck])
 442
 443 if test "$enable_spellcheck" = "yes"; then
 444 PKG_CHECK_MODULES(ENCHANT, enchant >= $ENCHANT_REQUIRED_VERSION, [], [enable_spellcheck="no"])
 445 AC_SUBST(ENCHANT_CFLAGS)
 446 AC_SUBST(ENCHANT_LIBS)
 447 fi
 448
 449 PKG_CHECK_MODULES(GAIL, $GAIL_PC_NAME >= $GAIL_REQUIRED_VERSION)
 450 AC_SUBST(GAIL_CFLAGS)
 451 AC_SUBST(GAIL_LIBS)
 452
 453 # check for target-specific dependencies
 454 if test "$with_target" = "directfb"; then
 455    PKG_CHECK_MODULES(CAIRO, cairo-directfb >= $CAIRO_REQUIRED_VERSION)
 456    PKG_CHECK_MODULES(GTK, gtk+-directfb-2.0 >= $GTK_REQUIRED_VERSION)
 457    AC_DEFINE([WTF_PLATFORM_DIRECTFB],[1],[Define if target is DirectFB])
 458 else
 459    PKG_CHECK_MODULES(CAIRO, cairo >= $CAIRO_REQUIRED_VERSION)
 460    PKG_CHECK_MODULES(GTK, gtk+-$GTK_API_VERSION >= $GTK_REQUIRED_VERSION)
 461
 462    if test "$with_target" = "x11" && test "$os_win32" = "no"; then
 463       # check for XT
 464       PKG_CHECK_MODULES([XT],
 465                         [xt],
 466                         [xt_has_pkg_config=yes],
 467                         [xt_has_pkg_config=no])
 468       # some old versions of Xt do not provide xt.pc, so try to link against Xt
 469       # and if it's installed fall back to just adding -lXt
 470       if test "$xt_has_pkg_config" = "no"; then
 471          # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
 472          # we don't care about the XtOpenDisplay symbol but only about the
 473          # existence of libXt
 474          AC_CHECK_LIB([Xt], [XtOpenDisplay],
 475                       [XT_CFLAGS=""; XT_LIBS="-lXt"],
 476                       [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
 477       fi
 478       AC_SUBST([XT_CFLAGS])
 479       AC_SUBST([XT_LIBS])
 480       AC_DEFINE([WTF_PLATFORM_X11],[1],[Define if target is X11])
 481    fi
 482 fi
 483 AC_SUBST(GTK_CFLAGS)
 484 AC_SUBST(GTK_LIBS)
 485 AC_SUBST(CAIRO_CFLAGS)
 486 AC_SUBST(CAIRO_LIBS)
 487
 488 # check whether to build with debugging enabled
 489 AC_MSG_CHECKING([whether to do a debug build])
 490 AC_ARG_ENABLE(debug,
 491               AC_HELP_STRING([--enable-debug],
 492                              [turn on debugging [default=no]]),
 493               [],[enable_debug="no"])
 494 AC_MSG_RESULT([$enable_debug])
 495
 496 # check whether to enable optimized builds
 497 AC_MSG_CHECKING([whether to enable optimized builds])
 498 AC_ARG_ENABLE(optimizations,
 499               AC_HELP_STRING([--enable-optimizations],
 500                              [turn on optimize builds (GCC only)
 501                              [default=yes]]),
 502               [enable_optimizations=$enableval],
 503               [if test "$enable_debug" = "yes"; then enable_optimizations="no"; else enable_optimizations="yes"; fi])
 504 AC_MSG_RESULT([$enable_optimizations])
 505
 506 found_opengl=no
 507 AC_ARG_ENABLE(glx,
 508               AC_HELP_STRING([--enable-glx], [enable support for GLX [default=auto]]),
 509               [], [enable_glx="auto"])
 510 AC_ARG_ENABLE(egl,
 511               AC_HELP_STRING([--enable-egl], [enable support for EGL [default=auto]]),
 512               [], [enable_egl="auto"])
 513 AC_ARG_ENABLE(gles2,
 514               AC_HELP_STRING([--enable-gles2], [enable support for OpenGL ES 2 [default=auto]]),
 515               [], [enable_gles2="auto"])
 516
 517 have_glx=no
 518 AC_CHECK_HEADERS([GL/glx.h], [have_glx="yes"], [have_glx="no"])
 519 AC_MSG_CHECKING([whether to enable GLX support])
 520 if test "$enable_glx" != "no"; then
 521    if test "$have_glx" = "no"; then
 522       if test "$enable_glx" = "yes"; then
 523          AC_MSG_ERROR([--enable-glx specified, but not available])
 524       else
 525          enable_glx=no
 526       fi
 527    elif test "$enable_gles2" != "yes"; then
 528       enable_glx=yes
 529    fi
 530 fi
 531 AC_MSG_RESULT([$enable_glx])
 532
 533 have_egl=no
 534 AC_CHECK_HEADERS([EGL/egl.h], [have_egl="yes"], [have_egl="no"])
 535 AC_MSG_CHECKING([whether to enable EGL support])
 536 if test "$enable_egl" != "no"; then
 537    if test "$have_egl" = "no"; then
 538       if test "$enable_egl" = "yes"; then
 539          AC_MSG_ERROR([--enable-egl specified, but not available])
 540       else
 541          enable_egl=no
 542       fi
 543    else
 544       enable_egl=yes
 545    fi
 546 fi
 547 AC_MSG_RESULT([$enable_egl])
 548
 549 have_gles2=no
 550 AC_CHECK_HEADERS([GLES2/gl2.h], [have_gles2="yes"], [have_gles2="no"])
 551 AC_MSG_CHECKING([whether to use OpenGL ES 2 support])
 552 if test "$enable_glx" = "yes"; then
 553    if test "$enable_gles2" = "yes"; then
 554       AC_MSG_ERROR([Cannot enable OpenGL ES 2 support with GLX])
 555    else
 556       enable_gles2=no
 557    fi
 558 fi
 559 if test "$enable_egl" = "no"; then
 560    if test "$enable_gles2" = "yes"; then
 561       AC_MSG_ERROR([Cannot enable OpenGL ES 2 support without EGL])
 562    else
 563       enable_gles2=no
 564    fi
 565 fi
 566 if test "$enable_gles2" != "no"; then
 567    if test "$have_gles2" = "no"; then
 568       if test "$enable_gles2" = "yes"; then
 569          AC_MSG_ERROR([--enable-gles2 specified, but not available])
 570       else
 571          enable_gles2=no
 572       fi
 573    else
 574       enable_gles2=yes
 575       found_opengl=yes
 576    fi
 577 fi
 578 AC_MSG_RESULT([$enable_gles2])
 579
 580 if test "$enable_gles2" != "yes"; then
 581     AC_CHECK_HEADERS([GL/gl.h], [found_opengl="yes"], [])
 582 fi
 583
 584 AC_MSG_CHECKING([which GPU acceleration backend to use])
 585 AC_ARG_WITH(acceleration_backend,
 586             AC_HELP_STRING([--with-acceleration-backend=@<:@opengl/clutter/none@:>@],
 587                            [Select accelerated backend (Clutter currently unsupported, OpenGL autodetected) [default=autodetect]]), [],
 588                            [
 589                                 if test "$found_opengl" = "yes"; then
 590                                    with_acceleration_backend="opengl";
 591                                 else
 592                                    with_acceleration_backend="none";
 593                                 fi
 594                            ])
 595 AC_MSG_RESULT([$with_acceleration_backend])
 596
 597 if test "$with_acceleration_backend" = "opengl"; then
 598     PKG_CHECK_MODULES([XCOMPOSITE], [xcomposite]);
 599     PKG_CHECK_MODULES([XDAMAGE], [xdamage]);
 600     AC_SUBST(XCOMPOSITE_CFLAGS)
 601     AC_SUBST(XCOMPOSITE_LIBS)
 602     AC_SUBST(XDAMAGE_CFLAGS)
 603     AC_SUBST(XDAMAGE_LIBS)
 604 fi
 605
 606 # OpenGL is turned on by default (along with WebGL and accelerated compositing), but if
 607 # Clutter is chosen as the accelerated drawing backend, we want to disable it. COGL does
 608 # not play well with OpenGL.
 609 AC_MSG_CHECKING([whether to enable WebGL support])
 610 AC_ARG_ENABLE(webgl,
 611               AC_HELP_STRING([--enable-webgl], [enable support for WebGL [default=check]]), [],
 612               [
 613                 if test "$with_acceleration_backend" = "opengl"; then
 614                     enable_webgl="yes";
 615                 else
 616                     enable_webgl="no";
 617                 fi
 618              ])
 619 AC_MSG_RESULT([$enable_webgl])
 620 if test "$enable_webgl" = "yes" && test "$with_acceleration_backend" != "opengl"; then
 621     AC_MSG_ERROR([OpenGL must be active (and Clutter disabled) to use WebGL.])
 622 fi;
 623
 624 AC_MSG_CHECKING([whether to enable accelerated compositing support])
 625 AC_ARG_ENABLE(accelerated_compositing,
 626             AC_HELP_STRING([--enable-accelerated-compositing], [enable support for accelerated compositing [default=check]]),
 627             [
 628                 if test "$enableval" = "yes" && test "$with_acceleration_backend" = "none"; then
 629                     AC_MSG_ERROR([OpenGL or Clutter must be active to use accelerated compositing.])
 630                 fi
 631                 enable_accelerated_compositing=$enableval;
 632             ],
 633             [
 634                 if test "$with_acceleration_backend" != "none"; then
 635                     enable_accelerated_compositing="yes";
 636                 else
 637                     enable_accelerated_compositing="no";
 638                 fi
 639             ])
 640 AC_MSG_RESULT([$enable_accelerated_compositing])
 641
 642 # check whether to enable Gamepad support
 643 AC_MSG_CHECKING([whether to enable Gamepad support])
 644 AC_ARG_ENABLE(gamepad,
 645               AC_HELP_STRING([--enable-gamepad],
 646                              [enable Gamepad support [default=no]]),
 647               [],[enable_gamepad="no"])
 648 AC_MSG_RESULT([$enable_gamepad])
 649
 650 if test "$enable_gamepad" = "yes" && test "$os_linux" = no; then
 651    AC_MSG_WARN([Gamepad support is only available on Linux. Disabling Gamepad support.])
 652    enable_gamepad=no;
 653 fi
 654
 655 # check whether to enable HTML5 audio/video support
 656 AC_MSG_CHECKING([whether to enable HTML5 video support])
 657 AC_ARG_ENABLE(video,
 658               AC_HELP_STRING([--enable-video],
 659                              [enable HTML5 video support [default=yes]]),
 660               [],[enable_video="yes"])
 661 AC_MSG_RESULT([$enable_video])
 662
 663 # check whether to enable media stream support
 664 AC_MSG_CHECKING([whether to enable media stream support])
 665 AC_ARG_ENABLE(media_stream,
 666               AC_HELP_STRING([--enable-media-stream],
 667                              [enable media stream support (incomplete) [default=no]]),
 668               [],[enable_media_stream="no"])
 669 AC_MSG_RESULT([$enable_media_stream])
 670
 671 # check whether to enable XSLT support
 672 AC_MSG_CHECKING([whether to enable XSLT support])
 673 AC_ARG_ENABLE(xslt,
 674               AC_HELP_STRING([--enable-xslt],
 675                              [enable support for XSLT [default=yes]]),
 676               [],[enable_xslt="yes"])
 677 AC_MSG_RESULT([$enable_xslt])
 678
 679 # check whether to enable geolocation support
 680 AC_MSG_CHECKING([whether to enable geolocation support])
 681 AC_ARG_ENABLE(geolocation,
 682               AC_HELP_STRING([--enable-geolocation],
 683                              [enable support for geolocation [default=yes]]),
 684               [],[enable_geolocation="yes"])
 685 AC_MSG_RESULT([$enable_geolocation])
 686
 687 # check whether to enable SVG support
 688 AC_MSG_CHECKING([whether to enable SVG support])
 689 AC_ARG_ENABLE(svg,
 690               AC_HELP_STRING([--enable-svg],
 691                              [enable support for SVG [default=yes]]),
 692               [],[enable_svg="yes"])
 693 AC_MSG_RESULT([$enable_svg])
 694
 695 # turn off svg features if --disable-svg is requested
 696 if test "$enable_svg" = "no"; then
 697    enable_svg_fonts=no
 698 fi
 699
 700 # check whether to enable support for SVG fonts
 701 AC_MSG_CHECKING([whether to enable support for SVG fonts])
 702 AC_ARG_ENABLE(svg_fonts,
 703               AC_HELP_STRING([--enable-svg-fonts],
 704                              [enable support for SVG fonts (experimental) [default=yes]]),
 705               [],[enable_svg_fonts="yes"])
 706 AC_MSG_RESULT([$enable_svg_fonts])
 707
 708 # check for SVG features, enabling SVG if necessary
 709 if test "$enable_svg_fonts" = "yes" && test "$enable_svg" = "no"; then
 710    AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
 711    enable_svg=yes
 712 fi
 713
 714 # check whether to enable Web Audio support
 715 AC_MSG_CHECKING([whether to enable Web Audio support])
 716 AC_ARG_ENABLE(web_audio,
 717               AC_HELP_STRING([--enable-web-audio],
 718                              [enable support for Web Audio [default=no]]),
 719               [],[enable_web_audio="no"])
 720 AC_MSG_RESULT([$enable_web_audio])
 721
 722 # check whether to enable code coverage
 723 AC_MSG_CHECKING([whether to enable code coverage support])
 724 AC_ARG_ENABLE(coverage,
 725               AC_HELP_STRING([--enable-coverage],
 726                              [enable code coverage support [default=no]]),
 727               [],[enable_coverage="no"])
 728 AC_MSG_RESULT([$enable_coverage])
 729
 730 # check whether to enable FastMalloc
 731 AC_MSG_CHECKING([whether to enable optimized memory allocator])
 732 AC_ARG_ENABLE(fast_malloc,
 733               AC_HELP_STRING([--enable-fast-malloc],
 734                              [enable optimized memory allocator default=yes, default=no for debug builds]),
 735               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
 736 AC_MSG_RESULT([$enable_fast_malloc])
 737
 738 # check whether to enable debug symbols
 739 AC_MSG_CHECKING([whether to enable debug symbols])
 740 AC_ARG_ENABLE(debug_symbols,
 741               AC_HELP_STRING([--enable-debug-symbols=yes|no|min|full],
 742                              [enable debug symbols default=no, default=yes for debug builds]),
 743               [],[if test "$enable_debug" = "yes"; then enable_debug_symbols="yes"; else enable_debug_symbols="no"; fi])
 744
 745 case "$enable_debug_symbols" in
 746   yes) enable_debug_symbols="full" ;;
 747   no|min|full) ;;
 748   *) AC_MSG_ERROR([Invalid debug symbols option: must be yes, no, min or full.]) ;;
 749 esac
 750 AC_MSG_RESULT([$enable_debug_symbols])
 751
 752 #selecting GStreamer version
 753 AC_MSG_CHECKING([the GStreamer version to use])
 754 AC_ARG_WITH([gstreamer],
 755         [AS_HELP_STRING([--with-gstreamer=1.0|0.10|auto], [the GStreamer version to use (default: auto, tries 1.0 first, 0.10 is fallback)])],
 756         [case "$with_gstreamer" in
 757         0.10|1.0|auto) ;;
 758         *) AC_MSG_ERROR([invalid GStreamer version specified]) ;;
 759         esac],
 760         [with_gstreamer=auto])
 761 AC_MSG_RESULT([$with_gstreamer])
 762
 763 GSTREAMER_0_10_REQUIRED_VERSION=0.10
 764 GSTREAMER_0_10_PLUGINS_BASE_REQUIRED_VERSION=0.10.30
 765 GSTREAMER_1_0_REQUIRED_VERSION=1.0.3
 766 GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION=1.0.3
 767
 768 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
 769    if test "$with_gstreamer" = "auto"; then
 770        gstreamer_modules="gstreamer-1.0 >= $GSTREAMER_1_0_REQUIRED_VERSION
 771                           gstreamer-app-1.0
 772                           gstreamer-audio-1.0
 773                           gstreamer-fft-1.0
 774                           gstreamer-base-1.0
 775                           gstreamer-pbutils-1.0
 776                           gstreamer-plugins-base-1.0 >= $GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION
 777                           gstreamer-video-1.0";
 778        PKG_CHECK_MODULES([GSTREAMER_1_0], [$gstreamer_modules], [with_gstreamer=1.0], [with_gstreamer=0.10])
 779        AC_MSG_NOTICE([Selected GStreamer $with_gstreamer])
 780    fi
 781 else
 782    if test "$with_gstreamer" != "auto"; then
 783        AC_MSG_WARN([You have specified GStreamer $with_gstreamer version but it will not be used because neither HTML5 Video nor Web Audio are enabled])
 784    fi
 785 fi
 786
 787 case "$with_gstreamer" in
 788      0.10) GSTREAMER_REQUIRED_VERSION=$GSTREAMER_0_10_REQUIRED_VERSION
 789            GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=$GSTREAMER_0_10_PLUGINS_BASE_REQUIRED_VERSION
 790            GST_API_VERSION=0.10
 791            ;;
 792      1.0) GSTREAMER_REQUIRED_VERSION=$GSTREAMER_1_0_REQUIRED_VERSION
 793            GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION=$GSTREAMER_1_0_PLUGINS_BASE_REQUIRED_VERSION
 794            GST_API_VERSION=1.0
 795            ;;
 796 esac
 797
 798 AC_SUBST([GST_API_VERSION])
 799 if test "$GST_API_VERSION" = "1.0"; then
 800    AC_DEFINE([GST_API_VERSION_1],[1], [Using GStreamer 1.0])
 801 fi
 802
 803 # check whether to enable debug features
 804 AC_MSG_CHECKING([whether to enable debug features])
 805 AC_ARG_ENABLE(debug_features,
 806               AC_HELP_STRING([--enable-debug-features],
 807                              [enable debug features default=no, default=yes for debug builds]),
 808               [],[if test "$enable_debug" = "yes"; then enable_debug_features="yes"; else enable_debug_features="no"; fi])
 809 AC_MSG_RESULT([$enable_debug_features])
 810
 811 AC_MSG_CHECKING([whether to enable JIT compilation])
 812 AC_ARG_ENABLE(jit,
 813               AS_HELP_STRING([--enable-jit],
 814                              [Enable JIT compilation (default: autodetect)]))
 815 case "$enable_jit" in
 816   yes) JSC_CPPFLAGS="-DENABLE_JIT=1" ;;
 817   no) JSC_CPPFLAGS="-DENABLE_JIT=0" ;;
 818   *) enable_jit="autodetect" ;;
 819 esac
 820 AC_SUBST(JSC_CPPFLAGS)
 821 AC_MSG_RESULT([$enable_jit])
 822
 823 # Opcode stats
 824 AC_MSG_CHECKING([whether to enable opcode stats])
 825 AC_ARG_ENABLE([opcode-stats],
 826   [AS_HELP_STRING([--enable-opcode-stats], [Enable Opcode statistics (default: disabled)])],
 827   [], [enable_opcode_stats=no])
 828 AC_MSG_RESULT([$enable_opcode_stats])
 829
 830 if test "$enable_opcode_stats" = "yes"; then
 831   if test "$enable_jit" = "yes"; then
 832     AC_MSG_ERROR([JIT must be disabled for Opcode stats to work.])
 833   fi
 834   AC_DEFINE([ENABLE_OPCODE_STATS], [1], [Define to enable Opcode statistics])
 835 fi
 836
 837 # GObject Introspection
 838 AC_MSG_CHECKING([whether to enable GObject introspection support])
 839 AC_ARG_ENABLE([introspection],
 840   [AS_HELP_STRING([--enable-introspection],[Enable GObject introspection (default: disabled)])],
 841   [],[enable_introspection=no])
 842 AC_MSG_RESULT([$enable_introspection])
 843
 844 # Enable CSS Filters and Shaders if accelerated_compositing is turned on.
 845 enable_css_filters=no;
 846 enable_css_shaders=no;
 847 AC_MSG_CHECKING([whether to enable CSS Filters and Shaders])
 848 if test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "opengl"; then
 849     enable_css_filters=yes;
 850     enable_css_shaders=yes;
 851 fi
 852 AC_MSG_RESULT([$enable_css_filters])
 853
 854 G_IR_SCANNER=
 855 G_IR_COMPILER=
 856 G_IR_GENERATE=
 857 GIRDIR=
 858 GIRTYPELIBDIR=
 859
 860 if test "$enable_introspection" = "yes"; then
 861   GOBJECT_INTROSPECTION_REQUIRED=0.9.5
 862   PKG_CHECK_MODULES([INTROSPECTION],[gobject-introspection-1.0 >= $GOBJECT_INTROSPECTION_REQUIRED])
 863
 864   G_IR_SCANNER="$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)"
 865   G_IR_COMPILER="$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)"
 866   G_IR_GENERATE="$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)"
 867   AC_DEFINE([ENABLE_INTROSPECTION],[1],[Define to enable GObject introspection support])
 868 fi
 869
 870 AC_SUBST([G_IR_SCANNER])
 871 AC_SUBST([G_IR_COMPILER])
 872 AC_SUBST([G_IR_GENERATE])
 873
 874 if test "$host_cpu" = "sh4"; then
 875    CXXFLAGS="$CXXFLAGS -mieee -w"
 876    CFLAGS="$CFLAGS -mieee -w"
 877 fi
 878
 879 # Add '-g' flag to gcc to build with debug symbols
 880 if test "$enable_debug_symbols" = "min"; then
 881    CXXFLAGS="$CXXFLAGS -g1"
 882    CFLAGS="$CFLAGS -g1"
 883 elif test "$enable_debug_symbols" != "no"; then
 884    CXXFLAGS="$CXXFLAGS -g"
 885    CFLAGS="$CFLAGS -g"
 886 fi
 887
 888 if test "$enable_debug_features" = "no"; then
 889    AC_DEFINE([NDEBUG], [1], [Define to disable debugging features])
 890 fi
 891
 892 # Add the appropriate 'O' level for optimized builds
 893 if test "$enable_optimizations" = "yes"; then
 894    CXXFLAGS="$CXXFLAGS -O2"
 895    CFLAGS="$CFLAGS -O2"
 896 else
 897    CXXFLAGS="$CXXFLAGS -O0"
 898    CFLAGS="$CFLAGS -O0"
 899 fi
 900
 901 PKG_CHECK_MODULES([LIBSOUP],
 902                   [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
 903 AC_SUBST([LIBSOUP_CFLAGS])
 904 AC_SUBST([LIBSOUP_LIBS])
 905
 906 PKG_CHECK_MODULES([LIBSECRET], [libsecret-1])
 907 AC_SUBST([LIBSECRET_CFLAGS])
 908 AC_SUBST([LIBSECRET_LIBS])
 909
 910 # check if FreeType/FontConfig are available
 911 if test "$with_target" = "directfb"; then
 912 PKG_CHECK_MODULES([FREETYPE],
 913                   [fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 914                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
 915                   harfbuzz])
 916 else
 917 PKG_CHECK_MODULES([FREETYPE],
 918                   [cairo-ft
 919                   fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 920                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
 921                   harfbuzz])
 922 fi
 923 AC_SUBST([FREETYPE_CFLAGS])
 924 AC_SUBST([FREETYPE_LIBS])
 925
 926 # check if SQLite3 is available. Error out only if one of the
 927 # features hard-depending on it is enabled while SQLite3 is
 928 # unavailable.
 929 PKG_CHECK_MODULES([SQLITE3],
 930                   [sqlite3 >= $SQLITE_REQUIRED_VERSION],
 931                   [sqlite3_has_pkg_config=yes],
 932                   [sqlite3_has_pkg_config=no])
 933 if test "$sqlite3_has_pkg_config" = "no"; then
 934    AC_SEARCH_LIBS([sqlite3_open16], [sqlite3],
 935                   [sqlite3_found=yes;SQLITE3_LIBS="$LIBS";SQLITE3_CFLAGS="-I $srcdir/WebKitLibraries/WebCoreSQLite3"],
 936                   [sqlite3_found=no])
 937 fi
 938 AC_SUBST([SQLITE3_CFLAGS])
 939 AC_SUBST([SQLITE3_LIBS])
 940
 941 if (test "$sqlite3_found" = "no"); then
 942    AC_MSG_ERROR([SQLite3 is required for the Database related features])
 943 fi
 944
 945 # check if libxslt is available
 946 if test "$enable_xslt" = "yes"; then
 947    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
 948    AC_SUBST([LIBXSLT_CFLAGS])
 949    AC_SUBST([LIBXSLT_LIBS])
 950 fi
 951
 952 # check if geoclue is available
 953 if test "$enable_geolocation" = "yes"; then
 954     PKG_CHECK_MODULES([GEOCLUE], [geoclue])
 955     AC_SUBST([GEOCLUE_CFLAGS])
 956     AC_SUBST([GEOCLUE_LIBS])
 957 fi
 958
 959 # check for XRender under Linux/Unix. Some linkers require explicit
 960 # linkage (like GNU Gold), so we cannot rely on GTK+ pulling XRender
 961 if test "$os_win32" = "no"; then
 962    PKG_CHECK_MODULES([XRENDER], [xrender])
 963    AC_SUBST([XRENDER_CFLAGS])
 964    AC_SUBST([XRENDER_LIBS])
 965 fi
 966
 967 # check if gstreamer is available
 968 if test "$enable_video" = "yes" || test "$enable_web_audio" = "yes"; then
 969     gstreamer_modules="gstreamer-$GST_API_VERSION >= $GSTREAMER_REQUIRED_VERSION
 970                        gstreamer-app-$GST_API_VERSION
 971                        gstreamer-audio-$GST_API_VERSION
 972                        gstreamer-fft-$GST_API_VERSION
 973                        gstreamer-base-$GST_API_VERSION
 974                        gstreamer-pbutils-$GST_API_VERSION
 975                        gstreamer-plugins-base-$GST_API_VERSION >= $GSTREAMER_PLUGINS_BASE_REQUIRED_VERSION
 976                        gstreamer-video-$GST_API_VERSION";
 977    if test "$GST_API_VERSION" != "1.0"; then
 978        gstreamer_modules="$gstreamer_modules gstreamer-interfaces-$GST_API_VERSION";
 979    fi
 980    PKG_CHECK_MODULES([GSTREAMER], [$gstreamer_modules], [have_gstreamer=yes])
 981    AC_SUBST([GSTREAMER_CFLAGS])
 982    AC_SUBST([GSTREAMER_LIBS])
 983 fi
 984
 985 # farstream-0.1 depends on gstreamer 0.10 currently. Disable
 986 # media_stream if gstreamer 1.0 build support is enabled.
 987 if test "$have_gstreamer" != "yes" || test "$GST_API_VERSION" = "1.0"; then
 988    if test "$enable_media_stream" = "yes"; then
 989       AC_MSG_WARN([Disabling Media Stream because no GStreamer 0.10 support is enabled])
 990    fi
 991    enable_media_stream=false
 992 fi
 993 if test "$enable_media_stream" = "yes"; then
 994    PKG_CHECK_MODULES([FARSTREAM], [farstream-0.1],
 995                      [have_farstream=yes], [enable_media_stream=false])
 996    AC_SUBST([FARSTREAM_CFLAGS])
 997    AC_SUBST([FARSTREAM_LIBS])
 998 fi
 999
1000 acceleration_backend_description=$with_acceleration_backend
1001 if test "$with_acceleration_backend" = "clutter"; then
1002    PKG_CHECK_MODULES(CLUTTER, clutter-1.0 >= $CLUTTER_REQUIRED_VERSION)
1003    PKG_CHECK_MODULES([CLUTTER_GTK],
1004                      [clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED_VERSION])
1005
1006    AC_SUBST(CLUTTER_CFLAGS)
1007    AC_SUBST(CLUTTER_LIBS)
1008    AC_SUBST(CLUTTER_GTK_CFLAGS)
1009    AC_SUBST(CLUTTER_GTK_LIBS)
1010
1011    enable_gles2=no
1012    enable_glx=no
1013    enable_egl=no
1014 fi
1015
1016 if test "$with_acceleration_backend" = "opengl"; then
1017    if test "$enable_gles2" = "yes"; then
1018     acceleration_backend_description+= "(gles2"
1019     OPENGL_LIBS="-lGLESv2"
1020    else
1021     acceleration_backend_description+="(gl"
1022     OPENGL_LIBS="-lGL"
1023    fi
1024    if test "$enable_egl" = "yes"; then
1025     acceleration_backend_description+=", egl"
1026     OPENGL_LIBS+=" -lEGL"
1027    fi
1028    if test "$enable_glx" = "yes"; then
1029     acceleration_backend_description+=", glx"
1030    fi
1031    OPENGL_LIBS+=" -ldl"
1032    acceleration_backend_description+=")"
1033 fi
1034 AC_SUBST([OPENGL_LIBS])
1035
1036 if test "$enable_gamepad" = "yes"; then
1037    PKG_CHECK_MODULES([GAMEPAD], [gio-unix-2.0 gudev-1.0])
1038
1039    AC_SUBST(GAMEPAD_CFLAGS)
1040    AC_SUBST(GAMEPAD_LIBS)
1041 fi
1042
1043 # check for code coverage support
1044 if test "$enable_coverage" = "yes"; then
1045    COVERAGE_CFLAGS="-MD"
1046    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
1047    AC_SUBST([COVERAGE_CFLAGS])
1048    AC_SUBST([COVERAGE_LDFLAGS])
1049 fi
1050
1051 # WebKit2
1052 # If you change the default here, please also make sure the assumptions made
1053 # in Tools/Scripts/webkitdirs.pm:buildAutotoolsProject still make sense.
1054 AC_MSG_CHECKING([whether to build Webkit2])
1055 AC_ARG_ENABLE(webkit2,
1056     AC_HELP_STRING([--enable-webkit2], [build webkit2 [default=yes]]),
1057     [], [enable_webkit2="yes"])
1058 AC_MSG_RESULT([$enable_webkit2])
1059 if test "$enable_webkit2" = "yes"; then
1060     if test "$GTK_API_VERSION" = "2.0"; then
1061         AC_MSG_ERROR([WebKit2 requires GTK+ 3.x, use --with-gtk=3.0])
1062     fi
1063
1064     # Make sure we have GTK+ 2.x to build the plugin process.
1065     PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= $GTK2_REQUIRED_VERSION gail >= $GAIL2_REQUIRED_VERSION)
1066     AC_SUBST(GTK2_CFLAGS)
1067     AC_SUBST(GTK2_LIBS)
1068
1069     # Check Unix printing
1070     PKG_CHECK_MODULES(GTK_UNIX_PRINTING, gtk+-unix-print-3.0,
1071                      [have_gtk_unix_printing=yes],
1072                      [have_gtk_unix_printing=no])
1073     AC_SUBST(GTK_UNIX_PRINTING_CFLAGS)
1074     AC_SUBST(GTK_UNIX_PRINTING_LIBS)
1075     if test "$have_gtk_unix_printing" = "yes"; then
1076         AC_DEFINE([HAVE_GTK_UNIX_PRINTING], [1], [Define if GTK+ UNIX Printing is available])
1077     fi
1078
1079     # On some Linux/Unix platforms, shm_* may only be available if linking
1080     # against librt
1081     if test "$os_win32" = "no"; then
1082         AC_SEARCH_LIBS([shm_open], [rt], [SHM_LIBS="-lrt"])
1083         AC_SUBST(SHM_LIBS)
1084     fi
1085 fi
1086
1087 GTK_DOC_CHECK([1.10])
1088
1089 # We need atspi2 for Webkit2 unit tests
1090 if test "$enable_webkit2" = "yes"; then
1091    PKG_CHECK_MODULES([ATSPI2],
1092                      [atspi-2 >= $ATSPI2_REQUIRED_VERSION],
1093                      [have_atspi2=yes], [have_atspi2=no])
1094
1095    AC_SUBST([ATSPI2_CFLAGS])
1096    AC_SUBST([ATSPI2_LIBS])
1097 fi
1098
1099 # OS conditionals
1100 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
1101 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
1102 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
1103 AM_CONDITIONAL([OS_GNU],[test "$os_gnu" = "yes"])
1104 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
1105
1106 # target conditionals
1107 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
1108 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
1109 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
1110 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
1111
1112 # Unicode backend conditionals
1113 AM_CONDITIONAL([USE_ICU_UNICODE], [test "$with_unicode_backend" = "icu"])
1114 AM_CONDITIONAL([USE_GLIB_UNICODE], [test "$with_unicode_backend" = "glib"])
1115
1116 # GStreamer feature conditional
1117 AM_CONDITIONAL([USE_GSTREAMER], [test "$have_gstreamer" = "yes"])
1118 AM_CONDITIONAL([USE_WEBAUDIO_GSTREAMER], [test "$enable_web_audio" = "yes"])
1119
1120 # ATSPI2 conditional
1121 AM_CONDITIONAL([HAVE_ATSPI2], [test "$have_atspi2" = "yes"])
1122
1123 # Accelerated compositing conditional
1124 AM_CONDITIONAL([USE_ACCELERATED_COMPOSITING], [test "$enable_accelerated_compositing" = "yes"])
1125 AM_CONDITIONAL([USE_TEXTURE_MAPPER_CAIRO], [test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "none"])
1126 AM_CONDITIONAL([USE_TEXTURE_MAPPER_GL], [test "$enable_accelerated_compositing" = "yes" && test "$with_acceleration_backend" = "opengl"])
1127 AM_CONDITIONAL([USE_CLUTTER], [test "$with_acceleration_backend" = "clutter"])
1128
1129 # These are the same now, but they will soon be separate.
1130 AM_CONDITIONAL([USE_OPENGL], [test "$with_acceleration_backend" = "opengl"])
1131 AM_CONDITIONAL([USE_EGL], [test "$enable_egl" = "yes"])
1132 AM_CONDITIONAL([USE_GLES2], [test "$enable_gles2" = "yes"])
1133 AM_CONDITIONAL([USE_GLX], [test "$enable_glx" = "yes"])
1134
1135 # Farstream feature conditional
1136 AM_CONDITIONAL([USE_FARSTREAM], [test "$have_farstream" = "yes"])
1137
1138 # WebKit feature conditionals
1139 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug_features" = "yes"])
1140 AM_CONDITIONAL([ENABLE_WEBGL],[test "$enable_webgl" = "yes"])
1141 AM_CONDITIONAL([ENABLE_GAMEPAD],[test "$enable_gamepad" = "yes"])
1142 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
1143 AM_CONDITIONAL([ENABLE_GEOLOCATION], [test "$enable_geolocation" = "yes"])
1144 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
1145 AM_CONDITIONAL([ENABLE_MEDIA_STREAM],[test "$enable_media_stream" = "yes"])
1146 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
1147 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
1148 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
1149 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
1150 AM_CONDITIONAL([ENABLE_WEB_AUDIO],[test "$enable_web_audio" = "yes"])
1151 AM_CONDITIONAL([ENABLE_OPCODE_STATS],[test "$enable_opcode_stats" = "yes"])
1152 AM_CONDITIONAL([ENABLE_WEBKIT2],[test "$enable_webkit2" = "yes"])
1153 AM_CONDITIONAL([ENABLE_SPELLCHECK],[test "$enable_spellcheck" = "yes"])
1154 AM_CONDITIONAL([ENABLE_CSS_FILTERS],[test "$enable_css_filters" = "yes"])
1155 AM_CONDITIONAL([ENABLE_CSS_SHADERS],[test "$enable_css_shaders" = "yes"])
1156
1157 # Gtk conditionals
1158 AM_CONDITIONAL([ENABLE_INTROSPECTION],[test "$enable_introspection" = "yes"])
1159
1160 AC_CONFIG_FILES([
1161 GNUmakefile
1162 ])
1163
1164
1165 AC_CONFIG_FILES([
1166 Source/WebKit/gtk/webkit/webkitversion.h
1167 Source/WebKit/gtk/po/POTFILES
1168 DerivedSources/WebCore/UserAgentGtk.h:Source/WebCore/platform/gtk/UserAgentGtk.h.in
1169 ])
1170
1171 AC_CONFIG_FILES([
1172 Source/WebKit/gtk/${WEBKITGTK_PC_NAME}-${WEBKITGTK_API_VERSION}.pc:Source/WebKit/gtk/webkit.pc.in
1173 Source/WebKit/gtk/JSCore-${WEBKITGTK_API_VERSION}.gir:Source/WebKit/gtk/JSCore.gir.in
1174 Source/JavaScriptCore/javascriptcoregtk-${WEBKITGTK_API_VERSION}.pc:Source/JavaScriptCore/javascriptcoregtk.pc.in
1175 ]
1176 ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
1177 )
1178
1179
1180 if test "$enable_webkit2" = "yes"; then
1181     AC_CONFIG_FILES([
1182     DerivedSources/WebKit2/webkit2gtk/webkit2/WebKitVersion.h:Source/WebKit2/UIProcess/API/gtk/WebKitVersion.h.in
1183     ])
1184
1185     AC_CONFIG_FILES([
1186     Source/WebKit2/webkit2gtk-${WEBKITGTK_API_VERSION}.pc:Source/WebKit2/webkit2gtk.pc.in
1187     ]
1188     ,[WEBKITGTK_API_VERSION=$WEBKITGTK_API_VERSION,WEBKITGTK_PC_NAME=$WEBKITGTK_PC_NAME]
1189     )
1190 fi
1191
1192 AC_OUTPUT
1193
1194 echo "
1195 WebKit was configured with the following options:
1196
1197 Build configuration:
1198  Enable debugging (slow)                                  : $enable_debug
1199  Compile with debug symbols (slow)                        : $enable_debug_symbols
1200  Enable debug features (slow)                             : $enable_debug_features
1201  Enable GCC build optimization                            : $enable_optimizations
1202  Code coverage support                                    : $enable_coverage
1203  Unicode backend                                          : $with_unicode_backend
1204  Optimized memory allocator                               : $enable_fast_malloc
1205  Accelerated rendering backend                            : $acceleration_backend_description
1206
1207 Features:
1208 =======
1209  WebKit2 support                                          : $enable_webkit2
1210  Accelerated Compositing                                  : $enable_accelerated_compositing
1211  Gamepad support                                          : $enable_gamepad
1212  Geolocation support                                      : $enable_geolocation
1213  HTML5 video element support                              : $enable_video
1214  JIT compilation                                          : $enable_jit
1215  Media stream support                                     : $enable_media_stream
1216  Opcode stats                                             : $enable_opcode_stats
1217  SVG fonts support                                        : $enable_svg_fonts
1218  SVG support                                              : $enable_svg
1219  Spellcheck support                                       : $enable_spellcheck
1220  Web Audio support                                        : $enable_web_audio
1221  WebGL                                                    : $enable_webgl
1222  XSLT support                                             : $enable_xslt
1223
1224
1225 GTK+ configuration:
1226  GTK+ version                                             : $with_gtk
1227  GDK target                                               : $with_target
1228  GStreamer version                                        : $with_gstreamer
1229  Introspection support                                    : $enable_introspection
1230  Generate documentation                                   : $enable_gtk_doc
1231 "
1232 if test "$with_unicode_backend" = "glib"; then
1233    echo "     >> WARNING: the glib-based unicode backend is slow and incomplete <<"
1234    echo
1235    echo
1236 fi