[wx] Unreviewed build fix. Remove from WebDOMEventTarget bindings methods that have...
[WebKit-https.git] / WebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file, used to load WebKit in Qt Creator and for
3 # building QtWebKit.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 TEMPLATE = subdirs
9 CONFIG += ordered
10
11 QMAKEPATH = $$(QMAKEPATH)
12 isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
13     error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
14     # Otherwise we won't pick up the feature prf files needed for the build
15 }
16
17 !CONFIG(v8) {
18     JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
19     JavaScriptCore.makefile = Makefile.JavaScriptCore
20
21     SUBDIRS += JavaScriptCore
22 }
23
24 WebCore.file = Source/WebCore/WebCore.pro
25 WebCore.makefile = Makefile.WebCore
26 SUBDIRS += WebCore
27
28 !CONFIG(no_webkit2) {
29     webkit2.file = Source/WebKit2/WebKit2.pro
30     webkit2.makefile = Makefile.WebKit2
31     SUBDIRS += webkit2
32 }
33
34 QtWebKit.file = Source/QtWebKit.pro
35 QtWebKit.makefile = Makefile.QtWebKit
36 SUBDIRS += QtWebKit
37
38 SUBDIRS += Tools
39
40 OTHER_FILES = \
41     Tools/qmake/README \
42     Tools/qmake/qt_webkit.pri \
43     Tools/qmake/mkspecs/features/*.prf \
44     Tools/qmake/mkspecs/features/mac/*.prf \
45     Tools/qmake/mkspecs/features/unix/*.prf \
46     Tools/qmake/mkspecs/features/win32/*.prf