(1) Fix build bustage by properly marking the moved Obj-C
[WebKit-https.git] / WebCore / css / tokenizer.flex
1 %option case-insensitive
2 %option noyywrap
3 %option 8bit
4
5 h               [0-9a-fA-F]
6 nonascii        [\200-\377]
7 unicode         \\{h}{1,6}[ \t\r\n\f]?
8 escape          {unicode}|\\[ -~\200-\377]
9 nmstart         [_a-zA-Z]|{nonascii}|{escape}
10 nmchar          [_a-zA-Z0-9-]|{nonascii}|{escape}
11 string1         \"([\t !#$%&(-~]|\\{nl}|\'|{nonascii}|{escape})*\"
12 string2         \'([\t !#$%&(-~]|\\{nl}|\"|{nonascii}|{escape})*\'
13
14 ident           -?{nmstart}{nmchar}*
15 name            {nmchar}+
16 num             [0-9]+|[0-9]*"."[0-9]+
17 string          {string1}|{string2}
18 url             ([!#$%&*-~]|{nonascii}|{escape})*
19 w               [ \t\r\n\f]*
20 nl              \n|\r\n|\r|\f
21 range           \?{1,6}|{h}(\?{0,5}|{h}(\?{0,4}|{h}(\?{0,3}|{h}(\?{0,2}|{h}(\??|{h})))))
22
23 %%
24
25 \/\*[^*]*\*+([^/*][^*]*\*+)*\/  /* ignore comments */
26
27 [ \t\r\n\f]+            {yyTok = WHITESPACE; return yyTok;}
28
29 "<!--"                  {yyTok = SGML_CD; return yyTok;}
30 "-->"                   {yyTok = SGML_CD; return yyTok;}
31 "~="                    {yyTok = INCLUDES; return yyTok;}
32 "|="                    {yyTok = DASHMATCH; return yyTok;}
33 "^="                    {yyTok = BEGINSWITH; return yyTok;}
34 "$="                    {yyTok = ENDSWITH; return yyTok;}
35 "*="                    {yyTok = CONTAINS; return yyTok;}
36
37 {string}                {yyTok = STRING; return yyTok;}
38
39 {ident}                 {yyTok = IDENT; return yyTok;}
40
41 "#"{name}               {yyTok = HASH; return yyTok;}
42
43 "@import"               {yyTok = IMPORT_SYM; return yyTok;}
44 "@page"                 {yyTok = PAGE_SYM; return yyTok;}
45 "@media"                {yyTok = MEDIA_SYM; return yyTok;}
46 "@font-face"            {yyTok = FONT_FACE_SYM; return yyTok;}
47 "@charset"              {yyTok = CHARSET_SYM; return yyTok;}
48 "@namespace"            {yyTok = NAMESPACE_SYM; return yyTok; }
49 "@-khtml-rule"    {yyTok = KHTML_RULE_SYM; return yyTok; }
50 "@-khtml-decls"   {yyTok = KHTML_DECLS_SYM; return yyTok; }
51 "@-khtml-value"   {yyTok = KHTML_VALUE_SYM; return yyTok; }
52
53 "!"{w}"important"         {yyTok = IMPORTANT_SYM; return yyTok;}
54
55 {num}em                 {yyTok = EMS; return yyTok;}
56 {num}__qem              {yyTok = QEMS; return yyTok;} /* quirky ems */
57 {num}ex                 {yyTok = EXS; return yyTok;}
58 {num}px                 {yyTok = PXS; return yyTok;}
59 {num}cm                 {yyTok = CMS; return yyTok;}
60 {num}mm                 {yyTok = MMS; return yyTok;}
61 {num}in                 {yyTok = INS; return yyTok;}
62 {num}pt                 {yyTok = PTS; return yyTok;}
63 {num}pc                 {yyTok = PCS; return yyTok;}
64 {num}deg                {yyTok = DEGS; return yyTok;}
65 {num}rad                {yyTok = RADS; return yyTok;}
66 {num}grad               {yyTok = GRADS; return yyTok;}
67 {num}ms                 {yyTok = MSECS; return yyTok;}
68 {num}s                  {yyTok = SECS; return yyTok;}
69 {num}Hz                 {yyTok = HERZ; return yyTok;}
70 {num}kHz                {yyTok = KHERZ; return yyTok;}
71 {num}{ident}            {yyTok = DIMEN; return yyTok;}
72 {num}%+                 {yyTok = PERCENTAGE; return yyTok;}
73 {num}                   {yyTok = NUMBER; return yyTok;}
74
75 "url("{w}{string}{w}")" {yyTok = URI; return yyTok;}
76 "url("{w}{url}{w}")"    {yyTok = URI; return yyTok;}
77 {ident}"("              {yyTok = FUNCTION; return yyTok;}
78
79 U\+{range}              {yyTok = UNICODERANGE; return yyTok;}
80 U\+{h}{1,6}-{h}{1,6}    {yyTok = UNICODERANGE; return yyTok;}
81
82 .                       {yyTok = *yytext; return yyTok;}
83
84 %%
85