Upgrade to Bugzilla 5.0.3.
[WebKit-https.git] / Websites / bugs.webkit.org / whineatnews.pl
1 #!/usr/bin/perl
2 # This Source Code Form is subject to the terms of the Mozilla Public
3 # License, v. 2.0. If a copy of the MPL was not distributed with this
4 # file, You can obtain one at http://mozilla.org/MPL/2.0/.
5 #
6 # This Source Code Form is "Incompatible With Secondary Licenses", as
7 # defined by the Mozilla Public License, v. 2.0.
8
9
10 # This is a script suitable for running once a day from a cron job.  It 
11 # looks at all the bugs, and sends whiny mail to anyone who has a bug 
12 # assigned to them that has status CONFIRMED, NEW, or REOPENED that has not
13 # been touched for more than the number of days specified in the whinedays
14 # param. (We have NEW and REOPENED in there to keep compatibility with old
15 # Bugzillas.)
16
17 use 5.10.1;
18 use strict;
19 use warnings;
20
21 use lib qw(. lib);
22
23 use Bugzilla;
24 use Bugzilla::Mailer;
25 use Bugzilla::Util;
26 use Bugzilla::User;
27
28 # Whining is disabled if whinedays is zero
29 exit unless Bugzilla->params->{'whinedays'} >= 1;
30
31 my $dbh = Bugzilla->dbh;
32 my $query = q{SELECT bug_id, short_desc, login_name
33                 FROM bugs
34           INNER JOIN profiles
35                   ON userid = assigned_to
36                WHERE bug_status IN (?,?,?)
37                  AND disable_mail = 0
38                  AND } . $dbh->sql_to_days('NOW()') . " - " .
39                        $dbh->sql_to_days('delta_ts') . " > " .
40                        Bugzilla->params->{'whinedays'} .
41           " ORDER BY bug_id";
42
43 my %bugs;
44 my %desc;
45
46 my $slt_bugs = $dbh->selectall_arrayref($query, undef, 'CONFIRMED', 'NEW',
47                                                        'REOPENED');
48
49 foreach my $bug (@$slt_bugs) {
50     my ($id, $desc, $email) = @$bug;
51     if (!defined $bugs{$email}) {
52         $bugs{$email} = [];
53     }
54     if (!defined $desc{$email}) {
55         $desc{$email} = [];
56     }
57     push @{$bugs{$email}}, $id;
58     push @{$desc{$email}}, $desc;
59 }
60
61
62 foreach my $email (sort (keys %bugs)) {
63     my $user = new Bugzilla::User({name => $email});
64     next if $user->email_disabled;
65
66     my $vars = {'email' => $email};
67
68     my @bugs = ();
69     foreach my $i (@{$bugs{$email}}) {
70         my $bug = {};
71         $bug->{'summary'} = shift(@{$desc{$email}});
72         $bug->{'id'} = $i;
73         push @bugs, $bug;
74     }
75     $vars->{'bugs'} = \@bugs;
76
77     my $msg;
78     my $template = Bugzilla->template_inner($user->setting('lang'));
79     $template->process("email/whine.txt.tmpl", $vars, \$msg)
80       or die($template->error());
81
82     MessageToMTA($msg);
83
84     say "$email      " . join(" ", @{$bugs{$email}});
85 }