Tools/Tools.pro

   1 # -------------------------------------------------------------------
   2 # Root project file for tools
   3 #
   4 # See 'Tools/qmake/README' for an overview of the build system
   5 # -------------------------------------------------------------------
   6
   7 TEMPLATE = subdirs
   8 CONFIG += ordered
   9
  10 load(features)
  11
  12 !no_webkit1 {
  13     SUBDIRS += QtTestBrowser/QtTestBrowser.pro
  14     SUBDIRS += DumpRenderTree/qt/DumpRenderTree.pro
  15     SUBDIRS += DumpRenderTree/qt/ImageDiff.pro
  16 }
  17
  18 !no_webkit2 {
  19     SUBDIRS += MiniBrowser/qt/MiniBrowser.pro
  20     # WTR's InjectedBundle depends currently on WK1's DumpRenderTreeSupport
  21     !no_webkit1: SUBDIRS += WebKitTestRunner/WebKitTestRunner.pro
  22 }
  23
  24 # FIXME: with Qt 5 the test plugin cause some trouble during layout tests.
  25 # See: https://bugs.webkit.org/show_bug.cgi?id=86620
  26 # Reenable it after we have a fix for this issue.
  27 !haveQt(5) {
  28     !win32:contains(DEFINES, ENABLE_NETSCAPE_PLUGIN_API=1) {
  29         SUBDIRS += DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro
  30     }
  31 }
  32
  33 OTHER_FILES = \
  34     Scripts/* \
  35     $$files(Scripts/webkitpy/*.py, true) \
  36     $$files(Scripts/webkitperl/*.p[l|m], true) \
  37     qmake/README \
  38     qmake/configure.pro \
  39     qmake/sync.profile \
  40     qmake/qt_webkit.pri \
  41     qmake/config.tests/README \
  42     qmake/config.tests/fontconfig/* \
  43     qmake/config.tests/gccdepends/* \
  44     qmake/mkspecs/modules/* \
  45     qmake/mkspecs/features/*.prf \
  46     qmake/mkspecs/features/*.pri \
  47     qmake/mkspecs/features/mac/*.prf \
  48     qmake/mkspecs/features/unix/*.prf \
  49     qmake/mkspecs/features/win32/*.prf