Hopefully the final build fix
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7 }
8
9 !gtk-port:CONFIG += qt-port
10 qt-port:DEFINES += BUILDING_QT__=1
11 qt-port:!building-libs {
12     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
13     LIBS += -lQtWebKit
14     DEPENDPATH += $$PWD/WebKit/qt/Api
15 }
16
17 gtk-port:!building-libs {
18     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
19     LIBS += -lWebKitGtk
20     DEPENDPATH += $$PWD/WebKit/gtk/Api $$PWD/WebKit/gtk/WebCoreSupport
21 }
22
23 gtk-port {
24     CONFIG += link_pkgconfig
25
26     DEFINES += BUILDING_CAIRO__=1 BUILDING_GTK__=1
27
28     # We use FreeType directly with Cairo
29     PKGCONFIG += cairo-ft
30
31     directfb: PKGCONFIG += cairo-directfb gtk+-directfb-2.0
32     else: PKGCONFIG += cairo gtk+-2.0
33
34     # Set a CONFIG flag for the GTK+ target (x11, quartz, win32, directfb)
35     CONFIG += $$system(pkg-config --variable=target $$PKGCONFIG)
36
37     # We use the curl http backend on all platforms
38     PKGCONFIG += libcurl
39
40     LIBS += -lWebKitGtk -ljpeg -lpng
41
42     QMAKE_CXXFLAGS += $$system(icu-config --cppflags)
43     QMAKE_LIBS += $$system(icu-config --ldflags)
44
45     # This set of warnings is borrowed from the Mac build
46     QMAKE_CXXFLAGS += -Wall -W -Wcast-align -Wchar-subscripts -Wformat-security -Wmissing-format-attribute -Wpointer-arith -Wwrite-strings -Wno-format-y2k -Wno-unused-parameter -Wundef
47 }
48
49 DEFINES += USE_SYSTEM_MALLOC
50 CONFIG(release) {
51     DEFINES += NDEBUG
52 }
53
54 BASE_DIR = $$PWD
55 qt-port:INCLUDEPATH += \
56     $$PWD/WebKit/qt/Api
57 gtk-port:INCLUDEPATH += \
58     $$BASE_DIR/WebCore/platform/gtk \
59     $$BASE_DIR/WebCore/platform/network/curl \
60     $$BASE_DIR/WebCore/platform/graphics/cairo \
61     $$BASE_DIR/WebCore/loader/gtk \
62     $$BASE_DIR/WebCore/page/gtk \
63     $$BASE_DIR/WebKit/gtk/Api \
64     $$BASE_DIR/WebKit/gtk/WebCoreSupport
65 INCLUDEPATH += \
66     $$BASE_DIR/JavaScriptCore/ \
67     $$BASE_DIR/JavaScriptCore/kjs \
68     $$BASE_DIR/JavaScriptCore/bindings \
69     $$BASE_DIR/JavaScriptCore/bindings/c \
70     $$BASE_DIR/JavaScriptCore/wtf \
71     $$BASE_DIR/JavaScriptCore/ForwardingHeaders \
72     $$BASE_DIR/WebCore \
73     $$BASE_DIR/WebCore/ForwardingHeaders \
74     $$BASE_DIR/WebCore/platform \
75     $$BASE_DIR/WebCore/platform/network \
76     $$BASE_DIR/WebCore/platform/graphics \
77     $$BASE_DIR/WebCore/loader \
78     $$BASE_DIR/WebCore/page \
79     $$BASE_DIR/WebCore/css \
80     $$BASE_DIR/WebCore/dom \
81     $$BASE_DIR/WebCore/bridge \
82     $$BASE_DIR/WebCore/editing \
83     $$BASE_DIR/WebCore/rendering \
84     $$BASE_DIR/WebCore/history \
85     $$BASE_DIR/WebCore/xml \
86     $$BASE_DIR/WebCore/html
87
88
89 macx {
90         INCLUDEPATH += /usr/include/libxml2
91         LIBS += -lxml2 -lxslt
92 }