WebCore/features.pri

   1 # Setting up features (enabled/disabled)
   2
   3 CONFIG(minimal) {
   4     DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0
   5 }
   6
   7 ## load mobilityconfig if mobility is available
   8 load(mobilityconfig, true)
   9
  10 contains(DEFINES, ENABLE_SINGLE_THREADED=1) {
  11     DEFINES+=ENABLE_DATABASE=0 ENABLE_DOM_STORAGE=0 ENABLE_ICONDATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0
  12 }
  13
  14 # turn off SQLITE support if we do not have sqlite3 available
  15 !CONFIG(QTDIR_build):win32-*:!exists( $${SQLITE3SRCDIR}/sqlite3.c ): DEFINES += ENABLE_SQLITE=0 ENABLE_DATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0 ENABLE_ICONDATABASE=0 ENABLE_OFFLINE_WEB_APPLICATIONS=0 ENABLE_DOM_STORAGE=0
  16
  17 !contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=.): DEFINES += ENABLE_JAVASCRIPT_DEBUGGER=1
  18 !contains(DEFINES, ENABLE_DATABASE=.): DEFINES += ENABLE_DATABASE=1
  19 !contains(DEFINES, ENABLE_EVENTSOURCE=.): DEFINES += ENABLE_EVENTSOURCE=1
  20 !contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=.): DEFINES += ENABLE_OFFLINE_WEB_APPLICATIONS=1
  21 !contains(DEFINES, ENABLE_DOM_STORAGE=.): DEFINES += ENABLE_DOM_STORAGE=1
  22 !contains(DEFINES, ENABLE_ICONDATABASE=.): DEFINES += ENABLE_ICONDATABASE=1
  23 !contains(DEFINES, ENABLE_CHANNEL_MESSAGING=.): DEFINES += ENABLE_CHANNEL_MESSAGING=1
  24 !contains(DEFINES, ENABLE_ORIENTATION_EVENTS=.): DEFINES += ENABLE_ORIENTATION_EVENTS=0
  25 !contains(DEFINES, ENABLE_DIRECTORY_UPLOAD=.): DEFINES += ENABLE_DIRECTORY_UPLOAD=0
  26 !contains(DEFINES, ENABLE_FILE_SYSTEM=.): DEFINES += ENABLE_FILE_SYSTEM=0
  27
  28 # turn on SQLITE support if any of the dependent features are turned on
  29 !contains(DEFINES, ENABLE_SQLITE=.) {
  30   contains(DEFINES, ENABLE_DATABASE=1)|contains(DEFINES, ENABLE_ICONDATABASE=1)|contains(DEFINES, ENABLE_DOM_STORAGE=1)|contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1) {
  31     DEFINES += ENABLE_SQLITE=1
  32   } else {
  33     DEFINES += ENABLE_SQLITE=0
  34   }
  35 }
  36
  37 !contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=.): DEFINES += ENABLE_DASHBOARD_SUPPORT=0
  38 !contains(DEFINES, ENABLE_FILTERS=.): DEFINES += ENABLE_FILTERS=1
  39 !contains(DEFINES, ENABLE_XPATH=.): DEFINES += ENABLE_XPATH=1
  40 #!contains(DEFINES, ENABLE_XBL=.): DEFINES += ENABLE_XBL=1
  41 !contains(DEFINES, ENABLE_WCSS=.): DEFINES += ENABLE_WCSS=0
  42 !contains(DEFINES, ENABLE_WML=.): DEFINES += ENABLE_WML=0
  43 !contains(DEFINES, ENABLE_SHARED_WORKERS=.): DEFINES += ENABLE_SHARED_WORKERS=1
  44 !contains(DEFINES, ENABLE_WORKERS=.): DEFINES += ENABLE_WORKERS=1
  45 !contains(DEFINES, ENABLE_XHTMLMP=.): DEFINES += ENABLE_XHTMLMP=0
  46 !contains(DEFINES, ENABLE_DATAGRID=.): DEFINES += ENABLE_DATAGRID=0
  47 !contains(DEFINES, ENABLE_RUBY=.): DEFINES += ENABLE_RUBY=1
  48 !contains(DEFINES, ENABLE_SANDBOX=.): DEFINES += ENABLE_SANDBOX=1
  49 !contains(DEFINES, ENABLE_METER_TAG=.): DEFINES += ENABLE_METER_TAG=1
  50 !contains(DEFINES, ENABLE_PROGRESS_TAG=.): DEFINES += ENABLE_PROGRESS_TAG=1
  51 !contains(DEFINES, ENABLE_BLOB_SLICE=.): DEFINES += ENABLE_BLOB_SLICE=0
  52 !contains(DEFINES, ENABLE_NOTIFICATIONS=.): DEFINES += ENABLE_NOTIFICATIONS=1
  53 !contains(DEFINES, ENABLE_IMAGE_RESIZER=.): DEFINES += ENABLE_IMAGE_RESIZER=0
  54 !contains(DEFINES, ENABLE_INPUT_SPEECH=.): DEFINES += ENABLE_INPUT_SPEECH=0
  55
  56 greaterThan(QT_MINOR_VERSION, 5) {
  57     !contains(DEFINES, ENABLE_3D_RENDERING=.): DEFINES += ENABLE_3D_RENDERING=1
  58 }
  59
  60 # SVG support
  61 !contains(DEFINES, ENABLE_SVG=0) {
  62     !contains(DEFINES, ENABLE_SVG=.): DEFINES += ENABLE_SVG=1
  63     !contains(DEFINES, ENABLE_SVG_FONTS=.): DEFINES += ENABLE_SVG_FONTS=1
  64     !contains(DEFINES, ENABLE_SVG_FOREIGN_OBJECT=.): DEFINES += ENABLE_SVG_FOREIGN_OBJECT=1
  65     !contains(DEFINES, ENABLE_SVG_ANIMATION=.): DEFINES += ENABLE_SVG_ANIMATION=1
  66     !contains(DEFINES, ENABLE_SVG_AS_IMAGE=.): DEFINES += ENABLE_SVG_AS_IMAGE=1
  67     !contains(DEFINES, ENABLE_SVG_USE=.): DEFINES += ENABLE_SVG_USE=1
  68 } else {
  69     DEFINES += ENABLE_SVG_FONTS=0 ENABLE_SVG_FOREIGN_OBJECT=0 ENABLE_SVG_ANIMATION=0 ENABLE_SVG_AS_IMAGE=0 ENABLE_SVG_USE=0
  70 }
  71
  72 # HTML5 datalist support
  73 !contains(DEFINES, ENABLE_DATALIST=.): DEFINES += ENABLE_DATALIST=1
  74
  75 # Tiled Backing Store support
  76 greaterThan(QT_MINOR_VERSION, 5) {
  77     !contains(DEFINES, ENABLE_TILED_BACKING_STORE=.): DEFINES += ENABLE_TILED_BACKING_STORE=1
  78 }
  79
  80 # Nescape plugins support (NPAPI)
  81 !contains(DEFINES, ENABLE_NETSCAPE_PLUGIN_API=.) {
  82     unix|win32-*:!embedded:!wince*: {
  83         DEFINES += ENABLE_NETSCAPE_PLUGIN_API=1
  84     } else {
  85         DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0
  86     }
  87 }
  88
  89 # Web Socket support.
  90 !contains(DEFINES, ENABLE_WEB_SOCKETS=.): DEFINES += ENABLE_WEB_SOCKETS=1
  91
  92 # Web Timing support.
  93 !contains(DEFINES, ENABLE_WEB_TIMING=.): DEFINES += ENABLE_WEB_TIMING=0
  94
  95 # XSLT support with QtXmlPatterns
  96 !contains(DEFINES, ENABLE_XSLT=.) {
  97     contains(QT_CONFIG, xmlpatterns):DEFINES += ENABLE_XSLT=1
  98     else:DEFINES += ENABLE_XSLT=0
  99 }
 100
 101 # geolocation support if QtMobility exists
 102 !CONFIG(QTDIR_build):!contains(DEFINES, ENABLE_GEOLOCATION=.) {
 103     contains(MOBILITY_CONFIG, location) {
 104        DEFINES += ENABLE_GEOLOCATION=1
 105     }
 106 }
 107
 108 # Bearer management is part of Qt 4.7
 109 # for older version, check for mobility with bearer
 110 !contains(DEFINES, ENABLE_QT_BEARER=.) {
 111      !lessThan(QT_MINOR_VERSION, 7) {
 112         DEFINES += ENABLE_QT_BEARER=1
 113      } else {
 114         contains(MOBILITY_CONFIG, bearer) {
 115             DEFINES += ENABLE_QT_BEARER=1
 116         }
 117     }
 118 }
 119
 120 # Enable touch event support with Qt 4.6
 121 !lessThan(QT_MINOR_VERSION, 6): DEFINES += ENABLE_TOUCH_EVENTS=1
 122
 123 # HTML5 Media Support
 124 # We require QtMultimedia or Phonon
 125 !contains(DEFINES, ENABLE_VIDEO=.) {
 126     DEFINES -= ENABLE_VIDEO=1
 127     DEFINES += ENABLE_VIDEO=0
 128
 129     !lessThan(QT_MINOR_VERSION, 6):contains(MOBILITY_CONFIG, multimedia) {
 130         DEFINES -= ENABLE_VIDEO=0
 131         DEFINES += ENABLE_VIDEO=1
 132     } else:contains(QT_CONFIG, phonon) {
 133         DEFINES -= ENABLE_VIDEO=0
 134         DEFINES += ENABLE_VIDEO=1
 135     }
 136 }
 137
 138 # Used to compute defaults for the build-webkit script
 139 CONFIG(compute_defaults) {
 140     message($$DEFINES)
 141     error("Done computing defaults")
 142 }
 143
 144 contains(DEFINES, ENABLE_WCSS=1) {
 145     contains(DEFINES, ENABLE_XHTMLMP=0) {
 146         DEFINES -= ENABLE_XHTMLMP=0
 147         DEFINES += ENABLE_XHTMLMP=1
 148     }
 149 }
 150
 151 ## Forward enabled feature macros to JavaScript enabled features macros
 152 FEATURE_DEFINES_JAVASCRIPT = LANGUAGE_JAVASCRIPT=1
 153 contains(DEFINES, ENABLE_CHANNEL_MESSAGING=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_CHANNEL_MESSAGING=1
 154 contains(DEFINES, ENABLE_ORIENTATION_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_ORIENTATION_EVENTS=1
 155 contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=0): DASHBOARDSUPPORTCSSPROPERTIES -= $$PWD/css/DashboardSupportCSSPropertyNames.in
 156 contains(DEFINES, ENABLE_DATAGRID=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATAGRID=1
 157 contains(DEFINES, ENABLE_EVENTSOURCE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_EVENTSOURCE=1
 158 contains(DEFINES, ENABLE_DATABASE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATABASE=1
 159 contains(DEFINES, ENABLE_DATALIST=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATALIST=1
 160 contains(DEFINES, ENABLE_DOM_STORAGE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DOM_STORAGE=1
 161 contains(DEFINES, ENABLE_SHARED_SCRIPT=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SHARED_SCRIPT=1
 162 contains(DEFINES, ENABLE_WORKERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WORKERS=1
 163 contains(DEFINES, ENABLE_SHARED_WORKERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SHARED_WORKERS=1
 164 contains(DEFINES, ENABLE_VIDEO=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_VIDEO=1
 165 contains(DEFINES, ENABLE_XPATH=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XPATH=1
 166 contains(DEFINES, ENABLE_XSLT=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XSLT=1
 167 contains(DEFINES, ENABLE_XBL=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XBL=1
 168 contains(DEFINES, ENABLE_FILTERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_FILTERS=1
 169 contains(DEFINES, ENABLE_WCSS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WCSS=1
 170 contains(DEFINES, ENABLE_WML=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WML=1
 171 contains(DEFINES, ENABLE_XHTMLMP=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XHTMLMP=1
 172 contains(DEFINES, ENABLE_SVG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SVG=1
 173 contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_JAVASCRIPT_DEBUGGER=1
 174 contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_OFFLINE_WEB_APPLICATIONS=1
 175 contains(DEFINES, ENABLE_WEB_SOCKETS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WEB_SOCKETS=1
 176 contains(DEFINES, ENABLE_WEB_TIMING=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WEB_TIMING=1
 177 contains(DEFINES, ENABLE_TOUCH_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TOUCH_EVENTS=1
 178 contains(DEFINES, ENABLE_TILED_BACKING_STORE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TILED_BACKING_STORE=1
 179 contains(DEFINES, ENABLE_NOTIFICATIONS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_NOTIFICATIONS=1
 180 contains(DEFINES, ENABLE_METER_TAG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_METER_TAG=1
 181 contains(DEFINES, ENABLE_PROGRESS_TAG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_PROGRESS_TAG=1
 182 contains(DEFINES, ENABLE_GEOLOCATION=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_GEOLOCATION=1