Adds an overlay window that covers the scripts panel and
[WebKit-https.git] / configure.ac
1 AC_INIT([WebKit],[0.1],[http://bugs.webkit.org/])
2
3 AC_PREREQ(2.59)
4
5 AC_CONFIG_HEADERS([aconfig.h])
6 AC_CONFIG_SRCDIR([WebCore/config.h])
7
8 # see http://www.gnu.org/software/libtool/manual.html#Versioning
9 LIBWEBKITGTK_VERSION=1:0:0
10 AC_SUBST([LIBWEBKITGTK_VERSION])
11
12 AM_INIT_AUTOMAKE([foreign subdir-objects])
13
14 AC_CANONICAL_HOST
15
16 # host checking - inspired by the GTK+ configure.in
17 # TODO: os_mac, os_bsd
18 AC_MSG_CHECKING([for native Win32])
19 case "$host" in
20      *-*-mingw*)
21        os_win32=yes
22        ;;
23      *)
24        os_win32=no
25        ;;
26 esac
27 AC_MSG_RESULT([$os_win32])
28
29 case "$host" in
30      *-*-linux*)
31        os_linux=yes
32        ;;
33      *-*-freebsd*)
34        os_freebsd=yes
35        ;;
36      *-*-darwin*)
37        os_darwin=yes
38        ;;
39 esac
40
41 # If CXXFLAGS and CFLAGS are unset, default to -O2
42 # This is to tell automake not to include '-g' if CXXFLAGS is not set
43 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
44 if test -z "$CXXFLAGS"; then
45    CXXFLAGS="-O2"
46 fi
47 if test -z "$CFLAGS"; then
48    CFLAGS="-O2"
49 fi
50
51 # programs
52 AC_DISABLE_STATIC
53 AM_PROG_LIBTOOL
54 AC_PROG_INSTALL
55 AM_PROG_CC_STDC
56 AC_PROG_CXX
57 AM_PROG_CC_C_O
58
59 # check for -fvisibility=hidden compiler support (GCC >= 4)
60 saved_CFLAGS="$CFLAGS"
61 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
62 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
63 AC_COMPILE_IFELSE([char foo;],
64       [ AC_MSG_RESULT([yes])
65         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
66         AC_MSG_RESULT([no]))
67 CFLAGS="$saved_CFLAGS"
68 AC_SUBST(SYMBOL_VISIBILITY)
69 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
70
71 AC_PATH_PROG(PERL, perl)
72 if test -z "$PERL"; then
73    AC_MSG_ERROR([You need 'perl' to compile WebKit])
74 fi
75
76 AC_PATH_PROG(BISON, bison)
77 if test -z "$BISON"; then
78    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
79 fi
80
81 AC_PATH_PROG(FLEX, flex)
82 if test -z "$FLEX"; then
83    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
84 fi
85
86 AC_PATH_PROG(GPERF, gperf)
87 if test -z "$GPERF"; then
88    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
89 fi
90
91 AC_PATH_PROG(MV, mv)
92 if test -z "$MV"; then
93    AC_MSG_ERROR([You need 'mv' to compile WebKit])
94 fi
95
96 # GTK+ port only
97 # Check for glib-genmarshal and glib-mkenums
98 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
99 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
100 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
101    AC_MSG_ERROR([You need the GLib dev tools in your path])
102 fi
103
104 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
105 # doesn't exist)
106 AC_LANG_PUSH([C++])
107 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
108 AC_LANG_POP([C++])
109
110 # C/C++ Language Features
111 AC_C_CONST
112 AC_C_INLINE
113 AC_C_VOLATILE
114
115 # C/C++ Headers
116 AC_HEADER_STDC
117 AC_HEADER_STDBOOL
118
119 # pthread (not needed on Windows)
120 if test "$os_win32" = "no"; then
121 AC_CHECK_HEADERS([pthread.h],
122                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
123                  AC_MSG_ERROR([pthread support is required to build WebKit]))
124 fi
125
126 # libjpeg headers
127 AC_CHECK_HEADERS([jpeglib.h])
128
129 # check for pkg-config
130 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
131 if test "$PKG_CONFIG" = "no"; then
132    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
133 fi
134
135 # determine the Unicode backend
136 AC_MSG_CHECKING([the Unicode backend to use])
137 AC_ARG_WITH(unicode_backend,
138             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
139                            [Select Unicode backend [default=icu]]),
140             [],[unicode_backend="icu"])
141
142 case "$unicode_backend" in
143      icu) ;;
144      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
145 esac
146
147 AC_MSG_RESULT([$unicode_backend])
148
149 if test "$unicode_backend" = "icu"; then
150         # check for icu-config
151         if test "$os_darwin" = "yes"; then
152                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
153                 UNICODE_LIBS="-licucore"
154         else
155                 AC_PATH_PROG(icu_config, icu-config, no)
156                 if test "$icu_config" = "no"; then
157                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
158                 fi
159
160                 # We don't use --cflags as this gives us a lot of things that we don't
161                 # necessarily want, like debugging and optimization flags
162                 # See man (1) icu-config for more info.
163                 UNICODE_CFLAGS=`$icu_config --cppflags`
164                 UNICODE_LIBS=`$icu_config --ldflags`
165         fi
166 fi
167
168 AC_SUBST([UNICODE_CFLAGS])
169 AC_SUBST([UNICODE_LIBS])
170
171 # determine the GDK/GTK+ target
172 AC_MSG_CHECKING([the target windowing system])
173 AC_ARG_WITH(target,
174             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
175                            [Select webkit target [default=x11]]),
176             [],[with_target="x11"])
177
178 case "$with_target" in
179      x11|win32|quartz|directfb) ;;
180      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
181 esac
182
183 AC_MSG_RESULT([$with_target])
184
185 AC_MSG_CHECKING([for Hildon UI extensions])
186 AC_ARG_WITH(hildon,
187             AC_HELP_STRING([--with-hildon],
188                            [Use Hildon UI extensions [default=no]]),
189             [],[with_hildon="no"])
190 AC_MSG_RESULT([$with_hildon])
191
192 if test "$with_hildon" = "yes"; then
193     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
194     PKG_CHECK_MODULES([HILDON], [hildon-1])
195     AC_SUBST([HILDON_CPPFLAGS])
196     AC_SUBST([HILDON_CFLAGS])
197     AC_SUBST([HILDON_LIBS])
198 fi
199
200 # determine the http backend
201 AC_MSG_CHECKING([the HTTP backend to use])
202 AC_ARG_WITH(http_backend,
203             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
204                            [Select HTTP backend [default=curl]]),
205             [],[with_http_backend="curl"])
206
207 case "$with_http_backend" in
208      curl|soup) ;;
209      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
210 esac
211
212 AC_MSG_RESULT([$with_http_backend])
213
214 # minimum base dependencies
215 CAIRO_REQUIRED_VERSION=1.4
216 FONTCONFIG_REQUIRED_VERSION=2.4
217 FREETYPE2_REQUIRED_VERSION=9.0
218 LIBXML_REQUIRED_VERSION=2.6
219
220 # minimum GTK+ base dependencies
221 GLIB_REQUIRED_VERSION=2.0
222 GOBJECT_REQUIRED_VERSION=2.0
223 GTHREAD_REQUIRED_VERSION=2.0
224 PANGO_REQUIRED_VERSION=1.0
225 GTK_REQUIRED_VERSION=2.8
226
227 # optional modules
228 LIBCURL_REQUIRED_VERSION=7.15
229 LIBSOUP_REQUIRED_VERSION=2.23
230 LIBXSLT_REQUIRED_VERSION=1.1.7
231 SQLITE_REQUIRED_VERSION=3.0
232 GSTREAMER_REQUIRED_VERSION=0.10
233 GNOME_VFS_REQUIRED_VERSION=2.0
234
235 PKG_CHECK_MODULES([GLOBALDEPS],
236                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
237                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
238                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
239 AC_SUBST([GLOBALDEPS_CFLAGS])
240 AC_SUBST([GLOBALDEPS_LIBS])
241
242 PKG_CHECK_MODULES([WEBKITDEPS],
243                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
244                   pango >= $PANGO_REQUIRED_VERSION
245                   cairo >= $CAIRO_REQUIRED_VERSION
246                   cairo-ft,
247                   fontconfig >= $FONTCONFIG_REQUIRED_VERSION
248                   freetype2 >= $FREETYPE2_REQUIRED_VERSION
249                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
250 AC_SUBST([WEBKITDEPS_CFLAGS])
251 AC_SUBST([WEBKITDEPS_LIBS])
252
253 # check whether to build with debugging enabled
254 AC_MSG_CHECKING([whether to do a debug build])
255 AC_ARG_ENABLE(debug,
256               AC_HELP_STRING([--enable-debug],
257                              [turn on debugging [default=no]]),
258               [],[enable_debug="no"])
259 AC_MSG_RESULT([$enable_debug])
260
261 # check whether to enable dashboard support
262 AC_MSG_CHECKING([whether to enable Dashboard support])
263 AC_ARG_ENABLE(dashboard_support,
264               AC_HELP_STRING([--enable-dashboard-support],
265                              [enable Dashboard support [default=yes]]),
266               [],[enable_dashboard_support="yes"])
267 AC_MSG_RESULT([$enable_dashboard_support])
268
269 # check whether to build with cross-document messaging support
270 AC_MSG_CHECKING([whether to enable HTML5 cross-document messaging support])
271 AC_ARG_ENABLE(cross_document_messaging,
272               AC_HELP_STRING([--enable-cross-document-messaging],
273                              [enable HTML5 cross-document messaging support [default=yes]]),
274               [],[enable_cross_document_messaging="yes"])
275 AC_MSG_RESULT([$enable_cross_document_messaging])
276
277 # check whether to enable HTML5 Offline Web Applications support
278 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
279 AC_ARG_ENABLE(offline_web_applications,
280               AC_HELP_STRING([--enable-offline-web-applications],
281                              [enable HTML5 offline web applications support [default=yes]]),
282               [],[enable_offline_web_applications="yes"])
283 AC_MSG_RESULT([$enable_offline_web_applications])
284
285 # check whether to enable HTML5 client-side session and persitent storage support
286 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
287 AC_ARG_ENABLE(dom_storage,
288               AC_HELP_STRING([--enable-dom-storage],
289                              [enable HTML5 client-side session and persistent storage support [default=no]]),
290               [],[enable_dom_storage="no"])
291 AC_MSG_RESULT([$enable_dom_storage])
292
293 # check whether to build with database support
294 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
295 AC_ARG_ENABLE(database,
296               AC_HELP_STRING([--enable-database],
297                              [enable HTML5 client-side database storage support [default=yes]]),
298               [],[enable_database="yes"])
299 AC_MSG_RESULT([$enable_database])
300
301 # check whether to build with icon database support
302 AC_MSG_CHECKING([whether to enable icon database support])
303 AC_ARG_ENABLE(icon_database,
304               AC_HELP_STRING([--enable-icon-database],
305                              [enable icon database [default=no]]),
306               [],[enable_icon_database="no"])
307 AC_MSG_RESULT([$enable_icon_database])
308
309 # check whether to enable HTML5 audio/video support
310 AC_MSG_CHECKING([whether to enable HTML5 video support])
311 AC_ARG_ENABLE(video,
312               AC_HELP_STRING([--enable-video],
313                              [enable HTML5 video support [default=no]]),
314               [],[enable_video="no"])
315 AC_MSG_RESULT([$enable_video])
316
317 # check whether to enable XPath support
318 AC_MSG_CHECKING([whether to enable XPath support])
319 AC_ARG_ENABLE(xpath,
320               AC_HELP_STRING([--enable-xpath],
321                              [enable support for XPath [default=yes]]),
322               [],[enable_xpath="yes"])
323 AC_MSG_RESULT([$enable_xpath])
324
325 # check whether to enable XSLT support
326 AC_MSG_CHECKING([whether to enable XSLT support])
327 AC_ARG_ENABLE(xslt,
328               AC_HELP_STRING([--enable-xslt],
329                              [enable support for XSLT [default=yes]]),
330               [],[enable_xslt="yes"])
331 AC_MSG_RESULT([$enable_xslt])
332
333 # check whether to enable SVG experimental features
334 # Enable all SVG if it is
335 AC_MSG_CHECKING([whether to enable SVG experimental features])
336 AC_ARG_ENABLE(svg_experimental,
337               AC_HELP_STRING([--enable-svg-experimental],
338                              [enable support for SVG experimental features [default=no]]),
339               [],[enable_svg_experimental="no"])
340 AC_MSG_RESULT([$enable_svg_experimental])
341
342 if test "$enable_svg_experimental" = "yes"; then
343    enable_svg=yes
344    enable_svg_animation=yes
345 #   enable_svg_filters=yes
346    enable_svg_fonts=yes
347    enable_svg_foreign_object=yes
348    enable_svg_as_image=yes
349    enable_svg_use_element=yes
350 fi
351
352 # check whether to enable SVG support
353 AC_MSG_CHECKING([whether to enable SVG support])
354 AC_ARG_ENABLE(svg,
355               AC_HELP_STRING([--enable-svg],
356                              [enable support for SVG [default=no]]),
357               [],[enable_svg="no"])
358 AC_MSG_RESULT([$enable_svg])
359
360 # check whether to enable support for SVG animation
361 AC_MSG_CHECKING([whether to enable support for SVG animation])
362 AC_ARG_ENABLE(svg_animation,
363               AC_HELP_STRING([--enable-svg-animation],
364                              [enable support for SVG animation (experimental) [default=no]]),
365               [],[enable_svg_animation="no"])
366 AC_MSG_RESULT([$enable_svg_animation])
367
368 # check whether to enable support for SVG filters
369 AC_MSG_CHECKING([whether to enable support for SVG filters])
370 AC_ARG_ENABLE(svg_filters,
371               AC_HELP_STRING([--enable-svg-filters],
372                              [enable support for SVG filters (experimental) [default=no]]),
373               [],[enable_svg_filters="no"])
374 AC_MSG_RESULT([$enable_svg_filters])
375
376 # check whether to enable support for SVG fonts
377 AC_MSG_CHECKING([whether to enable support for SVG fonts])
378 AC_ARG_ENABLE(svg_fonts,
379               AC_HELP_STRING([--enable-svg-fonts],
380                              [enable support for SVG fonts (experimental) [default=no]]),
381               [],[enable_svg_fonts="no"])
382 AC_MSG_RESULT([$enable_svg_fonts])
383
384 # check whether to enable foreign objects support for SVG
385 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
386 AC_ARG_ENABLE(svg_foreign_object,
387               AC_HELP_STRING([--enable-svg-foreign-object],
388                              [enable support for SVG foreign objects (experimental) [default=no]]),
389               [],[enable_svg_foreign_object="no"])
390 AC_MSG_RESULT([$enable_svg_foreign_object])
391
392 # check whether to enable SVG As Image support
393 AC_MSG_CHECKING([whether to enable SVG as Image support])
394 AC_ARG_ENABLE(svg_as_image,
395               AC_HELP_STRING([--enable-svg-as-image],
396                              [enable SVG as Image support (experimental) [default=no]]),
397               [],[enable_svg_as_image="no"])
398 AC_MSG_RESULT([$enable_svg_as_image])
399
400 # check whether to enable SVG USE element support
401 AC_MSG_CHECKING([whether to enable support for SVG use element])
402 AC_ARG_ENABLE(svg_use_element,
403               AC_HELP_STRING([--enable-svg-use-element],
404                              [enable SVG use element support (experimental) [default=no]]),
405               [],[enable_svg_use_element="no"])
406 AC_MSG_RESULT([$enable_svg_use_element])
407
408 # check whether to enable code coverage
409 AC_MSG_CHECKING([whether to enable code coverage support])
410 AC_ARG_ENABLE(coverage,
411               AC_HELP_STRING([--enable-coverage],
412                              [enable code coverage support [default=no]]),
413               [],[enable_coverage="no"])
414 AC_MSG_RESULT([$enable_coverage])
415
416 # check whether to enable FastMalloc
417 AC_MSG_CHECKING([whether to enable optimized memory allocator])
418 AC_ARG_ENABLE(fast_malloc,
419               AC_HELP_STRING([--enable-fast-malloc],
420                              [enable optimized memory allocator default=yes, default=no for debug builds]),
421               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
422 AC_MSG_RESULT([$enable_fast_malloc])
423
424 # determine the font backend
425 AC_MSG_CHECKING([the font backend to use])
426 AC_ARG_WITH(font_backend,
427             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
428                            [Select font backend [default=freetype]]),
429             [],[with_font_backend="freetype"])
430
431 case "$with_font_backend" in
432      freetype|pango) ;;
433      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
434 esac
435 AC_MSG_RESULT([$with_font_backend])
436
437 # Add '-g' flag to gcc if it's debug build
438 if test "$enable_debug" = "yes"; then
439    CXXFLAGS="$CXXFLAGS -g"
440    CFLAGS="$CFLAGS -g"
441 fi
442
443 # check if curl is available
444 if test "$with_http_backend" = "curl"; then
445    PKG_CHECK_MODULES([LIBCURL],
446                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
447    AC_SUBST([LIBCURL_CFLAGS])
448    AC_SUBST([LIBCURL_LIBS])
449 fi
450
451 if test "$with_http_backend" = "soup"; then
452    PKG_CHECK_MODULES([LIBSOUP],
453                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
454    AC_SUBST([LIBSOUP_CFLAGS])
455    AC_SUBST([LIBSOUP_LIBS])
456 fi
457
458 # check if sqlite 3 is available
459 if test "$enable_icon_database" = "yes" || test "$enable_database" = "yes"; then
460    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
461    AC_SUBST([SQLITE3_CFLAGS])
462    AC_SUBST([SQLITE3_LIBS])
463 fi
464
465 # check if libxslt is available
466 if test "$enable_xslt" = "yes"; then
467    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
468    AC_SUBST([LIBXSLT_CFLAGS])
469    AC_SUBST([LIBXSLT_LIBS])
470 fi
471
472 # check if gstreamer is available
473 if test "$enable_video" = "yes"; then
474    PKG_CHECK_MODULES([GSTREAMER],
475                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
476                      gstreamer-base-0.10,
477                      gstreamer-plugins-base-0.10,
478                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
479    AC_SUBST([GSTREAMER_CFLAGS])
480    AC_SUBST([GSTREAMER_LIBS])
481 fi
482
483 # check for code coverage support
484 if test "$enable_coverage" = "yes"; then
485    COVERAGE_CFLAGS="-MD"
486    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
487    AC_SUBST([COVERAGE_CFLAGS])
488    AC_SUBST([COVERAGE_LDFLAGS])
489 fi
490
491 # check for SVG features, enabling SVG if necessary
492 if test "$enable_svg_animation" = "yes" || \
493    test "$enable_svg_filters" = "yes" || \
494    test "$enable_svg_fonts" = "yes" || \
495    test "$enable_svg_foreign_object" = "yes" || \
496    test "$enable_svg_as_image" = "yes" || \
497    test "$enable_svg_use_element" = "yes"; then
498    svg_flags=yes
499    if test "$enable_svg" = "no"; then
500        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
501        enable_svg=yes
502    fi
503 fi
504
505 # OS conditionals
506 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
507 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
508 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
509 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
510
511 # target conditionals
512 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
513 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
514 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
515 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
516
517 # HTTP backend conditionals
518 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
519 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
520
521 # Font backend conditionals
522 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
523 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
524
525 # WebKit feature conditionals
526 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
527 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
528 AM_CONDITIONAL([ENABLE_CROSS_DOCUMENT_MESSAGING],[test "$enable_cross_document_messaging" = "yes"])
529 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
530 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
531 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
532 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
533 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
534 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
535 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
536 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
537 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
538 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
539 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
540 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
541 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
542 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
543 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
544 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
545 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
546
547 AC_CONFIG_FILES([
548 GNUmakefile
549 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
550 ]
551 )
552
553 AC_OUTPUT
554
555 echo "
556 WebKit was configured with the following options:
557
558 Build configuration:
559  Enable debugging (slow)                                  : $enable_debug
560  Code coverage support                                    : $enable_coverage
561  Unicode backend                                          : $unicode_backend
562  HTTP backend                                             : $with_http_backend
563  Font backend                                             : $with_font_backend
564  Optimized memory allocator                               : $enable_fast_malloc
565 Features:
566  Dashboard support                                        : $enable_dashboard_support
567  HTML5 cross-document messaging                           : $enable_cross_document_messaging
568  HTML5 offline web applications support                   : $enable_offline_web_applications
569  HTML5 client-side session and persistent storage support : $enable_dom_storage
570  HTML5 client-side database storage support               : $enable_database
571  HTML5 video element support                              : $enable_video
572  Icon database support                                    : $enable_icon_database
573  SVG support                                              : $enable_svg
574  SVG animation support                                    : $enable_svg_animation
575  SVG filters support                                      : $enable_svg_filters
576  SVG fonts support                                        : $enable_svg_fonts
577  SVG foreign object support                               : $enable_svg_foreign_object
578  SVG as image support                                     : $enable_svg_as_image
579  SVG use element support                                  : $enable_svg_use_element
580  XPATH support                                            : $enable_xpath
581  XSLT support                                             : $enable_xslt
582 GTK+ configuration:
583  GDK target                                               : $with_target
584  Hildon UI extensions                                     : $with_hildon
585 "