[Qt] Fix the build on Maemo5.
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3 # Detect that we are building as a standalone package by the presence of
4 # either the generated files directory or as part of the Qt package through
5 # QTDIR_build
6 CONFIG(QTDIR_build): CONFIG += standalone_package
7 else:exists($$PWD/WebCore/generated): CONFIG += standalone_package
8
9 CONFIG(standalone_package) {
10     OUTPUT_DIR=$$PWD
11 }
12
13 CONFIG += depend_includepath
14
15 isEmpty(OUTPUT_DIR) {
16     CONFIG(debug, debug|release) {
17         OUTPUT_DIR=$$PWD/WebKitBuild/Debug
18     } else { # Release
19         OUTPUT_DIR=$$PWD/WebKitBuild/Release
20     }
21 }
22
23 DEFINES += BUILDING_QT__=1
24 building-libs {
25     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
26 } else {
27     CONFIG(QTDIR_build) {
28         QT += webkit
29     } else {
30         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
31         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
32             LIBS += -framework QtWebKit
33             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
34         } else {
35             win32-*|wince* {
36                 LIBS += -lQtWebKit$${QT_MAJOR_VERSION}
37             } else {
38                 LIBS += -lQtWebKit
39                 symbian {
40                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
41                     TARGET.EPOCHEAPSIZE = 0x20000 0x2000000 // Min 128kB, Max 32MB
42                 }
43             }
44         }
45     }
46     DEPENDPATH += $$PWD/WebKit/qt/Api
47 }
48 greaterThan(QT_MINOR_VERSION, 5):DEFINES += WTF_USE_ACCELERATED_COMPOSITING
49
50 !mac:!unix|symbian {
51     DEFINES += USE_SYSTEM_MALLOC
52 }
53
54 CONFIG(release, debug|release) {
55     DEFINES += NDEBUG
56 }
57
58 BASE_DIR = $$PWD
59 INCLUDEPATH += $$PWD/WebKit/qt/Api
60
61 CONFIG -= warn_on
62 *-g++*:QMAKE_CXXFLAGS += -Wall -Wreturn-type -fno-strict-aliasing -Wcast-align -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
63
64 # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
65 symbian|*-armcc {
66     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
67     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
68 }
69
70 *-armcc {
71     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
72     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
73 }
74
75 symbian {
76     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
77 }
78
79 symbian|maemo5: DEFINES *= QT_NO_UITOOLS
80
81 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools
82
83 # Disable a few warnings on Windows. The warnings are also
84 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
85 win32-msvc*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
86