2010-05-11 Joseph Pecoraro <joepeck@webkit.org>
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3 # Detect that we are building as a standalone package by the presence of
4 # either the generated files directory or as part of the Qt package through
5 # QTDIR_build
6 CONFIG(QTDIR_build): CONFIG += standalone_package
7 else:exists($$PWD/WebCore/generated): CONFIG += standalone_package
8
9 CONFIG += depend_includepath
10
11 DEFINES += BUILDING_QT__=1
12 building-libs {
13     win32-msvc*|win32-icc: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
14 } else {
15     CONFIG(QTDIR_build) {
16         QT += webkit
17     } else {
18         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
19         QTWEBKITLIBNAME = QtWebKit
20         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
21             LIBS += -framework $$QTWEBKITLIBNAME
22             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
23         } else {
24             win32-*|wince* {
25                 CONFIG(debug, debug|release):build_pass: QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}d
26                 QTWEBKITLIBNAME = $${QTWEBKITLIBNAME}$${QT_MAJOR_VERSION}
27                 win32-g++: LIBS += -l$$QTWEBKITLIBNAME
28                 else: LIBS += $${QTWEBKITLIBNAME}.lib
29             } else {
30                 LIBS += -lQtWebKit
31                 symbian {
32                     TARGET.EPOCSTACKSIZE = 0x14000 // 80 kB
33                     TARGET.EPOCHEAPSIZE = 0x20000 0x2000000 // Min 128kB, Max 32MB
34                 }
35             }
36         }
37     }
38     DEPENDPATH += $$PWD/WebKit/qt/Api
39 }
40 greaterThan(QT_MINOR_VERSION, 5):DEFINES += WTF_USE_ACCELERATED_COMPOSITING
41
42 !mac:!unix|symbian {
43     DEFINES += USE_SYSTEM_MALLOC
44 }
45
46 CONFIG(release, debug|release) {
47     DEFINES += NDEBUG
48 }
49
50 BASE_DIR = $$PWD
51
52 symbian {
53     INCLUDEPATH += $$PWD/include/QtWebKit
54 } else {
55     INCLUDEPATH += $$OUTPUT_DIR/include/QtWebKit
56 }
57
58 CONFIG -= warn_on
59 *-g++*:QMAKE_CXXFLAGS += -Wall -Wextra -Wreturn-type -fno-strict-aliasing -Wcast-align -Wchar-subscripts -Wformat-security -Wreturn-type -Wno-unused-parameter -Wno-sign-compare -Wno-switch -Wno-switch-enum -Wundef -Wmissing-noreturn -Winit-self
60
61 # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
62 symbian|*-armcc {
63     RVCT_COMMON_CFLAGS = --gnu --diag_suppress 68,111,177,368,830,1293
64     RVCT_COMMON_CXXFLAGS = $$RVCT_COMMON_CFLAGS --no_parse_templates
65 }
66
67 *-armcc {
68     QMAKE_CFLAGS += $$RVCT_COMMON_CFLAGS
69     QMAKE_CXXFLAGS += $$RVCT_COMMON_CXXFLAGS
70 }
71
72 symbian {
73     QMAKE_CXXFLAGS.ARMCC += $$RVCT_COMMON_CXXFLAGS
74 }
75
76 symbian|maemo5: DEFINES *= QT_NO_UITOOLS
77
78 contains(DEFINES, QT_NO_UITOOLS): CONFIG -= uitools
79
80 # Disable a few warnings on Windows. The warnings are also
81 # disabled in WebKitLibraries/win/tools/vsprops/common.vsprops
82 win32-msvc*: QMAKE_CXXFLAGS += -wd4291 -wd4344 -wd4396 -wd4503 -wd4800 -wd4819 -wd4996
83