[Chromium] Move Task.(cpp|h) into TestRunner.a
[WebKit-https.git] / WebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file, used to load WebKit in Qt Creator and for
3 # building QtWebKit.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 haveQt(4) {
9     QMAKEPATH = $$(QMAKEPATH)
10     isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
11         error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
12         # Otherwise we won't pick up the feature prf files needed for the build
13     }
14 }
15
16 TEMPLATE = subdirs
17 CONFIG += ordered
18
19 WTF.file = Source/WTF/WTF.pro
20 WTF.makefile = Makefile.WTF
21 SUBDIRS += WTF
22
23 !v8 {
24     JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
25     JavaScriptCore.makefile = Makefile.JavaScriptCore
26     SUBDIRS += JavaScriptCore
27 }
28
29 WebCore.file = Source/WebCore/WebCore.pro
30 WebCore.makefile = Makefile.WebCore
31 SUBDIRS += WebCore
32
33 !no_webkit1 {
34     webkit1.file = Source/WebKit/WebKit1.pro
35     webkit1.makefile = Makefile.WebKit1
36     SUBDIRS += webkit1
37 }
38
39 !no_webkit2 {
40     webkit2.file = Source/WebKit2/WebKit2.pro
41     webkit2.makefile = Makefile.WebKit2
42     SUBDIRS += webkit2
43 }
44
45 QtWebKit.file = Source/QtWebKit.pro
46 QtWebKit.makefile = Makefile.QtWebKit
47 SUBDIRS += QtWebKit
48
49 SUBDIRS += Tools