[Qt] Fix -Werror for the buildbots
[WebKit-https.git] / Tools / qmake / mkspecs / features / unix / default_post.prf
1 # -------------------------------------------------------------------
2 # Unix specific defaults
3 #
4 # See 'Tools/qmake/README' for an overview of the build system
5 # -------------------------------------------------------------------
6
7 # Use SSE2 floating point math on 32 bit instead of the default
8 # 387 to make layout test results same on 32 and on 64 bit builds.
9 # See https://bugs.webkit.org/show_bug.cgi?id=52810#c39 for details.
10 linux-g++*:isEqual(QT_ARCH,i386) {
11     QMAKE_CFLAGS += -march=pentium4 -msse2 -mfpmath=sse
12     QMAKE_CXXFLAGS += -march=pentium4 -msse2 -mfpmath=sse
13 }
14
15 # Treat warnings as errors on x86/Linux/GCC
16 linux-g++* {
17     isEqual(QT_ARCH,x86_64)|isEqual(QT_ARCH,i386): QMAKE_CXXFLAGS += -Werror
18     greaterThan(QT_GCC_MAJOR_VERSION, 3):greaterThan(QT_GCC_MINOR_VERSION, 5) {
19         !contains(QMAKE_CXXFLAGS, -std=(c|gnu)\\+\\+(0x|11)) {
20             # We need to deactivate those warnings because some names conflicts with upcoming c++0x types (e.g.nullptr).
21             QMAKE_CXXFLAGS_WARN_ON += -Wno-c++0x-compat
22             QMAKE_CXXFLAGS += -Wno-c++0x-compat
23         }
24     }
25 }
26
27 # Don't warn about OVERRIDE and FINAL, since they are feature-checked anyways
28 *clang:!contains(QMAKE_CXXFLAGS, -std=c++11) {
29     QMAKE_CXXFLAGS += -Wno-c++11-extensions
30     QMAKE_OBJECTIVE_CFLAGS += -Wno-c++11-extensions
31 }
32
33 contains(TEMPLATE, app): CONFIG += rpath
34
35 isEqual(QT_ARCH,i386):CONFIG(debug, debug|release) {
36   # Make ld don't cache the symbol tables of input files in memory to avoid memory exhaustion during the linking phase.
37   # We have to use ld, because --no-keep-memory isn't supported by ld.gold.
38   QMAKE_LFLAGS += -Wl,--no-keep-memory
39 } else {
40   # Use gold if available
41   !scratchbox:!mac:exists(/usr/bin/ld.gold) {
42       # Upstream gcc 4.7 does not support the -fuse-ld=gold option ( see: http://sourceware.org/ml/binutils/2011-01/msg00178.html )
43       isEqual(QT_GCC_MAJOR_VERSION, 4):lessThan(QT_GCC_MINOR_VERSION, 7):QMAKE_LFLAGS += -fuse-ld=gold
44   }
45 }
46
47 load(default_post)