webkitpy: fix race in unit tests for manager_worker_broker
[WebKit-https.git] / WebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file, used to load WebKit in Qt Creator and for
3 # building QtWebKit.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 TEMPLATE = subdirs
9 CONFIG += ordered
10
11 load(features)
12
13 QMAKEPATH = $$(QMAKEPATH)
14 isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
15     error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
16     # Otherwise we won't pick up the feature prf files needed for the build
17 }
18
19 WTF.file = Source/WTF/WTF.pro
20 WTF.makefile = Makefile.WTF
21 SUBDIRS += WTF
22
23 !v8 {
24     JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
25     JavaScriptCore.makefile = Makefile.JavaScriptCore
26     SUBDIRS += JavaScriptCore
27 }
28
29 WebCore.file = Source/WebCore/WebCore.pro
30 WebCore.makefile = Makefile.WebCore
31 SUBDIRS += WebCore
32
33 !CONFIG(no_webkit2) {
34     webkit2.file = Source/WebKit2/WebKit2.pro
35     webkit2.makefile = Makefile.WebKit2
36     SUBDIRS += webkit2
37 }
38
39 QtWebKit.file = Source/QtWebKit.pro
40 QtWebKit.makefile = Makefile.QtWebKit
41 SUBDIRS += QtWebKit
42
43 SUBDIRS += Tools