configure.ac

   1 AC_INIT([WebKit],[0.1],[http://bugs.webkit.org/])
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_CONFIG_HEADERS([aconfig.h])
   6 AC_CONFIG_SRCDIR([WebCore/config.h])
   7
   8 # see http://www.gnu.org/software/libtool/manual.html#Versioning
   9 LIBWEBKITGTK_VERSION=1:0:0
  10 AC_SUBST([LIBWEBKITGTK_VERSION])
  11
  12 AM_INIT_AUTOMAKE([foreign subdir-objects])
  13
  14 AC_CANONICAL_HOST
  15
  16 # host checking - inspired by the GTK+ configure.in
  17 # TODO: os_mac, os_bsd
  18 AC_MSG_CHECKING([for native Win32])
  19 case "$host" in
  20      *-*-mingw*)
  21        os_win32=yes
  22        ;;
  23      *)
  24        os_win32=no
  25        ;;
  26 esac
  27 AC_MSG_RESULT([$os_win32])
  28
  29 case "$host" in
  30      *-*-linux*)
  31        os_linux=yes
  32        ;;
  33      *-*-freebsd*)
  34        os_freebsd=yes
  35        ;;
  36      *-*-darwin*)
  37        os_darwin=yes
  38        ;;
  39 esac
  40
  41 # If CXXFLAGS and CFLAGS are unset, default to -O2
  42 # This is to tell automake not to include '-g' if CXXFLAGS is not set
  43 # For more info - http://www.gnu.org/software/automake/manual/autoconf.html#C_002b_002b-Compiler
  44 if test -z "$CXXFLAGS"; then
  45    CXXFLAGS="-O2"
  46 fi
  47 if test -z "$CFLAGS"; then
  48    CFLAGS="-O2"
  49 fi
  50
  51 # programs
  52 AC_DISABLE_STATIC
  53 AM_PROG_LIBTOOL
  54 AC_PROG_INSTALL
  55 AM_PROG_CC_STDC
  56 AC_PROG_CXX
  57 AM_PROG_CC_C_O
  58
  59 # check for -fvisibility=hidden compiler support (GCC >= 4)
  60 saved_CFLAGS="$CFLAGS"
  61 CFLAGS="$CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  62 AC_MSG_CHECKING([if ${CXX} supports -fvisibility=hidden -fvisibility-inlines-hidden])
  63 AC_COMPILE_IFELSE([char foo;],
  64       [ AC_MSG_RESULT([yes])
  65         SYMBOL_VISIBILITY="-fvisibility=hidden" SYMBOL_VISIBILITY_INLINES="-fvisibility-inlines-hidden" ],
  66         AC_MSG_RESULT([no]))
  67 CFLAGS="$saved_CFLAGS"
  68 AC_SUBST(SYMBOL_VISIBILITY)
  69 AC_SUBST(SYMBOL_VISIBILITY_INLINES)
  70
  71 AC_PATH_PROG(PERL, perl)
  72 if test -z "$PERL"; then
  73    AC_MSG_ERROR([You need 'perl' to compile WebKit])
  74 fi
  75
  76 AC_PATH_PROG(BISON, bison)
  77 if test -z "$BISON"; then
  78    AC_MSG_ERROR([You need the 'bison' parser generator to compile WebKit])
  79 fi
  80
  81 AC_PATH_PROG(FLEX, flex)
  82 if test -z "$FLEX"; then
  83    AC_MSG_ERROR([You need the 'flex' lexer generator to compile WebKit])
  84 fi
  85
  86 AC_PATH_PROG(GPERF, gperf)
  87 if test -z "$GPERF"; then
  88    AC_MSG_ERROR([You need the 'gperf' hash function generator to compile WebKit])
  89 fi
  90
  91 AC_PATH_PROG(MV, mv)
  92 if test -z "$MV"; then
  93    AC_MSG_ERROR([You need 'mv' to compile WebKit])
  94 fi
  95
  96 # GTK+ port only
  97 # Check for glib-genmarshal and glib-mkenums
  98 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
  99 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
 100 if test -z "$GLIB_GENMARSHAL" || test -z "$GLIB_MKENUMS"; then
 101    AC_MSG_ERROR([You need the GLib dev tools in your path])
 102 fi
 103
 104 # Check whether a C++ was found (AC_PROG_CXX sets $CXX to "g++" even when it
 105 # doesn't exist)
 106 AC_LANG_PUSH([C++])
 107 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],[],[AC_MSG_ERROR([No C++ compiler found])])
 108 AC_LANG_POP([C++])
 109
 110 # C/C++ Language Features
 111 AC_C_CONST
 112 AC_C_INLINE
 113 AC_C_VOLATILE
 114
 115 # C/C++ Headers
 116 AC_HEADER_STDC
 117 AC_HEADER_STDBOOL
 118
 119 # pthread (not needed on Windows)
 120 if test "$os_win32" = "no"; then
 121 AC_CHECK_HEADERS([pthread.h],
 122                  AC_DEFINE([HAVE_PTHREAD_H],[1],[Define if pthread exists]),
 123                  AC_MSG_ERROR([pthread support is required to build WebKit]))
 124 fi
 125
 126 # libjpeg headers
 127 AC_CHECK_HEADERS([jpeglib.h])
 128
 129 # check for pkg-config
 130 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 131 if test "$PKG_CONFIG" = "no"; then
 132    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed in your PATH])
 133 fi
 134
 135 # determine the Unicode backend
 136 AC_MSG_CHECKING([the Unicode backend to use])
 137 AC_ARG_WITH(unicode_backend,
 138             AC_HELP_STRING([--with-unicode-backend=@<:@icu@:>@],
 139                            [Select Unicode backend [default=icu]]),
 140             [],[unicode_backend="icu"])
 141
 142 case "$unicode_backend" in
 143      icu) ;;
 144      *) AC_MSG_ERROR([Invalid Unicode backend: must be icu.]) ;;
 145 esac
 146
 147 AC_MSG_RESULT([$unicode_backend])
 148
 149 if test "$unicode_backend" = "icu"; then
 150         # check for icu-config
 151         if test "$os_darwin" = "yes"; then
 152                 UNICODE_CFLAGS="-I\$(srcdir)/JavaScriptCore/icu -I\$(srcdir)/WebCore/icu"
 153                 UNICODE_LIBS="-licucore"
 154         else
 155                 AC_PATH_PROG(icu_config, icu-config, no)
 156                 if test "$icu_config" = "no"; then
 157                         AC_MSG_ERROR([Cannot find icu-config. The ICU library is needed.])
 158                 fi
 159
 160                 # We don't use --cflags as this gives us a lot of things that we don't
 161                 # necessarily want, like debugging and optimization flags
 162                 # See man (1) icu-config for more info.
 163                 UNICODE_CFLAGS=`$icu_config --cppflags`
 164                 UNICODE_LIBS=`$icu_config --ldflags`
 165         fi
 166 fi
 167
 168 AC_SUBST([UNICODE_CFLAGS])
 169 AC_SUBST([UNICODE_LIBS])
 170
 171 # determine the GDK/GTK+ target
 172 AC_MSG_CHECKING([the target windowing system])
 173 AC_ARG_WITH(target,
 174             AC_HELP_STRING([--with-target=@<:@x11/win32/quartz/directfb@:>@],
 175                            [Select webkit target [default=x11]]),
 176             [],[with_target="x11"])
 177
 178 case "$with_target" in
 179      x11|win32|quartz|directfb) ;;
 180      *) AC_MSG_ERROR([Invalid target: must be x11, quartz, win32, or directfb.]) ;;
 181 esac
 182
 183 AC_MSG_RESULT([$with_target])
 184
 185 AC_MSG_CHECKING([for Hildon UI extensions])
 186 AC_ARG_WITH(hildon,
 187             AC_HELP_STRING([--with-hildon],
 188                            [Use Hildon UI extensions [default=no]]),
 189             [],[with_hildon="no"])
 190 AC_MSG_RESULT([$with_hildon])
 191
 192 if test "$with_hildon" = "yes"; then
 193     HILDON_CPPFLAGS="-DMAEMO_CHANGES"
 194     PKG_CHECK_MODULES([HILDON], [hildon-1])
 195     AC_SUBST([HILDON_CPPFLAGS])
 196     AC_SUBST([HILDON_CFLAGS])
 197     AC_SUBST([HILDON_LIBS])
 198 fi
 199
 200 # determine the http backend
 201 AC_MSG_CHECKING([the HTTP backend to use])
 202 AC_ARG_WITH(http_backend,
 203             AC_HELP_STRING([--with-http-backend=@<:@curl/soup@:>@],
 204                            [Select HTTP backend [default=curl]]),
 205             [],[with_http_backend="curl"])
 206
 207 case "$with_http_backend" in
 208      curl|soup) ;;
 209      *) AC_MSG_ERROR([Invalid HTTP backend: must be curl, soup.]) ;;
 210 esac
 211
 212 AC_MSG_RESULT([$with_http_backend])
 213
 214 # minimum base dependencies
 215 CAIRO_REQUIRED_VERSION=1.4
 216 FONTCONFIG_REQUIRED_VERSION=2.4
 217 FREETYPE2_REQUIRED_VERSION=9.0
 218 LIBXML_REQUIRED_VERSION=2.6
 219
 220 # minimum GTK+ base dependencies
 221 GLIB_REQUIRED_VERSION=2.0
 222 GOBJECT_REQUIRED_VERSION=2.0
 223 GTHREAD_REQUIRED_VERSION=2.0
 224 PANGO_REQUIRED_VERSION=1.0
 225 GTK_REQUIRED_VERSION=2.8
 226
 227 # optional modules
 228 LIBCURL_REQUIRED_VERSION=7.15
 229 LIBSOUP_REQUIRED_VERSION=2.23
 230 LIBXSLT_REQUIRED_VERSION=1.1.7
 231 SQLITE_REQUIRED_VERSION=3.0
 232 GSTREAMER_REQUIRED_VERSION=0.10
 233 GNOME_VFS_REQUIRED_VERSION=2.0
 234
 235 PKG_CHECK_MODULES([GLOBALDEPS],
 236                   [glib-2.0 >= $GLIB_REQUIRED_VERSION
 237                   gobject-2.0 >= $GOBJECT_REQUIRED_VERSION
 238                   gthread-2.0 >= $GTHREAD_REQUIRED_VERSION])
 239 AC_SUBST([GLOBALDEPS_CFLAGS])
 240 AC_SUBST([GLOBALDEPS_LIBS])
 241
 242 PKG_CHECK_MODULES([WEBKITDEPS],
 243                   [gtk+-2.0 >= $GTK_REQUIRED_VERSION
 244                   pango >= $PANGO_REQUIRED_VERSION
 245                   cairo >= $CAIRO_REQUIRED_VERSION
 246                   libxml-2.0 >= $LIBXML_REQUIRED_VERSION])
 247 AC_SUBST([WEBKITDEPS_CFLAGS])
 248 AC_SUBST([WEBKITDEPS_LIBS])
 249
 250 # check whether to build with debugging enabled
 251 AC_MSG_CHECKING([whether to do a debug build])
 252 AC_ARG_ENABLE(debug,
 253               AC_HELP_STRING([--enable-debug],
 254                              [turn on debugging [default=no]]),
 255               [],[enable_debug="no"])
 256 AC_MSG_RESULT([$enable_debug])
 257
 258 # check whether to enable dashboard support
 259 AC_MSG_CHECKING([whether to enable Dashboard support])
 260 AC_ARG_ENABLE(dashboard_support,
 261               AC_HELP_STRING([--enable-dashboard-support],
 262                              [enable Dashboard support [default=yes]]),
 263               [],[enable_dashboard_support="yes"])
 264 AC_MSG_RESULT([$enable_dashboard_support])
 265
 266 # check whether to build with cross-document messaging support
 267 AC_MSG_CHECKING([whether to enable HTML5 cross-document messaging support])
 268 AC_ARG_ENABLE(cross_document_messaging,
 269               AC_HELP_STRING([--enable-cross-document-messaging],
 270                              [enable HTML5 cross-document messaging support [default=yes]]),
 271               [],[enable_cross_document_messaging="yes"])
 272 AC_MSG_RESULT([$enable_cross_document_messaging])
 273
 274 # check whether to enable HTML5 Offline Web Applications support
 275 AC_MSG_CHECKING([whether to enable HTML5 offline web applications support])
 276 AC_ARG_ENABLE(offline_web_applications,
 277               AC_HELP_STRING([--enable-offline-web-applications],
 278                              [enable HTML5 offline web applications support [default=yes]]),
 279               [],[enable_offline_web_applications="yes"])
 280 AC_MSG_RESULT([$enable_offline_web_applications])
 281
 282 # check whether to enable HTML5 client-side session and persitent storage support
 283 AC_MSG_CHECKING([whether to enable HTML5 client-side session and persistent storage support])
 284 AC_ARG_ENABLE(dom_storage,
 285               AC_HELP_STRING([--enable-dom-storage],
 286                              [enable HTML5 client-side session and persistent storage support [default=yes]]),
 287               [],[enable_dom_storage="yes"])
 288 AC_MSG_RESULT([$enable_dom_storage])
 289
 290 # check whether to build with database support
 291 AC_MSG_CHECKING([whether to enable HTML5 client-side database storage support])
 292 AC_ARG_ENABLE(database,
 293               AC_HELP_STRING([--enable-database],
 294                              [enable HTML5 client-side database storage support [default=yes]]),
 295               [],[enable_database="yes"])
 296 AC_MSG_RESULT([$enable_database])
 297
 298 # check whether to build with icon database support
 299 AC_MSG_CHECKING([whether to enable icon database support])
 300 AC_ARG_ENABLE(icon_database,
 301               AC_HELP_STRING([--enable-icon-database],
 302                              [enable icon database [default=yes]]),
 303               [],[enable_icon_database="yes"])
 304 AC_MSG_RESULT([$enable_icon_database])
 305
 306 # check whether to enable HTML5 audio/video support
 307 AC_MSG_CHECKING([whether to enable HTML5 video support])
 308 AC_ARG_ENABLE(video,
 309               AC_HELP_STRING([--enable-video],
 310                              [enable HTML5 video support [default=no]]),
 311               [],[enable_video="no"])
 312 AC_MSG_RESULT([$enable_video])
 313
 314 # check whether to enable XPath support
 315 AC_MSG_CHECKING([whether to enable XPath support])
 316 AC_ARG_ENABLE(xpath,
 317               AC_HELP_STRING([--enable-xpath],
 318                              [enable support for XPath [default=yes]]),
 319               [],[enable_xpath="yes"])
 320 AC_MSG_RESULT([$enable_xpath])
 321
 322 # check whether to enable XSLT support
 323 AC_MSG_CHECKING([whether to enable XSLT support])
 324 AC_ARG_ENABLE(xslt,
 325               AC_HELP_STRING([--enable-xslt],
 326                              [enable support for XSLT [default=yes]]),
 327               [],[enable_xslt="yes"])
 328 AC_MSG_RESULT([$enable_xslt])
 329
 330 # check whether to enable SVG experimental features
 331 # Enable all SVG if it is
 332 AC_MSG_CHECKING([whether to enable SVG experimental features])
 333 AC_ARG_ENABLE(svg_experimental,
 334               AC_HELP_STRING([--enable-svg-experimental],
 335                              [enable support for SVG experimental features [default=yes]]),
 336               [],[enable_svg_experimental="yes"])
 337 AC_MSG_RESULT([$enable_svg_experimental])
 338
 339 # check whether to enable SVG support
 340 AC_MSG_CHECKING([whether to enable SVG support])
 341 AC_ARG_ENABLE(svg,
 342               AC_HELP_STRING([--enable-svg],
 343                              [enable support for SVG [default=yes]]),
 344               [],[enable_svg="yes"])
 345 AC_MSG_RESULT([$enable_svg])
 346
 347 # check for SVG features, enabling SVG if necessary
 348 if test "$enable_svg_experimental" = "no" || test "$enable_svg" = "no"; then
 349    enable_svg_animation=no
 350    enable_svg_filters=no
 351    enable_svg_fonts=no
 352    enable_svg_foreign_object=no
 353    enable_svg_as_image=no
 354    enable_svg_use_element=no
 355 elif test "$enable_svg_experimental" = "yes"; then
 356    enable_svg=yes
 357    enable_svg_animation=yes
 358 #   enable_svg_filters=yes
 359    enable_svg_fonts=yes
 360    enable_svg_foreign_object=yes
 361    enable_svg_as_image=yes
 362    enable_svg_use_element=yes
 363 fi
 364
 365 # check whether to enable support for SVG animation
 366 AC_MSG_CHECKING([whether to enable support for SVG animation])
 367 AC_ARG_ENABLE(svg_animation,
 368               AC_HELP_STRING([--enable-svg-animation],
 369                              [enable support for SVG animation (experimental) [default=yes]]),
 370               [],[enable_svg_animation="yes"])
 371 AC_MSG_RESULT([$enable_svg_animation])
 372
 373 # check whether to enable support for SVG filters
 374 AC_MSG_CHECKING([whether to enable support for SVG filters])
 375 AC_ARG_ENABLE(svg_filters,
 376               AC_HELP_STRING([--enable-svg-filters],
 377                              [enable support for SVG filters (experimental) [default=no]]),
 378               [],[enable_svg_filters="no"])
 379 AC_MSG_RESULT([$enable_svg_filters])
 380
 381 # check whether to enable support for SVG fonts
 382 AC_MSG_CHECKING([whether to enable support for SVG fonts])
 383 AC_ARG_ENABLE(svg_fonts,
 384               AC_HELP_STRING([--enable-svg-fonts],
 385                              [enable support for SVG fonts (experimental) [default=yes]]),
 386               [],[enable_svg_fonts="yes"])
 387 AC_MSG_RESULT([$enable_svg_fonts])
 388
 389 # check whether to enable foreign objects support for SVG
 390 AC_MSG_CHECKING([whether to enable support for SVG foreign objects])
 391 AC_ARG_ENABLE(svg_foreign_object,
 392               AC_HELP_STRING([--enable-svg-foreign-object],
 393                              [enable support for SVG foreign objects (experimental) [default=yes]]),
 394               [],[enable_svg_foreign_object="yes"])
 395 AC_MSG_RESULT([$enable_svg_foreign_object])
 396
 397 # check whether to enable SVG As Image support
 398 AC_MSG_CHECKING([whether to enable SVG as Image support])
 399 AC_ARG_ENABLE(svg_as_image,
 400               AC_HELP_STRING([--enable-svg-as-image],
 401                              [enable SVG as Image support (experimental) [default=yes]]),
 402               [],[enable_svg_as_image="yes"])
 403 AC_MSG_RESULT([$enable_svg_as_image])
 404
 405 # check whether to enable SVG USE element support
 406 AC_MSG_CHECKING([whether to enable support for SVG use element])
 407 AC_ARG_ENABLE(svg_use_element,
 408               AC_HELP_STRING([--enable-svg-use-element],
 409                              [enable SVG use element support (experimental) [default=yes]]),
 410               [],[enable_svg_use_element="yes"])
 411 AC_MSG_RESULT([$enable_svg_use_element])
 412
 413 if test "$enable_svg_animation" = "yes" || \
 414    test "$enable_svg_filters" = "yes" || \
 415    test "$enable_svg_fonts" = "yes" || \
 416    test "$enable_svg_foreign_object" = "yes" || \
 417    test "$enable_svg_as_image" = "yes" || \
 418    test "$enable_svg_use_element" = "yes"; then
 419    svg_flags=yes
 420    if test "$enable_svg" = "no"; then
 421        AC_MSG_WARN([SVG feature(s) requested but SVG is disabled.. Enabling SVG support])
 422        enable_svg=yes
 423    fi
 424 fi
 425
 426 # check whether to enable code coverage
 427 AC_MSG_CHECKING([whether to enable code coverage support])
 428 AC_ARG_ENABLE(coverage,
 429               AC_HELP_STRING([--enable-coverage],
 430                              [enable code coverage support [default=no]]),
 431               [],[enable_coverage="no"])
 432 AC_MSG_RESULT([$enable_coverage])
 433
 434 # check whether to enable FastMalloc
 435 AC_MSG_CHECKING([whether to enable optimized memory allocator])
 436 AC_ARG_ENABLE(fast_malloc,
 437               AC_HELP_STRING([--enable-fast-malloc],
 438                              [enable optimized memory allocator default=yes, default=no for debug builds]),
 439               [],[if test "$enable_debug" = "yes"; then enable_fast_malloc="no"; else enable_fast_malloc="yes"; fi])
 440 AC_MSG_RESULT([$enable_fast_malloc])
 441
 442 # determine the font backend
 443 AC_MSG_CHECKING([the font backend to use])
 444 AC_ARG_WITH(font_backend,
 445             AC_HELP_STRING([--with-font-backend=@<:@freetype/pango@:>@],
 446                            [Select font backend [default=freetype]]),
 447             [],[with_font_backend="freetype"])
 448
 449 case "$with_font_backend" in
 450      freetype|pango) ;;
 451      *) AC_MSG_ERROR([Invalid font backend: must be freetype or pango.]) ;;
 452 esac
 453 AC_MSG_RESULT([$with_font_backend])
 454
 455 # Add '-g' flag to gcc if it's debug build
 456 if test "$enable_debug" = "yes"; then
 457    CXXFLAGS="$CXXFLAGS -g"
 458    CFLAGS="$CFLAGS -g"
 459 fi
 460
 461 # check if curl is available
 462 if test "$with_http_backend" = "curl"; then
 463    PKG_CHECK_MODULES([LIBCURL],
 464                      [libcurl >= $LIBCURL_REQUIRED_VERSION])
 465    AC_SUBST([LIBCURL_CFLAGS])
 466    AC_SUBST([LIBCURL_LIBS])
 467 fi
 468
 469 if test "$with_http_backend" = "soup"; then
 470    PKG_CHECK_MODULES([LIBSOUP],
 471                      [libsoup-2.4 >= $LIBSOUP_REQUIRED_VERSION])
 472    AC_SUBST([LIBSOUP_CFLAGS])
 473    AC_SUBST([LIBSOUP_LIBS])
 474 fi
 475
 476 # check if FreeType/FontConfig are available
 477 if test "$with_font_backend" = "freetype"; then
 478    PKG_CHECK_MODULES([FREETYPE],
 479                      [cairo-ft
 480                      fontconfig >= $FONTCONFIG_REQUIRED_VERSION
 481                      freetype2 >= $FREETYPE2_REQUIRED_VERSION])
 482    AC_SUBST([FREETYPE_CFLAGS])
 483    AC_SUBST([FREETYPE_LIBS])
 484 fi
 485
 486 # check if sqlite 3 is available
 487 if test "$enable_icon_database" = "yes" || test "$enable_database" = "yes"; then
 488    PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $SQLITE_REQUIRED_VERSION])
 489    AC_SUBST([SQLITE3_CFLAGS])
 490    AC_SUBST([SQLITE3_LIBS])
 491 fi
 492
 493 # check if libxslt is available
 494 if test "$enable_xslt" = "yes"; then
 495    PKG_CHECK_MODULES([LIBXSLT],[libxslt >= $LIBXSLT_REQUIRED_VERSION])
 496    AC_SUBST([LIBXSLT_CFLAGS])
 497    AC_SUBST([LIBXSLT_LIBS])
 498 fi
 499
 500 # check if gstreamer is available
 501 if test "$enable_video" = "yes"; then
 502    PKG_CHECK_MODULES([GSTREAMER],
 503                      [gstreamer-0.10 >= $GSTREAMER_REQUIRED_VERSION
 504                      gstreamer-base-0.10,
 505                      gstreamer-plugins-base-0.10,
 506                      gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED_VERSION])
 507    AC_SUBST([GSTREAMER_CFLAGS])
 508    AC_SUBST([GSTREAMER_LIBS])
 509 fi
 510
 511 # check for code coverage support
 512 if test "$enable_coverage" = "yes"; then
 513    COVERAGE_CFLAGS="-MD"
 514    COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
 515    AC_SUBST([COVERAGE_CFLAGS])
 516    AC_SUBST([COVERAGE_LDFLAGS])
 517 fi
 518
 519 # check for HTML features
 520 if test "$enable_video" = "yes"; then
 521     html_flags=yes
 522 fi
 523
 524 # OS conditionals
 525 AM_CONDITIONAL([OS_WIN32],[test "$os_win32" = "yes"])
 526 AM_CONDITIONAL([OS_UNIX],[test "$os_win32" = "no"])
 527 AM_CONDITIONAL([OS_LINUX],[test "$os_linux" = "yes"])
 528 AM_CONDITIONAL([OS_FREEBSD],[test "$os_freebsd" = "yes"])
 529
 530 # target conditionals
 531 AM_CONDITIONAL([TARGET_X11], [test "$with_target" = "x11"])
 532 AM_CONDITIONAL([TARGET_WIN32], [test "$with_target" = "win32"])
 533 AM_CONDITIONAL([TARGET_QUARTZ], [test "$with_target" = "quartz"])
 534 AM_CONDITIONAL([TARGET_DIRECTFB], [test "$with_target" = "directfb"])
 535
 536 # HTTP backend conditionals
 537 AM_CONDITIONAL([USE_CURL], [test "$with_http_backend" = "curl"])
 538 AM_CONDITIONAL([USE_SOUP], [test "$with_http_backend" = "soup"])
 539
 540 # Font backend conditionals
 541 AM_CONDITIONAL([USE_FREETYPE], [test "$with_font_backend" = "freetype"])
 542 AM_CONDITIONAL([USE_PANGO], [test "$with_font_backend" = "pango"])
 543
 544 # WebKit feature conditionals
 545 AM_CONDITIONAL([ENABLE_DEBUG],[test "$enable_debug" = "yes"])
 546 AM_CONDITIONAL([ENABLE_DASHBOARD_SUPPORT],[test "$enable_dashboard_support" = "yes"])
 547 AM_CONDITIONAL([ENABLE_CROSS_DOCUMENT_MESSAGING],[test "$enable_cross_document_messaging" = "yes"])
 548 AM_CONDITIONAL([ENABLE_OFFLINE_WEB_APPLICATIONS],[test "$enable_offline_web_applications" = "yes"])
 549 AM_CONDITIONAL([ENABLE_DOM_STORAGE],[test "$enable_dom_storage" = "yes"])
 550 AM_CONDITIONAL([ENABLE_DATABASE],[test "$enable_database" = "yes"])
 551 AM_CONDITIONAL([ENABLE_ICONDATABASE],[test "$enable_icon_database" = "yes"])
 552 AM_CONDITIONAL([ENABLE_XPATH],[test "$enable_xpath" = "yes"])
 553 AM_CONDITIONAL([ENABLE_XSLT],[test "$enable_xslt" = "yes"])
 554 AM_CONDITIONAL([ENABLE_VIDEO],[test "$enable_video" = "yes"])
 555 AM_CONDITIONAL([ENABLE_SVG],[test "$enable_svg" = "yes"])
 556 AM_CONDITIONAL([ENABLE_SVG_ANIMATION],[test "$enable_svg_animation" = "yes"])
 557 AM_CONDITIONAL([ENABLE_SVG_FILTERS],[test "$enable_svg_filters" = "yes"])
 558 AM_CONDITIONAL([ENABLE_SVG_FONTS],[test "$enable_svg_fonts" = "yes"])
 559 AM_CONDITIONAL([ENABLE_SVG_FOREIGN_OBJECT],[test "$enable_svg_foreign_object" = "yes"])
 560 AM_CONDITIONAL([ENABLE_SVG_AS_IMAGE],[test "$enable_svg_as_image" = "yes"])
 561 AM_CONDITIONAL([ENABLE_SVG_USE],[test "$enable_svg_use_element" = "yes"])
 562 AM_CONDITIONAL([ENABLE_COVERAGE],[test "$enable_coverage" = "yes"])
 563 AM_CONDITIONAL([ENABLE_FAST_MALLOC],[test "$enable_fast_malloc" = "yes"])
 564 AM_CONDITIONAL([SVG_FLAGS],[test "$svg_flags" = "yes"])
 565 AM_CONDITIONAL([HTML_FLAGS],[test "$html_flags" = "yes"])
 566
 567 AC_CONFIG_FILES([
 568 GNUmakefile
 569 WebKit/gtk/webkit-1.0.pc:WebKit/gtk/webkit.pc.in
 570 ]
 571 )
 572
 573 AC_OUTPUT
 574
 575 echo "
 576 WebKit was configured with the following options:
 577
 578 Build configuration:
 579  Enable debugging (slow)                                  : $enable_debug
 580  Code coverage support                                    : $enable_coverage
 581  Unicode backend                                          : $unicode_backend
 582  HTTP backend                                             : $with_http_backend
 583  Font backend                                             : $with_font_backend
 584  Optimized memory allocator                               : $enable_fast_malloc
 585 Features:
 586  Dashboard support                                        : $enable_dashboard_support
 587  HTML5 cross-document messaging                           : $enable_cross_document_messaging
 588  HTML5 offline web applications support                   : $enable_offline_web_applications
 589  HTML5 client-side session and persistent storage support : $enable_dom_storage
 590  HTML5 client-side database storage support               : $enable_database
 591  HTML5 video element support                              : $enable_video
 592  Icon database support                                    : $enable_icon_database
 593  SVG support                                              : $enable_svg
 594  SVG animation support                                    : $enable_svg_animation
 595  SVG filters support                                      : $enable_svg_filters
 596  SVG fonts support                                        : $enable_svg_fonts
 597  SVG foreign object support                               : $enable_svg_foreign_object
 598  SVG as image support                                     : $enable_svg_as_image
 599  SVG use element support                                  : $enable_svg_use_element
 600  XPATH support                                            : $enable_xpath
 601  XSLT support                                             : $enable_xslt
 602 GTK+ configuration:
 603  GDK target                                               : $with_target
 604  Hildon UI extensions                                     : $with_hildon
 605 "