[Qt] Build system fixes against V8.
[WebKit-https.git] / WebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file, used to load WebKit in Qt Creator and for
3 # building QtWebKit.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 TEMPLATE = subdirs
9 CONFIG += ordered
10
11 QMAKEPATH = $$(QMAKEPATH)
12 isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
13     error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
14     # Otherwise we won't pick up the feature prf files needed for the build
15 }
16
17 WTF.file = Source/JavaScriptCore/wtf/wtf.pro
18 WTF.makefile = Makefile.WTF
19 SUBDIRS += WTF
20
21 !v8 {
22     JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
23     JavaScriptCore.makefile = Makefile.JavaScriptCore
24
25     SUBDIRS += JavaScriptCore
26 }
27
28 WebCore.file = Source/WebCore/WebCore.pro
29 WebCore.makefile = Makefile.WebCore
30 SUBDIRS += WebCore
31
32 !CONFIG(no_webkit2) {
33     webkit2.file = Source/WebKit2/WebKit2.pro
34     webkit2.makefile = Makefile.WebKit2
35     SUBDIRS += webkit2
36 }
37
38 QtWebKit.file = Source/QtWebKit.pro
39 QtWebKit.makefile = Makefile.QtWebKit
40 SUBDIRS += QtWebKit
41
42 SUBDIRS += Tools
43
44 OTHER_FILES = \
45     Tools/qmake/README \
46     Tools/qmake/mkspecs/modules/qt_webkit.pri \
47     Tools/qmake/mkspecs/features/*.prf \
48     Tools/qmake/mkspecs/features/mac/*.prf \
49     Tools/qmake/mkspecs/features/unix/*.prf \
50     Tools/qmake/mkspecs/features/win32/*.prf