2009-07-16 Laszlo Gombos <laszlo.1.gombos@nokia.com>
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(debug, debug|release) {
6         OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7     } else { # Release
8         OUTPUT_DIR=$$PWD/WebKitBuild/Release
9     }
10 }
11
12 DEFINES += BUILDING_QT__=1
13 building-libs {
14     win32-msvc*: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
15 } else {
16     CONFIG(QTDIR_build) {
17         QT += webkit
18     } else {
19         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
20         mac:!static:contains(QT_CONFIG, qt_framework):!CONFIG(webkit_no_framework) {
21             LIBS += -framework QtWebKit
22             QMAKE_FRAMEWORKPATH = $$OUTPUT_DIR/lib $$QMAKE_FRAMEWORKPATH
23         } else {
24             win32-*|wince* {
25                 LIBS += -lQtWebKit$${QT_MAJOR_VERSION}
26             } else {
27                 LIBS += -lQtWebKit
28             }
29         }
30     }
31     DEPENDPATH += $$PWD/WebKit/qt/Api
32 }
33
34 DEFINES += USE_SYSTEM_MALLOC
35 CONFIG(release, debug|release) {
36     DEFINES += NDEBUG
37 }
38
39 BASE_DIR = $$PWD
40 INCLUDEPATH += $$PWD/WebKit/qt/Api
41
42 # Enable GNU compiler extensions to the ARM compiler for all Qt ports using RVCT
43 *-armcc {
44     QMAKE_CFLAGS += --gnu
45     QMAKE_CXXFLAGS += --gnu --no_parse_templates
46
47
48 symbian {
49     QMAKE_CXXFLAGS.ARMCC += --gnu --no_parse_templates
50 }
51
52 #
53 # For builds inside Qt we interpret the output rule and the input of each extra compiler manually
54 # and add the resulting sources to the SOURCES variable, because the build inside Qt contains already
55 # all the generated files. We do not need to generate any extra compiler rules in that case.
56 #
57 # In addition this function adds a new target called 'generated_files' that allows manually calling
58 # all the extra compilers to generate all the necessary files for the build using 'make generated_files'
59 #
60 defineTest(addExtraCompiler) {
61     CONFIG(QTDIR_build) {
62         outputRule = $$eval($${1}.output)
63         outVariable = $$eval($${1}.variable_out)
64         !isEqual(outVariable,GENERATED_SOURCES):return(true)
65
66         input = $$eval($${1}.input)
67         input = $$eval($$input)
68
69         for(file,input) {
70             base = $$basename(file)
71             base ~= s/\..+//
72             newfile=$$replace(outputRule,\\$\\{QMAKE_FILE_BASE\\},$$base)
73             SOURCES += $$newfile
74         }
75
76         export(SOURCES)
77     } else {
78         QMAKE_EXTRA_COMPILERS += $$1
79         generated_files.depends += compiler_$${1}_make_all
80         export(QMAKE_EXTRA_COMPILERS)
81         export(generated_files.depends)
82     }
83     return(true)
84 }
85
86 defineTest(addExtraCompilerWithHeader) {
87     addExtraCompiler($$1)
88
89     eval(headerFile = $${2})
90     isEmpty(headerFile) {
91         eval($${1}_header.output = $$eval($${1}.output))
92         eval($${1}_header.output ~= s/\.cpp/.h/)
93         eval($${1}_header.output ~= s/\.c/.h/)
94     } else {
95         eval($${1}_header.output = $$headerFile)
96     }
97
98     eval($${1}_header.input = $$eval($${1}.input))
99     eval($${1}_header.commands = @echo -n '')
100     eval($${1}_header.depends = compiler_$${1}_make_all)
101     eval($${1}_header.variable_out = GENERATED_FILES)
102
103     export($${1}_header.output)
104     export($${1}_header.input)
105     export($${1}_header.commands)
106     export($${1}_header.depends)
107     export($${1}_header.variable_out)
108
109     !CONFIG(QTDIR_build): QMAKE_EXTRA_COMPILERS += $${1}_header
110
111     export(QMAKE_EXTRA_COMPILERS)
112     export(generated_files.depends)
113     export(SOURCES)
114
115     return(true)
116 }
117