WebKit.pro

   1 TEMPLATE = subdirs
   2 CONFIG += ordered
   3
   4 include(WebKit.pri)
   5
   6 !v8: SUBDIRS += JavaScriptCore
   7 webkit2 {
   8     SUBDIRS += WebKit2
   9 }
  10 SUBDIRS += WebCore
  11
  12 # If the source exists, built it
  13 exists($$PWD/Tools/QtTestBrowser): SUBDIRS += Tools/QtTestBrowser
  14 contains(QT_CONFIG, declarative) {
  15     exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
  16 }
  17 !v8:exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
  18 exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
  19 exists($$PWD/Tools/DumpRenderTree/qt/DumpRenderTree.pro): SUBDIRS += Tools/DumpRenderTree/qt/DumpRenderTree.pro
  20 exists($$PWD/Tools/DumpRenderTree/qt/ImageDiff.pro): SUBDIRS += Tools/DumpRenderTree/qt/ImageDiff.pro
  21
  22 !win32:!symbian {
  23     exists($$PWD/Tools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro): SUBDIRS += Tools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro
  24 }
  25
  26 build-qtscript {
  27     SUBDIRS += \
  28         JavaScriptCore/qt/api/QtScript.pro \
  29         JavaScriptCore/qt/tests \
  30         JavaScriptCore/qt/benchmarks
  31 }
  32
  33 webkit2 {
  34     exists($$PWD/WebKit2/WebProcess.pro): SUBDIRS += WebKit2/WebProcess.pro
  35     exists($$PWD/Tools/MiniBrowser/qt/MiniBrowser.pro): SUBDIRS += Tools/MiniBrowser/qt/MiniBrowser.pro
  36     exists($$PWD/Tools/WebKitTestRunner/WebKitTestRunner.pro): SUBDIRS += Tools/WebKitTestRunner/WebKitTestRunner.pro
  37 }
  38
  39 symbian {
  40     # Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
  41     install.commands = $(MAKE) -C WebCore install
  42     QMAKE_EXTRA_TARGETS += install
  43 }
  44
  45 include(WebKit/qt/docs/docs.pri)