WebCore/css/tokenizer.flex

   1 %option case-insensitive
   2 %option noyywrap
   3 %option 8bit
   4 %option stack
   5 %s mediaquery
   6
   7 h               [0-9a-fA-F]
   8 nonascii        [\200-\377]
   9 unicode         \\{h}{1,6}[ \t\r\n\f]?
  10 escape          {unicode}|\\[ -~\200-\377]
  11 nmstart         [_a-zA-Z]|{nonascii}|{escape}
  12 nmchar          [_a-zA-Z0-9-]|{nonascii}|{escape}
  13 string1         \"([\t !#$%&(-~]|\\{nl}|\'|{nonascii}|{escape})*\"
  14 string2         \'([\t !#$%&(-~]|\\{nl}|\"|{nonascii}|{escape})*\'
  15
  16 ident           -?{nmstart}{nmchar}*
  17 name            {nmchar}+
  18 num             [0-9]+|[0-9]*"."[0-9]+
  19 intnum          [0-9]+
  20 string          {string1}|{string2}
  21 url             ([!#$%&*-~]|{nonascii}|{escape})*
  22 w               [ \t\r\n\f]*
  23 nl              \n|\r\n|\r|\f
  24 range           \?{1,6}|{h}(\?{0,5}|{h}(\?{0,4}|{h}(\?{0,3}|{h}(\?{0,2}|{h}(\??|{h})))))
  25
  26 %%
  27
  28 \/\*[^*]*\*+([^/*][^*]*\*+)*\/  /* ignore comments */
  29
  30 [ \t\r\n\f]+            {yyTok = WHITESPACE; return yyTok;}
  31
  32 "<!--"                  {yyTok = SGML_CD; return yyTok;}
  33 "-->"                   {yyTok = SGML_CD; return yyTok;}
  34 "~="                    {yyTok = INCLUDES; return yyTok;}
  35 "|="                    {yyTok = DASHMATCH; return yyTok;}
  36 "^="                    {yyTok = BEGINSWITH; return yyTok;}
  37 "$="                    {yyTok = ENDSWITH; return yyTok;}
  38 "*="                    {yyTok = CONTAINS; return yyTok;}
  39 <mediaquery>"not"       {yyTok = MEDIA_NOT; return yyTok;}
  40 <mediaquery>"only"      {yyTok = MEDIA_ONLY; return yyTok;}
  41 <mediaquery>"and"       {yyTok = MEDIA_AND; return yyTok;}
  42
  43 {string}                {yyTok = STRING; return yyTok;}
  44
  45 {ident}                 {yyTok = IDENT; return yyTok;}
  46
  47 "#"{name}               {yyTok = HASH; return yyTok;}
  48
  49 "@import"               {BEGIN(mediaquery); yyTok = IMPORT_SYM; return yyTok;}
  50 "@page"                 {yyTok = PAGE_SYM; return yyTok;}
  51 "@media"                {BEGIN(mediaquery); yyTok = MEDIA_SYM; return yyTok;}
  52 "@font-face"            {yyTok = FONT_FACE_SYM; return yyTok;}
  53 "@charset"              {yyTok = CHARSET_SYM; return yyTok;}
  54 "@namespace"            {yyTok = NAMESPACE_SYM; return yyTok; }
  55 "@-webkit-rule"    {yyTok = WEBKIT_RULE_SYM; return yyTok; }
  56 "@-webkit-decls"   {yyTok = WEBKIT_DECLS_SYM; return yyTok; }
  57 "@-webkit-value"   {yyTok = WEBKIT_VALUE_SYM; return yyTok; }
  58 "@-webkit-mediaquery"   {BEGIN(mediaquery); yyTok = WEBKIT_MEDIAQUERY_SYM; return yyTok; }
  59
  60 "!"{w}"important"         {yyTok = IMPORTANT_SYM; return yyTok;}
  61
  62 {num}em                 {yyTok = EMS; return yyTok;}
  63 {num}__qem              {yyTok = QEMS; return yyTok;} /* quirky ems */
  64 {num}ex                 {yyTok = EXS; return yyTok;}
  65 {num}px                 {yyTok = PXS; return yyTok;}
  66 {num}cm                 {yyTok = CMS; return yyTok;}
  67 {num}mm                 {yyTok = MMS; return yyTok;}
  68 {num}in                 {yyTok = INS; return yyTok;}
  69 {num}pt                 {yyTok = PTS; return yyTok;}
  70 {num}pc                 {yyTok = PCS; return yyTok;}
  71 {num}deg                {yyTok = DEGS; return yyTok;}
  72 {num}rad                {yyTok = RADS; return yyTok;}
  73 {num}grad               {yyTok = GRADS; return yyTok;}
  74 {num}ms                 {yyTok = MSECS; return yyTok;}
  75 {num}s                  {yyTok = SECS; return yyTok;}
  76 {num}Hz                 {yyTok = HERZ; return yyTok;}
  77 {num}kHz                {yyTok = KHERZ; return yyTok;}
  78 {num}{ident}            {yyTok = DIMEN; return yyTok;}
  79 {num}%+                 {yyTok = PERCENTAGE; return yyTok;}
  80 {intnum}                {yyTok = INTEGER; return yyTok;}
  81 {num}                   {yyTok = FLOAT; return yyTok;}
  82
  83 "url("{w}{string}{w}")" {yyTok = URI; return yyTok;}
  84 "url("{w}{url}{w}")"    {yyTok = URI; return yyTok;}
  85 {ident}"("              {yyTok = FUNCTION; return yyTok;}
  86
  87 U\+{range}              {yyTok = UNICODERANGE; return yyTok;}
  88 U\+{h}{1,6}-{h}{1,6}    {yyTok = UNICODERANGE; return yyTok;}
  89
  90 <mediaquery>"{"         |
  91 <mediaquery>";"         {BEGIN(INITIAL); yyTok = *yytext; return yyTok; }
  92 .                       {yyTok = *yytext; return yyTok;}
  93
  94 %%
  95