Still fixing Windows build.
[WebKit-https.git] / configure.ac
1 AC_PREREQ(2.59)
2
3 m4_define([webkit_major_version], [1])
4 m4_define([webkit_minor_version], [0])
5 m4_define([webkit_micro_version], [2])
6
7 AC_INIT([WebKit],[webkit_major_version.webkit_minor_version.webkit_micro_version],[http://bugs.webkit.org/])
8
9 AC_CONFIG_HEADERS([aconfig.h])
10
11 WEBKIT_MAJOR_VERSION=webkit_major_version
12 WEBKIT_MINOR_VERSION=webkit_minor_version
13 WEBKIT_MICRO_VERSION=webkit_micro_version
14 AC_SUBST(WEBKIT_MAJOR_VERSION)
15 AC_SUBST(WEBKIT_MINOR_VERSION)
16 AC_SUBST(WEBKIT_MICRO_VERSION)
17
18 AC_CONFIG_SRCDIR([WebCore/config.h])
19
20 dnl # Libtool library version, not to confuse with API version
21 dnl # see http://www.gnu.org/software/libtool/manual.html#Versioning
22 LIBWEBKITGTK_VERSION=1:0:0
23 AC_SUBST([LIBWEBKITGTK_VERSION])
24
25 AM_INIT_AUTOMAKE([foreign subdir-objects])
26
27 AC_CANONICAL_HOST
28
29 # host checking - inspired by the GTK+ configure.in
30 # TODO: os_mac, os_bsd
31 AC_MSG_CHECKING([for native Win32])
32 case "$host" in
33      *-*-mingw*)
34        os_win32=yes
35        ;;
36      *)
37        os_win32=no
38        ;;
39 esac
40 AC_MSG_RESULT([$os_win32])
41
42 case "$host" in
43      *-*-linux*)
44        os_linux=yes
45        ;;
46      *-*-freebsd*)
47        os_freebsd=yes
48        ;;
49      *-*-darwin*)
50        os_darwin=yes
51        ;;
52 esac
53
54 # If CXXFLAGS and CFLAGS are unset, default to empty.
55 # This is to tell automake not to include '-g' if CXXFLAGS is not set
56 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
57 if test -z "$CXXFLAGS"; then
58    CXXFLAGS=""
59 fi
60 if test -z "$CFLAGS"; then
61    CFLAGS=""
62 fi
63
64 AM_PROG_CC_STDC
65 AM_PROG_CC_C_O
66 AC_PROG_CXX
67 AC_PROG_INSTALL
68 AC_DISABLE_STATIC
69 AC_LIBTOOL_WIN32_DLL
70 AC_PROG_LIBTOOL
71 DOLT
72
73 # check for -fvisibility=hidden compiler support (GCC >= 4)
74 saved_CFLAGS="$CFLAGS"
75 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
76 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
77 AC_COMPILE_IFELSE([char foo;],
78       [ AC_MSG_RESULT([yes])
79         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
80         AC_MSG_RESULT([no]))
81 CFLAGS="$saved_CFLAGS"
82 AC_SUBST(SYMBOL_VISIBILITY)
83 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
84
85 AC_PATH_PROG(PERL, perl)
86 if test -z "$PERL"; then
87    AC_MSG_ERROR([You need 'perl' to compile WebKit])
88 fi
89
90 AC_PATH_PROG(BISON, bison)
91 if test -z "$BISON"; then
92    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
93 fi
94
95 AC_PATH_PROG(FLEX, flex)
96 if test -z "$FLEX"; then
97    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
98 else
99    FLEX_VERSION=`$FLEX --version | sed 's,.*\ \([0-9]*\.[0-9]*\.[0-9]*\)$,\1,'`
100    AX_COMPARE_VERSION([2.5.33],[gt],[$FLEX_VERSION],
101       AC_MSG_WARN([You need at least version 2.5.33 of the 'flex' lexer generator to compile WebKit correctly]))
102 fi
103
104 AC_PATH_PROG(GPERF, gperf)
105 if test -z "$GPERF"; then
106    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
107 fi
108
109 AC_PATH_PROG(MV, mv)
110 if test -z "$MV"; then
111    AC_MSG_ERROR([You need 'mv' to compile WebKit])
112 fi
113
114 # GTK+ port only
115 # Check for glib-genmarshal and glib-mkenums
116 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
117 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
118 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
119    AC_MSG_ERROR([You need the GLib dev tools in your path])
120 fi
121
122 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
123 # doesn't exist)
124 AC_LANG_PUSH([C++])
125 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
126 AC_LANG_POP([C++])
127
128 # C/C++ Language Features
129 AC_C_CONST
130 AC_C_INLINE
131 AC_C_VOLATILE
132
133 # C/C++ Headers
134 AC_HEADER_STDC
135 AC_HEADER_STDBOOL
136
137 # pthread (not needed on Windows)
138 if test "$os_win32" = "no"; then
139 AC_CHECK_HEADERS([pthread.h],
140                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
141                  AC_MSG_ERROR([pthread support is required to build WebKit]))
142 fi
143
144 # check for libjpeg the way Gtk does it.
145 AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
146                    jpeg_ok=yes, jpeg_ok=no
147                    AC_MSG_ERROR([JPEG library (libjpeg) not found]))
148 if test "$jpeg_ok" = yes; then
149    AC_MSG_CHECKING([for jpeglib])
150    AC_TRY_CPP(
151 [#include <stdio.h>
152 #undef PACKAGE
153 #undef VERSION
154 #undef HAVE_STDLIB_H
155 #include <jpeglib.h>],
156          jpeg_ok=yes,
157          jpeg_ok=no)
158    AC_MSG_RESULT($jpeg_ok)
159    if test "$jpeg_ok" = yes; then
160       JPEG_LIBS="-ljpeg"
161       # should we check for progressive JPEG like GTK+ as well?
162    else
163       AC_MSG_ERROR([JPEG library (libjpeg) not found])
164    fi
165 fi
166 AC_SUBST([JPEG_LIBS])
167
168 # check for pkg-config
169 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
170 if test "$PKG_CONFIG" = "no"; then
171    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
172 fi
173
174 # determine the Unicode backend
175 AC_MSG_CHECKING([the Unicode backend to use])
176 AC_ARG_WITH(unicode_backend,
177             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
178                            [Select Unicode backend [default=icu]]),
179             [],[unicode_backend="icu"])
180
181 case "$unicode_backend" in
182      icu) ;;
183      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
184 esac
185
186 AC_MSG_RESULT([$unicode_backend])
187
188 if test "$unicode_backend" = "icu"; then
189         if test "$os_darwin" = "yes"; then
190                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
191                 UNICODE_LIBS="-licucore"
192         elif test "$os_win32" = "yes"; then
193                 UNICODE_CFLAGS=""
194                 UNICODE_LIBS="-licuin -licuuc"
195         else
196                 AC_PATH_PROG(icu_config, icu-config, no)
197                 if test "$icu_config" = "no"; then
198                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
199                 fi
200
201                 # We don't use --cflags as this gives us a lot of things that we don't
202                 # necessarily want, like debugging and optimization flags
203                 # See man (1) icu-config for more info.
204                 UNICODE_CFLAGS=`$icu_config --cppflags`
205                 UNICODE_LIBS=`$icu_config --ldflags`
206         fi
207 fi
208
209 AC_SUBST([UNICODE_CFLAGS])
210 AC_SUBST([UNICODE_LIBS])
211
212 # determine the GDK/GTK+ target
213 AC_MSG_CHECKING([the target windowing system])
214 AC_ARG_WITH(target,
215             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
216                            [Select webkit target [default=x11]]),
217             [],[with_target="x11"])
218
219 case "$with_target" in
220      x11|win32|quartz|directfb) ;;
221      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
222 esac
223
224 AC_MSG_RESULT([$with_target])
225
226 AC_MSG_CHECKING([for Hildon UI extensions])
227 AC_ARG_WITH(hildon,
228             AC_HELP_STRING([--with-hildon],
229                            [Use Hildon UI extensions [default=no]]),
230             [],[with_hildon="no"])
231 AC_MSG_RESULT([$with_hildon])
232
233 if test "$with_hildon" = "yes"; then
234     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
235     PKG_CHECK_MODULES([HILDON], [hildon-1])
236     AC_SUBST([HILDON_CPPFLAGS])
237     AC_SUBST([HILDON_CFLAGS])
238     AC_SUBST([HILDON_LIBS])
239 fi
240
241 # determine the http backend
242 AC_MSG_CHECKING([the HTTP backend to use])
243 AC_ARG_WITH(http_backend,
244             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
245                            [Select HTTP backend [default=curl]]),
246             [],[with_http_backend="curl"])
247
248 case "$with_http_backend" in
249      curl|soup) ;;
250      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
251 esac
252
253 AC_MSG_RESULT([$with_http_backend])
254
255 # minimum base dependencies
256 CAIRO_REQUIRED_VERSION=1.4
257 FONTCONFIG_REQUIRED_VERSION=2.4
258 FREETYPE2_REQUIRED_VERSION=9.0
259 LIBXML_REQUIRED_VERSION=2.6
260
261 # minimum GTK+ base dependencies
262 GLIB_REQUIRED_VERSION=2.0
263 GOBJECT_REQUIRED_VERSION=2.0
264 GTHREAD_REQUIRED_VERSION=2.0
265 PANGO_REQUIRED_VERSION=1.0
266 GTK_REQUIRED_VERSION=2.8
267
268 # optional modules
269 LIBCURL_REQUIRED_VERSION=7.15
270 LIBSOUP_REQUIRED_VERSION=2.23
271 LIBXSLT_REQUIRED_VERSION=1.1.7
272 SQLITE_REQUIRED_VERSION=3.0
273 GSTREAMER_REQUIRED_VERSION=0.10
274 GNOME_VFS_REQUIRED_VERSION=2.0
275
276 PKG_CHECK_MODULES([GLOBALDEPS],
277                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
278                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
279                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
280 AC_SUBST([GLOBALDEPS_CFLAGS])
281 AC_SUBST([GLOBALDEPS_LIBS])
282
283 PKG_CHECK_MODULES([WEBKITDEPS],
284                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
285                   pango >= $PANGO_REQUIRED_VERSION
286                   cairo >= $CAIRO_REQUIRED_VERSION
287                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
288 AC_SUBST([WEBKITDEPS_CFLAGS])
289 AC_SUBST([WEBKITDEPS_LIBS])
290
291 # check for Xt if the target is X11
292 if test "$with_target" = "x11"; then
293    PKG_CHECK_MODULES([XT],
294                      [xt],
295                      [xt_has_pkg_config=yes],
296                      [xt_has_pkg_config=no])
297    # some old versions of Xt do not provide xt.pc, so try to link against Xt
298    # and if it's installed fall back to just adding -lXt
299    if test "$xt_has_pkg_config" = "no"; then
300       # using AC_CHECK_LIB instead of AC_SEARCH_LIB is fine in this case as
301       # we don't care about the XtOpenDisplay symbol but only about the
302       # existence of libXt
303       AC_CHECK_LIB([Xt], [XtOpenDisplay],
304                    [XT_CFLAGS=""; XT_LIBS="-lXt"],
305                    [AC_MSG_ERROR([X Toolkit Intrinsics library (libXt) not found])])
306    fi
307    AC_SUBST([XT_CFLAGS])
308    AC_SUBST([XT_LIBS])
309 fi
310
311 # check whether to build with debugging enabled
312 AC_MSG_CHECKING([whether to do a debug build])
313 AC_ARG_ENABLE(debug,
314               AC_HELP_STRING([--enable-debug],
315                              [turn on debugging [default=no]]),
316               [],[enable_debug="no"])
317 AC_MSG_RESULT([$enable_debug])
318
319 # check whether to enable dashboard support
320 AC_MSG_CHECKING([whether to enable Dashboard support])
321 AC_ARG_ENABLE(dashboard_support,
322               AC_HELP_STRING([--enable-dashboard-support],
323                              [enable Dashboard support [default=yes]]),
324               [],[enable_dashboard_support="yes"])
325 AC_MSG_RESULT([$enable_dashboard_support])
326
327 # check whether to enable HTML5 Offline Web Applications support
328 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
329 AC_ARG_ENABLE(offline_web_applications,
330               AC_HELP_STRING([--enable-offline-web-applications],
331                              [enable HTML5 offline web applications support [default=yes]]),
332               [],[enable_offline_web_applications="yes"])
333 AC_MSG_RESULT([$enable_offline_web_applications])
334
335 # check whether to enable HTML5 client-side session and persitent storage support
336 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
337 AC_ARG_ENABLE(dom_storage,
338               AC_HELP_STRING([--enable-dom-storage],
339                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
340               [],[enable_dom_storage="yes"])
341 AC_MSG_RESULT([$enable_dom_storage])
342
343 # check whether to build with database support
344 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
345 AC_ARG_ENABLE(database,
346               AC_HELP_STRING([--enable-database],
347                              [enable HTML5 client-side database storage support [default=yes]]),
348               [],[enable_database="yes"])
349 AC_MSG_RESULT([$enable_database])
350
351 # check whether to build with icon database support
352 AC_MSG_CHECKING([whether to enable icon database support])
353 AC_ARG_ENABLE(icon_database,
354               AC_HELP_STRING([--enable-icon-database],
355                              [enable icon database [default=yes]]),
356               [],[enable_icon_database="yes"])
357 AC_MSG_RESULT([$enable_icon_database])
358
359 # check whether to enable HTML5 audio/video support
360 AC_MSG_CHECKING([whether to enable HTML5 video support])
361 AC_ARG_ENABLE(video,
362               AC_HELP_STRING([--enable-video],
363                              [enable HTML5 video support [default=no]]),
364               [],[enable_video="no"])
365 AC_MSG_RESULT([$enable_video])
366
367 # check whether to enable XPath support
368 AC_MSG_CHECKING([whether to enable XPath support])
369 AC_ARG_ENABLE(xpath,
370               AC_HELP_STRING([--enable-xpath],
371                              [enable support for XPath [default=yes]]),
372               [],[enable_xpath="yes"])
373 AC_MSG_RESULT([$enable_xpath])
374
375 # check whether to enable XSLT support
376 AC_MSG_CHECKING([whether to enable XSLT support])
377 AC_ARG_ENABLE(xslt,
378               AC_HELP_STRING([--enable-xslt],
379                              [enable support for XSLT [default=yes]]),
380               [],[enable_xslt="yes"])
381 AC_MSG_RESULT([$enable_xslt])
382
383 # check whether to enable SVG support
384 AC_MSG_CHECKING([whether to enable SVG support])
385 AC_ARG_ENABLE(svg,
386               AC_HELP_STRING([--enable-svg],
387                              [enable support for SVG [default=yes]]),
388               [],[enable_svg="yes"])
389 AC_MSG_RESULT([$enable_svg])
390
391 # turn off svg features if --disable-svg is requested
392 if test "$enable_svg" = "no"; then
393    enable_svg_animation=no
394    enable_svg_filters=no
395    enable_svg_fonts=no
396    enable_svg_foreign_object=no
397    enable_svg_as_image=no
398    enable_svg_use_element=no
399 fi
400
401 # check whether to enable support for SVG animation
402 AC_MSG_CHECKING([whether to enable support for SVG animation])
403 AC_ARG_ENABLE(svg_animation,
404               AC_HELP_STRING([--enable-svg-animation],
405                              [enable support for SVG animation (experimental) [default=yes]]),
406               [],[enable_svg_animation="yes"])
407 AC_MSG_RESULT([$enable_svg_animation])
408
409 # check whether to enable support for SVG filters
410 AC_MSG_CHECKING([whether to enable support for SVG filters])
411 AC_ARG_ENABLE(svg_filters,
412               AC_HELP_STRING([--enable-svg-filters],
413                              [enable support for SVG filters (experimental) [default=no]]),
414               [],[enable_svg_filters="no"])
415 AC_MSG_RESULT([$enable_svg_filters])
416
417 # check whether to enable support for SVG fonts
418 AC_MSG_CHECKING([whether to enable support for SVG fonts])
419 AC_ARG_ENABLE(svg_fonts,
420               AC_HELP_STRING([--enable-svg-fonts],
421                              [enable support for SVG fonts (experimental) [default=yes]]),
422               [],[enable_svg_fonts="yes"])
423 AC_MSG_RESULT([$enable_svg_fonts])
424
425 # check whether to enable foreign objects support for SVG
426 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
427 AC_ARG_ENABLE(svg_foreign_object,
428               AC_HELP_STRING([--enable-svg-foreign-object],
429                              [enable support for SVG foreign objects (experimental) [default=yes]]),
430               [],[enable_svg_foreign_object="yes"])
431 AC_MSG_RESULT([$enable_svg_foreign_object])
432
433 # check whether to enable SVG As Image support
434 AC_MSG_CHECKING([whether to enable SVG as Image support])
435 AC_ARG_ENABLE(svg_as_image,
436               AC_HELP_STRING([--enable-svg-as-image],
437                              [enable SVG as Image support (experimental) [default=yes]]),
438               [],[enable_svg_as_image="yes"])
439 AC_MSG_RESULT([$enable_svg_as_image])
440
441 # check whether to enable SVG USE element support
442 AC_MSG_CHECKING([whether to enable support for SVG use element])
443 AC_ARG_ENABLE(svg_use_element,
444               AC_HELP_STRING([--enable-svg-use-element],
445                              [enable SVG use element support (experimental) [default=yes]]),
446               [],[enable_svg_use_element="yes"])
447 AC_MSG_RESULT([$enable_svg_use_element])
448
449 # check for SVG features, enabling SVG if necessary
450 if test "$enable_svg_animation" = "yes" || \
451    test "$enable_svg_filters" = "yes" || \
452    test "$enable_svg_fonts" = "yes" || \
453    test "$enable_svg_foreign_object" = "yes" || \
454    test "$enable_svg_as_image" = "yes" || \
455    test "$enable_svg_use_element" = "yes"; then
456    svg_flags=yes
457    if test "$enable_svg" = "no"; then
458        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
459        enable_svg=yes
460    fi
461 fi
462
463 # check whether to enable code coverage
464 AC_MSG_CHECKING([whether to enable code coverage support])
465 AC_ARG_ENABLE(coverage,
466               AC_HELP_STRING([--enable-coverage],
467                              [enable code coverage support [default=no]]),
468               [],[enable_coverage="no"])
469 AC_MSG_RESULT([$enable_coverage])
470
471 # check whether to enable FastMalloc
472 AC_MSG_CHECKING([whether to enable optimized memory allocator])
473 AC_ARG_ENABLE(fast_malloc,
474               AC_HELP_STRING([--enable-fast-malloc],
475                              [enable optimized memory allocator default=yes, default=no for debug builds]),
476               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
477 AC_MSG_RESULT([$enable_fast_malloc])
478
479 # determine the font backend
480 AC_MSG_CHECKING([the font backend to use])
481 AC_ARG_WITH(font_backend,
482             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
483                            [Select font backend [default=freetype]]),
484             [],[with_font_backend="freetype"])
485
486 case "$with_font_backend" in
487      freetype|pango) ;;
488      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
489 esac
490 AC_MSG_RESULT([$with_font_backend])
491
492 # Add '-g' flag to gcc if it's debug build
493 if test "$enable_debug" = "yes"; then
494    CXXFLAGS="$CXXFLAGS -g"
495    CFLAGS="$CFLAGS -g"
496 fi
497
498 # check if curl is available
499 if test "$with_http_backend" = "curl"; then
500    PKG_CHECK_MODULES([LIBCURL],
501                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
502    if test "$os_win32" = "yes"; then
503       LIBCURL_LIBS="$LIBCURL_LIBS -lWs2_32"
504    fi
505    AC_SUBST([LIBCURL_CFLAGS])
506    AC_SUBST([LIBCURL_LIBS])
507 fi
508
509 if test "$with_http_backend" = "soup"; then
510    PKG_CHECK_MODULES([LIBSOUP],
511                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
512    AC_SUBST([LIBSOUP_CFLAGS])
513    AC_SUBST([LIBSOUP_LIBS])
514 fi
515
516 # check if FreeType/FontConfig are available
517 if test "$with_font_backend" = "freetype"; then
518    PKG_CHECK_MODULES([FREETYPE],
519                      [cairo-ft
520                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
521                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
522    AC_SUBST([FREETYPE_CFLAGS])
523    AC_SUBST([FREETYPE_LIBS])
524 fi
525
526 # check if sqlite 3 is available
527 if test "$enable_icon_database" = "yes" || \
528    test "$enable_database" = "yes" || \
529    test "$enable_offline_web_applications" = "yes" || \
530    test "$enable_dom_storage" = "yes"; then
531    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
532    AC_SUBST([SQLITE3_CFLAGS])
533    AC_SUBST([SQLITE3_LIBS])
534 fi
535
536 # check if libxslt is available
537 if test "$enable_xslt" = "yes"; then
538    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
539    AC_SUBST([LIBXSLT_CFLAGS])
540    AC_SUBST([LIBXSLT_LIBS])
541 fi
542
543 # check if gstreamer is available
544 if test "$enable_video" = "yes"; then
545    PKG_CHECK_MODULES([GSTREAMER],
546                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
547                      gstreamer-base-0.10,
548                      gstreamer-plugins-base-0.10,
549                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
550    AC_SUBST([GSTREAMER_CFLAGS])
551    AC_SUBST([GSTREAMER_LIBS])
552 fi
553
554 # check for code coverage support
555 if test "$enable_coverage" = "yes"; then
556    COVERAGE_CFLAGS="-MD"
557    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
558    AC_SUBST([COVERAGE_CFLAGS])
559    AC_SUBST([COVERAGE_LDFLAGS])
560 fi
561
562 # check for HTML features
563 if test "$enable_video" = "yes"; then
564     html_flags=yes
565 fi
566
567 # OS conditionals
568 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
569 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
570 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
571 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
572
573 # target conditionals
574 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
575 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
576 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
577 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
578
579 # HTTP backend conditionals
580 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
581 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
582
583 # Font backend conditionals
584 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
585 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
586
587 # WebKit feature conditionals
588 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
589 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
590 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
591 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
592 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
593 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
594 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
595 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
596 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
597 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
598 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
599 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
600 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
601 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
602 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
603 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
604 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
605 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
606 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
607 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
608
609 AC_CONFIG_FILES([
610 GNUmakefile
611 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
612 WebKit/gtk/webkit/webkitversion.h
613 ]
614 )
615
616 AC_OUTPUT
617
618 echo "
619 WebKit was configured with the following options:
620
621 Build configuration:
622  Enable debugging (slow)                                  : $enable_debug
623  Code coverage support                                    : $enable_coverage
624  Unicode backend                                          : $unicode_backend
625  HTTP backend                                             : $with_http_backend
626  Font backend                                             : $with_font_backend
627  Optimized memory allocator                               : $enable_fast_malloc
628 Features:
629  Dashboard support                                        : $enable_dashboard_support
630  HTML5 offline web applications support                   : $enable_offline_web_applications
631  HTML5 client-side session and persistent storage support : $enable_dom_storage
632  HTML5 client-side database storage support               : $enable_database
633  HTML5 video element support                              : $enable_video
634  Icon database support                                    : $enable_icon_database
635  SVG support                                              : $enable_svg
636  SVG animation support                                    : $enable_svg_animation
637  SVG filters support                                      : $enable_svg_filters
638  SVG fonts support                                        : $enable_svg_fonts
639  SVG foreign object support                               : $enable_svg_foreign_object
640  SVG as image support                                     : $enable_svg_as_image
641  SVG use element support                                  : $enable_svg_use_element
642  XPATH support                                            : $enable_xpath
643  XSLT support                                             : $enable_xslt
644 GTK+ configuration:
645  GDK target                                               : $with_target
646  Hildon UI extensions                                     : $with_hildon
647 "