WebCore/css/tokenizer.flex

   1 %option case-insensitive
   2 %option noyywrap
   3 %option 8bit
   4 %option stack
   5 %s mediaquery
   6
   7 h               [0-9a-fA-F]
   8 nonascii        [\200-\377]
   9 unicode         \\{h}{1,6}[ \t\r\n\f]?
  10 escape          {unicode}|\\[ -~\200-\377]
  11 nmstart         [_a-zA-Z]|{nonascii}|{escape}
  12 nmchar          [_a-zA-Z0-9-]|{nonascii}|{escape}
  13 string1         \"([\t !#$%&(-~]|\\{nl}|\'|{nonascii}|{escape})*\"
  14 string2         \'([\t !#$%&(-~]|\\{nl}|\"|{nonascii}|{escape})*\'
  15
  16 ident           -?{nmstart}{nmchar}*
  17 name            {nmchar}+
  18 num             [0-9]+|[0-9]*"."[0-9]+
  19 string          {string1}|{string2}
  20 url             ([!#$%&*-~]|{nonascii}|{escape})*
  21 w               [ \t\r\n\f]*
  22 nl              \n|\r\n|\r|\f
  23 range           \?{1,6}|{h}(\?{0,5}|{h}(\?{0,4}|{h}(\?{0,3}|{h}(\?{0,2}|{h}(\??|{h})))))
  24
  25 %%
  26
  27 \/\*[^*]*\*+([^/*][^*]*\*+)*\/  /* ignore comments */
  28
  29 [ \t\r\n\f]+            {yyTok = WHITESPACE; return yyTok;}
  30
  31 "<!--"                  {yyTok = SGML_CD; return yyTok;}
  32 "-->"                   {yyTok = SGML_CD; return yyTok;}
  33 "~="                    {yyTok = INCLUDES; return yyTok;}
  34 "|="                    {yyTok = DASHMATCH; return yyTok;}
  35 "^="                    {yyTok = BEGINSWITH; return yyTok;}
  36 "$="                    {yyTok = ENDSWITH; return yyTok;}
  37 "*="                    {yyTok = CONTAINS; return yyTok;}
  38 <mediaquery>"not"       {yyTok = MEDIA_NOT; return yyTok;}
  39 <mediaquery>"only"      {yyTok = MEDIA_ONLY; return yyTok;}
  40 <mediaquery>"and"       {yyTok = MEDIA_AND; return yyTok;}
  41
  42 {string}                {yyTok = STRING; return yyTok;}
  43
  44 {ident}                 {yyTok = IDENT; return yyTok;}
  45
  46 "#"{name}               {yyTok = HASH; return yyTok;}
  47
  48 "@import"               {BEGIN(mediaquery); yyTok = IMPORT_SYM; return yyTok;}
  49 "@page"                 {yyTok = PAGE_SYM; return yyTok;}
  50 "@media"                {BEGIN(mediaquery); yyTok = MEDIA_SYM; return yyTok;}
  51 "@font-face"            {yyTok = FONT_FACE_SYM; return yyTok;}
  52 "@charset"              {yyTok = CHARSET_SYM; return yyTok;}
  53 "@namespace"            {yyTok = NAMESPACE_SYM; return yyTok; }
  54 "@-khtml-rule"    {yyTok = KHTML_RULE_SYM; return yyTok; }
  55 "@-khtml-decls"   {yyTok = KHTML_DECLS_SYM; return yyTok; }
  56 "@-khtml-value"   {yyTok = KHTML_VALUE_SYM; return yyTok; }
  57 "@-khtml-mediaquery"   {BEGIN(mediaquery); yyTok = KHTML_MEDIAQUERY_SYM; return yyTok; }
  58
  59 "!"{w}"important"         {yyTok = IMPORTANT_SYM; return yyTok;}
  60
  61 {num}em                 {yyTok = EMS; return yyTok;}
  62 {num}__qem              {yyTok = QEMS; return yyTok;} /* quirky ems */
  63 {num}ex                 {yyTok = EXS; return yyTok;}
  64 {num}px                 {yyTok = PXS; return yyTok;}
  65 {num}cm                 {yyTok = CMS; return yyTok;}
  66 {num}mm                 {yyTok = MMS; return yyTok;}
  67 {num}in                 {yyTok = INS; return yyTok;}
  68 {num}pt                 {yyTok = PTS; return yyTok;}
  69 {num}pc                 {yyTok = PCS; return yyTok;}
  70 {num}deg                {yyTok = DEGS; return yyTok;}
  71 {num}rad                {yyTok = RADS; return yyTok;}
  72 {num}grad               {yyTok = GRADS; return yyTok;}
  73 {num}ms                 {yyTok = MSECS; return yyTok;}
  74 {num}s                  {yyTok = SECS; return yyTok;}
  75 {num}Hz                 {yyTok = HERZ; return yyTok;}
  76 {num}kHz                {yyTok = KHERZ; return yyTok;}
  77 {num}{ident}            {yyTok = DIMEN; return yyTok;}
  78 {num}%+                 {yyTok = PERCENTAGE; return yyTok;}
  79 {num}                   {yyTok = NUMBER; return yyTok;}
  80
  81 "url("{w}{string}{w}")" {yyTok = URI; return yyTok;}
  82 "url("{w}{url}{w}")"    {yyTok = URI; return yyTok;}
  83 {ident}"("              {yyTok = FUNCTION; return yyTok;}
  84
  85 U\+{range}              {yyTok = UNICODERANGE; return yyTok;}
  86 U\+{h}{1,6}-{h}{1,6}    {yyTok = UNICODERANGE; return yyTok;}
  87
  88 <mediaquery>"{"         |
  89 <mediaquery>";"         {BEGIN(INITIAL); yyTok = *yytext; return yyTok; }
  90 .                       {yyTok = *yytext; return yyTok;}
  91
  92 %%
  93