WebCore:
[WebKit-https.git] / WebKit.pri
1 # Include file to make it easy to include WebKit into Qt projects
2
3
4 isEmpty(OUTPUT_DIR) {
5     CONFIG(release):OUTPUT_DIR=$$PWD/WebKitBuild/Release
6     CONFIG(debug):OUTPUT_DIR=$$PWD/WebKitBuild/Debug
7 }
8
9 DEFINES += BUILDING_QT__=1
10 building-libs {
11     win32-msvc*: INCLUDEPATH += $$PWD/JavaScriptCore/os-win32
12 } else {
13     CONFIG(QTDIR_build) {
14         QT += webkit
15     } else {
16         QMAKE_LIBDIR = $$OUTPUT_DIR/lib $$QMAKE_LIBDIR
17         LIBS += -lQtWebKit
18     }
19     DEPENDPATH += $$PWD/WebKit/qt/Api
20 }
21
22 DEFINES += USE_SYSTEM_MALLOC
23 CONFIG(release) {
24     DEFINES += NDEBUG
25 }
26
27 BASE_DIR = $$PWD
28 INCLUDEPATH += $$PWD/WebKit/qt/Api
29
30 #
31 # For builds inside Qt we interpret the output rule and the input of each extra compiler manually
32 # and add the resulting sources to the SOURCES variable, because the build inside Qt contains already
33 # all the generated files. We do not need to generate any extra compiler rules in that case.
34 #
35 # In addition this function adds a new target called 'generated_files' that allows manually calling
36 # all the extra compilers to generate all the necessary files for the build using 'make generated_files'
37 #
38 defineTest(addExtraCompiler) {
39     CONFIG(QTDIR_build) {
40         outputRule = $$eval($${1}.output)
41
42         input = $$eval($${1}.input)
43         input = $$eval($$input)
44
45         for(file,input) {
46             base = $$basename(file)
47             base ~= s/\..+//
48             newfile=$$replace(outputRule,\\$\\{QMAKE_FILE_BASE\\},$$base)
49             SOURCES += $$newfile
50         }
51
52         export(SOURCES)
53     } else {
54         QMAKE_EXTRA_COMPILERS += $$1
55         generated_files.depends += compiler_$${1}_make_all
56         export(QMAKE_EXTRA_COMPILERS)
57         export(generated_files.depends)
58     }
59     return(true)
60 }
61
62 defineTest(addExtraCompilerWithHeader) {
63     addExtraCompiler($$1)
64
65     eval(headerFile = $${2})
66     isEmpty(headerFile) {
67         eval($${1}_header.output = $$eval($${1}.output))
68         eval($${1}_header.output ~= s/\.cpp/.h/)
69         eval($${1}_header.output ~= s/\.c/.h/)
70     } else {
71         eval($${1}_header.output = $$headerFile)
72     }
73
74     eval($${1}_header.input = $$eval($${1}.input))
75     eval($${1}_header.commands = @echo -n '')
76     eval($${1}_header.depends = compiler_$${1}_make_all)
77     eval($${1}_header.variable_out = GENERATED_FILES)
78
79     export($${1}_header.output)
80     export($${1}_header.input)
81     export($${1}_header.commands)
82     export($${1}_header.depends)
83     export($${1}_header.variable_out)
84
85     !CONFIG(QTDIR_build): QMAKE_EXTRA_COMPILERS += $${1}_header
86
87     export(QMAKE_EXTRA_COMPILERS)
88     export(generated_files.depends)
89     export(SOURCES)
90
91     return(true)
92 }
93