2010-12-30 Konstantin Tokarev <annulen@yandex.ru>
[WebKit-https.git] / Tools / WebKitTestRunner / qt / WebKitTestRunner.pro
1 TARGET = WebKitTestRunner
2 CONFIG -= app_bundle
3
4 BASEDIR = $$PWD/../
5 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../..
6 GENERATED_SOURCES_DIR = ../generated
7
8
9 include(../../../WebKit.pri)
10
11 !CONFIG(release, debug|release) {
12     OBJECTS_DIR = obj/debug
13 } else { # Release
14     OBJECTS_DIR = obj/release
15 }
16
17 DEFINES += USE_SYSTEM_MALLOC=1
18
19 INCLUDEPATH += \
20     $$BASEDIR \
21     $$BASEDIR/../../JavaScriptCore \
22     $$BASEDIR/../../WebKit2 \
23     $$BASEDIR/../../WebKit2/Shared \
24     $$BASEDIR/../../WebKit2/UIProcess/API/qt \
25     $$BASEDIR/../../WebKit2/UIProcess/API/cpp/qt \
26     $$GENERATED_SOURCES_DIR
27
28 INCLUDEPATH += \
29     $$OUTPUT_DIR/include \
30
31
32 DESTDIR = $$OUTPUT_DIR/bin
33
34 unix:!mac:!symbian {
35     CONFIG += link_pkgconfig
36     PKGCONFIG += fontconfig
37 }
38
39 QT = core gui network
40
41 HEADERS = \
42     $$BASEDIR/PlatformWebView.h \
43     $$BASEDIR/StringFunctions.h \
44     $$BASEDIR/TestController.h \
45     $$BASEDIR/TestInvocation.h
46
47 SOURCES = \
48     main.cpp \
49     PlatformWebViewQt.cpp \
50     TestControllerQt.cpp \
51     $$BASEDIR/TestController.cpp \
52     $$BASEDIR/TestInvocation.cpp \
53
54 PREFIX_HEADER = $$BASEDIR/WebKitTestRunnerPrefix.h
55 QMAKE_CXXFLAGS += "-include $$PREFIX_HEADER"
56
57 linux-* {
58     # From Creator's src/rpath.pri:
59     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
60     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
61     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
62     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
63
64     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\'
65     QMAKE_RPATHDIR =
66 } else {
67     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
68 }
69
70 include(../../../JavaScriptCore/JavaScriptCore.pri)
71 addJavaScriptCoreLib(../../../JavaScriptCore)