.:
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(debug, debug|release) {
6         OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7     } else { # Release
8         OUTPUT_DIR=$$PWD/WebKitBuild/Release
9     }
10 }
11
12 DEFINES += BUILDING_QT__=1
13 building-libs {
14     win32-msvc*: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
15 } else {
16     CONFIG(QTDIR_build) {
17         QT += webkit
18     } else {
19         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
20         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
21             LIBS += -framework QtWebKit
22             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
23         } else {
24             win32-*|wince* {
25                 LIBS += -lQtWebKit$${QT_MAJOR_VERSION}
26             } else {
27                 LIBS += -lQtWebKit
28             }
29         }
30     }
31     DEPENDPATH += $$PWD/WebKit/qt/Api
32 }
33
34 DEFINES += USE_SYSTEM_MALLOC
35 CONFIG(release, debug|release) {
36     DEFINES += NDEBUG
37 }
38
39 BASE_DIR = $$PWD
40 INCLUDEPATH += $$PWD/WebKit/qt/Api
41
42 # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
43 *-armcc {
44     QMAKE_CFLAGS += --gnu
45     QMAKE_CXXFLAGS += --gnu --no_parse_templates
46
47
48 symbian {
49     QMAKE_CXXFLAGS.ARMCC += --gnu --no_parse_templates
50     DEFINES *= QT_NO_UITOOLS
51 }
52
53 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools
54
55 # Disable a few warnings on Windows. The warnings are also
56 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
57 win32-msvc*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4503 -wd4800 -wd4819 -wd4996
58
59 #
60 # For builds inside Qt we interpret the output rule and the input of each extra compiler manually
61 # and add the resulting sources to the SOURCES variable, because the build inside Qt contains already
62 # all the generated files. We do not need to generate any extra compiler rules in that case.
63 #
64 # In addition this function adds a new target called 'generated_files' that allows manually calling
65 # all the extra compilers to generate all the necessary files for the build using 'make generated_files'
66 #
67 defineTest(addExtraCompiler) {
68     CONFIG(QTDIR_build) {
69         outputRule = $$eval($${1}.output)
70         outVariable = $$eval($${1}.variable_out)
71         !isEqual(outVariable,GENERATED_SOURCES):return(true)
72
73         input = $$eval($${1}.input)
74         input = $$eval($$input)
75
76         for(file,input) {
77             base = $$basename(file)
78             base ~= s/\..+//
79             newfile=$$replace(outputRule,\\$\\{QMAKE_FILE_BASE\\},$$base)
80             SOURCES += $$newfile
81         }
82
83         export(SOURCES)
84     } else {
85         QMAKE_EXTRA_COMPILERS += $$1
86         generated_files.depends += compiler_$${1}_make_all
87         export(QMAKE_EXTRA_COMPILERS)
88         export(generated_files.depends)
89     }
90     return(true)
91 }
92
93 defineTest(addExtraCompilerWithHeader) {
94     addExtraCompiler($$1)
95
96     eval(headerFile = $${2})
97     isEmpty(headerFile) {
98         eval($${1}_header.output = $$eval($${1}.output))
99         eval($${1}_header.output ~= s/\.cpp/.h/)
100         eval($${1}_header.output ~= s/\.c/.h/)
101     } else {
102         eval($${1}_header.output = $$headerFile)
103     }
104
105     eval($${1}_header.input = $$eval($${1}.input))
106     eval($${1}_header.commands = @echo -n '')
107     eval($${1}_header.depends = compiler_$${1}_make_all)
108     eval($${1}_header.variable_out = GENERATED_FILES)
109
110     export($${1}_header.output)
111     export($${1}_header.input)
112     export($${1}_header.commands)
113     export($${1}_header.depends)
114     export($${1}_header.variable_out)
115
116     !CONFIG(QTDIR_build): QMAKE_EXTRA_COMPILERS += $${1}_header
117
118     export(QMAKE_EXTRA_COMPILERS)
119     export(generated_files.depends)
120     export(SOURCES)
121
122     return(true)
123 }
124