WebCore/css/tokenizer.flex

   1 %option case-insensitive
   2 %option noyywrap
   3 %option 8bit
   4
   5 h               [0-9a-fA-F]
   6 nonascii        [\200-\377]
   7 unicode         \\{h}{1,6}[ \t\r\n\f]?
   8 escape          {unicode}|\\[ -~\200-\377]
   9 nmstart         [_a-zA-Z]|{nonascii}|{escape}
  10 nmchar          [_a-zA-Z0-9-]|{nonascii}|{escape}
  11 string1         \"([\t !#$%&(-~]|\\{nl}|\'|{nonascii}|{escape})*\"
  12 string2         \'([\t !#$%&(-~]|\\{nl}|\"|{nonascii}|{escape})*\'
  13
  14 ident           -?{nmstart}{nmchar}*
  15 name            {nmchar}+
  16 num             [0-9]+|[0-9]*"."[0-9]+
  17 intnum          [0-9]+
  18 string          {string1}|{string2}
  19 url             ([!#$%&*-~]|{nonascii}|{escape})*
  20 w               [ \t\r\n\f]*
  21 nl              \n|\r\n|\r|\f
  22 range           \?{1,6}|{h}(\?{0,5}|{h}(\?{0,4}|{h}(\?{0,3}|{h}(\?{0,2}|{h}(\??|{h})))))
  23
  24 %%
  25
  26 \/\*[^*]*\*+([^/*][^*]*\*+)*\/  /* ignore comments */
  27
  28 [ \t\r\n\f]+            {yyTok = WHITESPACE; return yyTok;}
  29
  30 "<!--"                  {yyTok = SGML_CD; return yyTok;}
  31 "-->"                   {yyTok = SGML_CD; return yyTok;}
  32 "~="                    {yyTok = INCLUDES; return yyTok;}
  33 "|="                    {yyTok = DASHMATCH; return yyTok;}
  34 "^="                    {yyTok = BEGINSWITH; return yyTok;}
  35 "$="                    {yyTok = ENDSWITH; return yyTok;}
  36 "*="                    {yyTok = CONTAINS; return yyTok;}
  37
  38 {string}                {yyTok = STRING; return yyTok;}
  39
  40 {ident}                 {yyTok = IDENT; return yyTok;}
  41
  42 "#"{name}               {yyTok = HASH; return yyTok;}
  43
  44 "@import"               {yyTok = IMPORT_SYM; return yyTok;}
  45 "@page"                 {yyTok = PAGE_SYM; return yyTok;}
  46 "@media"                {yyTok = MEDIA_SYM; return yyTok;}
  47 "@font-face"            {yyTok = FONT_FACE_SYM; return yyTok;}
  48 "@charset"              {yyTok = CHARSET_SYM; return yyTok;}
  49 "@namespace"            {yyTok = NAMESPACE_SYM; return yyTok; }
  50 "@-webkit-rule"    {yyTok = WEBKIT_RULE_SYM; return yyTok; }
  51 "@-webkit-decls"   {yyTok = WEBKIT_DECLS_SYM; return yyTok; }
  52 "@-webkit-value"   {yyTok = WEBKIT_VALUE_SYM; return yyTok; }
  53
  54 "!"{w}"important"         {yyTok = IMPORTANT_SYM; return yyTok;}
  55
  56 {num}em                 {yyTok = EMS; return yyTok;}
  57 {num}__qem              {yyTok = QEMS; return yyTok;} /* quirky ems */
  58 {num}ex                 {yyTok = EXS; return yyTok;}
  59 {num}px                 {yyTok = PXS; return yyTok;}
  60 {num}cm                 {yyTok = CMS; return yyTok;}
  61 {num}mm                 {yyTok = MMS; return yyTok;}
  62 {num}in                 {yyTok = INS; return yyTok;}
  63 {num}pt                 {yyTok = PTS; return yyTok;}
  64 {num}pc                 {yyTok = PCS; return yyTok;}
  65 {num}deg                {yyTok = DEGS; return yyTok;}
  66 {num}rad                {yyTok = RADS; return yyTok;}
  67 {num}grad               {yyTok = GRADS; return yyTok;}
  68 {num}ms                 {yyTok = MSECS; return yyTok;}
  69 {num}s                  {yyTok = SECS; return yyTok;}
  70 {num}Hz                 {yyTok = HERZ; return yyTok;}
  71 {num}kHz                {yyTok = KHERZ; return yyTok;}
  72 {num}{ident}            {yyTok = DIMEN; return yyTok;}
  73 {num}%+                 {yyTok = PERCENTAGE; return yyTok;}
  74 {intnum}                {yyTok = INTEGER; return yyTok;}
  75 {num}                   {yyTok = FLOAT; return yyTok;}
  76
  77 "url("{w}{string}{w}")" {yyTok = URI; return yyTok;}
  78 "url("{w}{url}{w}")"    {yyTok = URI; return yyTok;}
  79 {ident}"("              {yyTok = FUNCTION; return yyTok;}
  80
  81 U\+{range}              {yyTok = UNICODERANGE; return yyTok;}
  82 U\+{h}{1,6}-{h}{1,6}    {yyTok = UNICODERANGE; return yyTok;}
  83
  84 .                       {yyTok = *yytext; return yyTok;}
  85
  86 %%
  87