WebKitTools/Scripts/webkitdirs.pm

   1 # Copyright (C) 2005, 2006, 2007 Apple Inc. All rights reserved.
   2 #
   3 # Redistribution and use in source and binary forms, with or without
   4 # modification, are permitted provided that the following conditions
   5 # are met:
   6 #
   7 # 1.  Redistributions of source code must retain the above copyright
   8 #     notice, this list of conditions and the following disclaimer.
   9 # 2.  Redistributions in binary form must reproduce the above copyright
  10 #     notice, this list of conditions and the following disclaimer in the
  11 #     documentation and/or other materials provided with the distribution.
  12 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
  13 #     its contributors may be used to endorse or promote products derived
  14 #     from this software without specific prior written permission.
  15 #
  16 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
  17 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  18 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  19 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
  20 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  21 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  22 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  23 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  24 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  25 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26
  27 # Module to share code to get to WebKit directories.
  28
  29 use strict;
  30 use warnings;
  31 use FindBin;
  32 use File::Basename;
  33 use POSIX;
  34 use VCSUtils;
  35
  36 BEGIN {
  37    use Exporter   ();
  38    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  39    $VERSION     = 1.00;
  40    @ISA         = qw(Exporter);
  41    @EXPORT      = qw(&chdirWebKit &baseProductDir &productDir &XcodeOptions &XcodeOptionString &XcodeOptionStringNoConfig &passedConfiguration &setConfiguration &safariPath &checkFrameworks &currentSVNRevision);
  42    %EXPORT_TAGS = ( );
  43    @EXPORT_OK   = ();
  44 }
  45
  46 our @EXPORT_OK;
  47
  48 my $baseProductDir;
  49 my @baseProductDirOption;
  50 my $configuration;
  51 my $configurationForVisualStudio;
  52 my $configurationProductDir;
  53 my $sourceDir;
  54 my $currentSVNRevision;
  55 my $osXVersion;
  56 my $isQt;
  57 my $isGtk;
  58 my $isWx;
  59
  60 # Variables for Win32 support
  61 my $vcBuildPath;
  62 my $windowsTmpPath;
  63
  64 sub determineSourceDir
  65 {
  66     return if $sourceDir;
  67     $sourceDir = $FindBin::Bin;
  68
  69     # walks up path checking each directory to see if it is the main WebKit project dir,
  70     # defined by containing JavaScriptCore, WebCore, and WebKit
  71     until ((-d "$sourceDir/JavaScriptCore" && -d "$sourceDir/WebCore" && -d "$sourceDir/WebKit") || (-d "$sourceDir/Internal" && -d "$sourceDir/OpenSource"))
  72     {
  73         if ($sourceDir !~ s|/[^/]+$||) {
  74             die "Could not find top level webkit directory above source directory using FindBin.\n";
  75         }
  76     }
  77
  78     $sourceDir = "$sourceDir/OpenSource" if -d "$sourceDir/OpenSource";
  79 }
  80
  81 # used for scripts which are stored in a non-standard location
  82 sub setSourceDir($)
  83 {
  84     ($sourceDir) = @_;
  85 }
  86
  87 sub determineBaseProductDir
  88 {
  89     return if defined $baseProductDir;
  90     determineSourceDir();
  91     if (isOSX()) {
  92         open PRODUCT, "defaults read com.apple.Xcode PBXApplicationwideBuildSettings 2> /dev/null |" or die;
  93         $baseProductDir = join '', <PRODUCT>;
  94         close PRODUCT;
  95
  96         $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
  97         undef $baseProductDir unless $baseProductDir =~ /^\//;
  98
  99         if (!defined($baseProductDir)) {
 100             open PRODUCT, "defaults read com.apple.Xcode PBXProductDirectory 2> /dev/null |" or die;
 101             $baseProductDir = <PRODUCT>;
 102             close PRODUCT;
 103             if ($baseProductDir) {
 104                 chomp $baseProductDir;
 105                 undef $baseProductDir unless $baseProductDir =~ /^\//;
 106             }
 107         }
 108     } else {
 109         $baseProductDir = $ENV{"WEBKITOUTPUTDIR"};
 110         if (isCygwin() && $baseProductDir) {
 111             my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
 112             chomp $unixBuildPath;
 113             $baseProductDir = $unixBuildPath;
 114         }
 115     }
 116
 117     if ($baseProductDir && isOSX()) {
 118         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
 119         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
 120         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
 121         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
 122         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
 123         @baseProductDirOption = ();
 124     }
 125
 126     if (!defined($baseProductDir)) {
 127         $baseProductDir = "$sourceDir/WebKitBuild";
 128
 129         if (isGit() && isGitBranchBuild()) {
 130             my $branch = gitBranch();
 131             $baseProductDir = "$baseProductDir/$branch";
 132         }
 133
 134         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir") if (isOSX());
 135         if (isCygwin()) {
 136             my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
 137             chomp $dosBuildPath;
 138             $ENV{"WEBKITOUTPUTDIR"} = $dosBuildPath;
 139         }
 140     }
 141 }
 142
 143 sub setBaseProductDir($)
 144 {
 145     ($baseProductDir) = @_;
 146 }
 147
 148 sub determineConfiguration
 149 {
 150     return if defined $configuration;
 151     determineBaseProductDir();
 152     if (open CONFIGURATION, "$baseProductDir/Configuration") {
 153         $configuration = <CONFIGURATION>;
 154         close CONFIGURATION;
 155     }
 156     if ($configuration) {
 157         chomp $configuration;
 158         # compatibility for people who have old Configuration files
 159         $configuration = "Release" if $configuration eq "Deployment";
 160         $configuration = "Debug" if $configuration eq "Development";
 161     } else {
 162         $configuration = "Release";
 163     }
 164 }
 165
 166 sub determineConfigurationForVisualStudio
 167 {
 168     return if defined $configurationForVisualStudio;
 169     determineConfiguration();
 170     $configurationForVisualStudio = $configuration;
 171     return unless $configuration eq "Debug";
 172     setupCygwinEnv();
 173     chomp(my $dir = `cygpath -ua '$ENV{WEBKITLIBRARIESDIR}'`);
 174     $configurationForVisualStudio = "Debug_Internal" if -f "$dir/bin/CoreFoundation_debug.dll";
 175 }
 176
 177 sub determineConfigurationProductDir
 178 {
 179     return if defined $configurationProductDir;
 180     determineBaseProductDir();
 181     if(isCygwin() && !isWx()) {
 182         $configurationProductDir = "$baseProductDir/bin";
 183     } else {
 184         determineConfiguration();
 185         $configurationProductDir = "$baseProductDir/$configuration";
 186     }
 187 }
 188
 189 sub setConfigurationProductDir($)
 190 {
 191     ($configurationProductDir) = @_;
 192 }
 193
 194 sub determineCurrentSVNRevision
 195 {
 196     return if defined $currentSVNRevision;
 197     determineSourceDir();
 198     my $svnInfo = `LC_ALL=C svn info $sourceDir | grep Revision:`;
 199     ($currentSVNRevision) = ($svnInfo =~ m/Revision: (\d+).*/g);
 200     die "Unable to determine current SVN revision in $sourceDir" unless (defined $currentSVNRevision);
 201     return $currentSVNRevision;
 202 }
 203
 204
 205 sub chdirWebKit
 206 {
 207     determineSourceDir();
 208     chdir $sourceDir or die;
 209 }
 210
 211 sub baseProductDir
 212 {
 213     determineBaseProductDir();
 214     return $baseProductDir;
 215 }
 216
 217 sub sourceDir
 218 {
 219     determineSourceDir();
 220     return $sourceDir;
 221 }
 222
 223 sub productDir
 224 {
 225     determineConfigurationProductDir();
 226     return $configurationProductDir;
 227 }
 228
 229 sub configuration()
 230 {
 231     determineConfiguration();
 232     return $configuration;
 233 }
 234
 235 sub configurationForVisualStudio()
 236 {
 237     determineConfigurationForVisualStudio();
 238     return $configurationForVisualStudio;
 239 }
 240
 241 sub currentSVNRevision
 242 {
 243     determineCurrentSVNRevision();
 244     return $currentSVNRevision;
 245 }
 246
 247 sub XcodeOptions
 248 {
 249     determineBaseProductDir();
 250     determineConfiguration();
 251     return (@baseProductDirOption, "-configuration", $configuration);
 252 }
 253
 254 sub XcodeOptionString
 255 {
 256     return join " ", XcodeOptions();
 257 }
 258
 259 sub XcodeOptionStringNoConfig
 260 {
 261     return join " ", @baseProductDirOption;
 262 }
 263
 264 my $passedConfiguration;
 265 my $searchedForPassedConfiguration;
 266 sub determinePassedConfiguration
 267 {
 268     return if $searchedForPassedConfiguration;
 269     $searchedForPassedConfiguration = 1;
 270     for my $i (0 .. $#ARGV) {
 271         my $opt = $ARGV[$i];
 272         if ($opt =~ /^--debug$/i || $opt =~ /^--devel/i) {
 273             splice(@ARGV, $i, 1);
 274             $passedConfiguration = "Debug";
 275             return;
 276         }
 277         if ($opt =~ /^--release$/i || $opt =~ /^--deploy/i) {
 278             splice(@ARGV, $i, 1);
 279             $passedConfiguration = "Release";
 280             return;
 281         }
 282     }
 283     $passedConfiguration = undef;
 284 }
 285
 286 sub passedConfiguration
 287 {
 288     determinePassedConfiguration();
 289     return $passedConfiguration;
 290 }
 291
 292 sub setConfiguration
 293 {
 294     if (my $config = shift @_) {
 295         $configuration = $config;
 296         return;
 297     }
 298
 299     determinePassedConfiguration();
 300     $configuration = $passedConfiguration if $passedConfiguration;
 301 }
 302
 303 sub safariPathFromSafariBundle
 304 {
 305     my ($safariBundle) = @_;
 306
 307     return "$safariBundle/Contents/MacOS/Safari" if isOSX();
 308     return $safariBundle if isCygwin();
 309 }
 310
 311 sub installedSafariPath
 312 {
 313     my $safariBundle;
 314
 315     if (isOSX()) {
 316         $safariBundle = "/Applications/Safari.app";
 317     } elsif (isCygwin()) {
 318         my $findSafariName = "FindSafari";
 319         $findSafariName .= "_debug" if $configuration ne "Release";
 320         $findSafariName .= ".exe";
 321
 322         $safariBundle = `"$configurationProductDir/$findSafariName"`;
 323         $safariBundle =~ s/[\r\n]+$//;
 324         $safariBundle = `cygpath -u '$safariBundle'`;
 325         $safariBundle =~ s/[\r\n]+$//;
 326         $safariBundle .= "Safari.exe";
 327     }
 328
 329     return safariPathFromSafariBundle($safariBundle);
 330 }
 331
 332 # Locate Safari.
 333 sub safariPath
 334 {
 335     # Use WEBKIT_SAFARI environment variable if present.
 336     my $safariBundle = $ENV{WEBKIT_SAFARI};
 337     if (!$safariBundle) {
 338         determineConfigurationProductDir();
 339         # Use Safari.app in product directory if present (good for Safari development team).
 340         if (isOSX() && -d "$configurationProductDir/Safari.app") {
 341             $safariBundle = "$configurationProductDir/Safari.app";
 342         } elsif (isCygwin() && -x "$configurationProductDir/bin/Safari.exe") {
 343             $safariBundle = "$configurationProductDir/bin/Safari.exe";
 344         } else {
 345             return installedSafariPath();
 346         }
 347     }
 348     my $safariPath = safariPathFromSafariBundle($safariBundle);
 349     die "Can't find executable at $safariPath.\n" if isOSX() && !-x $safariPath;
 350     return $safariPath;
 351 }
 352
 353 sub builtDylibPathForName
 354 {
 355     my $framework = shift;
 356     determineConfigurationProductDir();
 357     if (isQt() or isGtk()) {
 358         return "$configurationProductDir/$framework";
 359     }
 360     if (isOSX()) {
 361         return "$configurationProductDir/$framework.framework/Versions/A/$framework";
 362     }
 363     if (isCygwin()) {
 364         if ($framework eq "JavaScriptCore") {
 365                 return "$baseProductDir/lib/$framework.lib";
 366         } else {
 367             return "$baseProductDir/$framework.intermediate/$configuration/$framework.intermediate/$framework.lib";
 368         }
 369     }
 370
 371     die "Unsupported platform, can't determine built library locations.";
 372 }
 373
 374 # Check to see that all the frameworks are built.
 375 sub checkFrameworks
 376 {
 377     return if isCygwin();
 378     my @frameworks = ("JavaScriptCore", "WebCore");
 379     push(@frameworks, "WebKit") if isOSX();
 380     for my $framework (@frameworks) {
 381         my $path = builtDylibPathForName($framework);
 382         die "Can't find built framework at \"$path\".\n" unless -x $path;
 383     }
 384 }
 385
 386 sub hasSVGSupport
 387 {
 388     return 0 if isCygwin();
 389
 390     my $path = shift;
 391
 392     if (isQt()) {
 393         return 1;
 394     }
 395
 396     if (isGtk() and $path =~ /WebCore/) {
 397         $path .= "/../lib/libWebKitGtk.so";
 398     }
 399
 400     open NM, "-|", "nm", $path or die;
 401     my $hasSVGSupport = 0;
 402     while (<NM>) {
 403         $hasSVGSupport = 1 if /SVGElement/;
 404     }
 405     close NM;
 406     return $hasSVGSupport;
 407 }
 408
 409 sub removeLibraryDependingOnSVG
 410 {
 411     my $frameworkName = shift;
 412     my $shouldHaveSVG = shift;
 413
 414     my $path = builtDylibPathForName($frameworkName);
 415     return unless -x $path;
 416
 417     my $hasSVG = hasSVGSupport($path);
 418     system "rm -f $path" if ($shouldHaveSVG xor $hasSVG);
 419 }
 420
 421 sub checkWebCoreSVGSupport
 422 {
 423     my $required = shift;
 424     my $framework = "WebCore";
 425     my $path = builtDylibPathForName($framework);
 426     my $hasSVG = hasSVGSupport($path);
 427     if ($required && !$hasSVG) {
 428         die "$framework at \"$path\" does not include SVG Support, please run build-webkit --svg\n";
 429     }
 430     return $hasSVG;
 431 }
 432
 433 sub isQt()
 434 {
 435     determineIsQt();
 436     return $isQt;
 437 }
 438
 439 sub checkArgv($)
 440 {
 441     my $argToCheck = shift;
 442     foreach my $opt (@ARGV) {
 443         if ($opt =~ /^$argToCheck/i ) {
 444             @ARGV = grep(!/^$argToCheck/i, @ARGV);
 445             return 1;
 446         }
 447     }
 448     return 0;
 449 }
 450
 451 sub determineIsQt()
 452 {
 453     return if defined($isQt);
 454
 455     # Allow override in case QTDIR is not set.
 456     if (checkArgv("--qt")) {
 457         $isQt = 1;
 458         return;
 459     }
 460
 461     # The presence of QTDIR only means Qt if --gtk is not on the command-line
 462     if (isGtk()) {
 463         $isQt = 0;
 464         return;
 465     }
 466
 467     $isQt = defined($ENV{'QTDIR'});
 468 }
 469
 470 sub isGtk()
 471 {
 472     determineIsGtk();
 473     return $isGtk;
 474 }
 475
 476 sub determineIsGtk()
 477 {
 478     return if defined($isGtk);
 479
 480     if (checkArgv("--gtk")) {
 481         $isGtk = 1;
 482     } else {
 483         $isGtk = 0;
 484     }
 485 }
 486
 487 sub isWx()
 488 {
 489     determineIsWx();
 490     return $isWx;
 491 }
 492
 493 sub determineIsWx()
 494 {
 495     return if defined($isWx);
 496
 497     if (checkArgv("--wx")) {
 498         $isWx = 1;
 499     } else {
 500         $isWx = 0;
 501     }
 502 }
 503
 504 # Determine if this is debian, ubuntu, linspire, or something similar.
 505 sub isDebianBased()
 506 {
 507     return -e "/etc/debian_version";
 508 }
 509
 510 sub isCygwin()
 511 {
 512     return ($^O eq "cygwin");
 513 }
 514
 515 sub isDarwin()
 516 {
 517     return ($^O eq "darwin");
 518 }
 519
 520 sub isOSX()
 521 {
 522     return isDarwin() unless (isQt() or isGtk() or isWx());
 523     return 0;
 524 }
 525
 526 sub determineOSXVersion()
 527 {
 528     return if $osXVersion;
 529
 530     if (!isOSX()) {
 531         $osXVersion = -1;
 532         return;
 533     }
 534
 535     my $version = `sw_vers -productVersion`;
 536     my @splitVersion = split(/\./, $version);
 537     @splitVersion >= 2 or die "Invalid version $version";
 538     $osXVersion = {
 539             "major" => $splitVersion[0],
 540             "minor" => $splitVersion[1],
 541             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
 542     };
 543 }
 544
 545 sub osXVersion()
 546 {
 547     determineOSXVersion();
 548     return $osXVersion;
 549 }
 550
 551 sub isTiger()
 552 {
 553     return isOSX() && osXVersion()->{"minor"} == 4;
 554 }
 555
 556 sub isLeopard()
 557 {
 558     return isOSX() && osXVersion()->{"minor"} == 5;
 559 }
 560
 561 sub relativeScriptsDir()
 562 {
 563     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel(dirname($0), getcwd()), "");
 564     if ($scriptDir eq "") {
 565         $scriptDir = ".";
 566     }
 567     return $scriptDir;
 568 }
 569
 570 sub launcherPath()
 571 {
 572     my $relativeScriptsPath = relativeScriptsDir();
 573     if (isGtk() || isQt()) {
 574         return "$relativeScriptsPath/run-launcher";
 575     } elsif (isOSX() || isCygwin()) {
 576         return "$relativeScriptsPath/run-safari";
 577     }
 578 }
 579
 580 sub launcherName()
 581 {
 582     if (isGtk()) {
 583         return "GtkLauncher";
 584     } elsif (isQt()) {
 585         return "QtLauncher";
 586     } elsif (isOSX() || isCygwin()) {
 587         return "Safari";
 588     }
 589 }
 590
 591 sub checkRequiredSystemConfig
 592 {
 593     if (isOSX()) {
 594         chomp(my $productVersion = `sw_vers -productVersion`);
 595         if ($productVersion lt "10.4") {
 596             print "*************************************************************\n";
 597             print "Mac OS X Version 10.4.0 or later is required to build WebKit.\n";
 598             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
 599             print "*************************************************************\n";
 600         }
 601         my $xcodeVersion = `xcodebuild -version`;
 602         if ($xcodeVersion !~ /DevToolsCore-(\d+)/ || $1 < 747) {
 603             print "*************************************************************\n";
 604             print "Xcode Version 2.3 or later is required to build WebKit.\n";
 605             print "You have an earlier version of Xcode, thus the build will\n";
 606             print "most likely fail.  The latest Xcode is available from the web:\n";
 607             print "http://developer.apple.com/tools/xcode\n";
 608             print "*************************************************************\n";
 609         }
 610     } elsif (isGtk() or isQt() or isWx()) {
 611         my @cmds = qw(flex bison gperf);
 612         my @missing = ();
 613         foreach my $cmd (@cmds) {
 614             if (not `$cmd --version`) {
 615                 push @missing, $cmd;
 616             }
 617         }
 618         if (@missing) {
 619             my $list = join ", ", @missing;
 620             die "ERROR: $list missing but required to build WebKit.\n";
 621         }
 622     }
 623     # Win32 and other platforms may want to check for minimum config
 624 }
 625
 626 sub setupCygwinEnv()
 627 {
 628     return if !isCygwin();
 629     return if $vcBuildPath;
 630
 631     my $programFilesPath = `cygpath "$ENV{'PROGRAMFILES'}"`;
 632     chomp $programFilesPath;
 633     $vcBuildPath = "$programFilesPath/Microsoft Visual Studio 8/Common7/IDE/devenv.com";
 634     if (! -e $vcBuildPath) {
 635         # VC++ not found, try VC++ Express
 636         my $vsInstallDir;
 637         if ($ENV{'VSINSTALLDIR'}) {
 638             $vsInstallDir = $ENV{'VSINSTALLDIR'};
 639         } else {
 640             $programFilesPath = $ENV{'PROGRAMFILES'} || "C:\\Program Files";
 641             $vsInstallDir = "$programFilesPath/Microsoft Visual Studio 8";
 642         }
 643         $vsInstallDir = `cygpath "$vsInstallDir"`;
 644         chomp $vsInstallDir;
 645         $vcBuildPath = "$vsInstallDir/Common7/IDE/VCExpress.exe";
 646         if (! -e $vcBuildPath) {
 647             print "*************************************************************\n";
 648             print "Cannot find '$vcBuildPath'\n";
 649             print "Please execute the file 'vcvars32.bat' from\n";
 650             print "'$programFilesPath\\Microsoft Visual Studio 8\\VC\\bin\\'\n";
 651             print "to setup the necessary environment variables.\n";
 652             print "*************************************************************\n";
 653             die;
 654         }
 655     }
 656
 657     my $qtSDKPath = "$programFilesPath/QuickTime SDK";
 658     if (0 && ! -e $qtSDKPath) {
 659         print "*************************************************************\n";
 660         print "Cannot find '$qtSDKPath'\n";
 661         print "Please download the QuickTime SDK for Windows from\n";
 662         print "http://developer.apple.com/quicktime/download/\n";
 663         print "*************************************************************\n";
 664         die;
 665     }
 666
 667     chomp($ENV{'WEBKITLIBRARIESDIR'} = `cygpath -wa "$sourceDir/WebKitLibraries/win"`) unless $ENV{'WEBKITLIBRARIESDIR'};
 668
 669     $windowsTmpPath = `cygpath -w /tmp`;
 670     chomp $windowsTmpPath;
 671     print "Building results into: ", baseProductDir(), "\n";
 672     print "WEBKITOUTPUTDIR is set to: ", $ENV{"WEBKITOUTPUTDIR"}, "\n";
 673     print "WEBKITLIBRARIESDIR is set to: ", $ENV{"WEBKITLIBRARIESDIR"}, "\n";
 674 }
 675
 676 sub buildVisualStudioProject
 677 {
 678     my ($project, $clean) = @_;
 679     setupCygwinEnv();
 680
 681     my $config = configurationForVisualStudio();
 682
 683     chomp(my $winProjectPath = `cygpath -w "$project"`);
 684
 685     my $command = "/build";
 686     if ($clean) {
 687         $command = "/clean";
 688     }
 689
 690     print "$vcBuildPath $winProjectPath /build $config\n";
 691     return system $vcBuildPath, $winProjectPath, $command, $config;
 692 }
 693
 694 sub qtMakeCommand($)
 695 {
 696     my ($qmakebin) = @_;
 697     chomp(my $mkspec = `$qmakebin -query QMAKE_MKSPECS`);
 698     $mkspec .= "/default";
 699
 700     my $compiler = "";
 701     open SPEC, "<$mkspec/qmake.conf" or return "make";
 702     while (<SPEC>) {
 703         if ($_ =~ /QMAKE_CC\s*=\s*([^\s]+)/) {
 704             $compiler = $1;
 705         }
 706     }
 707     close SPEC;
 708
 709     #print "default spec: " . $mkspec . "\n";
 710     #print "compiler found: " . $compiler . "\n";
 711
 712     if ($compiler eq "cl") {
 713         return "nmake";
 714     }
 715
 716     return "make";
 717 }
 718
 719 sub buildQMakeProject($@)
 720 {
 721     my ($clean, @buildArgs) = @_;
 722
 723     push @buildArgs, "-r";
 724
 725     my $qmakebin = "qmake"; # Allow override of the qmake binary from $PATH
 726     for my $i (0 .. $#ARGV) {
 727         my $opt = $ARGV[$i];
 728         if ($opt =~ /^--qmake=(.*)/i ) {
 729             $qmakebin = $1;
 730         } elsif ($opt =~ /^--qmakearg=(.*)/i ) {
 731             push @buildArgs, $1;
 732         }
 733     }
 734
 735     my $make = qtMakeCommand($qmakebin);
 736     my $config = configuration();
 737     my $prefix = $ENV{"WebKitInstallationPrefix"};
 738
 739     push @buildArgs, "OUTPUT_DIR=" . baseProductDir() . "/$config";
 740     push @buildArgs, sourceDir() . "/WebKit.pro";
 741     if ($config =~ m/debug/i) {
 742         push @buildArgs, "CONFIG-=release";
 743         push @buildArgs, "CONFIG+=debug";
 744     } else {
 745         push @buildArgs, "CONFIG+=release";
 746         push @buildArgs, "CONFIG-=debug";
 747     }
 748
 749     my $dir = baseProductDir();
 750     if (! -d $dir) {
 751         system "mkdir", "-p", "$dir";
 752         if (! -d $dir) {
 753             die "Failed to create product directory " . $dir;
 754         }
 755     }
 756     $dir = $dir . "/$config";
 757     if (! -d $dir) {
 758         system "mkdir", "-p", "$dir";
 759         if (! -d $dir) {
 760             die "Failed to create build directory " . $dir;
 761         }
 762     }
 763
 764     chdir $dir or die "Failed to cd into " . $dir . "\n";
 765
 766     print "Calling '$qmakebin @buildArgs' in " . $dir . "\n\n";
 767     print "Installation directory: $prefix\n" if(defined($prefix));
 768
 769     my $result = system $qmakebin, @buildArgs;
 770     if ($result ne 0) {
 771        die "Failed to setup build environment using $qmakebin!\n";
 772     }
 773
 774     if ($clean) {
 775       $result = system "$make distclean";
 776     } else {
 777       $result = system "$make";
 778     }
 779
 780     chdir ".." or die;
 781     return $result;
 782 }
 783
 784 sub buildQMakeQtProject($$)
 785 {
 786     my ($project, $clean) = @_;
 787
 788     my @buildArgs = ("CONFIG+=qt-port");
 789     return buildQMakeProject($clean, @buildArgs);
 790 }
 791
 792 sub buildQMakeGtkProject($$)
 793 {
 794     my ($project, $clean) = @_;
 795
 796     if ($project ne "WebKit") {
 797         die "The Gtk portbuilds JavaScriptCore/WebCore/WebKitQt in one shot! Only call it for 'WebKit'.\n";
 798     }
 799
 800     my @buildArgs = ("CONFIG+=gtk-port");
 801     push @buildArgs, "CONFIG-=qt";
 802
 803     return buildQMakeProject($clean, @buildArgs);
 804 }
 805
 806 sub setPathForRunningWebKitApp
 807 {
 808     my ($env) = @_;
 809
 810     return unless isCygwin();
 811
 812     $env->{PATH} = join(':', productDir(), dirname(installedSafariPath()), $env->{PATH} || "");
 813 }
 814
 815 sub exitStatus($)
 816 {
 817     my ($returnvalue) = @_;
 818     if ($^O eq "MSWin32") {
 819         return $returnvalue >> 8;
 820     }
 821     return WEXITSTATUS($returnvalue);
 822 }
 823
 824 sub runSafari
 825 {
 826     my ($debugger) = @_;
 827
 828     if (isOSX()) {
 829         return system "$FindBin::Bin/gdb-safari", @ARGV if $debugger;
 830
 831         my $productDir = productDir();
 832         print "Starting Safari with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
 833         $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
 834         $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
 835         return system safariPath(), @ARGV;
 836     }
 837
 838     if (isCygwin()) {
 839         my $script = "run-webkit-nightly.cmd";
 840         my $result = system "cp", "$FindBin::Bin/$script", productDir();
 841         return $result if $result;
 842
 843         my $cwd = getcwd();
 844         chdir productDir();
 845
 846         my $debuggerFlag = $debugger ? "/debugger" : "";
 847         $result = system "cmd", "/c", "call $script $debuggerFlag";
 848         chdir $cwd;
 849         return $result;
 850     }
 851
 852     return 1;
 853 }
 854
 855 sub runDrosera
 856 {
 857     my ($debugger) = @_;
 858
 859     if (isOSX()) {
 860         return system "$FindBin::Bin/gdb-drosera", @ARGV if $debugger;
 861
 862         my $productDir = productDir();
 863         print "Starting Drosera with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
 864         $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
 865         $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
 866
 867         my $droseraPath = "$productDir/Drosera.app/Contents/MacOS/Drosera";
 868         return system $droseraPath, @ARGV;
 869     }
 870
 871     if (isCygwin()) {
 872         print "Running Drosera\n";
 873         my $script = "run-drosera-nightly.cmd";
 874         my $prodDir = productDir();
 875         my $result = system "cp", "$FindBin::Bin/$script", $prodDir;
 876         return $result if $result;
 877
 878         my $cwd = getcwd();
 879         chdir $prodDir;
 880
 881         my $debuggerFlag = $debugger ? "/debugger" : "";
 882         $result = system "cmd", "/c", "call $script $debuggerFlag";
 883         chdir $cwd;
 884         return $result;
 885     }
 886
 887     return 1;
 888 }
 889
 890 1;