Use a faster and safer way of flattening the form data.
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7 }
8
9 !gtk-port:CONFIG += qt-port
10 qt-port:DEFINES += BUILDING_QT__=1
11 qt-port:!building-libs {
12     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
13     LIBS += -lQtWebKit
14     DEPENDPATH += $$PWD/WebKit/qt/Api
15 }
16
17 gtk-port:!building-libs {
18     QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
19     LIBS += -lWebKitGtk
20     DEPENDPATH += $$PWD/WebKit/gtk/WebView $$PWD/WebKit/gtk/WebCoreSupport
21 }
22
23 gtk-port {
24     CONFIG += link_pkgconfig
25
26     DEFINES += BUILDING_CAIRO__=1 BUILDING_GTK__=1
27
28     # We use FreeType directly with Cairo
29     PKGCONFIG += cairo-ft
30
31     directfb: PKGCONFIG += cairo-directfb gtk+-directfb-2.0
32     else: PKGCONFIG += cairo gtk+-2.0
33
34     # Set a CONFIG flag for the GTK+ target (x11, quartz, win32, directfb)
35     CONFIG += $$system(pkg-config --variable=target $$PKGCONFIG)
36
37     # We use the curl http backend on all platforms
38     PKGCONFIG += libcurl
39
40     LIBS += -lWebKitGtk -ljpeg -lpng
41
42     QMAKE_CXXFLAGS += $$system(icu-config --cppflags)
43     QMAKE_LIBS += $$system(icu-config --ldflags)
44
45     # This set of warnings is borrowed from the Mac build
46     QMAKE_CXXFLAGS += -Wall -W -Wcast-align -Wchar-subscripts -Wformat-security -Wmissing-format-attribute -Wpointer-arith -Wwrite-strings -Wno-format-y2k -Wno-unused-parameter -Wundef
47
48     # These flags are based on optimization experience from the Mac port:
49     # Helps code size significantly and speed a little
50     QMAKE_CXXFLAGS += -fno-exceptions -fno-rtti
51
52     DEPENDPATH += $$PWD/JavaScriptCore/API
53     INCLUDEPATH += $$PWD
54 }
55
56 DEFINES += USE_SYSTEM_MALLOC
57 CONFIG(release) {
58     DEFINES += NDEBUG
59 }
60
61 gtk-port:CONFIG(debug) {
62     DEFINES += G_DISABLE_DEPRECATED GDK_PIXBUF_DISABLE_DEPRECATED GDK_DISABLE_DEPRECATED GTK_DISABLE_DEPRECATED PANGO_DISABLE_DEPRECATED
63 # maybe useful for debugging   DEFINES += GDK_MULTIHEAD_SAFE GTK_MULTIHEAD_SAFE
64 }
65
66 BASE_DIR = $$PWD
67 qt-port:INCLUDEPATH += \
68     $$PWD/WebKit/qt/Api
69 gtk-port:INCLUDEPATH += \
70     $$BASE_DIR/WebCore/platform/gtk \
71     $$BASE_DIR/WebCore/platform/network/curl \
72     $$BASE_DIR/WebCore/platform/graphics/cairo \
73     $$BASE_DIR/WebCore/loader/gtk \
74     $$BASE_DIR/WebCore/page/gtk \
75     $$BASE_DIR/WebKit/gtk/WebView \
76     $$BASE_DIR/WebKit/gtk/WebCoreSupport
77 INCLUDEPATH += \
78     $$BASE_DIR/JavaScriptCore/ \
79     $$BASE_DIR/JavaScriptCore/kjs \
80     $$BASE_DIR/JavaScriptCore/bindings \
81     $$BASE_DIR/JavaScriptCore/bindings/c \
82     $$BASE_DIR/JavaScriptCore/wtf \
83     $$BASE_DIR/JavaScriptCore/ForwardingHeaders \
84     $$BASE_DIR/WebCore \
85     $$BASE_DIR/WebCore/ForwardingHeaders \
86     $$BASE_DIR/WebCore/platform \
87     $$BASE_DIR/WebCore/platform/network \
88     $$BASE_DIR/WebCore/platform/graphics \
89     $$BASE_DIR/WebCore/loader \
90     $$BASE_DIR/WebCore/page \
91     $$BASE_DIR/WebCore/css \
92     $$BASE_DIR/WebCore/dom \
93     $$BASE_DIR/WebCore/bridge \
94     $$BASE_DIR/WebCore/editing \
95     $$BASE_DIR/WebCore/rendering \
96     $$BASE_DIR/WebCore/history \
97     $$BASE_DIR/WebCore/xml \
98     $$BASE_DIR/WebCore/html
99
100
101 macx {
102         INCLUDEPATH += /usr/include/libxml2
103         LIBS += -lxml2 -lxslt
104 }