Add AudioFIFO class and simplify AudioPullFIFO
[WebKit-https.git] / WebKit.pro
1 # -------------------------------------------------------------------
2 # Root project file, used to load WebKit in Qt Creator and for
3 # building QtWebKit.
4 #
5 # See 'Tools/qmake/README' for an overview of the build system
6 # -------------------------------------------------------------------
7
8 TEMPLATE = subdirs
9 CONFIG += ordered
10
11 QMAKEPATH = $$(QMAKEPATH)
12 isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
13     error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
14     # Otherwise we won't pick up the feature prf files needed for the build
15 }
16
17 WTF.file = Source/WTF/WTF.pro
18 WTF.makefile = Makefile.WTF
19 SUBDIRS += WTF
20
21 !v8 {
22     JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
23     JavaScriptCore.makefile = Makefile.JavaScriptCore
24     SUBDIRS += JavaScriptCore
25 }
26
27 WebCore.file = Source/WebCore/WebCore.pro
28 WebCore.makefile = Makefile.WebCore
29 SUBDIRS += WebCore
30
31 !no_webkit2 {
32     webkit2.file = Source/WebKit2/WebKit2.pro
33     webkit2.makefile = Makefile.WebKit2
34     SUBDIRS += webkit2
35 }
36
37 !no_webkit1 {
38     webkit1.file = Source/WebKit/WebKit1.pro
39     webkit1.makefile = Makefile.WebKit1
40     SUBDIRS += webkit1
41 }
42
43 QtWebKit.file = Source/QtWebKit.pro
44 QtWebKit.makefile = Makefile.QtWebKit
45 SUBDIRS += QtWebKit
46
47 SUBDIRS += Tools