2010-10-08 Jocelyn Turcotte <jocelyn.turcotte@nokia.com>
[WebKit-https.git] / WebKit2 / WebKit2.pri
1 # WebKit2 - Qt4 build info
2
3 # Use a config-specific target to prevent parallel builds file clashes on Mac
4 mac: CONFIG(debug, debug|release): WEBKIT2_TARGET = webkit2d
5 else: WEBKIT2_TARGET = webkit2
6
7 # Output in WebKit2/<config>
8 CONFIG(debug, debug|release) : WEBKIT2_DESTDIR = debug
9 else: WEBKIT2_DESTDIR = release
10
11 defineTest(_addWebKit2Lib_common) {
12     pathToWebKit2Output = $$ARGS/$$WEBKIT2_DESTDIR
13
14     QMAKE_LIBDIR += $$pathToWebKit2Output
15
16     POST_TARGETDEPS += $${pathToWebKit2Output}$${QMAKE_DIR_SEP}lib$${WEBKIT2_TARGET}.a
17
18     # The following line is to prevent qmake from adding webkit2 to libQtWebKit's prl dependencies.
19     CONFIG -= explicitlib
20
21     export(QMAKE_LIBDIR)
22     export(POST_TARGETDEPS)
23     export(CONFIG)
24
25     return(true)
26 }
27
28 defineTest(addWebKit2Lib) {
29     _addWebKit2Lib_common($$ARGS)
30
31     QMAKE_LFLAGS += -l$$WEBKIT2_TARGET
32     export(QMAKE_LFLAGS)
33
34     return(true)
35 }
36
37 defineTest(addWebKit2LibWholeArchive) {
38     _addWebKit2Lib_common($$ARGS)
39
40     # -whole-archive makes all objects, even if unreferenced, included in the linked target.
41     mac:QMAKE_LFLAGS += -Wl,-all_load -l$$WEBKIT2_TARGET
42     else:QMAKE_LFLAGS += -Wl,-whole-archive -l$$WEBKIT2_TARGET -Wl,-no-whole-archive
43     export(QMAKE_LFLAGS)
44
45     return(true)
46 }