2010-10-19 Luiz Agostini <luiz.agostini@openbossa.org>
[WebKit-https.git] / WebKit2 / WebKit2.pri
1 # WebKit2 - Qt4 build info
2
3 QT += network
4
5 # Use a config-specific target to prevent parallel builds file clashes on Mac
6 mac: CONFIG(debug, debug|release): WEBKIT2_TARGET = webkit2d
7 else: WEBKIT2_TARGET = webkit2
8
9 # Output in WebKit2/<config>
10 CONFIG(debug, debug|release) : WEBKIT2_DESTDIR = debug
11 else: WEBKIT2_DESTDIR = release
12
13 defineTest(_addWebKit2Lib_common) {
14     pathToWebKit2Output = $$ARGS/$$WEBKIT2_DESTDIR
15
16     QMAKE_LIBDIR += $$pathToWebKit2Output
17
18     POST_TARGETDEPS += $${pathToWebKit2Output}$${QMAKE_DIR_SEP}lib$${WEBKIT2_TARGET}.a
19
20     # The following line is to prevent qmake from adding webkit2 to libQtWebKit's prl dependencies.
21     CONFIG -= explicitlib
22
23     export(QMAKE_LIBDIR)
24     export(POST_TARGETDEPS)
25     export(CONFIG)
26
27     return(true)
28 }
29
30 defineTest(addWebKit2Lib) {
31     _addWebKit2Lib_common($$ARGS)
32
33     QMAKE_LFLAGS += -l$$WEBKIT2_TARGET
34     export(QMAKE_LFLAGS)
35
36     return(true)
37 }
38
39 defineTest(addWebKit2LibWholeArchive) {
40     _addWebKit2Lib_common($$ARGS)
41
42     # -whole-archive makes all objects, even if unreferenced, included in the linked target.
43     mac:QMAKE_LFLAGS += -Wl,-all_load -l$$WEBKIT2_TARGET
44     else:QMAKE_LFLAGS += -Wl,-whole-archive -l$$WEBKIT2_TARGET -Wl,-no-whole-archive
45     export(QMAKE_LFLAGS)
46
47     return(true)
48 }