[Qt] new test fast/forms/radio/radio-group.html failing after r104668
[WebKit-https.git] / WebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file, used to load WebKit in Qt Creator and for
3 # building QtWebKit.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 TEMPLATE = subdirs
9 CONFIG += ordered
10
11 QMAKEPATH = $$(QMAKEPATH)
12 isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
13     error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
14     # Otherwise we won't pick up the feature prf files needed for the build
15 }
16
17 # Always go into JavaScriptCore to at least build WTF.
18 JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
19 JavaScriptCore.makefile = Makefile.JavaScriptCore
20 SUBDIRS += JavaScriptCore
21
22 WebCore.file = Source/WebCore/WebCore.pro
23 WebCore.makefile = Makefile.WebCore
24 SUBDIRS += WebCore
25
26 !CONFIG(no_webkit2) {
27     webkit2.file = Source/WebKit2/WebKit2.pro
28     webkit2.makefile = Makefile.WebKit2
29     SUBDIRS += webkit2
30 }
31
32 QtWebKit.file = Source/QtWebKit.pro
33 QtWebKit.makefile = Makefile.QtWebKit
34 SUBDIRS += QtWebKit
35
36 SUBDIRS += Tools
37
38 OTHER_FILES = \
39     Tools/qmake/README \
40     Tools/qmake/configure.pro \
41     Tools/qmake/sync.profile \
42     Tools/qmake/config.tests/fontconfig/* \
43     Tools/qmake/mkspecs/modules/* \
44     Tools/qmake/mkspecs/features/*.prf \
45     Tools/qmake/mkspecs/features/mac/*.prf \
46     Tools/qmake/mkspecs/features/unix/*.prf \
47     Tools/qmake/mkspecs/features/win32/*.prf