2009-06-09 Simon Hausmann <simon.hausmann@nokia.com>
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7 }
8
9 DEFINES += BUILDING_QT__=1
10 building-libs {
11     win32-msvc*: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
12 } else {
13     CONFIG(QTDIR_build) {
14         QT += webkit
15     } else {
16         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
17         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
18             LIBS += -framework QtWebKit
19             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
20         } else {
21             LIBS += -lQtWebKit
22         }
23     }
24     DEPENDPATH += $$PWD/WebKit/qt/Api
25 }
26
27 DEFINES += USE_SYSTEM_MALLOC
28 CONFIG(release) {
29     DEFINES += NDEBUG
30 }
31
32 BASE_DIR = $$PWD
33 INCLUDEPATH += $$PWD/WebKit/qt/Api
34
35 #
36 # For builds inside Qt we interpret the output rule and the input of each extra compiler manually
37 # and add the resulting sources to the SOURCES variable, because the build inside Qt contains already
38 # all the generated files. We do not need to generate any extra compiler rules in that case.
39 #
40 # In addition this function adds a new target called 'generated_files' that allows manually calling
41 # all the extra compilers to generate all the necessary files for the build using 'make generated_files'
42 #
43 defineTest(addExtraCompiler) {
44     CONFIG(QTDIR_build) {
45         outputRule = $$eval($${1}.output)
46         outVariable = $$eval($${1}.variable_out)
47         !isEqual(outVariable,GENERATED_SOURCES):return(true)
48
49         input = $$eval($${1}.input)
50         input = $$eval($$input)
51
52         for(file,input) {
53             base = $$basename(file)
54             base ~= s/\..+//
55             newfile=$$replace(outputRule,\\$\\{QMAKE_FILE_BASE\\},$$base)
56             SOURCES += $$newfile
57         }
58
59         export(SOURCES)
60     } else {
61         QMAKE_EXTRA_COMPILERS += $$1
62         generated_files.depends += compiler_$${1}_make_all
63         export(QMAKE_EXTRA_COMPILERS)
64         export(generated_files.depends)
65     }
66     return(true)
67 }
68
69 defineTest(addExtraCompilerWithHeader) {
70     addExtraCompiler($$1)
71
72     eval(headerFile = $${2})
73     isEmpty(headerFile) {
74         eval($${1}_header.output = $$eval($${1}.output))
75         eval($${1}_header.output ~= s/\.cpp/.h/)
76         eval($${1}_header.output ~= s/\.c/.h/)
77     } else {
78         eval($${1}_header.output = $$headerFile)
79     }
80
81     eval($${1}_header.input = $$eval($${1}.input))
82     eval($${1}_header.commands = @echo -n '')
83     eval($${1}_header.depends = compiler_$${1}_make_all)
84     eval($${1}_header.variable_out = GENERATED_FILES)
85
86     export($${1}_header.output)
87     export($${1}_header.input)
88     export($${1}_header.commands)
89     export($${1}_header.depends)
90     export($${1}_header.variable_out)
91
92     !CONFIG(QTDIR_build): QMAKE_EXTRA_COMPILERS += $${1}_header
93
94     export(QMAKE_EXTRA_COMPILERS)
95     export(generated_files.depends)
96     export(SOURCES)
97
98     return(true)
99 }
100