2009-07-28 Xan Lopez <xlopez@igalia.com>
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(debug, debug|release) {
6         OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7     } else { # Release
8         OUTPUT_DIR=$$PWD/WebKitBuild/Release
9     }
10 }
11
12 DEFINES += BUILDING_QT__=1
13 building-libs {
14     win32-msvc*: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
15 } else {
16     CONFIG(QTDIR_build) {
17         QT += webkit
18     } else {
19         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
20         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
21             LIBS += -framework QtWebKit
22             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
23         } else {
24             win32-*|wince* {
25                 LIBS += -lQtWebKit$${QT_MAJOR_VERSION}
26             } else {
27                 LIBS += -lQtWebKit
28             }
29         }
30     }
31     DEPENDPATH += $$PWD/WebKit/qt/Api
32 }
33
34 DEFINES += USE_SYSTEM_MALLOC
35 CONFIG(release, debug|release) {
36     DEFINES += NDEBUG
37 }
38
39 BASE_DIR = $$PWD
40 INCLUDEPATH += $$PWD/WebKit/qt/Api
41
42 # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
43 *-armcc {
44     QMAKE_CFLAGS += --gnu
45     QMAKE_CXXFLAGS += --gnu --no_parse_templates
46
47
48 symbian {
49     QMAKE_CXXFLAGS.ARMCC += --gnu --no_parse_templates
50     DEFINES *= QT_NO_UITOOLS
51 }
52
53 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools
54
55 #
56 # For builds inside Qt we interpret the output rule and the input of each extra compiler manually
57 # and add the resulting sources to the SOURCES variable, because the build inside Qt contains already
58 # all the generated files. We do not need to generate any extra compiler rules in that case.
59 #
60 # In addition this function adds a new target called 'generated_files' that allows manually calling
61 # all the extra compilers to generate all the necessary files for the build using 'make generated_files'
62 #
63 defineTest(addExtraCompiler) {
64     CONFIG(QTDIR_build) {
65         outputRule = $$eval($${1}.output)
66         outVariable = $$eval($${1}.variable_out)
67         !isEqual(outVariable,GENERATED_SOURCES):return(true)
68
69         input = $$eval($${1}.input)
70         input = $$eval($$input)
71
72         for(file,input) {
73             base = $$basename(file)
74             base ~= s/\..+//
75             newfile=$$replace(outputRule,\\$\\{QMAKE_FILE_BASE\\},$$base)
76             SOURCES += $$newfile
77         }
78
79         export(SOURCES)
80     } else {
81         QMAKE_EXTRA_COMPILERS += $$1
82         generated_files.depends += compiler_$${1}_make_all
83         export(QMAKE_EXTRA_COMPILERS)
84         export(generated_files.depends)
85     }
86     return(true)
87 }
88
89 defineTest(addExtraCompilerWithHeader) {
90     addExtraCompiler($$1)
91
92     eval(headerFile = $${2})
93     isEmpty(headerFile) {
94         eval($${1}_header.output = $$eval($${1}.output))
95         eval($${1}_header.output ~= s/\.cpp/.h/)
96         eval($${1}_header.output ~= s/\.c/.h/)
97     } else {
98         eval($${1}_header.output = $$headerFile)
99     }
100
101     eval($${1}_header.input = $$eval($${1}.input))
102     eval($${1}_header.commands = @echo -n '')
103     eval($${1}_header.depends = compiler_$${1}_make_all)
104     eval($${1}_header.variable_out = GENERATED_FILES)
105
106     export($${1}_header.output)
107     export($${1}_header.input)
108     export($${1}_header.commands)
109     export($${1}_header.depends)
110     export($${1}_header.variable_out)
111
112     !CONFIG(QTDIR_build): QMAKE_EXTRA_COMPILERS += $${1}_header
113
114     export(QMAKE_EXTRA_COMPILERS)
115     export(generated_files.depends)
116     export(SOURCES)
117
118     return(true)
119 }
120