2010-08-24 Eric Seidel <eric@webkit.org>
[WebKit-https.git] / WebKitTools / Scripts / old-run-webkit-tests
1 #!/usr/bin/perl
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009, 2010 Apple Inc. All rights reserved.
4 # Copyright (C) 2006 Alexey Proskuryakov (ap@nypop.com)
5 # Copyright (C) 2007 Matt Lilek (pewtermoose@gmail.com)
6 # Copyright (C) 2007 Eric Seidel <eric@webkit.org>
7 # Copyright (C) 2009 Google Inc. All rights reserved.
8 # Copyright (C) 2009 Andras Becsi (becsi.andras@stud.u-szeged.hu), University of Szeged
9 #
10 # Redistribution and use in source and binary forms, with or without
11 # modification, are permitted provided that the following conditions
12 # are met:
13 #
14 # 1.  Redistributions of source code must retain the above copyright
15 #     notice, this list of conditions and the following disclaimer. 
16 # 2.  Redistributions in binary form must reproduce the above copyright
17 #     notice, this list of conditions and the following disclaimer in the
18 #     documentation and/or other materials provided with the distribution. 
19 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
20 #     its contributors may be used to endorse or promote products derived
21 #     from this software without specific prior written permission. 
22 #
23 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
24 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
25 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
26 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
27 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
28 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
29 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
30 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
31 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
32 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
33
34 # Script to run the WebKit Open Source Project layout tests.
35
36 # Run all the tests passed in on the command line.
37 # If no tests are passed, find all the .html, .shtml, .xml, .xhtml, .xhtmlmp, .pl, .php (and svg) files in the test directory.
38
39 # Run each text.
40 # Compare against the existing file xxx-expected.txt.
41 # If there is a mismatch, generate xxx-actual.txt and xxx-diffs.txt.
42
43 # At the end, report:
44 #   the number of tests that got the expected results
45 #   the number of tests that ran, but did not get the expected results
46 #   the number of tests that failed to run
47 #   the number of tests that were run but had no expected results to compare against
48
49 use strict;
50 use warnings;
51
52 use Cwd;
53 use Data::Dumper;
54 use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
55 use File::Basename;
56 use File::Copy;
57 use File::Find;
58 use File::Path;
59 use File::Spec;
60 use File::Spec::Functions;
61 use File::Temp;
62 use FindBin;
63 use Getopt::Long;
64 use IPC::Open2;
65 use IPC::Open3;
66 use Time::HiRes qw(time usleep);
67
68 use List::Util 'shuffle';
69
70 use lib $FindBin::Bin;
71 use webkitperl::features;
72 use webkitperl::httpd;
73 use webkitdirs;
74 use VCSUtils;
75 use POSIX;
76
77 sub buildPlatformResultHierarchy();
78 sub buildPlatformTestHierarchy(@);
79 sub checkPythonVersion();
80 sub closeCygpaths();
81 sub closeDumpTool();
82 sub closeWebSocketServer();
83 sub configureAndOpenHTTPDIfNeeded();
84 sub countAndPrintLeaks($$$);
85 sub countFinishedTest($$$$);
86 sub deleteExpectedAndActualResults($);
87 sub dumpToolDidCrash();
88 sub epiloguesAndPrologues($$);
89 sub expectedDirectoryForTest($;$;$);
90 sub fileNameWithNumber($$);
91 sub htmlForResultsSection(\@$&);
92 sub isTextOnlyTest($);
93 sub launchWithEnv(\@\%);
94 sub resolveAndMakeTestResultsDirectory();
95 sub numericcmp($$);
96 sub openDiffTool();
97 sub buildDumpTool($);
98 sub openDumpTool();
99 sub parseLeaksandPrintUniqueLeaks();
100 sub openWebSocketServerIfNeeded();
101 sub pathcmp($$);
102 sub printFailureMessageForTest($$);
103 sub processIgnoreTests($$);
104 sub readFromDumpToolWithTimer(**);
105 sub readSkippedFiles($);
106 sub recordActualResultsAndDiff($$);
107 sub sampleDumpTool();
108 sub setFileHandleNonBlocking(*$);
109 sub setUpWindowsCrashLogSaving();
110 sub slowestcmp($$);
111 sub splitpath($);
112 sub stopRunningTestsEarlyIfNeeded();
113 sub stripExtension($);
114 sub stripMetrics($$);
115 sub testCrashedOrTimedOut($$$$$);
116 sub toCygwinPath($);
117 sub toURL($);
118 sub toWindowsPath($);
119 sub validateSkippedArg($$;$);
120 sub writeToFile($$);
121
122 # Argument handling
123 my $addPlatformExceptions = 0;
124 my $complexText = 0;
125 my $exitAfterNFailures = 0;
126 my $exitAfterNCrashesOrTimeouts = 0;
127 my $generateNewResults = isAppleMacWebKit() ? 1 : 0;
128 my $guardMalloc = '';
129 # FIXME: Dynamic HTTP-port configuration in this file is wrong.  The various
130 # apache config files in LayoutTests/http/config govern the port numbers.
131 # Dynamic configuration as-written will also cause random failures in
132 # an IPv6 environment.  See https://bugs.webkit.org/show_bug.cgi?id=37104.
133 my $httpdPort = 8000;
134 my $httpdSSLPort = 8443;
135 my $ignoreMetrics = 0;
136 my $webSocketPort = 8880;
137 # wss is disabled until all platforms support pyOpenSSL.
138 # my $webSocketSecurePort = 9323;
139 my $ignoreTests = '';
140 my $iterations = 1;
141 my $launchSafari = 1;
142 my $mergeDepth;
143 my $pixelTests = '';
144 my $platform;
145 my $quiet = '';
146 my $randomizeTests = 0;
147 my $repeatEach = 1;
148 my $report10Slowest = 0;
149 my $resetResults = 0;
150 my $reverseTests = 0;
151 my $root;
152 my $runSample = 1;
153 my $shouldCheckLeaks = 0;
154 my $showHelp = 0;
155 my $stripEditingCallbacks;
156 my $testHTTP = 1;
157 my $testWebSocket = 1;
158 my $testMedia = 1;
159 my $tmpDir = "/tmp";
160 my $testResultsDirectory = File::Spec->catfile($tmpDir, "layout-test-results");
161 my $testsPerDumpTool = 1000;
162 my $threaded = 0;
163 # DumpRenderTree has an internal timeout of 30 seconds, so this must be > 30.
164 my $timeoutSeconds = 35;
165 my $tolerance = 0;
166 my $treatSkipped = "default";
167 my $useRemoteLinksToTests = 0;
168 my $useValgrind = 0;
169 my $verbose = 0;
170 my $shouldWaitForHTTPD = 0;
171 my $useWebKitTestRunner = 0;
172
173 my @leaksFilenames;
174
175 if (isWindows() || isMsys()) {
176     print "This script has to be run under Cygwin to function correctly.\n";
177     exit 1;
178 }
179
180 # Default to --no-http for wx for now.
181 $testHTTP = 0 if (isWx());
182
183 my $expectedTag = "expected";
184 my $actualTag = "actual";
185 my $prettyDiffTag = "pretty-diff";
186 my $diffsTag = "diffs";
187 my $errorTag = "stderr";
188
189 # These are defined here instead of closer to where they are used so that they
190 # will always be accessible from the END block that uses them, even if the user
191 # presses Ctrl-C before Perl has finished evaluating this whole file.
192 my $windowsPostMortemDebuggerKey = "/HKLM/SOFTWARE/Microsoft/Windows NT/CurrentVersion/AeDebug";
193 my %previousWindowsPostMortemDebuggerValues;
194
195 my $realPlatform;
196
197 my @macPlatforms = ("mac-tiger", "mac-leopard", "mac-snowleopard", "mac");
198 my @winPlatforms = ("win-xp", "win-vista", "win-7", "win");
199
200 if (isAppleMacWebKit()) {
201     if (isTiger()) {
202         $platform = "mac-tiger";
203         $tolerance = 1.0;
204     } elsif (isLeopard()) {
205         $platform = "mac-leopard";
206         $tolerance = 0.1;
207     } elsif (isSnowLeopard()) {
208         $platform = "mac-snowleopard";
209         $tolerance = 0.1;
210     } else {
211         $platform = "mac";
212     }
213 } elsif (isQt()) {
214     if (isDarwin()) {
215         $platform = "qt-mac";
216     } elsif (isLinux()) {
217         $platform = "qt-linux";
218     } elsif (isWindows() || isCygwin()) {
219         $platform = "qt-win";
220     } else {
221         $platform = "qt";
222     }
223 } elsif (isGtk()) {
224     $platform = "gtk";
225 } elsif (isWx()) {
226     $platform = "wx";
227 } elsif (isCygwin()) {
228     if (isWindowsXP()) {
229         $platform = "win-xp";
230     } elsif (isWindowsVista()) {
231         $platform = "win-vista";
232     } elsif (isWindows7()) {
233         $platform = "win-7";
234     } else {
235         $platform = "win";
236     }
237 }
238
239 if (isQt() || isGtk() || isCygwin()) {
240     my $testfontPath = $ENV{"WEBKIT_TESTFONTS"};
241     if (!$testfontPath || !-d "$testfontPath") {
242         print "The WEBKIT_TESTFONTS environment variable is not defined or not set properly\n";
243         print "You must set it before running the tests.\n";
244         print "Use git to grab the actual fonts from http://gitorious.org/qtwebkit/testfonts\n";
245         exit 1;
246     }
247 }
248
249 if (!defined($platform)) {
250     print "WARNING: Your platform is not recognized. Any platform-specific results will be generated in platform/undefined.\n";
251     $platform = "undefined";
252 }
253
254 if (!checkPythonVersion()) {
255     print "WARNING: Your platform does not have Python 2.5+, which is required to run websocket server, so disabling websocket/tests.\n";
256     $testWebSocket = 0;
257 }
258
259 my $programName = basename($0);
260 my $launchSafariDefault = $launchSafari ? "launch" : "do not launch";
261 my $httpDefault = $testHTTP ? "run" : "do not run";
262 my $sampleDefault = $runSample ? "run" : "do not run";
263
264 my $usage = <<EOF;
265 Usage: $programName [options] [testdir|testpath ...]
266   --add-platform-exceptions       Put new results for non-platform-specific failing tests into the platform-specific results directory
267   --complex-text                  Use the complex text code path for all text (Mac OS X and Windows only)
268   -c|--configuration config       Set DumpRenderTree build configuration
269   -g|--guard-malloc               Enable malloc guard
270   --exit-after-n-failures N       Exit after the first N failures (includes crashes) instead of running all tests
271   --exit-after-n-crashes-or-timeouts N
272                                   Exit after the first N crashes instead of running all tests
273   -h|--help                       Show this help message
274   --[no-]http                     Run (or do not run) http tests (default: $httpDefault)
275   --[no-]wait-for-httpd           Wait for httpd if some other test session is using it already (same as WEBKIT_WAIT_FOR_HTTPD=1). (default: $shouldWaitForHTTPD) 
276   -i|--ignore-tests               Comma-separated list of directories or tests to ignore
277   --iterations n                  Number of times to run the set of tests (e.g. ABCABCABC)
278   --[no-]launch-safari            Launch (or do not launch) Safari to display test results (default: $launchSafariDefault)
279   -l|--leaks                      Enable leaks checking
280   --[no-]new-test-results         Generate results for new tests
281   --nthly n                       Restart DumpRenderTree every n tests (default: $testsPerDumpTool)
282   -p|--pixel-tests                Enable pixel tests
283   --tolerance t                   Ignore image differences less than this percentage (default: $tolerance)
284   --platform                      Override the detected platform to use for tests and results (default: $platform)
285   --port                          Web server port to use with http tests
286   -q|--quiet                      Less verbose output
287   --reset-results                 Reset ALL results (including pixel tests if --pixel-tests is set)
288   -o|--results-directory          Output results directory (default: $testResultsDirectory)
289   --random                        Run the tests in a random order
290   --repeat-each n                 Number of times to run each test (e.g. AAABBBCCC)
291   --reverse                       Run the tests in reverse alphabetical order
292   --root                          Path to root tools build
293   --[no-]sample-on-timeout        Run sample on timeout (default: $sampleDefault) (Mac OS X only)
294   -1|--singly                     Isolate each test case run (implies --nthly 1 --verbose)
295   --skipped=[default|ignore|only] Specifies how to treat the Skipped file
296                                      default: Tests/directories listed in the Skipped file are not tested
297                                      ignore:  The Skipped file is ignored
298                                      only:    Only those tests/directories listed in the Skipped file will be run
299   --slowest                       Report the 10 slowest tests
300   --ignore-metrics                Ignore metrics in tests
301   --[no-]strip-editing-callbacks  Remove editing callbacks from expected results
302   -t|--threaded                   Run a concurrent JavaScript thead with each test
303   --timeout t                     Sets the number of seconds before a test times out (default: $timeoutSeconds)
304   --valgrind                      Run DumpRenderTree inside valgrind (Qt/Linux only)
305   -v|--verbose                    More verbose output (overrides --quiet)
306   -m|--merge-leak-depth arg       Merges leak callStacks and prints the number of unique leaks beneath a callstack depth of arg.  Defaults to 5.
307   --use-remote-links-to-tests     Link to test files within the SVN repository in the results.
308   -2|--webkit-test-runner         Use WebKitTestRunner rather than DumpRenderTree.
309 EOF
310
311 setConfiguration();
312
313 my $getOptionsResult = GetOptions(
314     'add-platform-exceptions' => \$addPlatformExceptions,
315     'complex-text' => \$complexText,
316     'exit-after-n-failures=i' => \$exitAfterNFailures,
317     'exit-after-n-crashes-or-timeouts=i' => \$exitAfterNCrashesOrTimeouts,
318     'guard-malloc|g' => \$guardMalloc,
319     'help|h' => \$showHelp,
320     'http!' => \$testHTTP,
321     'wait-for-httpd!' => \$shouldWaitForHTTPD,
322     'ignore-metrics!' => \$ignoreMetrics,
323     'ignore-tests|i=s' => \$ignoreTests,
324     'iterations=i' => \$iterations,
325     'launch-safari!' => \$launchSafari,
326     'leaks|l' => \$shouldCheckLeaks,
327     'merge-leak-depth|m:5' => \$mergeDepth,
328     'new-test-results!' => \$generateNewResults,
329     'nthly=i' => \$testsPerDumpTool,
330     'pixel-tests|p' => \$pixelTests,
331     'platform=s' => \$platform,
332     'port=i' => \$httpdPort,
333     'quiet|q' => \$quiet,
334     'random' => \$randomizeTests,
335     'repeat-each=i' => \$repeatEach,
336     'reset-results' => \$resetResults,
337     'results-directory|o=s' => \$testResultsDirectory,
338     'reverse' => \$reverseTests,
339     'root=s' => \$root,
340     'sample-on-timeout!' => \$runSample,
341     'singly|1' => sub { $testsPerDumpTool = 1; },
342     'skipped=s' => \&validateSkippedArg,
343     'slowest' => \$report10Slowest,
344     'strip-editing-callbacks!' => \$stripEditingCallbacks,
345     'threaded|t' => \$threaded,
346     'timeout=i' => \$timeoutSeconds,
347     'tolerance=f' => \$tolerance,
348     'use-remote-links-to-tests' => \$useRemoteLinksToTests,
349     'valgrind' => \$useValgrind,
350     'verbose|v' => \$verbose,
351     'webkit-test-runner|2' => \$useWebKitTestRunner,
352 );
353
354 if (!$getOptionsResult || $showHelp) {
355     print STDERR $usage;
356     exit 1;
357 }
358
359 if ($useWebKitTestRunner) {
360     if (isAppleMacWebKit()) {
361         $realPlatform = $platform;
362         $platform = "mac-wk2";
363     } elsif (isAppleWinWebKit()) {
364         $stripEditingCallbacks = 0 unless defined $stripEditingCallbacks;
365         $realPlatform = $platform;
366         $platform = "win-wk2";
367     }
368 }
369
370 $stripEditingCallbacks = isCygwin() unless defined $stripEditingCallbacks;
371
372 my $ignoreSkipped = $treatSkipped eq "ignore";
373 my $skippedOnly = $treatSkipped eq "only";
374
375 my $configuration = configuration();
376
377 # We need an environment variable to be able to enable the feature per-slave
378 $shouldWaitForHTTPD = $ENV{"WEBKIT_WAIT_FOR_HTTPD"} unless ($shouldWaitForHTTPD);
379 $verbose = 1 if $testsPerDumpTool == 1;
380
381 if ($shouldCheckLeaks && $testsPerDumpTool > 1000) {
382     print STDERR "\nWARNING: Running more than 1000 tests at a time with MallocStackLogging enabled may cause a crash.\n\n";
383 }
384
385 # Stack logging does not play well with QuickTime on Tiger (rdar://problem/5537157)
386 $testMedia = 0 if $shouldCheckLeaks && isTiger();
387
388 # Generating remote links causes a lot of unnecessary spew on GTK build bot
389 $useRemoteLinksToTests = 0 if isGtk();
390
391 setUpWindowsCrashLogSaving() if isCygwin();
392
393 setConfigurationProductDir(Cwd::abs_path($root)) if (defined($root));
394 my $productDir = productDir();
395 $productDir .= "/bin" if isQt();
396 $productDir .= "/Programs" if isGtk();
397
398 chdirWebKit();
399
400 if (!defined($root)) {
401     # FIXME: We build both DumpRenderTree and WebKitTestRunner for
402     # WebKitTestRunner runs becuase DumpRenderTree still includes
403     # the DumpRenderTreeSupport module and the TestNetscapePlugin.
404     # These two projects should be factored out into their own
405     # projects.
406     buildDumpTool("DumpRenderTree");
407     buildDumpTool("WebKitTestRunner") if $useWebKitTestRunner;
408 }
409
410 my $dumpToolName = $useWebKitTestRunner ? "WebKitTestRunner" : "DumpRenderTree";
411
412 $dumpToolName .= "_debug" if isCygwin() && configurationForVisualStudio() !~ /^Release|Debug_Internal$/;
413 my $dumpTool = "$productDir/$dumpToolName";
414 die "can't find executable $dumpToolName (looked in $productDir)\n" unless -x $dumpTool;
415
416 my $imageDiffTool = "$productDir/ImageDiff";
417 $imageDiffTool .= "_debug" if isCygwin() && configurationForVisualStudio() !~ /^Release|Debug_Internal$/;
418 die "can't find executable $imageDiffTool (looked in $productDir)\n" if $pixelTests && !-x $imageDiffTool;
419
420 checkFrameworks() unless isCygwin();
421
422 if (isAppleMacWebKit()) {
423     push @INC, $productDir;
424     require DumpRenderTreeSupport;
425 }
426
427 my $layoutTestsName = "LayoutTests";
428 my $testDirectory = File::Spec->rel2abs($layoutTestsName);
429 my $expectedDirectory = $testDirectory;
430 my $platformBaseDirectory = catdir($testDirectory, "platform");
431 my $platformTestDirectory = catdir($platformBaseDirectory, $platform);
432 my @platformResultHierarchy = buildPlatformResultHierarchy();
433 my @platformTestHierarchy = buildPlatformTestHierarchy(@platformResultHierarchy);
434
435 $expectedDirectory = $ENV{"WebKitExpectedTestResultsDirectory"} if $ENV{"WebKitExpectedTestResultsDirectory"};
436
437 $testResultsDirectory = File::Spec->rel2abs($testResultsDirectory);
438 my $testResults = File::Spec->catfile($testResultsDirectory, "results.html");
439
440 if (isAppleMacWebKit()) {
441     print STDERR "Compiling Java tests\n";
442     my $javaTestsDirectory = catdir($testDirectory, "java");
443
444     if (system("/usr/bin/make", "-C", "$javaTestsDirectory")) {
445         exit 1;
446     }
447 }
448
449
450 print "Running tests from $testDirectory\n";
451 if ($pixelTests) {
452     print "Enabling pixel tests with a tolerance of $tolerance%\n";
453     if (isDarwin()) {
454         print "WARNING: Temporarily changing the main display color profile:\n";
455         print "\tThe colors on your screen will change for the duration of the testing.\n";
456         print "\tThis allows the pixel tests to have consistent color values across all machines.\n";
457         
458         if (isPerianInstalled()) {
459             print "WARNING: Perian's QuickTime component is installed and this may affect pixel test results!\n";
460             print "\tYou should avoid generating new pixel results in this environment.\n";
461             print "\tSee https://bugs.webkit.org/show_bug.cgi?id=22615 for details.\n";
462         }
463     }
464 }
465
466 system "ln", "-s", $testDirectory, "/tmp/LayoutTests" unless -x "/tmp/LayoutTests";
467
468 my %ignoredFiles = ( "results.html" => 1 );
469 my %ignoredDirectories = map { $_ => 1 } qw(platform);
470 my %ignoredLocalDirectories = map { $_ => 1 } qw(.svn _svn resources script-tests);
471 my %supportedFileExtensions = map { $_ => 1 } qw(html shtml xml xhtml xhtmlmp pl php);
472
473 if (!checkWebCoreFeatureSupport("MathML", 0)) {
474     $ignoredDirectories{'mathml'} = 1;
475 }
476
477 # FIXME: We should fix webkitperl/features.pm:hasFeature() to do the correct feature detection for Cygwin.
478 if (checkWebCoreFeatureSupport("SVG", 0)) {
479     $supportedFileExtensions{'svg'} = 1;
480 } elsif (isCygwin()) {
481     $supportedFileExtensions{'svg'} = 1;
482 } else {
483     $ignoredLocalDirectories{'svg'} = 1;
484 }
485
486 if (!$testHTTP) {
487     $ignoredDirectories{'http'} = 1;
488     $ignoredDirectories{'websocket'} = 1;
489 }
490 if (!$testWebSocket) {
491     $ignoredDirectories{'websocket'} = 1;
492 }
493
494 if (!$testMedia) {
495     $ignoredDirectories{'media'} = 1;
496     $ignoredDirectories{'http/tests/media'} = 1;
497 }
498
499 my $supportedFeaturesResult = "";
500
501 if (isCygwin()) {
502     # Collect supported features list
503     setPathForRunningWebKitApp(\%ENV);
504     my $supportedFeaturesCommand = $dumpTool . " --print-supported-features 2>&1";
505     $supportedFeaturesResult = `$supportedFeaturesCommand 2>&1`;
506 }
507
508 my $hasAcceleratedCompositing = 0;
509 my $has3DRendering = 0;
510
511 if (isCygwin()) {
512     $hasAcceleratedCompositing = $supportedFeaturesResult =~ /AcceleratedCompositing/;
513     $has3DRendering = $supportedFeaturesResult =~ /3DRendering/;
514 } else {
515     $hasAcceleratedCompositing = checkWebCoreFeatureSupport("Accelerated Compositing", 0);
516     $has3DRendering = checkWebCoreFeatureSupport("3D Rendering", 0);
517 }
518
519 if (!$hasAcceleratedCompositing) {
520     $ignoredDirectories{'compositing'} = 1;
521 }
522
523 if (!$has3DRendering) {
524     $ignoredDirectories{'animations/3d'} = 1;
525     $ignoredDirectories{'transforms/3d'} = 1;
526 }
527
528 if (!checkWebCoreFeatureSupport("3D Canvas", 0)) {
529     $ignoredDirectories{'fast/canvas/webgl'} = 1;
530     $ignoredDirectories{'compositing/webgl'} = 1;
531 }
532
533 if (checkWebCoreFeatureSupport("WML", 0)) {
534     $supportedFileExtensions{'wml'} = 1;
535 } else {
536     $ignoredDirectories{'http/tests/wml'} = 1;
537     $ignoredDirectories{'fast/wml'} = 1;
538     $ignoredDirectories{'wml'} = 1;
539 }
540
541 if (!checkWebCoreFeatureSupport("WCSS", 0)) {
542     $ignoredDirectories{'fast/wcss'} = 1;
543 }
544
545 if (!checkWebCoreFeatureSupport("XHTMLMP", 0)) {
546     $ignoredDirectories{'fast/xhtmlmp'} = 1;
547 }
548
549 processIgnoreTests($ignoreTests, "ignore-tests") if $ignoreTests;
550 if (!$ignoreSkipped) {
551     if (!$skippedOnly || @ARGV == 0) {
552         readSkippedFiles("");
553     } else {
554         # Since readSkippedFiles() appends to @ARGV, we must use a foreach
555         # loop so that we only iterate over the original argument list.
556         foreach my $argnum (0 .. $#ARGV) {
557             readSkippedFiles(shift @ARGV);
558         }
559     }
560 }
561
562 my @tests = findTestsToRun();
563
564 die "no tests to run\n" if !@tests;
565
566 my %counts;
567 my %tests;
568 my %imagesPresent;
569 my %imageDifferences;
570 my %durations;
571 my $count = 0;
572 my $leaksOutputFileNumber = 1;
573 my $totalLeaks = 0;
574
575 my @toolArgs = ();
576 push @toolArgs, "--pixel-tests" if $pixelTests;
577 push @toolArgs, "--threaded" if $threaded;
578 push @toolArgs, "--complex-text" if $complexText;
579 push @toolArgs, "-";
580
581 my @diffToolArgs = ();
582 push @diffToolArgs, "--tolerance", $tolerance;
583
584 $| = 1;
585
586 my $dumpToolPID;
587 my $isDumpToolOpen = 0;
588 my $dumpToolCrashed = 0;
589 my $imageDiffToolPID;
590 my $isDiffToolOpen = 0;
591
592 my $atLineStart = 1;
593 my $lastDirectory = "";
594
595 my $isHttpdOpen = 0;
596 my $isWebSocketServerOpen = 0;
597 my $webSocketServerPidFile = 0;
598 my $failedToStartWebSocketServer = 0;
599 # wss is disabled until all platforms support pyOpenSSL.
600 # my $webSocketSecureServerPID = 0;
601
602 sub catch_pipe { $dumpToolCrashed = 1; }
603 $SIG{"PIPE"} = "catch_pipe";
604
605 print "Testing ", scalar @tests, " test cases";
606 print " $iterations times" if ($iterations > 1);
607 print ", repeating each test $repeatEach times" if ($repeatEach > 1);
608 print ".\n";
609
610 my $overallStartTime = time;
611
612 my %expectedResultPaths;
613
614 my @originalTests = @tests;
615 # Add individual test repetitions
616 if ($repeatEach > 1) {
617     @tests = ();
618     foreach my $test (@originalTests) {
619         for (my $i = 0; $i < $repeatEach; $i++) {
620             push(@tests, $test);
621         }
622     }
623 }
624 # Add test set repetitions
625 for (my $i = 1; $i < $iterations; $i++) {
626     push(@tests, @originalTests);
627 }
628
629 for my $test (@tests) {
630     my $newDumpTool = not $isDumpToolOpen;
631     openDumpTool();
632
633     my $base = stripExtension($test);
634     my $expectedExtension = ".txt";
635     
636     my $dir = $base;
637     $dir =~ s|/[^/]+$||;
638
639     if ($newDumpTool || $dir ne $lastDirectory) {
640         foreach my $logue (epiloguesAndPrologues($newDumpTool ? "" : $lastDirectory, $dir)) {
641             if (isCygwin()) {
642                 $logue = toWindowsPath($logue);
643             } else {
644                 $logue = canonpath($logue);
645             }
646             if ($verbose) {
647                 print "running epilogue or prologue $logue\n";
648             }
649             print OUT "$logue\n";
650             # Throw away output from DumpRenderTree.
651             # Once for the test output and once for pixel results (empty)
652             while (<IN>) {
653                 last if /#EOF/;
654             }
655             while (<IN>) {
656                 last if /#EOF/;
657             }
658         }
659     }
660
661     if ($verbose) {
662         print "running $test -> ";
663         $atLineStart = 0;
664     } elsif (!$quiet) {
665         if ($dir ne $lastDirectory) {
666             print "\n" unless $atLineStart;
667             print "$dir ";
668         }
669         print ".";
670         $atLineStart = 0;
671     }
672
673     $lastDirectory = $dir;
674
675     my $result;
676
677     my $startTime = time if $report10Slowest;
678
679     # Try to read expected hash file for pixel tests
680     my $suffixExpectedHash = "";
681     if ($pixelTests && !$resetResults) {
682         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
683         if (open EXPECTEDHASH, "$expectedPixelDir/$base-$expectedTag.checksum") {
684             my $expectedHash = <EXPECTEDHASH>;
685             chomp($expectedHash);
686             close EXPECTEDHASH;
687             
688             # Format expected hash into a suffix string that is appended to the path / URL passed to DRT
689             $suffixExpectedHash = "'$expectedHash";
690         }
691     }
692
693     if ($test =~ /^http\//) {
694         configureAndOpenHTTPDIfNeeded();
695         if ($test !~ /^http\/tests\/local\// && $test !~ /^http\/tests\/ssl\// && $test !~ /^http\/tests\/wml\// && $test !~ /^http\/tests\/media\//) {
696             my $path = canonpath($test);
697             $path =~ s/^http\/tests\///;
698             print OUT "http://127.0.0.1:$httpdPort/$path$suffixExpectedHash\n";
699         } elsif ($test =~ /^http\/tests\/ssl\//) {
700             my $path = canonpath($test);
701             $path =~ s/^http\/tests\///;
702             print OUT "https://127.0.0.1:$httpdSSLPort/$path$suffixExpectedHash\n";
703         } else {
704             my $testPath = "$testDirectory/$test";
705             if (isCygwin()) {
706                 $testPath = toWindowsPath($testPath);
707             } else {
708                 $testPath = canonpath($testPath);
709             }
710             print OUT "$testPath$suffixExpectedHash\n";
711         }
712     } elsif ($test =~ /^websocket\//) {
713         if ($test =~ /^websocket\/tests\/local\//) {
714             my $testPath = "$testDirectory/$test";
715             if (isCygwin()) {
716                 $testPath = toWindowsPath($testPath);
717             } else {
718                 $testPath = canonpath($testPath);
719             }
720             print OUT "$testPath\n";
721         } else {
722             if (openWebSocketServerIfNeeded()) {
723                 my $path = canonpath($test);
724                 if ($test =~ /^websocket\/tests\/ssl\//) {
725                     # wss is disabled until all platforms support pyOpenSSL.
726                     print STDERR "Error: wss is disabled until all platforms support pyOpenSSL.";
727                     # print OUT "https://127.0.0.1:$webSocketSecurePort/$path\n";
728                 } else {
729                     print OUT "http://127.0.0.1:$webSocketPort/$path\n";
730                 }
731             } else {
732                 # We failed to launch the WebSocket server.  Display a useful error message rather than attempting
733                 # to run tests that expect the server to be available.
734                 my $errorMessagePath = "$testDirectory/websocket/resources/server-failed-to-start.html";
735                 $errorMessagePath = isCygwin() ? toWindowsPath($errorMessagePath) : canonpath($errorMessagePath);
736                 print OUT "$errorMessagePath\n";
737             }
738         }
739     } else {
740         my $testPath = "$testDirectory/$test";
741         if (isCygwin()) {
742             $testPath = toWindowsPath($testPath);
743         } else {
744             $testPath = canonpath($testPath);
745         }
746         print OUT "$testPath$suffixExpectedHash\n" if defined $testPath;
747     }
748
749     # DumpRenderTree is expected to dump two "blocks" to stdout for each test.
750     # Each block is terminated by a #EOF on a line by itself.
751     # The first block is the output of the test (in text, RenderTree or other formats).
752     # The second block is for optional pixel data in PNG format, and may be empty if
753     # pixel tests are not being run, or the test does not dump pixels (e.g. text tests).
754     my $readResults = readFromDumpToolWithTimer(IN, ERROR);
755
756     my $actual = $readResults->{output};
757     my $error = $readResults->{error};
758
759     $expectedExtension = $readResults->{extension};
760     my $expectedFileName = "$base-$expectedTag.$expectedExtension";
761
762     my $isText = isTextOnlyTest($actual);
763
764     my $expectedDir = expectedDirectoryForTest($base, $isText, $expectedExtension);
765     $expectedResultPaths{$base} = "$expectedDir/$expectedFileName";
766
767     unless ($readResults->{status} eq "success") {
768         my $crashed = $readResults->{status} eq "crashed";
769         testCrashedOrTimedOut($test, $base, $crashed, $actual, $error);
770         countFinishedTest($test, $base, $crashed ? "crash" : "timedout", 0);
771         last if stopRunningTestsEarlyIfNeeded();
772         next;
773     }
774
775     $durations{$test} = time - $startTime if $report10Slowest;
776
777     my $expected;
778
779     if (!$resetResults && open EXPECTED, "<", "$expectedDir/$expectedFileName") {
780         $expected = "";
781         while (<EXPECTED>) {
782             next if $stripEditingCallbacks && $_ =~ /^EDITING DELEGATE:/;
783             $expected .= $_;
784         }
785         close EXPECTED;
786     }
787
788     if ($ignoreMetrics && !$isText && defined $expected) {
789         ($actual, $expected) = stripMetrics($actual, $expected);
790     }
791
792     if ($shouldCheckLeaks && $testsPerDumpTool == 1) {
793         print "        $test -> ";
794     }
795
796     my $actualPNG = "";
797     my $diffPNG = "";
798     my $diffPercentage = 0;
799     my $diffResult = "passed";
800
801     my $actualHash = "";
802     my $expectedHash = "";
803     my $actualPNGSize = 0;
804
805     while (<IN>) {
806         last if /#EOF/;
807         if (/ActualHash: ([a-f0-9]{32})/) {
808             $actualHash = $1;
809         } elsif (/ExpectedHash: ([a-f0-9]{32})/) {
810             $expectedHash = $1;
811         } elsif (/Content-Length: (\d+)\s*/) {
812             $actualPNGSize = $1;
813             read(IN, $actualPNG, $actualPNGSize);
814         }
815     }
816
817     if ($verbose && $pixelTests && !$resetResults && $actualPNGSize) {
818         if ($actualHash eq "" && $expectedHash eq "") {
819             printFailureMessageForTest($test, "WARNING: actual & expected pixel hashes are missing!");
820         } elsif ($actualHash eq "") {
821             printFailureMessageForTest($test, "WARNING: actual pixel hash is missing!");
822         } elsif ($expectedHash eq "") {
823             printFailureMessageForTest($test, "WARNING: expected pixel hash is missing!");
824         }
825     }
826
827     if ($actualPNGSize > 0) {
828         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
829
830         if (!$resetResults && ($expectedHash ne $actualHash || ($actualHash eq "" && $expectedHash eq ""))) {
831             if (-f "$expectedPixelDir/$base-$expectedTag.png") {
832                 my $expectedPNGSize = -s "$expectedPixelDir/$base-$expectedTag.png";
833                 my $expectedPNG = "";
834                 open EXPECTEDPNG, "$expectedPixelDir/$base-$expectedTag.png";
835                 read(EXPECTEDPNG, $expectedPNG, $expectedPNGSize);
836
837                 openDiffTool();
838                 print DIFFOUT "Content-Length: $actualPNGSize\n";
839                 print DIFFOUT $actualPNG;
840
841                 print DIFFOUT "Content-Length: $expectedPNGSize\n";
842                 print DIFFOUT $expectedPNG;
843
844                 while (<DIFFIN>) {
845                     last if /^error/ || /^diff:/;
846                     if (/Content-Length: (\d+)\s*/) {
847                         read(DIFFIN, $diffPNG, $1);
848                     }
849                 }
850
851                 if (/^diff: (.+)% (passed|failed)/) {
852                     $diffPercentage = $1 + 0;
853                     $imageDifferences{$base} = $diffPercentage;
854                     $diffResult = $2;
855                 }
856                 
857                 if (!$diffPercentage) {
858                     printFailureMessageForTest($test, "pixel hash failed (but pixel test still passes)");
859                 }
860             } elsif ($verbose) {
861                 printFailureMessageForTest($test, "WARNING: expected image is missing!");
862             }
863         }
864
865         if ($resetResults || !-f "$expectedPixelDir/$base-$expectedTag.png") {
866             mkpath catfile($expectedPixelDir, dirname($base)) if $testDirectory ne $expectedPixelDir;
867             writeToFile("$expectedPixelDir/$base-$expectedTag.png", $actualPNG);
868         }
869
870         if ($actualHash ne "" && ($resetResults || !-f "$expectedPixelDir/$base-$expectedTag.checksum")) {
871             writeToFile("$expectedPixelDir/$base-$expectedTag.checksum", $actualHash);
872         }
873     }
874
875     if (dumpToolDidCrash()) {
876         $result = "crash";
877         testCrashedOrTimedOut($test, $base, 1, $actual, $error);
878     } elsif (!defined $expected) {
879         if ($verbose) {
880             print "new " . ($resetResults ? "result" : "test") ."\n";
881             $atLineStart = 1;
882         }
883         $result = "new";
884
885         if ($generateNewResults || $resetResults) {
886             mkpath catfile($expectedDir, dirname($base)) if $testDirectory ne $expectedDir;
887             writeToFile("$expectedDir/$expectedFileName", $actual);
888         }
889         deleteExpectedAndActualResults($base);
890         recordActualResultsAndDiff($base, $actual);
891         if (!$resetResults) {
892             # Always print the file name for new tests, as they will probably need some manual inspection.
893             # in verbose mode we already printed the test case, so no need to do it again.
894             unless ($verbose) {
895                 print "\n" unless $atLineStart;
896                 print "$test -> ";
897             }
898             my $resultsDir = catdir($expectedDir, dirname($base));
899             if ($generateNewResults) {
900                 print "new (results generated in $resultsDir)\n";
901             } else {
902                 print "new\n";
903             }
904             $atLineStart = 1;
905         }
906     } elsif ($actual eq $expected && $diffResult eq "passed") {
907         if ($verbose) {
908             print "succeeded\n";
909             $atLineStart = 1;
910         }
911         $result = "match";
912         deleteExpectedAndActualResults($base);
913     } else {
914         $result = "mismatch";
915
916         my $pixelTestFailed = $pixelTests && $diffPNG && $diffPNG ne "";
917         my $testFailed = $actual ne $expected;
918
919         my $message = !$testFailed ? "pixel test failed" : "failed";
920
921         if (($testFailed || $pixelTestFailed) && $addPlatformExceptions) {
922             my $testBase = catfile($testDirectory, $base);
923             my $expectedBase = catfile($expectedDir, $base);
924             my $testIsMaximallyPlatformSpecific = $testBase =~ m|^\Q$platformTestDirectory\E/|;
925             my $expectedResultIsMaximallyPlatformSpecific = $expectedBase =~ m|^\Q$platformTestDirectory\E/|;
926             if (!$testIsMaximallyPlatformSpecific && !$expectedResultIsMaximallyPlatformSpecific) {
927                 mkpath catfile($platformTestDirectory, dirname($base));
928                 if ($testFailed) {
929                     my $expectedFile = catfile($platformTestDirectory, "$expectedFileName");
930                     writeToFile("$expectedFile", $actual);
931                 }
932                 if ($pixelTestFailed) {
933                     my $expectedFile = catfile($platformTestDirectory, "$base-$expectedTag.checksum");
934                     writeToFile("$expectedFile", $actualHash);
935
936                     $expectedFile = catfile($platformTestDirectory, "$base-$expectedTag.png");
937                     writeToFile("$expectedFile", $actualPNG);
938                 }
939                 $message .= " (results generated in $platformTestDirectory)";
940             }
941         }
942
943         printFailureMessageForTest($test, $message);
944
945         my $dir = "$testResultsDirectory/$base";
946         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
947         my $testName = $1;
948         mkpath $dir;
949
950         deleteExpectedAndActualResults($base);
951         recordActualResultsAndDiff($base, $actual);
952
953         if ($pixelTestFailed) {
954             $imagesPresent{$base} = 1;
955
956             writeToFile("$testResultsDirectory/$base-$actualTag.png", $actualPNG);
957             writeToFile("$testResultsDirectory/$base-$diffsTag.png", $diffPNG);
958
959             my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
960             copy("$expectedPixelDir/$base-$expectedTag.png", "$testResultsDirectory/$base-$expectedTag.png");
961
962             open DIFFHTML, ">$testResultsDirectory/$base-$diffsTag.html" or die;
963             print DIFFHTML "<html>\n";
964             print DIFFHTML "<head>\n";
965             print DIFFHTML "<title>$base Image Compare</title>\n";
966             print DIFFHTML "<script language=\"Javascript\" type=\"text/javascript\">\n";
967             print DIFFHTML "var currentImage = 0;\n";
968             print DIFFHTML "var imageNames = new Array(\"Actual\", \"Expected\");\n";
969             print DIFFHTML "var imagePaths = new Array(\"$testName-$actualTag.png\", \"$testName-$expectedTag.png\");\n";
970             if (-f "$testDirectory/$base-w3c.png") {
971                 copy("$testDirectory/$base-w3c.png", "$testResultsDirectory/$base-w3c.png");
972                 print DIFFHTML "imageNames.push(\"W3C\");\n";
973                 print DIFFHTML "imagePaths.push(\"$testName-w3c.png\");\n";
974             }
975             print DIFFHTML "function animateImage() {\n";
976             print DIFFHTML "    var image = document.getElementById(\"animatedImage\");\n";
977             print DIFFHTML "    var imageText = document.getElementById(\"imageText\");\n";
978             print DIFFHTML "    image.src = imagePaths[currentImage];\n";
979             print DIFFHTML "    imageText.innerHTML = imageNames[currentImage] + \" Image\";\n";
980             print DIFFHTML "    currentImage = (currentImage + 1) % imageNames.length;\n";
981             print DIFFHTML "    setTimeout('animateImage()',2000);\n";
982             print DIFFHTML "}\n";
983             print DIFFHTML "</script>\n";
984             print DIFFHTML "</head>\n";
985             print DIFFHTML "<body onLoad=\"animateImage();\">\n";
986             print DIFFHTML "<table>\n";
987             if ($diffPercentage) {
988                 print DIFFHTML "<tr>\n";
989                 print DIFFHTML "<td>Difference between images: <a href=\"$testName-$diffsTag.png\">$diffPercentage%</a></td>\n";
990                 print DIFFHTML "</tr>\n";
991             }
992             print DIFFHTML "<tr>\n";
993             print DIFFHTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">test file</a></td>\n";
994             print DIFFHTML "</tr>\n";
995             print DIFFHTML "<tr>\n";
996             print DIFFHTML "<td id=\"imageText\" style=\"text-weight: bold;\">Actual Image</td>\n";
997             print DIFFHTML "</tr>\n";
998             print DIFFHTML "<tr>\n";
999             print DIFFHTML "<td><img src=\"$testName-$actualTag.png\" id=\"animatedImage\"></td>\n";
1000             print DIFFHTML "</tr>\n";
1001             print DIFFHTML "</table>\n";
1002             print DIFFHTML "</body>\n";
1003             print DIFFHTML "</html>\n";
1004         }
1005     }
1006
1007     if ($error) {
1008         my $dir = "$testResultsDirectory/$base";
1009         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
1010         mkpath $dir;
1011         
1012         writeToFile("$testResultsDirectory/$base-$errorTag.txt", $error);
1013         
1014         $counts{error}++;
1015         push @{$tests{error}}, $test;
1016     }
1017
1018     countFinishedTest($test, $base, $result, $isText);
1019     last if stopRunningTestsEarlyIfNeeded();
1020 }
1021
1022 my $totalTestingTime = time - $overallStartTime;
1023 my $waitTime = getWaitTime();
1024 if ($waitTime > 0.1) {
1025     my $normalizedTestingTime = $totalTestingTime - $waitTime;
1026     printf "\n%0.2fs HTTPD waiting time\n", $waitTime . "";
1027     printf "%0.2fs normalized testing time", $normalizedTestingTime . "";
1028 }
1029 printf "\n%0.2fs total testing time\n", $totalTestingTime . "";
1030
1031 !$isDumpToolOpen || die "Failed to close $dumpToolName.\n";
1032
1033 $isHttpdOpen = !closeHTTPD();
1034 closeWebSocketServer();
1035
1036 # Because multiple instances of this script are running concurrently we cannot 
1037 # safely delete this symlink.
1038 # system "rm /tmp/LayoutTests";
1039
1040 # FIXME: Do we really want to check the image-comparison tool for leaks every time?
1041 if ($isDiffToolOpen && $shouldCheckLeaks) {
1042     $totalLeaks += countAndPrintLeaks("ImageDiff", $imageDiffToolPID, "$testResultsDirectory/ImageDiff-leaks.txt");
1043 }
1044
1045 if ($totalLeaks) {
1046     if ($mergeDepth) {
1047         parseLeaksandPrintUniqueLeaks();
1048     } else { 
1049         print "\nWARNING: $totalLeaks total leaks found!\n";
1050         print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
1051     }
1052 }
1053
1054 close IN;
1055 close OUT;
1056 close ERROR;
1057
1058 if ($report10Slowest) {
1059     print "\n\nThe 10 slowest tests:\n\n";
1060     my $count = 0;
1061     for my $test (sort slowestcmp keys %durations) {
1062         printf "%0.2f secs: %s\n", $durations{$test}, $test;
1063         last if ++$count == 10;
1064     }
1065 }
1066
1067 print "\n";
1068
1069 if ($skippedOnly && $counts{"match"}) {
1070     print "The following tests are in the Skipped file (" . File::Spec->abs2rel("$platformTestDirectory/Skipped", $testDirectory) . "), but succeeded:\n";
1071     foreach my $test (@{$tests{"match"}}) {
1072         print "  $test\n";
1073     }
1074 }
1075
1076 if ($resetResults || ($counts{match} && $counts{match} == $count)) {
1077     print "all $count test cases succeeded\n";
1078     unlink $testResults;
1079     exit;
1080 }
1081
1082 printResults();
1083
1084 mkpath $testResultsDirectory;
1085
1086 open HTML, ">", $testResults or die "Failed to open $testResults. $!";
1087 print HTML "<html>\n";
1088 print HTML "<head>\n";
1089 print HTML "<title>Layout Test Results</title>\n";
1090 print HTML "</head>\n";
1091 print HTML "<body>\n";
1092
1093 if ($ignoreMetrics) {
1094     print HTML "<h4>Tested with metrics ignored.</h4>";
1095 }
1096
1097 print HTML htmlForResultsSection(@{$tests{mismatch}}, "Tests where results did not match expected results", \&linksForMismatchTest);
1098 print HTML htmlForResultsSection(@{$tests{timedout}}, "Tests that timed out", \&linksForErrorTest);
1099 print HTML htmlForResultsSection(@{$tests{crash}}, "Tests that caused the DumpRenderTree tool to crash", \&linksForErrorTest);
1100 print HTML htmlForResultsSection(@{$tests{error}}, "Tests that had stderr output", \&linksForErrorTest);
1101 print HTML htmlForResultsSection(@{$tests{new}}, "Tests that had no expected results (probably new)", \&linksForNewTest);
1102
1103 print HTML "</body>\n";
1104 print HTML "</html>\n";
1105 close HTML;
1106
1107 my @configurationArgs = argumentsForConfiguration();
1108
1109 if (isGtk()) {
1110   system "WebKitTools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1111 } elsif (isQt()) {
1112   unshift @configurationArgs, qw(-graphicssystem raster -style windows);
1113   if (isCygwin()) {
1114     $testResults = "/" . toWindowsPath($testResults);
1115     $testResults =~ s/\\/\//g;
1116   }
1117   system "WebKitTools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1118 } elsif (isCygwin()) {
1119   system "cygstart", $testResults if $launchSafari;
1120 } else {
1121   system "WebKitTools/Scripts/run-safari", @configurationArgs, "-NSOpen", $testResults if $launchSafari;
1122 }
1123
1124 closeCygpaths() if isCygwin();
1125
1126 exit 1;
1127
1128 sub countAndPrintLeaks($$$)
1129 {
1130     my ($dumpToolName, $dumpToolPID, $leaksFilePath) = @_;
1131
1132     print "\n" unless $atLineStart;
1133     $atLineStart = 1;
1134
1135     # We are excluding the following reported leaks so they don't get in our way when looking for WebKit leaks:
1136     # This allows us ignore known leaks and only be alerted when new leaks occur. Some leaks are in the old
1137     # versions of the system frameworks that are being used by the leaks bots. Even though a leak has been
1138     # fixed, it will be listed here until the bot has been updated with the newer frameworks.
1139
1140     my @typesToExclude = (
1141     );
1142
1143     my @callStacksToExclude = (
1144         "Flash_EnforceLocalSecurity" # leaks in Flash plug-in code, rdar://problem/4449747
1145     );
1146
1147     if (isTiger()) {
1148         # Leak list for the version of Tiger used on the build bot.
1149         push @callStacksToExclude, (
1150             "CFRunLoopRunSpecific \\| malloc_zone_malloc", "CFRunLoopRunSpecific \\| CFAllocatorAllocate ", # leak in CFRunLoopRunSpecific, rdar://problem/4670839
1151             "CGImageSourceGetPropertiesAtIndex", # leak in ImageIO, rdar://problem/4628809
1152             "FOGetCoveredUnicodeChars", # leak in ATS, rdar://problem/3943604
1153             "GetLineDirectionPreference", "InitUnicodeUtilities", # leaks tool falsely reporting leak in CFNotificationCenterAddObserver, rdar://problem/4964790
1154             "ICCFPrefWrapper::GetPrefDictionary", # leaks in Internet Config. code, rdar://problem/4449794
1155             "NSHTTPURLProtocol setResponseHeader:", # leak in multipart/mixed-replace handling in Foundation, no Radar, but fixed in Leopard
1156             "NSURLCache cachedResponseForRequest", # leak in CFURL cache, rdar://problem/4768430
1157             "PCFragPrepareClosureFromFile", # leak in Code Fragment Manager, rdar://problem/3426998
1158             "WebCore::Selection::toRange", # bug in 'leaks', rdar://problem/4967949
1159             "WebCore::SubresourceLoader::create", # bug in 'leaks', rdar://problem/4985806
1160             "_CFPreferencesDomainDeepCopyDictionary", # leak in CFPreferences, rdar://problem/4220786
1161             "_objc_msgForward", # leak in NSSpellChecker, rdar://problem/4965278
1162             "gldGetString", # leak in OpenGL, rdar://problem/5013699
1163             "_setDefaultUserInfoFromURL", # leak in NSHTTPAuthenticator, rdar://problem/5546453 
1164             "SSLHandshake", # leak in SSL, rdar://problem/5546440 
1165             "SecCertificateCreateFromData", # leak in SSL code, rdar://problem/4464397
1166         );
1167         push @typesToExclude, (
1168             "THRD", # bug in 'leaks', rdar://problem/3387783
1169             "DRHT", # ditto (endian little hate i)
1170         );
1171     }
1172
1173     if (isLeopard()) {
1174         # Leak list for the version of Leopard used on the build bot.
1175         push @callStacksToExclude, (
1176             "CFHTTPMessageAppendBytes", # leak in CFNetwork, rdar://problem/5435912
1177             "sendDidReceiveDataCallback", # leak in CFNetwork, rdar://problem/5441619
1178             "_CFHTTPReadStreamReadMark", # leak in CFNetwork, rdar://problem/5441468
1179             "httpProtocolStart", # leak in CFNetwork, rdar://problem/5468837
1180             "_CFURLConnectionSendCallbacks", # leak in CFNetwork, rdar://problem/5441600
1181             "DispatchQTMsg", # leak in QuickTime, PPC only, rdar://problem/5667132
1182             "QTMovieContentView createVisualContext", # leak in QuickTime, PPC only, rdar://problem/5667132
1183             "_CopyArchitecturesForJVMVersion", # leak in Java, rdar://problem/5910823
1184         );
1185     }
1186
1187     if (isSnowLeopard()) {
1188         push @callStacksToExclude, (
1189             "readMakerNoteProps", # <rdar://problem/7156432> leak in ImageIO
1190             "QTKitMovieControllerView completeUISetup", # <rdar://problem/7155156> leak in QTKit
1191             "getVMInitArgs", # <rdar://problem/7714444> leak in Java
1192             "Java_java_lang_System_initProperties", # <rdar://problem/7714465> leak in Java
1193             "glrCompExecuteKernel", # <rdar://problem/7815391> leak in graphics driver while using OpenGL
1194         );
1195     }
1196
1197     if (isDarwin() && !isTiger() && !isLeopard() && !isSnowLeopard()) {
1198         push @callStacksToExclude, (
1199             "CGGradientCreateWithColorComponents", # leak in CoreGraphics, <rdar://problem/7888492>
1200         );
1201     }
1202
1203     my $leaksTool = sourceDir() . "/WebKitTools/Scripts/run-leaks";
1204     my $excludeString = "--exclude-callstack '" . (join "' --exclude-callstack '", @callStacksToExclude) . "'";
1205     $excludeString .= " --exclude-type '" . (join "' --exclude-type '", @typesToExclude) . "'" if @typesToExclude;
1206
1207     print " ? checking for leaks in $dumpToolName\n";
1208     my $leaksOutput = `$leaksTool $excludeString $dumpToolPID`;
1209     my ($count, $bytes) = $leaksOutput =~ /Process $dumpToolPID: (\d+) leaks? for (\d+) total/;
1210     my ($excluded) = $leaksOutput =~ /(\d+) leaks? excluded/;
1211
1212     my $adjustedCount = $count;
1213     $adjustedCount -= $excluded if $excluded;
1214
1215     if (!$adjustedCount) {
1216         print " - no leaks found\n";
1217         unlink $leaksFilePath;
1218         return 0;
1219     } else {
1220         my $dir = $leaksFilePath;
1221         $dir =~ s|/[^/]+$|| or die;
1222         mkpath $dir;
1223
1224         if ($excluded) {
1225             print " + $adjustedCount leaks ($bytes bytes including $excluded excluded leaks) were found, details in $leaksFilePath\n";
1226         } else {
1227             print " + $count leaks ($bytes bytes) were found, details in $leaksFilePath\n";
1228         }
1229
1230         writeToFile($leaksFilePath, $leaksOutput);
1231         
1232         push @leaksFilenames, $leaksFilePath;
1233     }
1234
1235     return $adjustedCount;
1236 }
1237
1238 sub writeToFile($$)
1239 {
1240     my ($filePath, $contents) = @_;
1241     open NEWFILE, ">", "$filePath" or die "Could not create $filePath. $!\n";
1242     print NEWFILE $contents;
1243     close NEWFILE;
1244 }
1245
1246 # Break up a path into the directory (with slash) and base name.
1247 sub splitpath($)
1248 {
1249     my ($path) = @_;
1250
1251     my $pathSeparator = "/";
1252     my $dirname = dirname($path) . $pathSeparator;
1253     $dirname = "" if $dirname eq "." . $pathSeparator;
1254
1255     return ($dirname, basename($path));
1256 }
1257
1258 # Sort first by directory, then by file, so all paths in one directory are grouped
1259 # rather than being interspersed with items from subdirectories.
1260 # Use numericcmp to sort directory and filenames to make order logical.
1261 sub pathcmp($$)
1262 {
1263     my ($patha, $pathb) = @_;
1264
1265     my ($dira, $namea) = splitpath($patha);
1266     my ($dirb, $nameb) = splitpath($pathb);
1267
1268     return numericcmp($dira, $dirb) if $dira ne $dirb;
1269     return numericcmp($namea, $nameb);
1270 }
1271
1272 # Sort numeric parts of strings as numbers, other parts as strings.
1273 # Makes 1.33 come after 1.3, which is cool.
1274 sub numericcmp($$)
1275 {
1276     my ($aa, $bb) = @_;
1277
1278     my @a = split /(\d+)/, $aa;
1279     my @b = split /(\d+)/, $bb;
1280
1281     # Compare one chunk at a time.
1282     # Each chunk is either all numeric digits, or all not numeric digits.
1283     while (@a && @b) {
1284         my $a = shift @a;
1285         my $b = shift @b;
1286         
1287         # Use numeric comparison if chunks are non-equal numbers.
1288         return $a <=> $b if $a =~ /^\d/ && $b =~ /^\d/ && $a != $b;
1289
1290         # Use string comparison if chunks are any other kind of non-equal string.
1291         return $a cmp $b if $a ne $b;
1292     }
1293     
1294     # One of the two is now empty; compare lengths for result in this case.
1295     return @a <=> @b;
1296 }
1297
1298 # Sort slowest tests first.
1299 sub slowestcmp($$)
1300 {
1301     my ($testa, $testb) = @_;
1302
1303     my $dura = $durations{$testa};
1304     my $durb = $durations{$testb};
1305     return $durb <=> $dura if $dura != $durb;
1306     return pathcmp($testa, $testb);
1307 }
1308
1309 sub launchWithEnv(\@\%)
1310 {
1311     my ($args, $env) = @_;
1312
1313     # Dump the current environment as perl code and then put it in quotes so it is one parameter.
1314     my $environmentDumper = Data::Dumper->new([\%{$env}], [qw(*ENV)]);
1315     $environmentDumper->Indent(0);
1316     $environmentDumper->Purity(1);
1317     my $allEnvVars = $environmentDumper->Dump();
1318     unshift @{$args}, "\"$allEnvVars\"";
1319
1320     my $execScript = File::Spec->catfile(sourceDir(), qw(WebKitTools Scripts execAppWithEnv));
1321     unshift @{$args}, $execScript;
1322     return @{$args};
1323 }
1324
1325 sub resolveAndMakeTestResultsDirectory()
1326 {
1327     my $absTestResultsDirectory = File::Spec->rel2abs(glob $testResultsDirectory);
1328     mkpath $absTestResultsDirectory;
1329     return $absTestResultsDirectory;
1330 }
1331
1332 sub openDiffTool()
1333 {
1334     return if $isDiffToolOpen;
1335     return if !$pixelTests;
1336
1337     my %CLEAN_ENV;
1338     $CLEAN_ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1339     $imageDiffToolPID = open2(\*DIFFIN, \*DIFFOUT, $imageDiffTool, launchWithEnv(@diffToolArgs, %CLEAN_ENV)) or die "unable to open $imageDiffTool\n";
1340     $isDiffToolOpen = 1;
1341 }
1342
1343 sub buildDumpTool($)
1344 {
1345     my ($dumpToolName) = @_;
1346
1347     my $dumpToolBuildScript =  "build-" . lc($dumpToolName);
1348     print STDERR "Running $dumpToolBuildScript\n";
1349
1350     local *DEVNULL;
1351     my ($childIn, $childOut, $childErr);
1352     if ($quiet) {
1353         open(DEVNULL, ">", File::Spec->devnull()) or die "Failed to open /dev/null";
1354         $childOut = ">&DEVNULL";
1355         $childErr = ">&DEVNULL";
1356     } else {
1357         # When not quiet, let the child use our stdout/stderr.
1358         $childOut = ">&STDOUT";
1359         $childErr = ">&STDERR";
1360     }
1361
1362     my @args = argumentsForConfiguration();
1363     my $buildProcess = open3($childIn, $childOut, $childErr, "WebKitTools/Scripts/$dumpToolBuildScript", @args) or die "Failed to run build-dumprendertree";
1364     close($childIn);
1365     waitpid $buildProcess, 0;
1366     my $buildResult = $?;
1367     close($childOut);
1368     close($childErr);
1369
1370     close DEVNULL if ($quiet);
1371
1372     if ($buildResult) {
1373         print STDERR "Compiling $dumpToolName failed!\n";
1374         exit exitStatus($buildResult);
1375     }
1376 }
1377
1378 sub openDumpTool()
1379 {
1380     return if $isDumpToolOpen;
1381
1382     my %CLEAN_ENV;
1383
1384     # Generic environment variables
1385     if (defined $ENV{'WEBKIT_TESTFONTS'}) {
1386         $CLEAN_ENV{WEBKIT_TESTFONTS} = $ENV{'WEBKIT_TESTFONTS'};
1387     }
1388
1389     # unique temporary directory for each DumpRendertree - needed for running more DumpRenderTree in parallel
1390     $CLEAN_ENV{DUMPRENDERTREE_TEMP} = File::Temp::tempdir('DumpRenderTree-XXXXXX', TMPDIR => 1, CLEANUP => 1);
1391     $CLEAN_ENV{XML_CATALOG_FILES} = ""; # work around missing /etc/catalog <rdar://problem/4292995>
1392
1393     # Platform spesifics
1394     if (isLinux()) {
1395         if (defined $ENV{'DISPLAY'}) {
1396             $CLEAN_ENV{DISPLAY} = $ENV{'DISPLAY'};
1397         } else {
1398             $CLEAN_ENV{DISPLAY} = ":1";
1399         }
1400         if (defined $ENV{'XAUTHORITY'}) {
1401             $CLEAN_ENV{XAUTHORITY} = $ENV{'XAUTHORITY'};
1402         }
1403
1404         $CLEAN_ENV{HOME} = $ENV{'HOME'};
1405
1406         if (defined $ENV{'LD_LIBRARY_PATH'}) {
1407             $CLEAN_ENV{LD_LIBRARY_PATH} = $ENV{'LD_LIBRARY_PATH'};
1408         }
1409         if (defined $ENV{'DBUS_SESSION_BUS_ADDRESS'}) {
1410             $CLEAN_ENV{DBUS_SESSION_BUS_ADDRESS} = $ENV{'DBUS_SESSION_BUS_ADDRESS'};
1411         }
1412     } elsif (isDarwin()) {
1413         if (defined $ENV{'DYLD_LIBRARY_PATH'}) {
1414             $CLEAN_ENV{DYLD_LIBRARY_PATH} = $ENV{'DYLD_LIBRARY_PATH'};
1415         }
1416
1417         $CLEAN_ENV{DYLD_FRAMEWORK_PATH} = $productDir;
1418         $CLEAN_ENV{DYLD_INSERT_LIBRARIES} = "/usr/lib/libgmalloc.dylib" if $guardMalloc;
1419     } elsif (isCygwin()) {
1420         $CLEAN_ENV{HOMEDRIVE} = $ENV{'HOMEDRIVE'};
1421         $CLEAN_ENV{HOMEPATH} = $ENV{'HOMEPATH'};
1422         $CLEAN_ENV{_NT_SYMBOL_PATH} = $ENV{_NT_SYMBOL_PATH};
1423
1424         setPathForRunningWebKitApp(\%CLEAN_ENV);
1425     }
1426
1427     # Port specifics
1428     if (isGtk()) {
1429         $CLEAN_ENV{GTK_MODULES} = "gail";
1430         $CLEAN_ENV{WEBKIT_INSPECTOR_PATH} = "$productDir/resources/inspector";
1431     }
1432
1433     if (isQt()) {
1434         $CLEAN_ENV{QTWEBKIT_PLUGIN_PATH} = productDir() . "/lib/plugins";
1435         $CLEAN_ENV{QT_DRT_WEBVIEW_MODE} = $ENV{"QT_DRT_WEBVIEW_MODE"};
1436     }
1437     
1438     my @args = ($dumpTool, @toolArgs);
1439     if (isAppleMacWebKit() and !isTiger()) { 
1440         unshift @args, "arch", "-" . architecture();             
1441     }
1442
1443     if ($useValgrind) {
1444         unshift @args, "valgrind", "--suppressions=$platformBaseDirectory/qt/SuppressedValgrindErrors";
1445     } 
1446
1447     $CLEAN_ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1448
1449     $dumpToolPID = open3(\*OUT, \*IN, \*ERROR, launchWithEnv(@args, %CLEAN_ENV)) or die "Failed to start tool: $dumpTool\n";
1450     $isDumpToolOpen = 1;
1451     $dumpToolCrashed = 0;
1452 }
1453
1454 sub closeDumpTool()
1455 {
1456     return if !$isDumpToolOpen;
1457
1458     close IN;
1459     close OUT;
1460     waitpid $dumpToolPID, 0;
1461     
1462     # check for WebCore counter leaks.
1463     if ($shouldCheckLeaks) {
1464         while (<ERROR>) {
1465             print;
1466         }
1467     }
1468     close ERROR;
1469     $isDumpToolOpen = 0;
1470 }
1471
1472 sub dumpToolDidCrash()
1473 {
1474     return 1 if $dumpToolCrashed;
1475     return 0 unless $isDumpToolOpen;
1476     my $pid = waitpid(-1, WNOHANG);
1477     return 1 if ($pid == $dumpToolPID);
1478
1479     # On Mac OS X, crashing may be significantly delayed by crash reporter.
1480     return 0 unless isAppleMacWebKit();
1481
1482     return DumpRenderTreeSupport::processIsCrashing($dumpToolPID);
1483 }
1484
1485 sub configureAndOpenHTTPDIfNeeded()
1486 {
1487     return if $isHttpdOpen;
1488     my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
1489     my $listen = "127.0.0.1:$httpdPort";
1490     my @args = (
1491         "-c", "CustomLog \"$absTestResultsDirectory/access_log.txt\" common",
1492         "-c", "ErrorLog \"$absTestResultsDirectory/error_log.txt\"",
1493         "-C", "Listen $listen"
1494     );
1495
1496     my @defaultArgs = getDefaultConfigForTestDirectory($testDirectory);
1497     @args = (@defaultArgs, @args);
1498
1499     waitForHTTPDLock() if $shouldWaitForHTTPD;
1500     $isHttpdOpen = openHTTPD(@args);
1501 }
1502
1503 sub checkPythonVersion()
1504 {
1505     # we have not chdir to sourceDir yet.
1506     system sourceDir() . "/WebKitTools/Scripts/ensure-valid-python", "--check-only";
1507     return exitStatus($?) == 0;
1508 }
1509
1510 sub openWebSocketServerIfNeeded()
1511 {
1512     return 1 if $isWebSocketServerOpen;
1513     return 0 if $failedToStartWebSocketServer;
1514
1515     my $webSocketHandlerDir = "$testDirectory";
1516     my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
1517     $webSocketServerPidFile = "$absTestResultsDirectory/websocket.pid";
1518
1519     my @args = (
1520         "WebKitTools/Scripts/new-run-webkit-websocketserver",
1521         "--server", "start",
1522         "--port", "$webSocketPort",
1523         "--root", "$webSocketHandlerDir",
1524         "--output-dir", "$absTestResultsDirectory",
1525         "--pidfile", "$webSocketServerPidFile"
1526     );
1527     system "/usr/bin/python", @args;
1528
1529     $isWebSocketServerOpen = 1;
1530     return 1;
1531 }
1532
1533 sub closeWebSocketServer()
1534 {
1535     return if !$isWebSocketServerOpen;
1536
1537     my @args = (
1538         "WebKitTools/Scripts/new-run-webkit-websocketserver",
1539         "--server", "stop",
1540         "--pidfile", "$webSocketServerPidFile"
1541     );
1542     system "/usr/bin/python", @args;
1543     unlink "$webSocketServerPidFile";
1544
1545     # wss is disabled until all platforms support pyOpenSSL.
1546     $isWebSocketServerOpen = 0;
1547 }
1548
1549 sub fileNameWithNumber($$)
1550 {
1551     my ($base, $number) = @_;
1552     return "$base$number" if ($number > 1);
1553     return $base;
1554 }
1555
1556 sub processIgnoreTests($$)
1557 {
1558     my @ignoreList = split(/\s*,\s*/, shift);
1559     my $listName = shift;
1560
1561     my $disabledSuffix = "-disabled";
1562
1563     my $addIgnoredDirectories = sub {
1564         return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
1565         $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)} = 1;
1566         return @_;
1567     };
1568     foreach my $item (@ignoreList) {
1569         my $path = catfile($testDirectory, $item); 
1570         if (-d $path) {
1571             $ignoredDirectories{$item} = 1;
1572             find({ preprocess => $addIgnoredDirectories, wanted => sub {} }, $path);
1573         }
1574         elsif (-f $path) {
1575             $ignoredFiles{$item} = 1;
1576         } elsif (-f $path . $disabledSuffix) {
1577             # The test is disabled, so do nothing.
1578         } else {
1579             print "$listName list contained '$item', but no file of that name could be found\n";
1580         }
1581     }
1582 }
1583
1584 sub stripExtension($)
1585 {
1586     my ($test) = @_;
1587
1588     $test =~ s/\.[a-zA-Z]+$//;
1589     return $test;
1590 }
1591
1592 sub isTextOnlyTest($)
1593 {
1594     my ($actual) = @_;
1595     my $isText;
1596     if ($actual =~ /^layer at/ms) {
1597         $isText = 0;
1598     } else {
1599         $isText = 1;
1600     }
1601     return $isText;
1602 }
1603
1604 sub expectedDirectoryForTest($;$;$)
1605 {
1606     my ($base, $isText, $expectedExtension) = @_;
1607
1608     my @directories = @platformResultHierarchy;
1609     push @directories, map { catdir($platformBaseDirectory, $_) } qw(mac-snowleopard mac) if isCygwin();
1610     push @directories, $expectedDirectory;
1611
1612     # If we already have expected results, just return their location.
1613     foreach my $directory (@directories) {
1614         return $directory if (-f "$directory/$base-$expectedTag.$expectedExtension");
1615     }
1616
1617     # For cross-platform tests, text-only results should go in the cross-platform directory,
1618     # while render tree dumps should go in the least-specific platform directory.
1619     return $isText ? $expectedDirectory : $platformResultHierarchy[$#platformResultHierarchy];
1620 }
1621
1622 sub countFinishedTest($$$$)
1623 {
1624     my ($test, $base, $result, $isText) = @_;
1625
1626     if (($count + 1) % $testsPerDumpTool == 0 || $count == $#tests) {
1627         if ($shouldCheckLeaks) {
1628             my $fileName;
1629             if ($testsPerDumpTool == 1) {
1630                 $fileName = "$testResultsDirectory/$base-leaks.txt";
1631             } else {
1632                 $fileName = "$testResultsDirectory/" . fileNameWithNumber($dumpToolName, $leaksOutputFileNumber) . "-leaks.txt";
1633             }
1634             my $leakCount = countAndPrintLeaks($dumpToolName, $dumpToolPID, $fileName);
1635             $totalLeaks += $leakCount;
1636             $leaksOutputFileNumber++ if ($leakCount);
1637         }
1638
1639         closeDumpTool();
1640     }
1641     
1642     $count++;
1643     $counts{$result}++;
1644     push @{$tests{$result}}, $test;
1645 }
1646
1647 sub testCrashedOrTimedOut($$$$$)
1648 {
1649     my ($test, $base, $didCrash, $actual, $error) = @_;
1650
1651     printFailureMessageForTest($test, $didCrash ? "crashed" : "timed out");
1652
1653     sampleDumpTool() unless $didCrash;
1654
1655     my $dir = "$testResultsDirectory/$base";
1656     $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
1657     mkpath $dir;
1658
1659     deleteExpectedAndActualResults($base);
1660
1661     if (defined($error) && length($error)) {
1662         writeToFile("$testResultsDirectory/$base-$errorTag.txt", $error);
1663     }
1664
1665     recordActualResultsAndDiff($base, $actual);
1666
1667     kill 9, $dumpToolPID unless $didCrash;
1668
1669     closeDumpTool();
1670     
1671     return unless isCygwin() && !$didCrash && $base =~ /^http/;
1672     # On Cygwin, http tests timing out can be a symptom of a non-responsive httpd.
1673     # If we timed out running an http test, try restarting httpd.
1674     $isHttpdOpen = !closeHTTPD();
1675     configureAndOpenHTTPDIfNeeded();
1676 }
1677
1678 sub printFailureMessageForTest($$)
1679 {
1680     my ($test, $description) = @_;
1681
1682     unless ($verbose) {
1683         print "\n" unless $atLineStart;
1684         print "$test -> ";
1685     }
1686     print "$description\n";
1687     $atLineStart = 1;
1688 }
1689
1690 my %cygpaths = ();
1691
1692 sub openCygpathIfNeeded($)
1693 {
1694     my ($options) = @_;
1695
1696     return unless isCygwin();
1697     return $cygpaths{$options} if $cygpaths{$options} && $cygpaths{$options}->{"open"};
1698
1699     local (*CYGPATHIN, *CYGPATHOUT);
1700     my $pid = open2(\*CYGPATHIN, \*CYGPATHOUT, "cygpath -f - $options");
1701     my $cygpath =  {
1702         "pid" => $pid,
1703         "in" => *CYGPATHIN,
1704         "out" => *CYGPATHOUT,
1705         "open" => 1
1706     };
1707
1708     $cygpaths{$options} = $cygpath;
1709
1710     return $cygpath;
1711 }
1712
1713 sub closeCygpaths()
1714 {
1715     return unless isCygwin();
1716
1717     foreach my $cygpath (values(%cygpaths)) {
1718         close $cygpath->{"in"};
1719         close $cygpath->{"out"};
1720         waitpid($cygpath->{"pid"}, 0);
1721         $cygpath->{"open"} = 0;
1722
1723     }
1724 }
1725
1726 sub convertPathUsingCygpath($$)
1727 {
1728     my ($path, $options) = @_;
1729
1730     # cygpath -f (at least in Cygwin 1.7) converts spaces into newlines. We remove spaces here and
1731     # add them back in after conversion to work around this.
1732     my $spaceSubstitute = "__NOTASPACE__";
1733     $path =~ s/ /\Q$spaceSubstitute\E/g;
1734
1735     my $cygpath = openCygpathIfNeeded($options);
1736     local *inFH = $cygpath->{"in"};
1737     local *outFH = $cygpath->{"out"};
1738     print outFH $path . "\n";
1739     my $convertedPath = <inFH>;
1740     chomp($convertedPath) if defined $convertedPath;
1741
1742     $convertedPath =~ s/\Q$spaceSubstitute\E/ /g;
1743     return $convertedPath;
1744 }
1745
1746 sub toCygwinPath($)
1747 {
1748     my ($path) = @_;
1749     return unless isCygwin();
1750
1751     return convertPathUsingCygpath($path, "-u");
1752 }
1753
1754 sub toWindowsPath($)
1755 {
1756     my ($path) = @_;
1757     return unless isCygwin();
1758
1759     return convertPathUsingCygpath($path, "-w");
1760 }
1761
1762 sub toURL($)
1763 {
1764     my ($path) = @_;
1765
1766     if ($useRemoteLinksToTests) {
1767         my $relativePath = File::Spec->abs2rel($path, $testDirectory);
1768
1769         # If the file is below the test directory then convert it into a link to the file in SVN
1770         if ($relativePath !~ /^\.\.\//) {
1771             my $revision = svnRevisionForDirectory($testDirectory);
1772             my $svnPath = pathRelativeToSVNRepositoryRootForPath($path);
1773             return "http://trac.webkit.org/export/$revision/$svnPath";
1774         }
1775     }
1776
1777     return $path unless isCygwin();
1778
1779     return "file:///" . convertPathUsingCygpath($path, "-m");
1780 }
1781
1782 sub validateSkippedArg($$;$)
1783 {
1784     my ($option, $value, $value2) = @_;
1785     my %validSkippedValues = map { $_ => 1 } qw(default ignore only);
1786     $value = lc($value);
1787     die "Invalid argument '" . $value . "' for option $option" unless $validSkippedValues{$value};
1788     $treatSkipped = $value;
1789 }
1790
1791 sub htmlForResultsSection(\@$&)
1792 {
1793     my ($tests, $description, $linkGetter) = @_;
1794
1795     my @html = ();
1796     return join("\n", @html) unless @{$tests};
1797
1798     push @html, "<p>$description:</p>";
1799     push @html, "<table>";
1800     foreach my $test (@{$tests}) {
1801         push @html, "<tr>";
1802         push @html, "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$test</a></td>";
1803         foreach my $link (@{&{$linkGetter}($test)}) {
1804             push @html, "<td><a href=\"$link->{href}\">$link->{text}</a></td>";
1805         }
1806         push @html, "</tr>";
1807     }
1808     push @html, "</table>";
1809
1810     return join("\n", @html);
1811 }
1812
1813 sub linksForExpectedAndActualResults($)
1814 {
1815     my ($base) = @_;
1816
1817     my @links = ();
1818
1819     return \@links unless -s "$testResultsDirectory/$base-$diffsTag.txt";
1820     
1821     my $expectedResultPath = $expectedResultPaths{$base};
1822     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1823
1824     push @links, { href => "$base-$expectedTag$expectedResultExtension", text => "expected" };
1825     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "actual" };
1826     push @links, { href => "$base-$diffsTag.txt", text => "diff" };
1827     push @links, { href => "$base-$prettyDiffTag.html", text => "pretty diff" };
1828
1829     return \@links;
1830 }
1831
1832 sub linksForMismatchTest
1833 {
1834     my ($test) = @_;
1835
1836     my @links = ();
1837
1838     my $base = stripExtension($test);
1839
1840     push @links, @{linksForExpectedAndActualResults($base)};
1841     return \@links unless $pixelTests && $imagesPresent{$base};
1842
1843     push @links, { href => "$base-$expectedTag.png", text => "expected image" };
1844     push @links, { href => "$base-$diffsTag.html", text => "image diffs" };
1845     push @links, { href => "$base-$diffsTag.png", text => "$imageDifferences{$base}%" };
1846
1847     return \@links;
1848 }
1849
1850 sub linksForErrorTest
1851 {
1852     my ($test) = @_;
1853
1854     my @links = ();
1855
1856     my $base = stripExtension($test);
1857
1858     push @links, @{linksForExpectedAndActualResults($base)};
1859     push @links, { href => "$base-$errorTag.txt", text => "stderr" };
1860
1861     return \@links;
1862 }
1863
1864 sub linksForNewTest
1865 {
1866     my ($test) = @_;
1867
1868     my @links = ();
1869
1870     my $base = stripExtension($test);
1871
1872     my $expectedResultPath = $expectedResultPaths{$base};
1873     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1874
1875     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "result" };
1876     if ($pixelTests && $imagesPresent{$base}) {
1877         push @links, { href => "$base-$expectedTag.png", text => "image" };
1878     }
1879
1880     return \@links;
1881 }
1882
1883 sub deleteExpectedAndActualResults($)
1884 {
1885     my ($base) = @_;
1886
1887     unlink "$testResultsDirectory/$base-$actualTag.txt";
1888     unlink "$testResultsDirectory/$base-$diffsTag.txt";
1889     unlink "$testResultsDirectory/$base-$errorTag.txt";
1890 }
1891
1892 sub recordActualResultsAndDiff($$)
1893 {
1894     my ($base, $actualResults) = @_;
1895
1896     return unless defined($actualResults) && length($actualResults);
1897
1898     my $expectedResultPath = $expectedResultPaths{$base};
1899     my ($expectedResultFileNameMinusExtension, $expectedResultDirectoryPath, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1900     my $actualResultsPath = "$testResultsDirectory/$base-$actualTag$expectedResultExtension";
1901     my $copiedExpectedResultsPath = "$testResultsDirectory/$base-$expectedTag$expectedResultExtension";
1902
1903     mkpath(dirname($actualResultsPath));
1904     writeToFile("$actualResultsPath", $actualResults);
1905
1906     if (-f $expectedResultPath) {
1907         copy("$expectedResultPath", "$copiedExpectedResultsPath");
1908     } else {
1909         open EMPTY, ">$copiedExpectedResultsPath";
1910         close EMPTY;
1911     }
1912
1913     my $diffOuputBasePath = "$testResultsDirectory/$base";
1914     my $diffOutputPath = "$diffOuputBasePath-$diffsTag.txt";
1915     system "diff -u \"$copiedExpectedResultsPath\" \"$actualResultsPath\" > \"$diffOutputPath\"";
1916
1917     my $prettyDiffOutputPath = "$diffOuputBasePath-$prettyDiffTag.html";
1918     my $prettyPatchPath = "BugsSite/PrettyPatch/";
1919     my $prettifyPath = "$prettyPatchPath/prettify.rb";
1920     system "ruby -I \"$prettyPatchPath\" \"$prettifyPath\" \"$diffOutputPath\" > \"$prettyDiffOutputPath\"";
1921 }
1922
1923 sub buildPlatformResultHierarchy()
1924 {
1925     mkpath($platformTestDirectory) if ($platform eq "undefined" && !-d "$platformTestDirectory");
1926
1927     my @platforms;
1928     
1929     my $isMac = $platform =~ /^mac/;
1930     my $isWin = $platform =~ /^win/;
1931     if ($isMac || $isWin) {
1932         my $effectivePlatform = $platform;
1933         if ($platform eq "mac-wk2" || $platform eq "win-wk2") {
1934             push @platforms, $platform;
1935             $effectivePlatform = $realPlatform;
1936         }
1937
1938         my @platformList = $isMac ? @macPlatforms : @winPlatforms;
1939         my $i;
1940         for ($i = 0; $i < @platformList; $i++) {
1941             last if $platformList[$i] eq $effectivePlatform;
1942         }
1943         for (; $i < @platformList; $i++) {
1944             push @platforms, $platformList[$i];
1945         }
1946     } elsif ($platform =~ /^qt-/) {
1947         push @platforms, $platform;
1948         push @platforms, "qt";
1949     } else {
1950         @platforms = $platform;
1951     }
1952
1953     my @hierarchy;
1954     for (my $i = 0; $i < @platforms; $i++) {
1955         my $scoped = catdir($platformBaseDirectory, $platforms[$i]);
1956         push(@hierarchy, $scoped) if (-d $scoped);
1957     }
1958     
1959     return @hierarchy;
1960 }
1961
1962 sub buildPlatformTestHierarchy(@)
1963 {
1964     my (@platformHierarchy) = @_;
1965     return @platformHierarchy if (@platformHierarchy < 2);
1966     if ($platformHierarchy[0] =~ /mac-wk2/) {
1967         return ($platformHierarchy[0], $platformHierarchy[1], $platformHierarchy[$#platformHierarchy]);
1968     }
1969     return ($platformHierarchy[0], $platformHierarchy[$#platformHierarchy]);
1970 }
1971
1972 sub epiloguesAndPrologues($$)
1973 {
1974     my ($lastDirectory, $directory) = @_;
1975     my @lastComponents = split('/', $lastDirectory);
1976     my @components = split('/', $directory);
1977
1978     while (@lastComponents) {
1979         if (!defined($components[0]) || $lastComponents[0] ne $components[0]) {
1980             last;
1981         }
1982         shift @components;
1983         shift @lastComponents;
1984     }
1985
1986     my @result;
1987     my $leaving = $lastDirectory;
1988     foreach (@lastComponents) {
1989         my $epilogue = $leaving . "/resources/run-webkit-tests-epilogue.html";
1990         foreach (@platformResultHierarchy) {
1991             push @result, catdir($_, $epilogue) if (stat(catdir($_, $epilogue)));
1992         }
1993         push @result, catdir($testDirectory, $epilogue) if (stat(catdir($testDirectory, $epilogue)));
1994         $leaving =~ s|(^\|/)[^/]+$||;
1995     }
1996
1997     my $entering = $leaving;
1998     foreach (@components) {
1999         $entering .= '/' . $_;
2000         my $prologue = $entering . "/resources/run-webkit-tests-prologue.html";
2001         push @result, catdir($testDirectory, $prologue) if (stat(catdir($testDirectory, $prologue)));
2002         foreach (reverse @platformResultHierarchy) {
2003             push @result, catdir($_, $prologue) if (stat(catdir($_, $prologue)));
2004         }
2005     }
2006     return @result;
2007 }
2008     
2009 sub parseLeaksandPrintUniqueLeaks()
2010 {
2011     return unless @leaksFilenames;
2012      
2013     my $mergedFilenames = join " ", @leaksFilenames;
2014     my $parseMallocHistoryTool = sourceDir() . "/WebKitTools/Scripts/parse-malloc-history";
2015     
2016     open MERGED_LEAKS, "cat $mergedFilenames | $parseMallocHistoryTool --merge-depth $mergeDepth  - |" ;
2017     my @leakLines = <MERGED_LEAKS>;
2018     close MERGED_LEAKS;
2019     
2020     my $uniqueLeakCount = 0;
2021     my $totalBytes;
2022     foreach my $line (@leakLines) {
2023         ++$uniqueLeakCount if ($line =~ /^(\d*)\scalls/);
2024         $totalBytes = $1 if $line =~ /^total\:\s(.*)\s\(/;
2025     }
2026     
2027     print "\nWARNING: $totalLeaks total leaks found for a total of $totalBytes!\n";
2028     print "WARNING: $uniqueLeakCount unique leaks found!\n";
2029     print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
2030     
2031 }
2032
2033 sub extensionForMimeType($)
2034 {
2035     my ($mimeType) = @_;
2036
2037     if ($mimeType eq "application/x-webarchive") {
2038         return "webarchive";
2039     } elsif ($mimeType eq "application/pdf") {
2040         return "pdf";
2041     }
2042     return "txt";
2043 }
2044
2045 # Read up to the first #EOF (the content block of the test), or until detecting crashes or timeouts.
2046 sub readFromDumpToolWithTimer(**)
2047 {
2048     my ($fhIn, $fhError) = @_;
2049
2050     setFileHandleNonBlocking($fhIn, 1);
2051     setFileHandleNonBlocking($fhError, 1);
2052
2053     my $maximumSecondsWithoutOutput = $timeoutSeconds;
2054     $maximumSecondsWithoutOutput *= 10 if $guardMalloc;
2055     my $microsecondsToWaitBeforeReadingAgain = 1000;
2056
2057     my $timeOfLastSuccessfulRead = time;
2058
2059     my @output = ();
2060     my @error = ();
2061     my $status = "success";
2062     my $mimeType = "text/plain";
2063     # We don't have a very good way to know when the "headers" stop
2064     # and the content starts, so we use this as a hack:
2065     my $haveSeenContentType = 0;
2066     my $haveSeenEofIn = 0;
2067     my $haveSeenEofError = 0;
2068
2069     while (1) {
2070         if (time - $timeOfLastSuccessfulRead > $maximumSecondsWithoutOutput) {
2071             $status = dumpToolDidCrash() ? "crashed" : "timedOut";
2072             last;
2073         }
2074
2075         # Once we've seen the EOF, we must not read anymore.
2076         my $lineIn = readline($fhIn) unless $haveSeenEofIn;
2077         my $lineError = readline($fhError) unless $haveSeenEofError;
2078         if (!defined($lineIn) && !defined($lineError)) {
2079             last if ($haveSeenEofIn && $haveSeenEofError);
2080
2081             if ($! != EAGAIN) {
2082                 $status = "crashed";
2083                 last;
2084             }
2085
2086             # No data ready
2087             usleep($microsecondsToWaitBeforeReadingAgain);
2088             next;
2089         }
2090
2091         $timeOfLastSuccessfulRead = time;
2092
2093         if (defined($lineIn)) {
2094             if (!$haveSeenContentType && $lineIn =~ /^Content-Type: (\S+)$/) {
2095                 $mimeType = $1;
2096                 $haveSeenContentType = 1;
2097             } elsif ($lineIn =~ /#EOF/) {
2098                 $haveSeenEofIn = 1;
2099             } else {
2100                 push @output, $lineIn;
2101             }
2102         }
2103         if (defined($lineError)) {
2104             if ($lineError =~ /#CRASHED/) {
2105                 $status = "crashed";
2106                 last;
2107             }
2108             if ($lineError =~ /#EOF/) {
2109                 $haveSeenEofError = 1;
2110             } else {
2111                 push @error, $lineError;
2112             }
2113         }
2114     }
2115
2116     setFileHandleNonBlocking($fhIn, 0);
2117     setFileHandleNonBlocking($fhError, 0);
2118     return {
2119         output => join("", @output),
2120         error => join("", @error),
2121         status => $status,
2122         mimeType => $mimeType,
2123         extension => extensionForMimeType($mimeType)
2124     };
2125 }
2126
2127 sub setFileHandleNonBlocking(*$)
2128 {
2129     my ($fh, $nonBlocking) = @_;
2130
2131     my $flags = fcntl($fh, F_GETFL, 0) or die "Couldn't get filehandle flags";
2132
2133     if ($nonBlocking) {
2134         $flags |= O_NONBLOCK;
2135     } else {
2136         $flags &= ~O_NONBLOCK;
2137     }
2138
2139     fcntl($fh, F_SETFL, $flags) or die "Couldn't set filehandle flags";
2140
2141     return 1;
2142 }
2143
2144 sub sampleDumpTool()
2145 {
2146     return unless isAppleMacWebKit();
2147     return unless $runSample;
2148
2149     my $outputDirectory = "$ENV{HOME}/Library/Logs/DumpRenderTree";
2150     -d $outputDirectory or mkdir $outputDirectory;
2151
2152     my $outputFile = "$outputDirectory/HangReport.txt";
2153     system "/usr/bin/sample", $dumpToolPID, qw(10 10 -file), $outputFile;
2154 }
2155
2156 sub stripMetrics($$)
2157 {
2158     my ($actual, $expected) = @_;
2159
2160     foreach my $result ($actual, $expected) {
2161         $result =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
2162         $result =~ s/size -?[0-9]+x-?[0-9]+ *//g;
2163         $result =~ s/text run width -?[0-9]+: //g;
2164         $result =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
2165         $result =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
2166         $result =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
2167         $result =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
2168         $result =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
2169         $result =~ s/\([0-9]+px/px/g;
2170         $result =~ s/ *" *\n +" */ /g;
2171         $result =~ s/" +$/"/g;
2172
2173         $result =~ s/- /-/g;
2174         $result =~ s/\n( *)"\s+/\n$1"/g;
2175         $result =~ s/\s+"\n/"\n/g;
2176         $result =~ s/scrollWidth [0-9]+/scrollWidth/g;
2177         $result =~ s/scrollHeight [0-9]+/scrollHeight/g;
2178     }
2179
2180     return ($actual, $expected);
2181 }
2182
2183 sub fileShouldBeIgnored
2184 {
2185     my ($filePath) = @_;
2186     foreach my $ignoredDir (keys %ignoredDirectories) {
2187         if ($filePath =~ m/^$ignoredDir/) {
2188             return 1;
2189         }
2190     }
2191     return 0;
2192 }
2193
2194 sub readSkippedFiles($)
2195 {
2196     my ($constraintPath) = @_;
2197
2198     my @skippedFileDirectories = @platformTestHierarchy;
2199
2200     # Because nearly all of the skipped tests for WebKit 2 on Mac are due to
2201     # cross-platform issues, Windows will use both the Mac and Windows skipped
2202     # lists to avoid maintaining separate lists.
2203     push(@skippedFileDirectories, catdir($platformBaseDirectory, "mac-wk2")) if $platform eq "win-wk2";
2204
2205     foreach my $level (@skippedFileDirectories) {
2206         if (open SKIPPED, "<", "$level/Skipped") {
2207             if ($verbose) {
2208                 my ($dir, $name) = splitpath($level);
2209                 print "Skipped tests in $name:\n";
2210             }
2211
2212             while (<SKIPPED>) {
2213                 my $skipped = $_;
2214                 chomp $skipped;
2215                 $skipped =~ s/^[ \n\r]+//;
2216                 $skipped =~ s/[ \n\r]+$//;
2217                 if ($skipped && $skipped !~ /^#/) {
2218                     if ($skippedOnly) {
2219                         if (!fileShouldBeIgnored($skipped)) {
2220                             if (!$constraintPath) {
2221                                 # Always add $skipped since no constraint path was specified on the command line.
2222                                 push(@ARGV, $skipped);
2223                             } elsif ($skipped =~ /^($constraintPath)/) {
2224                                 # Add $skipped only if it matches the current path constraint, e.g.,
2225                                 # "--skipped=only dir1" with "dir1/file1.html" on the skipped list.
2226                                 push(@ARGV, $skipped);
2227                             } elsif ($constraintPath =~ /^($skipped)/) {
2228                                 # Add current path constraint if it is more specific than the skip list entry,
2229                                 # e.g., "--skipped=only dir1/dir2/dir3" with "dir1" on the skipped list.
2230                                 push(@ARGV, $constraintPath);
2231                             }
2232                         } elsif ($verbose) {
2233                             print "    $skipped\n";
2234                         }
2235                     } else {
2236                         if ($verbose) {
2237                             print "    $skipped\n";
2238                         }
2239                         processIgnoreTests($skipped, "Skipped");
2240                     }
2241                 }
2242             }
2243             close SKIPPED;
2244         }
2245     }
2246 }
2247
2248 my @testsFound;
2249
2250 sub directoryFilter
2251 {
2252     return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
2253     return () if exists $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)};
2254     return @_;
2255 }
2256
2257 sub fileFilter
2258 {
2259     my $filename = $_;
2260     if ($filename =~ /\.([^.]+)$/) {
2261         if (exists $supportedFileExtensions{$1}) {
2262             my $path = File::Spec->abs2rel(catfile($File::Find::dir, $filename), $testDirectory);
2263             push @testsFound, $path if !exists $ignoredFiles{$path};
2264         }
2265     }
2266 }
2267
2268 sub findTestsToRun
2269 {
2270     my @testsToRun = ();
2271
2272     for my $test (@ARGV) {
2273         $test =~ s/^($layoutTestsName|$testDirectory)\///;
2274         my $fullPath = catfile($testDirectory, $test);
2275         if (file_name_is_absolute($test)) {
2276             print "can't run test $test outside $testDirectory\n";
2277         } elsif (-f $fullPath) {
2278             my ($filename, $pathname, $fileExtension) = fileparse($test, qr{\.[^.]+$});
2279             if (!exists $supportedFileExtensions{substr($fileExtension, 1)}) {
2280                 print "test $test does not have a supported extension\n";
2281             } elsif ($testHTTP || $pathname !~ /^http\//) {
2282                 push @testsToRun, $test;
2283             }
2284         } elsif (-d $fullPath) {
2285             @testsFound = ();
2286             find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $fullPath);
2287             for my $level (@platformTestHierarchy) {
2288                 my $platformPath = catfile($level, $test);
2289                 find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $platformPath) if (-d $platformPath);
2290             }
2291             push @testsToRun, sort pathcmp @testsFound;
2292             @testsFound = ();
2293         } else {
2294             print "test $test not found\n";
2295         }
2296     }
2297
2298     if (!scalar @ARGV) {
2299         @testsFound = ();
2300         find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $testDirectory);
2301         for my $level (@platformTestHierarchy) {
2302             find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $level);
2303         }
2304         push @testsToRun, sort pathcmp @testsFound;
2305         @testsFound = ();
2306
2307         # We need to minimize the time when Apache and WebSocketServer is locked by tests
2308         # so run them last if no explicit order was specified in the argument list.
2309         my @httpTests;
2310         my @websocketTests;
2311         my @otherTests;
2312         foreach my $test (@testsToRun) {
2313             if ($test =~ /^http\//) {
2314                 push(@httpTests, $test);
2315             } elsif ($test =~ /^websocket\//) {
2316                 push(@websocketTests, $test);
2317             } else {
2318                 push(@otherTests, $test);
2319             }
2320         }
2321         @testsToRun = (@otherTests, @httpTests, @websocketTests);
2322     }
2323
2324     # Reverse the tests
2325     @testsToRun = reverse @testsToRun if $reverseTests;
2326
2327     # Shuffle the array
2328     @testsToRun = shuffle(@testsToRun) if $randomizeTests;
2329
2330     return @testsToRun;
2331 }
2332
2333 sub printResults
2334 {
2335     my %text = (
2336         match => "succeeded",
2337         mismatch => "had incorrect layout",
2338         new => "were new",
2339         timedout => "timed out",
2340         crash => "crashed",
2341         error => "had stderr output"
2342     );
2343
2344     for my $type ("match", "mismatch", "new", "timedout", "crash", "error") {
2345         my $typeCount = $counts{$type};
2346         next unless $typeCount;
2347         my $typeText = $text{$type};
2348         my $message;
2349         if ($typeCount == 1) {
2350             $typeText =~ s/were/was/;
2351             $message = sprintf "1 test case (%d%%) %s\n", 1 * 100 / $count, $typeText;
2352         } else {
2353             $message = sprintf "%d test cases (%d%%) %s\n", $typeCount, $typeCount * 100 / $count, $typeText;
2354         }
2355         $message =~ s-\(0%\)-(<1%)-;
2356         print $message;
2357     }
2358 }
2359
2360 sub stopRunningTestsEarlyIfNeeded()
2361 {
2362     # --reset-results does not check pass vs. fail, so exitAfterNFailures makes no sense with --reset-results.
2363     return 0 if $resetResults;
2364
2365     my $passCount = $counts{match} || 0; # $counts{match} will be undefined if we've not yet passed a test (e.g. the first test fails).
2366     my $newCount = $counts{new} || 0;
2367     my $failureCount = $count - $passCount - $newCount; # "Failure" here includes timeouts, crashes, etc.
2368     if ($exitAfterNFailures && $failureCount >= $exitAfterNFailures) {
2369         print "\nExiting early after $failureCount failures. $count tests run.";
2370         closeDumpTool();
2371         return 1;
2372     }
2373
2374     my $crashCount = $counts{crash} || 0;
2375     my $timeoutCount = $counts{timedout} || 0;
2376     if ($exitAfterNCrashesOrTimeouts && $crashCount + $timeoutCount >= $exitAfterNCrashesOrTimeouts) {
2377         print "\nExiting early after $crashCount crashes and $timeoutCount timeouts. $count tests run.";
2378         closeDumpTool();
2379         return 1;
2380     }
2381
2382     return 0;
2383 }
2384
2385 sub setUpWindowsCrashLogSaving()
2386 {
2387     return unless isCygwin();
2388
2389     unless (defined $ENV{_NT_SYMBOL_PATH}) {
2390         print "The _NT_SYMBOL_PATH environment variable is not set. Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2391         return;
2392     }
2393
2394     my $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{PROGRAMFILES}), "Debugging Tools for Windows (x86)", "ntsd.exe");
2395     unless (-f $ntsdPath) {
2396         $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{SYSTEMROOT}), "system32", "ntsd.exe");
2397         unless (-f $ntsdPath) {
2398             print STDERR "Can't find ntsd.exe. Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2399             return;
2400         }
2401     }
2402
2403     my %values = (
2404         Debugger => '"' . toWindowsPath($ntsdPath) . '" -p %ld -e %ld -g -lines -c ".logopen /t \"' . toWindowsPath($testResultsDirectory) . '\CrashLog.txt\";!analyze -vv;~*kpn;q"',
2405         Auto => 1
2406     );
2407
2408     foreach my $value (keys %values) {
2409         chomp($previousWindowsPostMortemDebuggerValues{$value} = `regtool get "$windowsPostMortemDebuggerKey/$value"`);
2410         my $result = system "regtool", "set", "-s", "$windowsPostMortemDebuggerKey/$value", $values{$value};
2411         next unless $result;
2412
2413         print "Failed to set \"$windowsPostMortemDebuggerKey/$value\". Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2414         return;
2415     }
2416
2417     print "Crash logs will be saved to $testResultsDirectory.\n";
2418 }
2419
2420 END {
2421     return unless isCygwin();
2422
2423     foreach my $value (keys %previousWindowsPostMortemDebuggerValues) {
2424         my $result = system "regtool", "set", "-s", "$windowsPostMortemDebuggerKey/$value", $previousWindowsPostMortemDebuggerValues{$value};
2425         !$result or print "Failed to restore \"$windowsPostMortemDebuggerKey/$value\" to its previous value \"$previousWindowsPostMortemDebuggerValues{$value}\"\n.";
2426     }
2427 }