95c4a6c0d5c0914574d3c517909052c59740d5e6
[WebKit-https.git] / WebKitTools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005, 2006, 2007 Apple Inc. All rights reserved.
2 #
3 # Redistribution and use in source and binary forms, with or without
4 # modification, are permitted provided that the following conditions
5 # are met:
6 #
7 # 1.  Redistributions of source code must retain the above copyright
8 #     notice, this list of conditions and the following disclaimer. 
9 # 2.  Redistributions in binary form must reproduce the above copyright
10 #     notice, this list of conditions and the following disclaimer in the
11 #     documentation and/or other materials provided with the distribution. 
12 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
13 #     its contributors may be used to endorse or promote products derived
14 #     from this software without specific prior written permission. 
15 #
16 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
17 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
18 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
19 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
20 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
21 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
22 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
23 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
24 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
25 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
26
27 # Module to share code to get to WebKit directories.
28
29 use strict;
30 use warnings;
31 use FindBin;
32 use File::Basename;
33 use POSIX;
34 use VCSUtils;
35
36 BEGIN {
37    use Exporter   ();
38    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
39    $VERSION     = 1.00;
40    @ISA         = qw(Exporter);
41    @EXPORT      = qw(&chdirWebKit &baseProductDir &productDir &XcodeOptions &XcodeOptionString &XcodeOptionStringNoConfig &passedConfiguration &setConfiguration &safariPath &checkFrameworks &currentSVNRevision);
42    %EXPORT_TAGS = ( );
43    @EXPORT_OK   = ();
44 }
45
46 our @EXPORT_OK;
47
48 my $baseProductDir;
49 my @baseProductDirOption;
50 my $configuration;
51 my $configurationForVisualStudio;
52 my $configurationProductDir;
53 my $sourceDir;
54 my $currentSVNRevision;
55 my $osXVersion;
56 my $isQt;
57 my $isGtk;
58 my $isWx;
59 my $isChromium;
60 my $forceRun64Bit;
61
62 # Variables for Win32 support
63 my $vcBuildPath;
64 my $windowsTmpPath;
65
66 sub determineSourceDir
67 {
68     return if $sourceDir;
69     $sourceDir = $FindBin::Bin;
70     $sourceDir =~ s|/+$||; # Remove trailing '/' as we would die later
71
72     # walks up path checking each directory to see if it is the main WebKit project dir, 
73     # defined by containing JavaScriptCore, WebCore, and WebKit
74     until ((-d "$sourceDir/JavaScriptCore" && -d "$sourceDir/WebCore" && -d "$sourceDir/WebKit") || (-d "$sourceDir/Internal" && -d "$sourceDir/OpenSource"))
75     {
76         if ($sourceDir !~ s|/[^/]+$||) {
77             die "Could not find top level webkit directory above source directory using FindBin.\n";
78         }
79     }
80
81     $sourceDir = "$sourceDir/OpenSource" if -d "$sourceDir/OpenSource";
82 }
83
84 # used for scripts which are stored in a non-standard location
85 sub setSourceDir($)
86 {
87     ($sourceDir) = @_;
88 }
89
90 sub determineBaseProductDir
91 {
92     return if defined $baseProductDir;
93     determineSourceDir();
94     if (isAppleMacWebKit()) {
95         open PRODUCT, "defaults read com.apple.Xcode PBXApplicationwideBuildSettings 2> /dev/null |" or die;
96         $baseProductDir = join '', <PRODUCT>;
97         close PRODUCT;
98
99         $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
100         undef $baseProductDir unless $baseProductDir =~ /^\//;
101
102         if (!defined($baseProductDir)) {
103             open PRODUCT, "defaults read com.apple.Xcode PBXProductDirectory 2> /dev/null |" or die;
104             $baseProductDir = <PRODUCT>;
105             close PRODUCT;
106             if ($baseProductDir) {
107                 chomp $baseProductDir;
108                 undef $baseProductDir unless $baseProductDir =~ /^\//;
109             }
110         }
111     } else {
112         $baseProductDir = $ENV{"WEBKITOUTPUTDIR"};
113         if (isAppleWinWebKit() && $baseProductDir) {
114             my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
115             chomp $unixBuildPath;
116             $baseProductDir = $unixBuildPath;
117         }
118     }
119
120     if ($baseProductDir && isAppleMacWebKit()) {
121         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
122         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
123         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
124         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
125         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
126         @baseProductDirOption = ();
127     }
128
129     if (!defined($baseProductDir)) {
130         $baseProductDir = "$sourceDir/WebKitBuild";
131
132         if (isGit() && isGitBranchBuild()) {
133             my $branch = gitBranch();
134             $baseProductDir = "$baseProductDir/$branch";
135         }
136
137         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir") if (isAppleMacWebKit());
138         if (isCygwin()) {
139             my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
140             chomp $dosBuildPath;
141             $ENV{"WEBKITOUTPUTDIR"} = $dosBuildPath;
142         }
143     }
144 }
145
146 sub setBaseProductDir($)
147 {
148     ($baseProductDir) = @_;
149 }
150
151 sub determineConfiguration
152 {
153     return if defined $configuration;
154     determineBaseProductDir();
155     if (open CONFIGURATION, "$baseProductDir/Configuration") {
156         $configuration = <CONFIGURATION>;
157         close CONFIGURATION;
158     }
159     if ($configuration) {
160         chomp $configuration;
161         # compatibility for people who have old Configuration files
162         $configuration = "Release" if $configuration eq "Deployment";
163         $configuration = "Debug" if $configuration eq "Development";
164     } else {
165         $configuration = "Release";
166     }
167 }
168
169 sub argumentsForConfiguration()
170 {
171     determineConfiguration();
172
173     my @args = ();
174     push(@args, '--debug') if $configuration eq "Debug";
175     push(@args, '--release') if $configuration eq "Release";
176     push(@args, '--qt') if isQt();
177     push(@args, '--gtk') if isGtk();
178     push(@args, '--wx') if isWx();
179     push(@args, '--chromium') if isChromium();
180     return @args;
181 }
182
183 sub determineConfigurationForVisualStudio
184 {
185     return if defined $configurationForVisualStudio;
186     determineConfiguration();
187     $configurationForVisualStudio = $configuration;
188     return unless $configuration eq "Debug";
189     setupCygwinEnv();
190     chomp(my $dir = `cygpath -ua '$ENV{WEBKITLIBRARIESDIR}'`);
191     $configurationForVisualStudio = "Debug_Internal" if -f "$dir/bin/CoreFoundation_debug.dll";
192 }
193
194 sub determineConfigurationProductDir
195 {
196     return if defined $configurationProductDir;
197     determineBaseProductDir();
198     determineConfiguration();
199     if (isAppleWinWebKit() && !isWx()) {
200         $configurationProductDir = "$baseProductDir/bin";
201     } else {
202         $configurationProductDir = "$baseProductDir/$configuration";
203     }
204 }
205
206 sub setConfigurationProductDir($)
207 {
208     ($configurationProductDir) = @_;
209 }
210
211 sub determineCurrentSVNRevision
212 {
213     return if defined $currentSVNRevision;
214     determineSourceDir();
215     my $svnInfo = `LC_ALL=C svn info $sourceDir | grep Revision:`;
216     ($currentSVNRevision) = ($svnInfo =~ m/Revision: (\d+).*/g);
217     die "Unable to determine current SVN revision in $sourceDir" unless (defined $currentSVNRevision);
218     return $currentSVNRevision;
219 }
220
221
222 sub chdirWebKit
223 {
224     determineSourceDir();
225     chdir $sourceDir or die;
226 }
227
228 sub baseProductDir
229 {
230     determineBaseProductDir();
231     return $baseProductDir;
232 }
233
234 sub sourceDir
235 {
236     determineSourceDir();
237     return $sourceDir;
238 }
239
240 sub productDir
241 {
242     determineConfigurationProductDir();
243     return $configurationProductDir;
244 }
245
246 sub configuration()
247 {
248     determineConfiguration();
249     return $configuration;
250 }
251
252 sub configurationForVisualStudio()
253 {
254     determineConfigurationForVisualStudio();
255     return $configurationForVisualStudio;
256 }
257
258 sub currentSVNRevision
259 {
260     determineCurrentSVNRevision();
261     return $currentSVNRevision;
262 }
263
264 sub XcodeOptions
265 {
266     determineBaseProductDir();
267     determineConfiguration();
268     return (@baseProductDirOption, "-configuration", $configuration);
269 }
270
271 sub XcodeOptionString
272 {
273     return join " ", XcodeOptions();
274 }
275
276 sub XcodeOptionStringNoConfig
277 {
278     return join " ", @baseProductDirOption;
279 }
280
281 sub XcodeCoverageSupportOptions()
282 {
283     my @coverageSupportOptions = ();
284     push @coverageSupportOptions, "GCC_GENERATE_TEST_COVERAGE_FILES=YES";
285     push @coverageSupportOptions, "GCC_INSTRUMENT_PROGRAM_FLOW_ARCS=YES";
286     push @coverageSupportOptions, "EXTRA_LINK= -ftest-coverage -fprofile-arcs";
287     push @coverageSupportOptions, "OTHER_CFLAGS= -MD";
288     push @coverageSupportOptions, "OTHER_LDFLAGS=\$(OTHER_LDFLAGS) -ftest-coverage -fprofile-arcs -framework AppKit";
289     return @coverageSupportOptions;
290 }
291
292 my $passedConfiguration;
293 my $searchedForPassedConfiguration;
294 sub determinePassedConfiguration
295 {
296     return if $searchedForPassedConfiguration;
297     $searchedForPassedConfiguration = 1;
298
299     my $isWinCairo = checkForArgumentAndRemoveFromARGV("--cairo-win32");
300
301     for my $i (0 .. $#ARGV) {
302         my $opt = $ARGV[$i];
303         if ($opt =~ /^--debug$/i || $opt =~ /^--devel/i) {
304             splice(@ARGV, $i, 1);
305             $passedConfiguration = "Debug";
306             $passedConfiguration .= "_Cairo" if ($isWinCairo && isCygwin());
307             return;
308         }
309         if ($opt =~ /^--release$/i || $opt =~ /^--deploy/i) {
310             splice(@ARGV, $i, 1);
311             $passedConfiguration = "Release";
312             $passedConfiguration .= "_Cairo" if ($isWinCairo && isCygwin());
313             return;
314         }
315         if ($opt =~ /^--profil(e|ing)$/i) {
316             splice(@ARGV, $i, 1);
317             $passedConfiguration = "Profiling";
318             $passedConfiguration .= "_Cairo" if ($isWinCairo && isCygwin());
319             return;
320         }
321     }
322     $passedConfiguration = undef;
323 }
324
325 sub passedConfiguration
326 {
327     determinePassedConfiguration();
328     return $passedConfiguration;
329 }
330
331 sub setConfiguration
332 {
333     if (my $config = shift @_) {
334         $configuration = $config;
335         return;
336     }
337
338     determinePassedConfiguration();
339     $configuration = $passedConfiguration if $passedConfiguration;
340 }
341
342 sub safariPathFromSafariBundle
343 {
344     my ($safariBundle) = @_;
345
346     return "$safariBundle/Contents/MacOS/Safari" if isAppleMacWebKit();
347     return $safariBundle if isAppleWinWebKit();
348 }
349
350 sub installedSafariPath
351 {
352     my $safariBundle;
353
354     if (isAppleMacWebKit()) {
355         $safariBundle = "/Applications/Safari.app";
356     } elsif (isAppleWinWebKit()) {
357         $safariBundle = `"$configurationProductDir/FindSafari.exe"`;
358         $safariBundle =~ s/[\r\n]+$//;
359         $safariBundle = `cygpath -u '$safariBundle'`;
360         $safariBundle =~ s/[\r\n]+$//;
361         $safariBundle .= "Safari.exe";
362     }
363
364     return safariPathFromSafariBundle($safariBundle);
365 }
366
367 # Locate Safari.
368 sub safariPath
369 {
370     # Use WEBKIT_SAFARI environment variable if present.
371     my $safariBundle = $ENV{WEBKIT_SAFARI};
372     if (!$safariBundle) {
373         determineConfigurationProductDir();
374         # Use Safari.app in product directory if present (good for Safari development team).
375         if (isAppleMacWebKit() && -d "$configurationProductDir/Safari.app") {
376             $safariBundle = "$configurationProductDir/Safari.app";
377         } elsif (isAppleWinWebKit() && -x "$configurationProductDir/bin/Safari.exe") {
378             $safariBundle = "$configurationProductDir/bin/Safari.exe";
379         } else {
380             return installedSafariPath();
381         }
382     }
383     my $safariPath = safariPathFromSafariBundle($safariBundle);
384     die "Can't find executable at $safariPath.\n" if isAppleMacWebKit() && !-x $safariPath;
385     return $safariPath;
386 }
387
388 sub builtDylibPathForName
389 {
390     my $libraryName = shift;
391     determineConfigurationProductDir();
392     if (isQt() or isGtk() or isChromium()) {
393         return "$configurationProductDir/$libraryName";
394     }
395     if (isAppleMacWebKit()) {
396         return "$configurationProductDir/$libraryName.framework/Versions/A/$libraryName";
397     }
398     if (isAppleWinWebKit()) {
399         if ($libraryName eq "JavaScriptCore") {
400             return "$baseProductDir/lib/$libraryName.lib";
401         } else {
402             return "$baseProductDir/$libraryName.intermediate/$configuration/$libraryName.intermediate/$libraryName.lib";
403         }
404     }
405
406     die "Unsupported platform, can't determine built library locations.";
407 }
408
409 # Check to see that all the frameworks are built.
410 sub checkFrameworks
411 {
412     return if isCygwin();
413     my @frameworks = ("JavaScriptCore", "WebCore");
414     push(@frameworks, "WebKit") if isAppleMacWebKit();
415     for my $framework (@frameworks) {
416         my $path = builtDylibPathForName($framework);
417         die "Can't find built framework at \"$path\".\n" unless -x $path;
418     }
419 }
420
421 sub hasSVGSupport
422 {
423     return 0 if isCygwin();
424
425     my $path = shift;
426
427     if (isQt()) {
428         return 1;
429     }
430
431     if (isGtk() and $path =~ /WebCore/) {
432         $path .= "/../.libs/libwebkit-1.0.so";
433     }
434
435     my $hasSVGSupport = 0;
436     if (-e $path) {
437         open NM, "-|", "nm", $path or die;
438         while (<NM>) {
439             $hasSVGSupport = 1 if /SVGElement/;
440         }
441         close NM;
442     }
443     return $hasSVGSupport;
444 }
445
446 sub removeLibraryDependingOnSVG
447 {
448     my $frameworkName = shift;
449     my $shouldHaveSVG = shift;
450
451     my $path = builtDylibPathForName($frameworkName);
452     return unless -x $path;
453
454     my $hasSVG = hasSVGSupport($path);
455     system "rm -f $path" if ($shouldHaveSVG xor $hasSVG);
456 }
457
458 sub checkWebCoreSVGSupport
459 {
460     my $required = shift;
461     my $framework = "WebCore";
462     my $path = builtDylibPathForName($framework);
463     my $hasSVG = hasSVGSupport($path);
464     if ($required && !$hasSVG) {
465         die "$framework at \"$path\" does not include SVG Support, please run build-webkit --svg\n";
466     }
467     return $hasSVG;
468 }
469
470 sub hasWMLSupport
471 {
472     return 0 if isCygwin();
473
474     my $path = shift;
475
476     if (isQt()) {
477         # FIXME: Check built library for WML support, just like Gtk does it below.
478         return 0;
479     }
480
481     if (isGtk() and $path =~ /WebCore/) {
482         $path .= "/../.libs/webkit-1.0.so";
483     }
484
485     my $hasWMLSupport = 0;
486     if (-e $path) {
487         open NM, "-|", "nm", $path or die;
488         while (<NM>) {
489             $hasWMLSupport = 1 if /WMLElement/;
490         }
491         close NM;
492     }
493     return $hasWMLSupport;
494 }
495
496 sub removeLibraryDependingOnWML
497 {
498     my $frameworkName = shift;
499     my $shouldHaveWML = shift;
500
501     my $path = builtDylibPathForName($frameworkName);
502     return unless -x $path;
503
504     my $hasWML = hasWMLSupport($path);
505     system "rm -f $path" if ($shouldHaveWML xor $hasWML);
506 }
507
508 sub checkWebCoreWMLSupport
509 {
510     my $required = shift;
511     my $framework = "WebCore";
512     my $path = builtDylibPathForName($framework);
513     my $hasWML = hasWMLSupport($path);
514     if ($required && !$hasWML) {
515         die "$framework at \"$path\" does not include WML Support, please run build-webkit --wml\n";
516     }
517     return $hasWML;
518 }
519
520 sub isQt()
521 {
522     determineIsQt();
523     return $isQt;
524 }
525
526 sub checkForArgumentAndRemoveFromARGV
527 {
528     my $argToCheck = shift;
529     foreach my $opt (@ARGV) {
530         if ($opt =~ /^$argToCheck/i ) {
531             @ARGV = grep(!/^$argToCheck/i, @ARGV);
532             return 1;
533         }
534     }
535     return 0;
536 }
537
538 sub determineIsQt()
539 {
540     return if defined($isQt);
541
542     # Allow override in case QTDIR is not set.
543     if (checkForArgumentAndRemoveFromARGV("--qt")) {
544         $isQt = 1;
545         return;
546     }
547
548     # The presence of QTDIR only means Qt if --gtk is not on the command-line
549     if (isGtk()) {
550         $isQt = 0;
551         return;
552     }
553     
554     $isQt = defined($ENV{'QTDIR'});
555 }
556
557 sub isGtk()
558 {
559     determineIsGtk();
560     return $isGtk;
561 }
562
563 sub determineIsGtk()
564 {
565     return if defined($isGtk);
566     $isGtk = checkForArgumentAndRemoveFromARGV("--gtk");
567 }
568
569 sub isWx()
570 {
571     determineIsWx();
572     return $isWx;
573 }
574
575 sub determineIsWx()
576 {
577     return if defined($isWx);
578     $isWx = checkForArgumentAndRemoveFromARGV("--wx");
579 }
580
581 # Determine if this is debian, ubuntu, linspire, or something similar.
582 sub isDebianBased()
583 {
584     return -e "/etc/debian_version";
585 }
586
587 sub isChromium()
588 {
589     determineIsChromium();
590     return $isChromium;
591 }
592
593 sub determineIsChromium()
594 {
595     return if defined($isChromium);
596     $isChromium = checkForArgumentAndRemoveFromARGV("--chromium");
597 }
598
599 sub isCygwin()
600 {
601     return ($^O eq "cygwin") || 0;
602 }
603
604 sub isDarwin()
605 {
606     return ($^O eq "darwin") || 0;
607 }
608
609 sub isAppleWebKit()
610 {
611     return !(isQt() or isGtk() or isWx() or isChromium());
612 }
613
614 sub isAppleMacWebKit()
615 {
616     return isAppleWebKit() && isDarwin();
617 }
618
619 sub isAppleWinWebKit()
620 {
621     return isAppleWebKit() && isCygwin();
622 }
623
624 sub determineOSXVersion()
625 {
626     return if $osXVersion;
627
628     if (!isDarwin()) {
629         $osXVersion = -1;
630         return;
631     }
632
633     my $version = `sw_vers -productVersion`;
634     my @splitVersion = split(/\./, $version);
635     @splitVersion >= 2 or die "Invalid version $version";
636     $osXVersion = {
637             "major" => $splitVersion[0],
638             "minor" => $splitVersion[1],
639             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
640     };
641 }
642
643 sub osXVersion()
644 {
645     determineOSXVersion();
646     return $osXVersion;
647 }
648
649 sub isTiger()
650 {
651     return isDarwin() && osXVersion()->{"minor"} == 4;
652 }
653
654 sub isLeopard()
655 {
656     return isDarwin() && osXVersion()->{"minor"} == 5;
657 }
658
659 sub isSnowLeopard()
660 {
661     return isDarwin() && osXVersion()->{"minor"} == 6;
662 }
663
664 sub relativeScriptsDir()
665 {
666     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel(dirname($0), getcwd()), "");
667     if ($scriptDir eq "") {
668         $scriptDir = ".";
669     }
670     return $scriptDir;
671 }
672
673 sub launcherPath()
674 {
675     my $relativeScriptsPath = relativeScriptsDir();
676     if (isGtk() || isQt()) {
677         return "$relativeScriptsPath/run-launcher";
678     } elsif (isAppleWebKit()) {
679         return "$relativeScriptsPath/run-safari";
680     }
681 }
682
683 sub launcherName()
684 {
685     if (isGtk()) {
686         return "GtkLauncher";
687     } elsif (isQt()) {
688         return "QtLauncher";
689     } elsif (isAppleWebKit()) {
690         return "Safari";
691     }
692 }
693
694 sub checkRequiredSystemConfig
695 {
696     if (isDarwin()) {
697         chomp(my $productVersion = `sw_vers -productVersion`);
698         if ($productVersion lt "10.4") {
699             print "*************************************************************\n";
700             print "Mac OS X Version 10.4.0 or later is required to build WebKit.\n";
701             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
702             print "*************************************************************\n";
703         }
704         my $xcodeVersion = `xcodebuild -version`;
705         if ($xcodeVersion !~ /DevToolsCore-(\d+)/ || $1 < 747) {
706             print "*************************************************************\n";
707             print "Xcode Version 2.3 or later is required to build WebKit.\n";
708             print "You have an earlier version of Xcode, thus the build will\n";
709             print "most likely fail.  The latest Xcode is available from the web:\n";
710             print "http://developer.apple.com/tools/xcode\n";
711             print "*************************************************************\n";
712         }
713     } elsif (isGtk() or isQt() or isWx()) {
714         my @cmds = qw(flex bison gperf);
715         my @missing = ();
716         foreach my $cmd (@cmds) {
717             if (not `$cmd --version`) {
718                 push @missing, $cmd;
719             }
720         }
721         if (@missing) {
722             my $list = join ", ", @missing;
723             die "ERROR: $list missing but required to build WebKit.\n";
724         }
725     }
726     # Win32 and other platforms may want to check for minimum config
727 }
728
729 sub setupCygwinEnv()
730 {
731     return if !isCygwin();
732     return if $vcBuildPath;
733
734     my $programFilesPath = `cygpath "$ENV{'PROGRAMFILES'}"`;
735     chomp $programFilesPath;
736     $vcBuildPath = "$programFilesPath/Microsoft Visual Studio 8/Common7/IDE/devenv.com";
737     if (! -e $vcBuildPath) {
738         # VC++ not found, try VC++ Express
739         my $vsInstallDir;
740         if ($ENV{'VSINSTALLDIR'}) {
741             $vsInstallDir = $ENV{'VSINSTALLDIR'};
742         } else {
743             $programFilesPath = $ENV{'PROGRAMFILES'} || "C:\\Program Files";
744             $vsInstallDir = "$programFilesPath/Microsoft Visual Studio 8";
745         }
746         $vsInstallDir = `cygpath "$vsInstallDir"`;
747         chomp $vsInstallDir;
748         $vcBuildPath = "$vsInstallDir/Common7/IDE/VCExpress.exe";
749         if (! -e $vcBuildPath) {
750             print "*************************************************************\n";
751             print "Cannot find '$vcBuildPath'\n";
752             print "Please execute the file 'vcvars32.bat' from\n";
753             print "'$programFilesPath\\Microsoft Visual Studio 8\\VC\\bin\\'\n";
754             print "to setup the necessary environment variables.\n";
755             print "*************************************************************\n";
756             die;
757         }
758     }
759
760     my $qtSDKPath = "$programFilesPath/QuickTime SDK";
761     if (0 && ! -e $qtSDKPath) {
762         print "*************************************************************\n";
763         print "Cannot find '$qtSDKPath'\n";
764         print "Please download the QuickTime SDK for Windows from\n";
765         print "http://developer.apple.com/quicktime/download/\n";
766         print "*************************************************************\n";
767         die;
768     }
769     
770     chomp($ENV{'WEBKITLIBRARIESDIR'} = `cygpath -wa "$sourceDir/WebKitLibraries/win"`) unless $ENV{'WEBKITLIBRARIESDIR'};
771
772     $windowsTmpPath = `cygpath -w /tmp`;
773     chomp $windowsTmpPath;
774     print "Building results into: ", baseProductDir(), "\n";
775     print "WEBKITOUTPUTDIR is set to: ", $ENV{"WEBKITOUTPUTDIR"}, "\n";
776     print "WEBKITLIBRARIESDIR is set to: ", $ENV{"WEBKITLIBRARIESDIR"}, "\n";
777 }
778
779 sub buildXCodeProject($$@)
780 {
781     my ($project, $clean, @extraOptions) = @_;
782
783     if ($clean) {
784         push(@extraOptions, "-alltargets");
785         push(@extraOptions, "clean");
786     }
787
788     return system "xcodebuild", "-project", "$project.xcodeproj", @extraOptions;
789 }
790
791 sub buildVisualStudioProject
792 {
793     my ($project, $clean) = @_;
794     setupCygwinEnv();
795
796     my $config = configurationForVisualStudio();
797
798     chomp(my $winProjectPath = `cygpath -w "$project"`);
799     
800     my $command = "/build";
801     if ($clean) {
802         $command = "/clean";
803     }
804
805     print "$vcBuildPath $winProjectPath /build $config\n";
806     return system $vcBuildPath, $winProjectPath, $command, $config;
807 }
808
809 sub buildSconsProject
810 {
811     my ($project, $shouldClean) = @_;
812     print "Building from $project/$project.scons\n";
813
814     my $sconsCommand = "scons";
815     if (isCygwin()) {
816         # HACK: Launch scons with Win32 python instead of CYGWIN python
817         # Scons + MSVC only works under Win32 python
818         # http://scons.tigris.org/issues/show_bug.cgi?id=2266
819         $sconsCommand = "cmd /c 'C:\\Python26\\Scripts\\scons'";
820     }
821     if ($shouldClean) {
822         return system $sconsCommand, "--clean";
823     }
824     return system $sconsCommand;
825 }
826
827 sub retrieveQMakespecVar
828 {
829     my $mkspec = $_[0];
830     my $varname = $_[1];
831
832     my $compiler = "unknown";
833     #print "retrieveMakespecVar " . $mkspec . ", " . $varname . "\n";
834
835     local *SPEC;
836     open SPEC, "<$mkspec" or return "make";
837     while (<SPEC>) {
838         if ($_ =~ /\s*include\((.+)\)/) {
839             # open the included mkspec
840             my $oldcwd = getcwd();
841             (my $volume, my $directories, my $file) = File::Spec->splitpath($mkspec);
842             chdir "$volume$directories";
843             $compiler = retrieveQMakespecVar($1, $varname);
844             chdir $oldcwd;
845         } elsif ($_ =~ /$varname\s*=\s*([^\s]+)/) {
846             $compiler = $1;
847             last;
848         }
849     }
850     close SPEC;
851     return $compiler;
852 }
853
854 sub qtMakeCommand($)
855 {
856     my ($qmakebin) = @_;
857     chomp(my $mkspec = `$qmakebin -query QMAKE_MKSPECS`);
858     $mkspec .= "/default";
859     my $compiler = retrieveQMakespecVar("$mkspec/qmake.conf", "QMAKE_CC");
860
861     #print "default spec: " . $mkspec . "\n";
862     #print "compiler found: " . $compiler . "\n";
863
864     if ($compiler eq "cl") {
865         return "nmake";
866     }
867
868     return "make";
869 }
870
871 sub autotoolsFlag($$)
872 {
873     my ($flag, $feature) = @_;
874     my $prefix = $flag ? "--enable" : "--disable";
875
876     return $prefix . '-' . $feature;
877 }
878
879 sub buildAutotoolsProject($@)
880 {
881     my ($clean, @buildArgs) = @_;
882
883     my $make = 'make';
884     my $dir = productDir();
885     my $config = passedConfiguration() || configuration();
886     my $prefix = $ENV{"WebKitInstallationPrefix"};
887
888     # check if configuration is Debug
889     if ($config =~ m/debug/i) {
890         push @buildArgs, "--enable-debug";
891     } else {
892         push @buildArgs, "--disable-debug";
893     }
894
895     # Use rm to clean the build directory since distclean may miss files
896     if ($clean && -d $dir) {
897         system "rm", "-rf", "$dir";
898     }
899
900     if (! -d $dir) {
901         system "mkdir", "-p", "$dir";
902         if (! -d $dir) {
903             die "Failed to create build directory " . $dir;
904         }
905     }
906
907     chdir $dir or die "Failed to cd into " . $dir . "\n";
908
909     my $result;
910     if ($clean) {
911         #$result = system $make, "distclean";
912         return 0;
913     }
914
915     print "Calling configure in " . $dir . "\n\n";
916     print "Installation directory: $prefix\n" if(defined($prefix));
917
918     # Make the path relative since it will appear in all -I compiler flags.
919     # Long argument lists cause bizarre slowdowns in libtool.
920     my $relSourceDir = File::Spec->abs2rel($sourceDir);
921     $relSourceDir = "." if !$relSourceDir;
922
923     $result = system "$relSourceDir/autogen.sh", @buildArgs;
924     if ($result ne 0) {
925         die "Failed to setup build environment using 'autotools'!\n";
926     }
927
928     $result = system $make;
929     if ($result ne 0) {
930         die "\nFailed to build WebKit using '$make'!\n";
931     }
932
933     chdir ".." or die;
934     return $result;
935 }
936
937 sub buildQMakeProject($@)
938 {
939     my ($clean, @buildArgs) = @_;
940
941     push @buildArgs, "-r";
942
943     my $qmakebin = "qmake"; # Allow override of the qmake binary from $PATH
944     for my $i (0 .. $#ARGV) {
945         my $opt = $ARGV[$i];
946         if ($opt =~ /^--qmake=(.*)/i ) {
947             $qmakebin = $1;
948         } elsif ($opt =~ /^--qmakearg=(.*)/i ) {
949             push @buildArgs, $1;
950         }
951     }
952
953     my $make = qtMakeCommand($qmakebin);
954     my $config = configuration();
955     my $prefix = $ENV{"WebKitInstallationPrefix"};
956
957     push @buildArgs, "OUTPUT_DIR=" . baseProductDir() . "/$config";
958     push @buildArgs, sourceDir() . "/WebKit.pro";
959     if ($config =~ m/debug/i) {
960         push @buildArgs, "CONFIG-=release";
961         push @buildArgs, "CONFIG+=debug";
962     } else {
963         push @buildArgs, "CONFIG+=release";
964         push @buildArgs, "CONFIG-=debug";
965     }
966
967     my $dir = baseProductDir();
968     if (! -d $dir) {
969         system "mkdir", "-p", "$dir";
970         if (! -d $dir) {
971             die "Failed to create product directory " . $dir;
972         }
973     }
974     $dir = $dir . "/$config";
975     if (! -d $dir) {
976         system "mkdir", "-p", "$dir";
977         if (! -d $dir) {
978             die "Failed to create build directory " . $dir;
979         }
980     }
981
982     chdir $dir or die "Failed to cd into " . $dir . "\n";
983
984     print "Calling '$qmakebin @buildArgs' in " . $dir . "\n\n";
985     print "Installation directory: $prefix\n" if(defined($prefix));
986
987     my $result = system $qmakebin, @buildArgs;
988     if ($result ne 0) {
989        die "Failed to setup build environment using $qmakebin!\n";
990     }
991
992     if ($clean) {
993       $result = system "$make distclean";
994     } else {
995       $result = system "$make";
996     }
997
998     chdir ".." or die;
999     return $result;
1000 }
1001
1002 sub buildQMakeQtProject($$@)
1003 {
1004     my ($project, $clean, @buildArgs) = @_;
1005
1006     push @buildArgs, "CONFIG+=qt-port";
1007
1008     return buildQMakeProject($clean, @buildArgs);
1009 }
1010
1011 sub buildGtkProject($$@)
1012 {
1013     my ($project, $clean, @buildArgs) = @_;
1014
1015     if ($project ne "WebKit") {
1016         die "The Gtk port builds JavaScriptCore, WebCore and WebKit in one shot! Only call it for 'WebKit'.\n";
1017     }
1018
1019     return buildAutotoolsProject($clean, @buildArgs);
1020 }
1021
1022 sub setPathForRunningWebKitApp
1023 {
1024     my ($env) = @_;
1025
1026     return unless isAppleWinWebKit();
1027
1028     $env->{PATH} = join(':', productDir(), dirname(installedSafariPath()), $env->{PATH} || "");
1029 }
1030
1031 sub exitStatus($)
1032 {
1033     my ($returnvalue) = @_;
1034     if ($^O eq "MSWin32") {
1035         return $returnvalue >> 8;
1036     }
1037     return WEXITSTATUS($returnvalue);
1038 }
1039
1040 sub runSafari
1041 {
1042     my ($debugger) = @_;
1043
1044     if (isAppleMacWebKit()) {
1045         return system "$FindBin::Bin/gdb-safari", @ARGV if $debugger;
1046
1047         my $productDir = productDir();
1048         print "Starting Safari with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
1049         $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
1050         $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
1051         exportArchPreference();
1052         if (!isTiger()) {
1053             return system "arch", safariPath(), @ARGV;
1054         } else {
1055             return system safariPath(), @ARGV;
1056         }
1057     }
1058
1059     if (isAppleWinWebKit()) {
1060         my $script = "run-webkit-nightly.cmd";
1061         my $result = system "cp", "$FindBin::Bin/$script", productDir();
1062         return $result if $result;
1063
1064         my $cwd = getcwd();
1065         chdir productDir();
1066
1067         my $debuggerFlag = $debugger ? "/debugger" : "";
1068         $result = system "cmd", "/c", "call $script $debuggerFlag";
1069         chdir $cwd;
1070         return $result;
1071     }
1072
1073     return 1;
1074 }
1075
1076 sub setRun64Bit($)
1077 {
1078     ($forceRun64Bit) = @_;
1079 }
1080
1081 sub preferredArchitecture
1082 {
1083     return unless isAppleMacWebKit();
1084     
1085     my $framework = shift;
1086     $framework = "WebKit" if !defined($framework);
1087
1088     my $currentArchitecture = `arch`;
1089     chomp($currentArchitecture);
1090
1091     my $run64Bit = 0;
1092     if (!defined($forceRun64Bit)) {
1093         my $frameworkPath = builtDylibPathForName($framework);
1094         die "Couldn't find path for $framework" if !defined($frameworkPath);
1095         # The binary is 64-bit if one of the architectures it contains has "64" in the name
1096         $run64Bit = `lipo -info "$frameworkPath"` =~ /(are|architecture):.*64/;
1097     }
1098
1099     if ($forceRun64Bit or $run64Bit) {
1100         return ($currentArchitecture eq "i386") ? "x86_64" : "ppc64";
1101     }
1102     return $currentArchitecture;
1103 }
1104
1105 sub exportArchPreference
1106 {
1107     $ENV{ARCHPREFERENCE} = preferredArchitecture() if isAppleMacWebKit();
1108 }
1109
1110 1;