WebKitTools/Scripts/webkitperl/httpd.pm

   1 # Copyright (C) 2005, 2006, 2007, 2008, 2009 Apple Inc. All rights reserved
   2 # Copyright (C) 2006 Alexey Proskuryakov (ap@nypop.com)
   3 # Copyright (C) 2010 Andras Becsi (abecsi@inf.u-szeged.hu), University of Szeged
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 # 1.  Redistributions of source code must retain the above copyright
  10 #     notice, this list of conditions and the following disclaimer.
  11 # 2.  Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in the
  13 #     documentation and/or other materials provided with the distribution.
  14 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
  15 #     its contributors may be used to endorse or promote products derived
  16 #     from this software without specific prior written permission.
  17 #
  18 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
  19 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  21 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
  22 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  25 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  27 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28
  29 # Module to share code to start and stop the Apache daemon.
  30
  31 use strict;
  32 use warnings;
  33
  34 use File::Path;
  35 use File::Spec;
  36 use File::Spec::Functions;
  37 use IPC::Open2;
  38
  39 use webkitdirs;
  40
  41 BEGIN {
  42    use Exporter   ();
  43    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  44    $VERSION     = 1.00;
  45    @ISA         = qw(Exporter);
  46    @EXPORT      = qw(&getHTTPDPath &getDefaultConfigForTestDirectory &openHTTPD &closeHTTPD &getHTTPDPid &setShouldWaitForUserInterrupt);
  47    %EXPORT_TAGS = ( );
  48    @EXPORT_OK   = ();
  49 }
  50
  51 my $tmpDir = "/tmp";
  52 my $httpdPath;
  53 my $httpdPidDir = File::Spec->catfile($tmpDir, "WebKit");
  54 my $httpdPidFile = File::Spec->catfile($httpdPidDir, "httpd.pid");
  55 my $httpdPid;
  56 my $waitForUserInterrupt = 0;
  57
  58 $SIG{'INT'} = 'cleanup';
  59 $SIG{'TERM'} = 'cleanup';
  60
  61 sub getHTTPDPath
  62 {
  63     if (isDebianBased()) {
  64         $httpdPath = "/usr/sbin/apache2";
  65     } else {
  66         $httpdPath = "/usr/sbin/httpd";
  67     }
  68     return $httpdPath;
  69 }
  70
  71 sub getDefaultConfigForTestDirectory
  72 {
  73     my ($testDirectory) = @_;
  74     die "No test directory has been specified." unless ($testDirectory);
  75
  76     my $httpdConfig;
  77     getHTTPDPath();
  78     if (isCygwin()) {
  79         my $windowsConfDirectory = "$testDirectory/http/conf/";
  80         unless (-x "/usr/lib/apache/libphp4.dll") {
  81             copy("$windowsConfDirectory/libphp4.dll", "/usr/lib/apache/libphp4.dll");
  82             chmod(0755, "/usr/lib/apache/libphp4.dll");
  83         }
  84         $httpdConfig = "$windowsConfDirectory/cygwin-httpd.conf";
  85     } elsif (isDebianBased()) {
  86         $httpdConfig = "$testDirectory/http/conf/apache2-debian-httpd.conf";
  87     } elsif (isFedoraBased()) {
  88         $httpdConfig = "$testDirectory/http/conf/fedora-httpd.conf";
  89     } else {
  90         $httpdConfig = "$testDirectory/http/conf/httpd.conf";
  91         $httpdConfig = "$testDirectory/http/conf/apache2-httpd.conf" if `$httpdPath -v` =~ m|Apache/2|;
  92     }
  93
  94     my $documentRoot = "$testDirectory/http/tests";
  95     my $jsTestResourcesDirectory = $testDirectory . "/fast/js/resources";
  96     my $typesConfig = "$testDirectory/http/conf/mime.types";
  97     my $httpdLockFile = File::Spec->catfile($httpdPidDir, "httpd.lock");
  98     my $httpdScoreBoardFile = File::Spec->catfile($httpdPidDir, "httpd.scoreboard");
  99
 100     my @httpdArgs = (
 101         "-f", "$httpdConfig",
 102         "-C", "DocumentRoot \"$documentRoot\"",
 103         # Setup a link to where the js test templates are stored, use -c so that mod_alias will already be loaded.
 104         "-c", "Alias /js-test-resources \"$jsTestResourcesDirectory\"",
 105         "-c", "TypesConfig \"$typesConfig\"",
 106         # Apache wouldn't run CGIs with permissions==700 otherwise
 107         "-c", "User \"#$<\"",
 108         "-c", "LockFile \"$httpdLockFile\"",
 109         "-c", "PidFile \"$httpdPidFile\"",
 110         "-c", "ScoreBoardFile \"$httpdScoreBoardFile\"",
 111     );
 112
 113     # FIXME: Enable this on Windows once <rdar://problem/5345985> is fixed
 114     # The version of Apache we use with Cygwin does not support SSL
 115     my $sslCertificate = "$testDirectory/http/conf/webkit-httpd.pem";
 116     push(@httpdArgs, "-c", "SSLCertificateFile \"$sslCertificate\"") unless isCygwin();
 117
 118     return @httpdArgs;
 119
 120 }
 121
 122 sub openHTTPD(@)
 123 {
 124     my (@args) = @_;
 125     die "No HTTPD configuration has been specified" unless (@args);
 126     mkdir($httpdPidDir, 0755);
 127     die "No write permissions to $httpdPidDir" unless (-w $httpdPidDir);
 128
 129     if (-f $httpdPidFile) {
 130         open (PIDFILE, $httpdPidFile);
 131         my $oldPid = <PIDFILE>;
 132         chomp $oldPid;
 133         close PIDFILE;
 134         if (0 != kill 0, $oldPid) {
 135             print "\nhttpd is already running: pid $oldPid, killing...\n";
 136             kill 15, $oldPid;
 137
 138             my $retryCount = 20;
 139             while ((kill(0, $oldPid) != 0) && $retryCount) {
 140                 sleep 1;
 141                 --$retryCount;
 142             }
 143
 144             die "Timed out waiting for httpd to quit" unless $retryCount;
 145         }
 146     }
 147
 148     $httpdPath = "/usr/sbin/httpd" unless ($httpdPath);
 149
 150     open2(\*HTTPDIN, \*HTTPDOUT, $httpdPath, @args);
 151
 152     my $retryCount = 20;
 153     while (!-f $httpdPidFile && $retryCount) {
 154         sleep 1;
 155         --$retryCount;
 156     }
 157
 158     if (!$retryCount) {
 159         rmtree $httpdPidDir;
 160         die "Timed out waiting for httpd to start";
 161     }
 162
 163     $httpdPid = <PIDFILE> if open(PIDFILE, $httpdPidFile);
 164     chomp $httpdPid if $httpdPid;
 165     close PIDFILE;
 166
 167     waitpid($httpdPid, 0) if ($waitForUserInterrupt && $httpdPid);
 168
 169     return 1;
 170 }
 171
 172 sub closeHTTPD
 173 {
 174     close HTTPDIN;
 175     close HTTPDOUT;
 176
 177     if ($httpdPid) {
 178         kill 15, $httpdPid;
 179         my $retryCount = 20;
 180         while (-f $httpdPidFile && $retryCount) {
 181             sleep 1;
 182             --$retryCount;
 183         }
 184
 185         if (!$retryCount) {
 186             print STDERR "Timed out waiting for httpd to terminate!\n";
 187             return 0;
 188         }
 189     }
 190     rmdir $httpdPidDir;
 191     return 1;
 192 }
 193
 194 sub setShouldWaitForUserInterrupt
 195 {
 196     $waitForUserInterrupt = 1;
 197 }
 198
 199 sub cleanup
 200 {
 201     closeHTTPD();
 202     print "\n";
 203     exit(1);
 204 }