[Qt] Build files for the WTR's InjectedBundle
[WebKit-https.git] / WebKitTools / WebKitTestRunner / DerivedSources.pro
1 # DerivedSources - qmake build info
2
3 CONFIG -= debug_and_release
4
5 TEMPLATE = lib
6 TARGET = dummy
7
8 QMAKE_EXTRA_TARGETS += generated_files
9
10 GENERATED_SOURCES_DIR = generated
11
12 IDL_BINDINGS += \
13     InjectedBundle/Bindings/EventSendingController.idl \
14     InjectedBundle/Bindings/GCController.idl \
15     InjectedBundle/Bindings/LayoutTestController.idl \
16
17 defineTest(addExtraCompiler) {
18     eval($${1}.CONFIG = target_predeps no_link)
19     eval($${1}.variable_out =)
20     eval($${1}.dependency_type = TYPE_C)
21
22     wkScript = $$eval($${1}.wkScript)
23     eval($${1}.depends += $$wkScript)
24
25     export($${1}.CONFIG)
26     export($${1}.variable_out)
27     export($${1}.dependency_type)
28     export($${1}.depends)
29
30     QMAKE_EXTRA_COMPILERS += $$1
31     generated_files.depends += compiler_$${1}_make_all
32     export(QMAKE_EXTRA_COMPILERS)
33     export(generated_files.depends)
34     return(true)
35 }
36
37 SRC_ROOT_DIR = $$replace(PWD, /WebKitTools/WebKitTestRunner, /)
38
39 # Make sure forwarded headers needed by this project are present
40 fwheader_generator.commands = perl $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl $${SRC_ROOT_DIR}/WebKitTools/WebKitTestRunner $${OUTPUT_DIR}/include qt
41 fwheader_generator.depends  = $${SRC_ROOT_DIR}/WebKitTools/Scripts/generate-forwarding-headers.pl
42 generated_files.depends     += fwheader_generator
43 QMAKE_EXTRA_TARGETS         += fwheader_generator
44
45 # GENERATOR 1: IDL compiler
46 idl.output = $${GENERATED_SOURCES_DIR}/JS${QMAKE_FILE_BASE}.cpp
47 idl.input = IDL_BINDINGS
48 idl.wkScript = $$PWD/../../WebCore/bindings/scripts/generate-bindings.pl
49 idl.commands = perl -I$$PWD/../../WebCore/bindings/scripts -I$$PWD/InjectedBundle/Bindings $$idl.wkScript --defines \"\" --generator TestRunner --include $$PWD/InjectedBundle/Bindings --outputDir $$GENERATED_SOURCES_DIR --preprocessor \"$${QMAKE_MOC} -E\" ${QMAKE_FILE_NAME}
50 idl.depends = $$PWD/../../WebCore/bindings/scripts/CodeGenerator.pm \
51               $$PWD/InjectedBundle/Bindings/CodeGeneratorTestRunner.pm \
52               $$PWD/../../WebCore/bindings/scripts/IDLParser.pm \
53               $$PWD/../../WebCore/bindings/scripts/IDLStructure.pm \
54               $$PWD/../../WebCore/bindings/scripts/InFilesParser.pm \
55               $$PWD/../../WebCore/bindings/scripts/generate-bindings.pl
56 addExtraCompiler(idl)
57