Added new port JSCOnly.
[WebKit-https.git] / Tools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005-2007, 2010-2016 Apple Inc. All rights reserved.
2 # Copyright (C) 2009 Google Inc. All rights reserved.
3 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
4 # Copyright (C) 2013 Nokia Corporation and/or its subsidiary(-ies).
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30 # Module to share code to get to WebKit directories.
31
32 use strict;
33 use version;
34 use warnings;
35 use Config;
36 use Cwd qw(realpath);
37 use Digest::MD5 qw(md5_hex);
38 use FindBin;
39 use File::Basename;
40 use File::Find;
41 use File::Path qw(make_path mkpath rmtree);
42 use File::Spec;
43 use File::stat;
44 use List::Util;
45 use POSIX;
46 use Time::HiRes qw(usleep);
47 use VCSUtils;
48
49 BEGIN {
50    use Exporter   ();
51    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
52    $VERSION     = 1.00;
53    @ISA         = qw(Exporter);
54    @EXPORT      = qw(
55        &XcodeCoverageSupportOptions
56        &XcodeOptionString
57        &XcodeOptionStringNoConfig
58        &XcodeOptions
59        &XcodeStaticAnalyzerOption
60        &appDisplayNameFromBundle
61        &appendToEnvironmentVariableList
62        &baseProductDir
63        &chdirWebKit
64        &checkFrameworks
65        &cmakeBasedPortArguments
66        &currentSVNRevision
67        &debugSafari
68        &executableProductDir
69        &findOrCreateSimulatorForIOSDevice
70        &iosSimulatorDeviceByName
71        &nmPath
72        &passedConfiguration
73        &prependToEnvironmentVariableList
74        &printHelpAndExitForRunAndDebugWebKitAppIfNeeded
75        &productDir
76        &quitIOSSimulator
77        &relaunchIOSSimulator
78        &restartIOSSimulatorDevice
79        &runIOSWebKitApp
80        &runMacWebKitApp
81        &safariPath
82        &iosVersion
83        &setConfiguration
84        &setupMacWebKitEnvironment
85        &sharedCommandLineOptions
86        &sharedCommandLineOptionsUsage
87        &shutDownIOSSimulatorDevice
88        &willUseIOSDeviceSDK
89        &willUseIOSSimulatorSDK
90        SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT
91        USE_OPEN_COMMAND
92    );
93    %EXPORT_TAGS = ( );
94    @EXPORT_OK   = ();
95 }
96
97 # Ports
98 use constant {
99     AppleWin => "AppleWin",
100     GTK      => "GTK",
101     Efl      => "Efl",
102     iOS      => "iOS",
103     Mac      => "Mac",
104     JSCOnly  => "JSCOnly",
105     WinCairo => "WinCairo",
106     Unknown  => "Unknown"
107 };
108
109 use constant USE_OPEN_COMMAND => 1; # Used in runMacWebKitApp().
110 use constant INCLUDE_OPTIONS_FOR_DEBUGGING => 1;
111 use constant SIMULATOR_DEVICE_STATE_SHUTDOWN => "1";
112 use constant SIMULATOR_DEVICE_STATE_BOOTED => "3";
113 use constant SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT  => "For WebKit Development";
114
115 # See table "Certificate types and names" on <https://developer.apple.com/library/ios/documentation/IDEs/Conceptual/AppDistributionGuide/MaintainingCertificates/MaintainingCertificates.html#//apple_ref/doc/uid/TP40012582-CH31-SW41>.
116 use constant IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX => "iPhone Developer: ";
117
118 our @EXPORT_OK;
119
120 my $architecture;
121 my $asanIsEnabled;
122 my $numberOfCPUs;
123 my $maxCPULoad;
124 my $baseProductDir;
125 my @baseProductDirOption;
126 my $configuration;
127 my $xcodeSDK;
128 my $configurationForVisualStudio;
129 my $configurationProductDir;
130 my $sourceDir;
131 my $currentSVNRevision;
132 my $debugger;
133 my $didLoadIPhoneSimulatorNotification;
134 my $nmPath;
135 my $osXVersion;
136 my $iosVersion;
137 my $generateDsym;
138 my $isCMakeBuild;
139 my $isWin64;
140 my $isInspectorFrontend;
141 my $portName;
142 my $shouldUseGuardMalloc;
143 my $shouldNotUseNinja;
144 my $xcodeVersion;
145
146 my $unknownPortProhibited = 0;
147
148 # Variables for Win32 support
149 my $programFilesPath;
150 my $vcBuildPath;
151 my $vsInstallDir;
152 my $msBuildInstallDir;
153 my $vsVersion;
154 my $windowsSourceDir;
155 my $winVersion;
156 my $willUseVCExpressWhenBuilding = 0;
157
158 # Defined in VCSUtils.
159 sub exitStatus($);
160
161 sub findMatchingArguments($$);
162 sub hasArgument($$);
163
164 sub determineSourceDir
165 {
166     return if $sourceDir;
167     $sourceDir = $FindBin::Bin;
168     $sourceDir =~ s|/+$||; # Remove trailing '/' as we would die later
169
170     # walks up path checking each directory to see if it is the main WebKit project dir, 
171     # defined by containing Sources, WebCore, and WebKit
172     until ((-d File::Spec->catdir($sourceDir, "Source") && -d File::Spec->catdir($sourceDir, "Source", "WebCore") && -d File::Spec->catdir($sourceDir, "Source", "WebKit")) || (-d File::Spec->catdir($sourceDir, "Internal") && -d File::Spec->catdir($sourceDir, "OpenSource")))
173     {
174         if ($sourceDir !~ s|/[^/]+$||) {
175             die "Could not find top level webkit directory above source directory using FindBin.\n";
176         }
177     }
178
179     $sourceDir = File::Spec->catdir($sourceDir, "OpenSource") if -d File::Spec->catdir($sourceDir, "OpenSource");
180 }
181
182 sub currentPerlPath()
183 {
184     my $thisPerl = $^X;
185     if ($^O ne 'VMS') {
186         $thisPerl .= $Config{_exe} unless $thisPerl =~ m/$Config{_exe}$/i;
187     }
188     return $thisPerl;
189 }
190
191 # used for scripts which are stored in a non-standard location
192 sub setSourceDir($)
193 {
194     ($sourceDir) = @_;
195 }
196
197 sub determineNinjaVersion
198 {
199     chomp(my $ninjaVersion = `ninja --version`);
200     return $ninjaVersion;
201 }
202
203 sub determineXcodeVersion
204 {
205     return if defined $xcodeVersion;
206     my $xcodebuildVersionOutput = `xcodebuild -version`;
207     $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : "3.0";
208 }
209
210 sub readXcodeUserDefault($)
211 {
212     my ($unprefixedKey) = @_;
213
214     determineXcodeVersion();
215
216     my $xcodeDefaultsDomain = (eval "v$xcodeVersion" lt v4) ? "com.apple.Xcode" : "com.apple.dt.Xcode";
217     my $xcodeDefaultsPrefix = (eval "v$xcodeVersion" lt v4) ? "PBX" : "IDE";
218     my $devnull = File::Spec->devnull();
219
220     my $value = `defaults read $xcodeDefaultsDomain ${xcodeDefaultsPrefix}${unprefixedKey} 2> ${devnull}`;
221     return if $?;
222
223     chomp $value;
224     return $value;
225 }
226
227 sub determineBaseProductDir
228 {
229     return if defined $baseProductDir;
230     determineSourceDir();
231
232     my $setSharedPrecompsDir;
233     $baseProductDir = $ENV{"WEBKIT_OUTPUTDIR"};
234
235     if (!defined($baseProductDir) and isAppleMacWebKit()) {
236         # Silently remove ~/Library/Preferences/xcodebuild.plist which can
237         # cause build failure. The presence of
238         # ~/Library/Preferences/xcodebuild.plist can prevent xcodebuild from
239         # respecting global settings such as a custom build products directory
240         # (<rdar://problem/5585899>).
241         my $personalPlistFile = $ENV{HOME} . "/Library/Preferences/xcodebuild.plist";
242         if (-e $personalPlistFile) {
243             unlink($personalPlistFile) || die "Could not delete $personalPlistFile: $!";
244         }
245
246         determineXcodeVersion();
247
248         if (eval "v$xcodeVersion" ge v4) {
249             my $buildLocationStyle = join '', readXcodeUserDefault("BuildLocationStyle");
250             if ($buildLocationStyle eq "Custom") {
251                 my $buildLocationType = join '', readXcodeUserDefault("CustomBuildLocationType");
252                 # FIXME: Read CustomBuildIntermediatesPath and set OBJROOT accordingly.
253                 $baseProductDir = readXcodeUserDefault("CustomBuildProductsPath") if $buildLocationType eq "Absolute";
254             }
255
256             # DeterminedByTargets corresponds to a setting of "Legacy" in Xcode.
257             # It is the only build location style for which SHARED_PRECOMPS_DIR is not
258             # overridden when building from within Xcode.
259             $setSharedPrecompsDir = 1 if $buildLocationStyle ne "DeterminedByTargets";
260         }
261
262         if (!defined($baseProductDir)) {
263             $baseProductDir = join '', readXcodeUserDefault("ApplicationwideBuildSettings");
264             $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
265         }
266
267         undef $baseProductDir unless $baseProductDir =~ /^\//;
268     }
269
270     if (!defined($baseProductDir)) { # Port-specific checks failed, use default
271         $baseProductDir = File::Spec->catdir($sourceDir, "WebKitBuild");
272     }
273
274     if (isGit() && isGitBranchBuild()) {
275         my $branch = gitBranch();
276         $baseProductDir = "$baseProductDir/$branch";
277     }
278
279     if (isAppleMacWebKit()) {
280         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
281         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
282         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
283         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
284         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
285         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir");
286         push(@baseProductDirOption, "SHARED_PRECOMPS_DIR=${baseProductDir}/PrecompiledHeaders") if $setSharedPrecompsDir;
287     }
288
289     if (isCygwin()) {
290         my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
291         chomp $dosBuildPath;
292         $ENV{"WEBKIT_OUTPUTDIR"} = $dosBuildPath;
293         my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
294         chomp $unixBuildPath;
295         $baseProductDir = $dosBuildPath;
296     }
297 }
298
299 sub setBaseProductDir($)
300 {
301     ($baseProductDir) = @_;
302 }
303
304 sub determineConfiguration
305 {
306     return if defined $configuration;
307     determineBaseProductDir();
308     if (open CONFIGURATION, "$baseProductDir/Configuration") {
309         $configuration = <CONFIGURATION>;
310         close CONFIGURATION;
311     }
312     if ($configuration) {
313         chomp $configuration;
314         # compatibility for people who have old Configuration files
315         $configuration = "Release" if $configuration eq "Deployment";
316         $configuration = "Debug" if $configuration eq "Development";
317     } else {
318         $configuration = "Release";
319     }
320 }
321
322 sub determineArchitecture
323 {
324     return if defined $architecture;
325     # make sure $architecture is defined in all cases
326     $architecture = "";
327
328     determineBaseProductDir();
329     determineXcodeSDK();
330
331     if (isAppleMacWebKit()) {
332         if (open ARCHITECTURE, "$baseProductDir/Architecture") {
333             $architecture = <ARCHITECTURE>;
334             close ARCHITECTURE;
335         }
336         if ($architecture) {
337             chomp $architecture;
338         } else {
339             if (not defined $xcodeSDK or $xcodeSDK =~ /^(\/$|macosx)/) {
340                 my $supports64Bit = `sysctl -n hw.optional.x86_64`;
341                 chomp $supports64Bit;
342                 $architecture = 'x86_64' if $supports64Bit;
343             } elsif ($xcodeSDK =~ /^iphonesimulator/) {
344                 $architecture = 'x86_64';
345             } elsif ($xcodeSDK =~ /^iphoneos/) {
346                 $architecture = 'arm64';
347             }
348         }
349     } elsif (isCMakeBuild()) {
350         my $host_processor = "";
351         if (open my $cmake_sysinfo, "cmake --system-information |") {
352             while (<$cmake_sysinfo>) {
353                 next unless index($_, 'CMAKE_SYSTEM_PROCESSOR') == 0;
354                 if (/^CMAKE_SYSTEM_PROCESSOR \"([^"]+)\"/) {
355                     $architecture = $1;
356                     $architecture = 'x86_64' if $architecture eq 'amd64';
357                     last;
358                 }
359             }
360             close $cmake_sysinfo;
361         }
362     }
363
364     if (!isAnyWindows()) {
365         if (!$architecture) {
366             # Fall back to output of `arch', if it is present.
367             $architecture = `arch`;
368             chomp $architecture;
369         }
370
371         if (!$architecture) {
372             # Fall back to output of `uname -m', if it is present.
373             $architecture = `uname -m`;
374             chomp $architecture;
375         }
376     }
377
378     $architecture = 'x86_64' if ($architecture =~ /amd64/ && isBSD());
379 }
380
381 sub determineASanIsEnabled
382 {
383     return if defined $asanIsEnabled;
384     determineBaseProductDir();
385
386     $asanIsEnabled = 0;
387     my $asanConfigurationValue;
388
389     if (open ASAN, "$baseProductDir/ASan") {
390         $asanConfigurationValue = <ASAN>;
391         close ASAN;
392         chomp $asanConfigurationValue;
393         $asanIsEnabled = 1 if $asanConfigurationValue eq "YES";
394     }
395 }
396
397 sub determineNumberOfCPUs
398 {
399     return if defined $numberOfCPUs;
400     if (defined($ENV{NUMBER_OF_PROCESSORS})) {
401         $numberOfCPUs = $ENV{NUMBER_OF_PROCESSORS};
402     } elsif (isLinux()) {
403         # First try the nproc utility, if it exists. If we get no
404         # results fall back to just interpretting /proc directly.
405         chomp($numberOfCPUs = `nproc --all 2> /dev/null`);
406         if ($numberOfCPUs eq "") {
407             $numberOfCPUs = (grep /processor/, `cat /proc/cpuinfo`);
408         }
409     } elsif (isAnyWindows()) {
410         # Assumes cygwin
411         $numberOfCPUs = `ls /proc/registry/HKEY_LOCAL_MACHINE/HARDWARE/DESCRIPTION/System/CentralProcessor | wc -w`;
412     } elsif (isDarwin() || isBSD()) {
413         chomp($numberOfCPUs = `sysctl -n hw.ncpu`);
414     }
415 }
416
417 sub determineMaxCPULoad
418 {
419     return if defined $maxCPULoad;
420     if (defined($ENV{MAX_CPU_LOAD})) {
421         $maxCPULoad = $ENV{MAX_CPU_LOAD};
422     }
423 }
424
425 sub jscPath($)
426 {
427     my ($productDir) = @_;
428     my $jscName = "jsc";
429     $jscName .= "_debug"  if configuration() eq "Debug_All";
430     $jscName .= ".exe" if (isAnyWindows());
431     return "$productDir/$jscName" if -e "$productDir/$jscName";
432     return "$productDir/JavaScriptCore.framework/Resources/$jscName";
433 }
434
435 sub argumentsForConfiguration()
436 {
437     determineConfiguration();
438     determineArchitecture();
439     determineXcodeSDK();
440
441     my @args = ();
442     # FIXME: Is it necessary to pass --debug, --release, --32-bit or --64-bit?
443     # These are determined automatically from stored configuration.
444     push(@args, '--debug') if ($configuration =~ "^Debug");
445     push(@args, '--release') if ($configuration =~ "^Release");
446     push(@args, '--device') if (defined $xcodeSDK && $xcodeSDK =~ /^iphoneos/);
447     push(@args, '--ios-simulator') if (defined $xcodeSDK && $xcodeSDK =~ /^iphonesimulator/);
448     push(@args, '--32-bit') if ($architecture ne "x86_64" and !isWin64());
449     push(@args, '--64-bit') if (isWin64());
450     push(@args, '--gtk') if isGtk();
451     push(@args, '--efl') if isEfl();
452     push(@args, '--jsc-only') if isJSCOnly();
453     push(@args, '--wincairo') if isWinCairo();
454     push(@args, '--inspector-frontend') if isInspectorFrontend();
455     return @args;
456 }
457
458 sub determineXcodeSDK
459 {
460     return if defined $xcodeSDK;
461     my $sdk;
462     if (checkForArgumentAndRemoveFromARGVGettingValue("--sdk", \$sdk)) {
463         $xcodeSDK = $sdk;
464     }
465     if (checkForArgumentAndRemoveFromARGV("--device")) {
466         my $hasInternalSDK = exitStatus(system("xcrun --sdk iphoneos.internal --show-sdk-version > /dev/null 2>&1")) == 0;
467         $xcodeSDK ||= $hasInternalSDK ? "iphoneos.internal" : "iphoneos";
468     }
469     if (checkForArgumentAndRemoveFromARGV("--ios-simulator")) {
470         $xcodeSDK ||= 'iphonesimulator';
471     }
472 }
473
474 sub xcodeSDK
475 {
476     determineXcodeSDK();
477     return $xcodeSDK;
478 }
479
480 sub setXcodeSDK($)
481 {
482     ($xcodeSDK) = @_;
483 }
484
485
486 sub xcodeSDKPlatformName()
487 {
488     determineXcodeSDK();
489     return "" if !defined $xcodeSDK;
490     return "iphoneos" if $xcodeSDK =~ /iphoneos/i;
491     return "iphonesimulator" if $xcodeSDK =~ /iphonesimulator/i;
492     return "macosx" if $xcodeSDK =~ /macosx/i;
493     die "Couldn't determine platform name from Xcode SDK";
494 }
495
496 sub XcodeSDKPath
497 {
498     determineXcodeSDK();
499
500     die "Can't find the SDK path because no Xcode SDK was specified" if not $xcodeSDK;
501
502     my $sdkPath = `xcrun --sdk $xcodeSDK --show-sdk-path` if $xcodeSDK;
503     die 'Failed to get SDK path from xcrun' if $?;
504     chomp $sdkPath;
505
506     return $sdkPath;
507 }
508
509 sub xcodeSDKVersion
510 {
511     determineXcodeSDK();
512
513     die "Can't find the SDK version because no Xcode SDK was specified" if !$xcodeSDK;
514
515     chomp(my $sdkVersion = `xcrun --sdk $xcodeSDK --show-sdk-version`);
516     die "Failed to get SDK version from xcrun" if exitStatus($?);
517
518     return $sdkVersion;
519 }
520
521 sub programFilesPath
522 {
523     return $programFilesPath if defined $programFilesPath;
524
525     $programFilesPath = $ENV{'PROGRAMFILES(X86)'} || $ENV{'PROGRAMFILES'} || "C:\\Program Files";
526
527     return $programFilesPath;
528 }
529
530 sub visualStudioInstallDir
531 {
532     return $vsInstallDir if defined $vsInstallDir;
533
534     if ($ENV{'VSINSTALLDIR'}) {
535         $vsInstallDir = $ENV{'VSINSTALLDIR'};
536         $vsInstallDir =~ s|[\\/]$||;
537     } else {
538         $vsInstallDir = File::Spec->catdir(programFilesPath(), "Microsoft Visual Studio 14.0");
539     }
540     chomp($vsInstallDir = `cygpath "$vsInstallDir"`) if isCygwin();
541
542     print "Using Visual Studio: $vsInstallDir\n";
543     return $vsInstallDir;
544 }
545
546 sub msBuildInstallDir
547 {
548     return $msBuildInstallDir if defined $msBuildInstallDir;
549
550     $msBuildInstallDir = File::Spec->catdir(programFilesPath(), "MSBuild", "14.0", "Bin");
551    
552     chomp($msBuildInstallDir = `cygpath "$msBuildInstallDir"`) if isCygwin();
553
554     print "Using MSBuild: $msBuildInstallDir\n";
555     return $msBuildInstallDir;
556 }
557
558 sub visualStudioVersion
559 {
560     return $vsVersion if defined $vsVersion;
561
562     my $installDir = visualStudioInstallDir();
563
564     $vsVersion = ($installDir =~ /Microsoft Visual Studio ([0-9]+\.[0-9]*)/) ? $1 : "14";
565
566     print "Using Visual Studio $vsVersion\n";
567     return $vsVersion;
568 }
569
570 sub determineConfigurationForVisualStudio
571 {
572     return if defined $configurationForVisualStudio;
573     determineConfiguration();
574     # FIXME: We should detect when Debug_All or Production has been chosen.
575     $configurationForVisualStudio = "/p:Configuration=" . $configuration;
576 }
577
578 sub usesPerConfigurationBuildDirectory
579 {
580     # [Gtk] We don't have Release/Debug configurations in straight
581     # autotool builds (non build-webkit). In this case and if
582     # WEBKIT_OUTPUTDIR exist, use that as our configuration dir. This will
583     # allows us to run run-webkit-tests without using build-webkit.
584     return ($ENV{"WEBKIT_OUTPUTDIR"} && isGtk()) || isAppleWinWebKit();
585 }
586
587 sub determineConfigurationProductDir
588 {
589     return if defined $configurationProductDir;
590     determineBaseProductDir();
591     determineConfiguration();
592     if (isAppleWinWebKit() || isWinCairo()) {
593         $configurationProductDir = File::Spec->catdir($baseProductDir, $configuration);
594     } else {
595         if (usesPerConfigurationBuildDirectory()) {
596             $configurationProductDir = "$baseProductDir";
597         } else {
598             $configurationProductDir = "$baseProductDir/$configuration";
599             $configurationProductDir .= "-" . xcodeSDKPlatformName() if isIOSWebKit();
600         }
601     }
602 }
603
604 sub setConfigurationProductDir($)
605 {
606     ($configurationProductDir) = @_;
607 }
608
609 sub determineCurrentSVNRevision
610 {
611     # We always update the current SVN revision here, and leave the caching
612     # to currentSVNRevision(), so that changes to the SVN revision while the
613     # script is running can be picked up by calling this function again.
614     determineSourceDir();
615     $currentSVNRevision = svnRevisionForDirectory($sourceDir);
616     return $currentSVNRevision;
617 }
618
619
620 sub chdirWebKit
621 {
622     determineSourceDir();
623     chdir $sourceDir or die;
624 }
625
626 sub baseProductDir
627 {
628     determineBaseProductDir();
629     return $baseProductDir;
630 }
631
632 sub sourceDir
633 {
634     determineSourceDir();
635     return $sourceDir;
636 }
637
638 sub productDir
639 {
640     determineConfigurationProductDir();
641     return $configurationProductDir;
642 }
643
644 sub executableProductDir
645 {
646     my $productDirectory = productDir();
647
648     my $binaryDirectory;
649     if (isEfl() || isGtk() || isJSCOnly()) {
650         $binaryDirectory = "bin";
651     } elsif (isAnyWindows()) {
652         $binaryDirectory = isWin64() ? "bin64" : "bin32";
653     } else {
654         return $productDirectory;
655     }
656
657     return File::Spec->catdir($productDirectory, $binaryDirectory);
658 }
659
660 sub jscProductDir
661 {
662     return executableProductDir();
663 }
664
665 sub configuration()
666 {
667     determineConfiguration();
668     return $configuration;
669 }
670
671 sub asanIsEnabled()
672 {
673     determineASanIsEnabled();
674     return $asanIsEnabled;
675 }
676
677 sub configurationForVisualStudio()
678 {
679     determineConfigurationForVisualStudio();
680     return $configurationForVisualStudio;
681 }
682
683 sub currentSVNRevision
684 {
685     determineCurrentSVNRevision() if not defined $currentSVNRevision;
686     return $currentSVNRevision;
687 }
688
689 sub generateDsym()
690 {
691     determineGenerateDsym();
692     return $generateDsym;
693 }
694
695 sub determineGenerateDsym()
696 {
697     return if defined($generateDsym);
698     $generateDsym = checkForArgumentAndRemoveFromARGV("--dsym");
699 }
700
701 sub hasIOSDevelopmentCertificate()
702 {
703     return !exitStatus(system("security find-identity -p codesigning | grep '" . IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX . "' > /dev/null 2>&1"));
704 }
705
706 sub argumentsForXcode()
707 {
708     my @args = ();
709     push @args, "DEBUG_INFORMATION_FORMAT=dwarf-with-dsym" if generateDsym();
710     return @args;
711 }
712
713 sub XcodeOptions
714 {
715     determineBaseProductDir();
716     determineConfiguration();
717     determineArchitecture();
718     determineASanIsEnabled();
719     determineXcodeSDK();
720
721     my @options;
722     push @options, "-UseSanitizedBuildSystemEnvironment=YES";
723     push @options, ("-configuration", $configuration);
724     push @options, ("-xcconfig", sourceDir() . "/Tools/asan/asan.xcconfig", "ASAN_IGNORE=" . sourceDir() . "/Tools/asan/webkit-asan-ignore.txt") if $asanIsEnabled;
725     push @options, @baseProductDirOption;
726     push @options, "ARCHS=$architecture" if $architecture;
727     push @options, "SDKROOT=$xcodeSDK" if $xcodeSDK;
728     if (willUseIOSDeviceSDK()) {
729         push @options, "ENABLE_BITCODE=NO";
730         if (hasIOSDevelopmentCertificate()) {
731             # FIXME: May match more than one installed development certificate.
732             push @options, "CODE_SIGN_IDENTITY=" . IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX;
733         } else {
734             push @options, "CODE_SIGN_IDENTITY="; # No identity
735             push @options, "CODE_SIGNING_REQUIRED=NO";
736         }
737     }
738     push @options, argumentsForXcode();
739     return @options;
740 }
741
742 sub XcodeOptionString
743 {
744     return join " ", XcodeOptions();
745 }
746
747 sub XcodeOptionStringNoConfig
748 {
749     return join " ", @baseProductDirOption;
750 }
751
752 sub XcodeCoverageSupportOptions()
753 {
754     my @coverageSupportOptions = ();
755     push @coverageSupportOptions, "GCC_GENERATE_TEST_COVERAGE_FILES=YES";
756     push @coverageSupportOptions, "GCC_INSTRUMENT_PROGRAM_FLOW_ARCS=YES";
757     return @coverageSupportOptions;
758 }
759
760 sub XcodeStaticAnalyzerOption()
761 {
762     return "RUN_CLANG_STATIC_ANALYZER=YES";
763 }
764
765 my $passedConfiguration;
766 my $searchedForPassedConfiguration;
767 sub determinePassedConfiguration
768 {
769     return if $searchedForPassedConfiguration;
770     $searchedForPassedConfiguration = 1;
771     $passedConfiguration = undef;
772
773     if (checkForArgumentAndRemoveFromARGV("--debug")) {
774         $passedConfiguration = "Debug";
775     } elsif(checkForArgumentAndRemoveFromARGV("--release")) {
776         $passedConfiguration = "Release";
777     } elsif (checkForArgumentAndRemoveFromARGV("--profile") || checkForArgumentAndRemoveFromARGV("--profiling")) {
778         $passedConfiguration = "Profiling";
779     }
780 }
781
782 sub passedConfiguration
783 {
784     determinePassedConfiguration();
785     return $passedConfiguration;
786 }
787
788 sub setConfiguration
789 {
790     setArchitecture();
791
792     if (my $config = shift @_) {
793         $configuration = $config;
794         return;
795     }
796
797     determinePassedConfiguration();
798     $configuration = $passedConfiguration if $passedConfiguration;
799 }
800
801
802 my $passedArchitecture;
803 my $searchedForPassedArchitecture;
804 sub determinePassedArchitecture
805 {
806     return if $searchedForPassedArchitecture;
807     $searchedForPassedArchitecture = 1;
808
809     $passedArchitecture = undef;
810     if (checkForArgumentAndRemoveFromARGV("--32-bit")) {
811         if (isAppleMacWebKit()) {
812             # PLATFORM_IOS: Don't run `arch` command inside Simulator environment
813             local %ENV = %ENV;
814             delete $ENV{DYLD_ROOT_PATH};
815             delete $ENV{DYLD_FRAMEWORK_PATH};
816
817             $passedArchitecture = `arch`;
818             chomp $passedArchitecture;
819         }
820     }
821 }
822
823 sub passedArchitecture
824 {
825     determinePassedArchitecture();
826     return $passedArchitecture;
827 }
828
829 sub architecture()
830 {
831     determineArchitecture();
832     return $architecture;
833 }
834
835 sub numberOfCPUs()
836 {
837     determineNumberOfCPUs();
838     return $numberOfCPUs;
839 }
840
841 sub maxCPULoad()
842 {
843     determineMaxCPULoad();
844     return $maxCPULoad;
845 }
846
847 sub setArchitecture
848 {
849     if (my $arch = shift @_) {
850         $architecture = $arch;
851         return;
852     }
853
854     determinePassedArchitecture();
855     $architecture = $passedArchitecture if $passedArchitecture;
856 }
857
858 sub skipSafariExecutableEntitlementChecks
859 {
860     return `defaults read /Library/Preferences/org.webkit.BuildConfiguration SkipSafariExecutableEntitlementChecks 2>/dev/null` eq "1\n";
861 }
862
863 sub executableHasEntitlements
864 {
865     my $executablePath = shift;
866     return (`codesign -d --entitlements - $executablePath 2>&1` =~ /<key>/);
867 }
868
869 sub safariPathFromSafariBundle
870 {
871     my ($safariBundle) = @_;
872
873     die "Safari path is only relevant on Apple Mac platform\n" unless isAppleMacWebKit();
874
875     my $safariPath = "$safariBundle/Contents/MacOS/Safari";
876     return $safariPath if skipSafariExecutableEntitlementChecks();
877
878     my $safariForWebKitDevelopmentPath = "$safariBundle/Contents/MacOS/SafariForWebKitDevelopment";
879     return $safariForWebKitDevelopmentPath if -f $safariForWebKitDevelopmentPath && executableHasEntitlements($safariPath);
880
881     return $safariPath;
882 }
883
884 sub installedSafariPath
885 {
886     return safariPathFromSafariBundle("/Applications/Safari.app");
887 }
888
889 # Locate Safari.
890 sub safariPath
891 {
892     die "Safari path is only relevant on Apple Mac platform\n" unless isAppleMacWebKit();
893
894     # Use WEBKIT_SAFARI environment variable if present.
895     my $safariBundle = $ENV{WEBKIT_SAFARI};
896     if (!$safariBundle) {
897         determineConfigurationProductDir();
898         # Use Safari.app in product directory if present (good for Safari development team).
899         if (-d "$configurationProductDir/Safari.app") {
900             $safariBundle = "$configurationProductDir/Safari.app";
901         }
902         if (!$safariBundle) {
903             return installedSafariPath();
904         }
905     }
906     my $safariPath = safariPathFromSafariBundle($safariBundle);
907     die "Can't find executable at $safariPath.\n" if !-x $safariPath;
908     return $safariPath;
909 }
910
911 sub builtDylibPathForName
912 {
913     my $libraryName = shift;
914     determineConfigurationProductDir();
915
916     if (isGtk()) {
917         my $extension = isDarwin() ? ".dylib" : ".so";
918         return "$configurationProductDir/lib/libwebkit2gtk-4.0" . $extension;
919     }
920     if (isEfl()) {
921         return "$configurationProductDir/lib/libewebkit2.so";
922     }
923     if (isIOSWebKit()) {
924         return "$configurationProductDir/$libraryName.framework/$libraryName";
925     }
926     if (isAppleMacWebKit()) {
927         return "$configurationProductDir/$libraryName.framework/Versions/A/$libraryName";
928     }
929     if (isAppleWinWebKit()) {
930         if ($libraryName eq "JavaScriptCore") {
931             return "$baseProductDir/lib/$libraryName.lib";
932         } else {
933             return "$baseProductDir/$libraryName.intermediate/$configuration/$libraryName.intermediate/$libraryName.lib";
934         }
935     }
936
937     die "Unsupported platform, can't determine built library locations.\nTry `build-webkit --help` for more information.\n";
938 }
939
940 # Check to see that all the frameworks are built.
941 sub checkFrameworks # FIXME: This is a poor name since only the Mac calls built WebCore a Framework.
942 {
943     return if isAnyWindows();
944     my @frameworks = ("JavaScriptCore", "WebCore");
945     push(@frameworks, "WebKit") if isAppleMacWebKit(); # FIXME: This seems wrong, all ports should have a WebKit these days.
946     for my $framework (@frameworks) {
947         my $path = builtDylibPathForName($framework);
948         die "Can't find built framework at \"$path\".\n" unless -e $path;
949     }
950 }
951
952 sub isInspectorFrontend()
953 {
954     determineIsInspectorFrontend();
955     return $isInspectorFrontend;
956 }
957
958 sub determineIsInspectorFrontend()
959 {
960     return if defined($isInspectorFrontend);
961     $isInspectorFrontend = checkForArgumentAndRemoveFromARGV("--inspector-frontend");
962 }
963
964 sub commandExists($)
965 {
966     my $command = shift;
967     my $devnull = File::Spec->devnull();
968
969     if (isAnyWindows()) {
970         return exitStatus(system("where /q $command >$devnull 2>&1")) == 0;
971     }
972     return exitStatus(system("which $command >$devnull 2>&1")) == 0;
973 }
974
975 sub checkForArgumentAndRemoveFromARGV($)
976 {
977     my $argToCheck = shift;
978     return checkForArgumentAndRemoveFromArrayRef($argToCheck, \@ARGV);
979 }
980
981 sub checkForArgumentAndRemoveFromArrayRefGettingValue($$$)
982 {
983     my ($argToCheck, $valueRef, $arrayRef) = @_;
984     my $argumentStartRegEx = qr#^$argToCheck(?:=\S|$)#;
985     my $i = 0;
986     for (; $i < @$arrayRef; ++$i) {
987         last if $arrayRef->[$i] =~ $argumentStartRegEx;
988     }
989     if ($i >= @$arrayRef) {
990         return $$valueRef = undef;
991     }
992     my ($key, $value) = split("=", $arrayRef->[$i]);
993     splice(@$arrayRef, $i, 1);
994     if (defined($value)) {
995         # e.g. --sdk=iphonesimulator
996         return $$valueRef = $value;
997     }
998     return $$valueRef = splice(@$arrayRef, $i, 1); # e.g. --sdk iphonesimulator
999 }
1000
1001 sub checkForArgumentAndRemoveFromARGVGettingValue($$)
1002 {
1003     my ($argToCheck, $valueRef) = @_;
1004     return checkForArgumentAndRemoveFromArrayRefGettingValue($argToCheck, $valueRef, \@ARGV);
1005 }
1006
1007 sub findMatchingArguments($$)
1008 {
1009     my ($argToCheck, $arrayRef) = @_;
1010     my @matchingIndices;
1011     foreach my $index (0 .. $#$arrayRef) {
1012         my $opt = $$arrayRef[$index];
1013         if ($opt =~ /^$argToCheck$/i ) {
1014             push(@matchingIndices, $index);
1015         }
1016     }
1017     return @matchingIndices; 
1018 }
1019
1020 sub hasArgument($$)
1021 {
1022     my ($argToCheck, $arrayRef) = @_;
1023     my @matchingIndices = findMatchingArguments($argToCheck, $arrayRef);
1024     return scalar @matchingIndices > 0;
1025 }
1026
1027 sub checkForArgumentAndRemoveFromArrayRef
1028 {
1029     my ($argToCheck, $arrayRef) = @_;
1030     my @indicesToRemove = findMatchingArguments($argToCheck, $arrayRef);
1031     my $removeOffset = 0;
1032     foreach my $index (@indicesToRemove) {
1033         splice(@$arrayRef, $index - $removeOffset++, 1);
1034     }
1035     return scalar @indicesToRemove > 0;
1036 }
1037
1038 sub prohibitUnknownPort()
1039 {
1040     $unknownPortProhibited = 1;
1041 }
1042
1043 sub determinePortName()
1044 {
1045     return if defined $portName;
1046
1047     my %argToPortName = (
1048         efl => Efl,
1049         gtk => GTK,
1050         'jsc-only' => JSCOnly,
1051         wincairo => WinCairo
1052     );
1053
1054     for my $arg (sort keys %argToPortName) {
1055         if (checkForArgumentAndRemoveFromARGV("--$arg")) {
1056             die "Argument '--$arg' conflicts with selected port '$portName'\n"
1057                 if defined $portName;
1058
1059             $portName = $argToPortName{$arg};
1060         }
1061     }
1062
1063     return if defined $portName;
1064
1065     # Port was not selected via command line, use appropriate default value
1066
1067     if (isAnyWindows()) {
1068         $portName = AppleWin;
1069     } elsif (isDarwin()) {
1070         determineXcodeSDK();
1071         if (willUseIOSDeviceSDK() || willUseIOSSimulatorSDK()) {
1072             $portName = iOS;
1073         } else {
1074             $portName = Mac;
1075         }
1076     } else {
1077         if ($unknownPortProhibited) {
1078             my $portsChoice = join "\n\t", qw(
1079                 --efl
1080                 --gtk
1081                 --jsc-only
1082             );
1083             die "Please specify which WebKit port to build using one of the following options:"
1084                 . "\n\t$portsChoice\n";
1085         }
1086
1087         # If script is run without arguments we cannot determine port
1088         # TODO: This state should be outlawed
1089         $portName = Unknown;
1090     }
1091 }
1092
1093 sub portName()
1094 {
1095     determinePortName();
1096     return $portName;
1097 }
1098
1099 sub isEfl()
1100 {
1101     return portName() eq Efl;
1102 }
1103
1104 sub isGtk()
1105 {
1106     return portName() eq GTK;
1107 }
1108
1109 sub isJSCOnly()
1110 {
1111     return portName() eq JSCOnly;
1112 }
1113
1114 # Determine if this is debian, ubuntu, linspire, or something similar.
1115 sub isDebianBased()
1116 {
1117     return -e "/etc/debian_version";
1118 }
1119
1120 sub isFedoraBased()
1121 {
1122     return -e "/etc/fedora-release";
1123 }
1124
1125 sub isWinCairo()
1126 {
1127     return portName() eq WinCairo;
1128 }
1129
1130 sub isWin64()
1131 {
1132     determineIsWin64();
1133     return $isWin64;
1134 }
1135
1136 sub determineIsWin64()
1137 {
1138     return if defined($isWin64);
1139     $isWin64 = checkForArgumentAndRemoveFromARGV("--64-bit");
1140 }
1141
1142 sub determineIsWin64FromArchitecture($)
1143 {
1144     my $arch = shift;
1145     $isWin64 = ($arch eq "x86_64");
1146     return $isWin64;
1147 }
1148
1149 sub isCygwin()
1150 {
1151     return ($^O eq "cygwin") || 0;
1152 }
1153
1154 sub isAnyWindows()
1155 {
1156     return isWindows() || isCygwin();
1157 }
1158
1159 sub determineWinVersion()
1160 {
1161     return if $winVersion;
1162
1163     if (!isAnyWindows()) {
1164         $winVersion = -1;
1165         return;
1166     }
1167
1168     my $versionString = `cmd /c ver`;
1169     $versionString =~ /(\d)\.(\d)\.(\d+)/;
1170
1171     $winVersion = {
1172         major => $1,
1173         minor => $2,
1174         build => $3,
1175     };
1176 }
1177
1178 sub winVersion()
1179 {
1180     determineWinVersion();
1181     return $winVersion;
1182 }
1183
1184 sub isWindows7SP0()
1185 {
1186     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 1 && winVersion()->{build} == 7600;
1187 }
1188
1189 sub isWindowsVista()
1190 {
1191     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 0;
1192 }
1193
1194 sub isWindowsXP()
1195 {
1196     return isAnyWindows() && winVersion()->{major} == 5 && winVersion()->{minor} == 1;
1197 }
1198
1199 sub isDarwin()
1200 {
1201     return ($^O eq "darwin") || 0;
1202 }
1203
1204 sub isWindows()
1205 {
1206     return ($^O eq "MSWin32") || 0;
1207 }
1208
1209 sub isLinux()
1210 {
1211     return ($^O eq "linux") || 0;
1212 }
1213
1214 sub isBSD()
1215 {
1216     return ($^O eq "freebsd") || ($^O eq "openbsd") || ($^O eq "netbsd") || 0;
1217 }
1218
1219 sub isARM()
1220 {
1221     return ($Config{archname} =~ /^arm[v\-]/) || ($Config{archname} =~ /^aarch64[v\-]/);
1222 }
1223
1224 sub isX86_64()
1225 {
1226     return (architecture() eq "x86_64") || 0;
1227 }
1228
1229 sub isCrossCompilation()
1230 {
1231   my $compiler = "";
1232   $compiler = $ENV{'CC'} if (defined($ENV{'CC'}));
1233   if ($compiler =~ /gcc/) {
1234       my $compiler_options = `$compiler -v 2>&1`;
1235       my @host = $compiler_options =~ m/--host=(.*?)\s/;
1236       my @target = $compiler_options =~ m/--target=(.*?)\s/;
1237
1238       return ($host[0] ne "" && $target[0] ne "" && $host[0] ne $target[0]);
1239   }
1240   return 0;
1241 }
1242
1243 sub isAppleWebKit()
1244 {
1245     return isAppleMacWebKit() || isAppleWinWebKit();
1246 }
1247
1248 sub isAppleMacWebKit()
1249 {
1250     return (portName() eq Mac) || isIOSWebKit();
1251 }
1252
1253 sub isAppleWinWebKit()
1254 {
1255     return portName() eq AppleWin;
1256 }
1257
1258 sub iOSSimulatorDevicesPath
1259 {
1260     return "$ENV{HOME}/Library/Developer/CoreSimulator/Devices";
1261 }
1262
1263 sub iOSSimulatorDevices
1264 {
1265     eval "require Foundation";
1266     my $devicesPath = iOSSimulatorDevicesPath();
1267     opendir(DEVICES, $devicesPath);
1268     my @udids = grep {
1269         $_ =~ m/[0-9A-F]{8}-([0-9A-F]{4}-){3}[0-9A-F]{12}/;
1270     } readdir(DEVICES);
1271     close(DEVICES);
1272
1273     # FIXME: We should parse the device.plist file ourself and map the dictionary keys in it to known
1274     #        dictionary keys so as to decouple our representation of the plist from the actual structure
1275     #        of the plist, which may change.
1276     my @devices = map {
1277         Foundation::perlRefFromObjectRef(NSDictionary->dictionaryWithContentsOfFile_("$devicesPath/$_/device.plist"));
1278     } @udids;
1279
1280     return @devices;
1281 }
1282
1283 sub createiOSSimulatorDevice
1284 {
1285     my $name = shift;
1286     my $deviceTypeId = shift;
1287     my $runtimeId = shift;
1288
1289     my $created = system("xcrun", "--sdk", "iphonesimulator", "simctl", "create", $name, $deviceTypeId, $runtimeId) == 0;
1290     die "Couldn't create simulator device: $name $deviceTypeId $runtimeId" if not $created;
1291
1292     system("xcrun", "--sdk", "iphonesimulator", "simctl", "list");
1293
1294     print "Waiting for device to be created ...\n";
1295     sleep 5;
1296     for (my $tries = 0; $tries < 5; $tries++){
1297         my @devices = iOSSimulatorDevices();
1298         foreach my $device (@devices) {
1299             return $device if $device->{name} eq $name and $device->{deviceType} eq $deviceTypeId and $device->{runtime} eq $runtimeId;
1300         }
1301         sleep 5;
1302     }
1303     die "Device $name $deviceTypeId $runtimeId wasn't found in " . iOSSimulatorDevicesPath();
1304 }
1305
1306 sub willUseIOSDeviceSDK()
1307 {
1308     return xcodeSDKPlatformName() eq "iphoneos";
1309 }
1310
1311 sub willUseIOSSimulatorSDK()
1312 {
1313     return xcodeSDKPlatformName() eq "iphonesimulator";
1314 }
1315
1316 sub isIOSWebKit()
1317 {
1318     return portName() eq iOS;
1319 }
1320
1321 sub determineNmPath()
1322 {
1323     return if $nmPath;
1324
1325     if (isAppleMacWebKit()) {
1326         $nmPath = `xcrun -find nm`;
1327         chomp $nmPath;
1328     }
1329     $nmPath = "nm" if !$nmPath;
1330 }
1331
1332 sub nmPath()
1333 {
1334     determineNmPath();
1335     return $nmPath;
1336 }
1337
1338 sub splitVersionString
1339 {
1340     my $versionString = shift;
1341     my @splitVersion = split(/\./, $versionString);
1342     @splitVersion >= 2 or die "Invalid version $versionString";
1343     $osXVersion = {
1344             "major" => $splitVersion[0],
1345             "minor" => $splitVersion[1],
1346             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
1347     };
1348 }
1349
1350 sub determineOSXVersion()
1351 {
1352     return if $osXVersion;
1353
1354     if (!isDarwin()) {
1355         $osXVersion = -1;
1356         return;
1357     }
1358
1359     my $versionString = `sw_vers -productVersion`;
1360     $osXVersion = splitVersionString($versionString);
1361 }
1362
1363 sub osXVersion()
1364 {
1365     determineOSXVersion();
1366     return $osXVersion;
1367 }
1368
1369 sub determineIOSVersion()
1370 {
1371     return if $iosVersion;
1372
1373     if (!isIOSWebKit()) {
1374         $iosVersion = -1;
1375         return;
1376     }
1377
1378     my $versionString = xcodeSDKVersion();
1379     $iosVersion = splitVersionString($versionString);
1380 }
1381
1382 sub iosVersion()
1383 {
1384     determineIOSVersion();
1385     return $iosVersion;
1386 }
1387
1388 sub isWindowsNT()
1389 {
1390     return $ENV{'OS'} eq 'Windows_NT';
1391 }
1392
1393 sub debugger
1394 {
1395     determineDebugger();
1396     return $debugger;
1397 }
1398
1399 sub determineDebugger
1400 {
1401     return if defined($debugger);
1402
1403     determineXcodeVersion();
1404     if (eval "v$xcodeVersion" ge v4.5) {
1405         $debugger = "lldb";
1406     } else {
1407         $debugger = "gdb";
1408     }
1409
1410     if (checkForArgumentAndRemoveFromARGV("--use-lldb")) {
1411         $debugger = "lldb";
1412     }
1413
1414     if (checkForArgumentAndRemoveFromARGV("--use-gdb")) {
1415         $debugger = "gdb";
1416     }
1417 }
1418
1419 sub appendToEnvironmentVariableList($$)
1420 {
1421     my ($name, $value) = @_;
1422
1423     if (defined($ENV{$name})) {
1424         $ENV{$name} .= $Config{path_sep} . $value;
1425     } else {
1426         $ENV{$name} = $value;
1427     }
1428 }
1429
1430 sub prependToEnvironmentVariableList($$)
1431 {
1432     my ($name, $value) = @_;
1433
1434     if (defined($ENV{$name})) {
1435         $ENV{$name} = $value . $Config{path_sep} . $ENV{$name};
1436     } else {
1437         $ENV{$name} = $value;
1438     }
1439 }
1440
1441 sub sharedCommandLineOptions()
1442 {
1443     return (
1444         "g|guard-malloc" => \$shouldUseGuardMalloc,
1445     );
1446 }
1447
1448 sub sharedCommandLineOptionsUsage
1449 {
1450     my %opts = @_;
1451
1452     my %switches = (
1453         '-g|--guard-malloc' => 'Use guardmalloc when running executable',
1454     );
1455
1456     my $indent = " " x ($opts{indent} || 2);
1457     my $switchWidth = List::Util::max(int($opts{switchWidth}), List::Util::max(map { length($_) } keys %switches) + ($opts{brackets} ? 2 : 0));
1458
1459     my $result = "Common switches:\n";
1460
1461     for my $switch (keys %switches) {
1462         my $switchName = $opts{brackets} ? "[" . $switch . "]" : $switch;
1463         $result .= sprintf("%s%-" . $switchWidth . "s %s\n", $indent, $switchName, $switches{$switch});
1464     }
1465
1466     return $result;
1467 }
1468
1469 sub setUpGuardMallocIfNeeded
1470 {
1471     if (!isDarwin()) {
1472         return;
1473     }
1474
1475     if (!defined($shouldUseGuardMalloc)) {
1476         $shouldUseGuardMalloc = checkForArgumentAndRemoveFromARGV("-g") || checkForArgumentAndRemoveFromARGV("--guard-malloc");
1477     }
1478
1479     if ($shouldUseGuardMalloc) {
1480         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", "/usr/lib/libgmalloc.dylib");
1481         appendToEnvironmentVariableList("__XPC_DYLD_INSERT_LIBRARIES", "/usr/lib/libgmalloc.dylib");
1482     }
1483 }
1484
1485 sub relativeScriptsDir()
1486 {
1487     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel($FindBin::Bin, getcwd()), "");
1488     if ($scriptDir eq "") {
1489         $scriptDir = ".";
1490     }
1491     return $scriptDir;
1492 }
1493
1494 sub launcherPath()
1495 {
1496     my $relativeScriptsPath = relativeScriptsDir();
1497     if (isGtk() || isEfl()) {
1498         return "$relativeScriptsPath/run-minibrowser";
1499     } elsif (isAppleWebKit()) {
1500         return "$relativeScriptsPath/run-safari";
1501     }
1502 }
1503
1504 sub launcherName()
1505 {
1506     if (isGtk() || isEfl()) {
1507         return "MiniBrowser";
1508     } elsif (isAppleMacWebKit()) {
1509         return "Safari";
1510     } elsif (isAppleWinWebKit()) {
1511         return "MiniBrowser";
1512     }
1513 }
1514
1515 sub checkRequiredSystemConfig
1516 {
1517     if (isDarwin()) {
1518         chomp(my $productVersion = `sw_vers -productVersion`);
1519         if (eval "v$productVersion" lt v10.7.5) {
1520             print "*************************************************************\n";
1521             print "Mac OS X Version 10.7.5 or later is required to build WebKit.\n";
1522             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
1523             print "*************************************************************\n";
1524         }
1525         my $xcodebuildVersionOutput = `xcodebuild -version`;
1526         my $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : undef;
1527         if (!$xcodeVersion || $xcodeVersion && eval "v$xcodeVersion" lt v4.6) {
1528             print "*************************************************************\n";
1529             print "Xcode Version 4.6 or later is required to build WebKit.\n";
1530             print "You have an earlier version of Xcode, thus the build will\n";
1531             print "most likely fail. The latest Xcode is available from the App Store.\n";
1532             print "*************************************************************\n";
1533         }
1534     }
1535 }
1536
1537 sub determineWindowsSourceDir()
1538 {
1539     return if $windowsSourceDir;
1540     $windowsSourceDir = sourceDir();
1541     chomp($windowsSourceDir = `cygpath -w '$windowsSourceDir'`) if isCygwin();
1542 }
1543
1544 sub windowsSourceDir()
1545 {
1546     determineWindowsSourceDir();
1547     return $windowsSourceDir;
1548 }
1549
1550 sub windowsSourceSourceDir()
1551 {
1552     return File::Spec->catdir(windowsSourceDir(), "Source");
1553 }
1554
1555 sub windowsLibrariesDir()
1556 {
1557     return File::Spec->catdir(windowsSourceDir(), "WebKitLibraries", "win");
1558 }
1559
1560 sub windowsOutputDir()
1561 {
1562     return File::Spec->catdir(windowsSourceDir(), "WebKitBuild");
1563 }
1564
1565 sub fontExists($)
1566 {
1567     my $font = shift;
1568     my $cmd = "reg query \"HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Fonts\\" . $font ."\" 2>&1";
1569     my $val = `$cmd`;
1570     return $? == 0;
1571 }
1572
1573 sub checkInstalledTools()
1574 {
1575     # environment variables. Avoid until this is corrected.
1576     my $pythonVer = `python --version 2>&1`;
1577     die "You must have Python installed to build WebKit.\n" if ($?);
1578
1579     # cURL 7.34.0 has a bug that prevents authentication with opensource.apple.com (and other things using SSL3).
1580     my $curlVer = `curl --version 2> NUL`;
1581     if (!$? and $curlVer =~ "(.*curl.*)") {
1582         $curlVer = $1;
1583         if ($curlVer =~ /libcurl\/7\.34\.0/) {
1584             print "cURL version 7.34.0 has a bug that prevents authentication with SSL v2 or v3.\n";
1585             print "cURL 7.33.0 is known to work. The cURL projects is preparing an update to\n";
1586             print "correct this problem.\n\n";
1587             die "Please install a working cURL and try again.\n";
1588         }
1589     }
1590
1591     # MathML requires fonts that do not ship with Windows (at least through Windows 8). Warn the user if they are missing
1592     my @fonts = qw(STIXGeneral-Regular MathJax_Main-Regular);
1593     my @missing = ();
1594     foreach my $font (@fonts) {
1595         push @missing, $font if not fontExists($font);
1596     }
1597
1598     if (scalar @missing > 0) {
1599         print "*************************************************************\n";
1600         print "Mathematical fonts, such as STIX and MathJax, are needed to\n";
1601         print "use the MathML feature.  You do not appear to have these fonts\n";
1602         print "on your system.\n\n";
1603         print "You can download a suitable set of fonts from the following URL:\n";
1604         print "https://developer.mozilla.org/Mozilla/MathML_Projects/Fonts\n";
1605         print "*************************************************************\n";
1606     }
1607
1608     print "Installed tools are correct for the WebKit build.\n";
1609 }
1610
1611 sub setupAppleWinEnv()
1612 {
1613     return unless isAppleWinWebKit();
1614
1615     checkInstalledTools();
1616
1617     if (isWindowsNT()) {
1618         my $restartNeeded = 0;
1619         my %variablesToSet = ();
1620
1621         # FIXME: We should remove this explicit version check for cygwin once we stop supporting Cygwin 1.7.9 or older versions. 
1622         # https://bugs.webkit.org/show_bug.cgi?id=85791
1623         my $uname_version = (POSIX::uname())[2];
1624         $uname_version =~ s/\(.*\)//;  # Remove the trailing cygwin version, if any.
1625         $uname_version =~ s/\-.*$//; # Remove trailing dash-version content, if any
1626         if (version->parse($uname_version) < version->parse("1.7.10")) {
1627             # Setting the environment variable 'CYGWIN' to 'tty' makes cygwin enable extra support (i.e., termios)
1628             # for UNIX-like ttys in the Windows console
1629             $variablesToSet{CYGWIN} = "tty" unless $ENV{CYGWIN};
1630         }
1631         
1632         # Those environment variables must be set to be able to build inside Visual Studio.
1633         $variablesToSet{WEBKIT_LIBRARIES} = windowsLibrariesDir() unless $ENV{WEBKIT_LIBRARIES};
1634         $variablesToSet{WEBKIT_OUTPUTDIR} = windowsOutputDir() unless $ENV{WEBKIT_OUTPUTDIR};
1635         $variablesToSet{MSBUILDDISABLENODEREUSE} = "1" unless $ENV{MSBUILDDISABLENODEREUSE};
1636         $variablesToSet{_IsNativeEnvironment} = "true" unless $ENV{_IsNativeEnvironment};
1637         $variablesToSet{PreferredToolArchitecture} = "x64" unless $ENV{PreferredToolArchitecture};
1638
1639         foreach my $variable (keys %variablesToSet) {
1640             print "Setting the Environment Variable '" . $variable . "' to '" . $variablesToSet{$variable} . "'\n\n";
1641             my $ret = system "setx", $variable, $variablesToSet{$variable};
1642             if ($ret != 0) {
1643                 system qw(regtool -s set), '\\HKEY_CURRENT_USER\\Environment\\' . $variable, $variablesToSet{$variable};
1644             }
1645             $restartNeeded ||=  $variable eq "WEBKIT_LIBRARIES" || $variable eq "WEBKIT_OUTPUTDIR";
1646         }
1647
1648         if ($restartNeeded) {
1649             print "Please restart your computer before attempting to build inside Visual Studio.\n\n";
1650         }
1651     } else {
1652         if (!defined $ENV{'WEBKIT_LIBRARIES'} || !$ENV{'WEBKIT_LIBRARIES'}) {
1653             print "Warning: You must set the 'WebKit_Libraries' environment variable\n";
1654             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n";
1655             print "         Make sure that 'WebKit_Libraries' points to the\n";
1656             print "         'WebKitLibraries/win' directory, not the 'WebKitLibraries/' directory.\n\n";
1657         }
1658         if (!defined $ENV{'WEBKIT_OUTPUTDIR'} || !$ENV{'WEBKIT_OUTPUTDIR'}) {
1659             print "Warning: You must set the 'WebKit_OutputDir' environment variable\n";
1660             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n\n";
1661         }
1662         if (!defined $ENV{'MSBUILDDISABLENODEREUSE'} || !$ENV{'MSBUILDDISABLENODEREUSE'}) {
1663             print "Warning: You should set the 'MSBUILDDISABLENODEREUSE' environment variable to '1'\n";
1664             print "         to avoid periodic locked log files when building.\n\n";
1665         }
1666     }
1667     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1668     if (isWin64() and !$ENV{'WEBKIT_64_SUPPORT'}) {
1669         print "Warning: You must set the 'WEBKIT_64_SUPPORT' environment variable\n";
1670         print "         to be able run WebKit or JavaScriptCore tests.\n\n";
1671     }
1672 }
1673
1674 sub setupCygwinEnv()
1675 {
1676     return if !isAnyWindows();
1677     return if $vcBuildPath;
1678
1679     my $programFilesPath = programFilesPath();
1680     my $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.com));
1681     if (-e $visualStudioPath) {
1682         # Visual Studio is installed;
1683         if (visualStudioVersion() eq "12") {
1684             $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.exe));
1685         }
1686     } else {
1687         # Visual Studio not found, try VC++ Express
1688         $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE WDExpress.exe));
1689         if (! -e $visualStudioPath) {
1690             print "*************************************************************\n";
1691             print "Cannot find '$visualStudioPath'\n";
1692             print "Please execute the file 'vcvars32.bat' from\n";
1693             print "'$programFilesPath\\Microsoft Visual Studio 14.0\\VC\\bin\\'\n";
1694             print "to setup the necessary environment variables.\n";
1695             print "*************************************************************\n";
1696             die;
1697         }
1698         $willUseVCExpressWhenBuilding = 1;
1699     }
1700
1701     print "Building results into: ", baseProductDir(), "\n";
1702     print "WEBKIT_OUTPUTDIR is set to: ", $ENV{"WEBKIT_OUTPUTDIR"}, "\n";
1703     print "WEBKIT_LIBRARIES is set to: ", $ENV{"WEBKIT_LIBRARIES"}, "\n";
1704     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1705     print "WEBKIT_64_SUPPORT is set to: ", $ENV{"WEBKIT_64_SUPPORT"}, "\n" if isWin64();
1706
1707     # We will actually use MSBuild to build WebKit, but we need to find the Visual Studio install (above) to make
1708     # sure we use the right options.
1709     $vcBuildPath = File::Spec->catfile(msBuildInstallDir(), qw(MSBuild.exe));
1710     if (! -e $vcBuildPath) {
1711         print "*************************************************************\n";
1712         print "Cannot find '$vcBuildPath'\n";
1713         print "Please make sure execute that the Microsoft .NET Framework SDK\n";
1714         print "is installed on this machine.\n";
1715         print "*************************************************************\n";
1716         die;
1717     }
1718 }
1719
1720 sub dieIfWindowsPlatformSDKNotInstalled
1721 {
1722     my $registry32Path = "/proc/registry/";
1723     my $registry64Path = "/proc/registry64/";
1724     my @windowsPlatformSDKRegistryEntries = (
1725         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0A",
1726         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0",
1727         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.1A",
1728         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.0A",
1729         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/MicrosoftSDK/InstalledSDKs/D2FF9F89-8AA2-4373-8A31-C838BF4DBBE1",
1730     );
1731
1732     # FIXME: It would be better to detect whether we are using 32- or 64-bit Windows
1733     # and only check the appropriate entry. But for now we just blindly check both.
1734     my $recommendedPlatformSDK = $windowsPlatformSDKRegistryEntries[0];
1735
1736     while (@windowsPlatformSDKRegistryEntries) {
1737         my $windowsPlatformSDKRegistryEntry = shift @windowsPlatformSDKRegistryEntries;
1738         return if (-e $registry32Path . $windowsPlatformSDKRegistryEntry) || (-e $registry64Path . $windowsPlatformSDKRegistryEntry);
1739     }
1740
1741     print "*************************************************************\n";
1742     print "Cannot find registry entry '$recommendedPlatformSDK'.\n";
1743     print "Please download and install the Microsoft Windows SDK\n";
1744     print "from <http://www.microsoft.com/en-us/download/details.aspx?id=8279>.\n\n";
1745     print "Then follow step 2 in the Windows section of the \"Installing Developer\n";
1746     print "Tools\" instructions at <http://www.webkit.org/building/tools.html>.\n";
1747     print "*************************************************************\n";
1748     die;
1749 }
1750
1751 sub buildXCodeProject($$@)
1752 {
1753     my ($project, $clean, @extraOptions) = @_;
1754
1755     if ($clean) {
1756         push(@extraOptions, "-alltargets");
1757         push(@extraOptions, "clean");
1758     }
1759
1760     chomp($ENV{DSYMUTIL_NUM_THREADS} = `sysctl -n hw.activecpu`);
1761     return system "xcodebuild", "-project", "$project.xcodeproj", @extraOptions;
1762 }
1763
1764 sub usingVisualStudioExpress()
1765 {
1766     setupCygwinEnv();
1767     return $willUseVCExpressWhenBuilding;
1768 }
1769
1770 sub buildVisualStudioProject
1771 {
1772     my ($project, $clean) = @_;
1773     setupCygwinEnv();
1774
1775     my $config = configurationForVisualStudio();
1776
1777     dieIfWindowsPlatformSDKNotInstalled() if $willUseVCExpressWhenBuilding;
1778
1779     chomp($project = `cygpath -w "$project"`) if isCygwin();
1780
1781     my $action = "/t:build";
1782     if ($clean) {
1783         $action = "/t:clean";
1784     }
1785
1786     my $platform = "/p:Platform=" . (isWin64() ? "x64" : "Win32");
1787     my $logPath = File::Spec->catdir($baseProductDir, $configuration);
1788     make_path($logPath) unless -d $logPath or $logPath eq ".";
1789
1790     my $errorLogFile = File::Spec->catfile($logPath, "webkit_errors.log");
1791     chomp($errorLogFile = `cygpath -w "$errorLogFile"`) if isCygwin();
1792     my $errorLogging = "/flp:LogFile=" . $errorLogFile . ";ErrorsOnly";
1793
1794     my $warningLogFile = File::Spec->catfile($logPath, "webkit_warnings.log");
1795     chomp($warningLogFile = `cygpath -w "$warningLogFile"`) if isCygwin();
1796     my $warningLogging = "/flp1:LogFile=" . $warningLogFile . ";WarningsOnly";
1797
1798     my @command = ($vcBuildPath, "/verbosity:minimal", $project, $action, $config, $platform, "/fl", $errorLogging, "/fl1", $warningLogging);
1799     print join(" ", @command), "\n";
1800     return system @command;
1801 }
1802
1803 sub getJhbuildPath()
1804 {
1805     my @jhbuildPath = File::Spec->splitdir(baseProductDir());
1806     if (isGit() && isGitBranchBuild() && gitBranch()) {
1807         pop(@jhbuildPath);
1808     }
1809     if (isEfl()) {
1810         push(@jhbuildPath, "DependenciesEFL");
1811     } elsif (isGtk()) {
1812         push(@jhbuildPath, "DependenciesGTK");
1813     } else {
1814         die "Cannot get JHBuild path for platform that isn't GTK+ or EFL.\n";
1815     }
1816     return File::Spec->catdir(@jhbuildPath);
1817 }
1818
1819 sub isCachedArgumentfileOutOfDate($@)
1820 {
1821     my ($filename, $currentContents) = @_;
1822
1823     if (! -e $filename) {
1824         return 1;
1825     }
1826
1827     open(CONTENTS_FILE, $filename);
1828     chomp(my $previousContents = <CONTENTS_FILE>);
1829     close(CONTENTS_FILE);
1830
1831     if ($previousContents ne $currentContents) {
1832         print "Contents for file $filename have changed.\n";
1833         print "Previous contents were: $previousContents\n\n";
1834         print "New contents are: $currentContents\n";
1835         return 1;
1836     }
1837
1838     return 0;
1839 }
1840
1841 sub wrapperPrefixIfNeeded()
1842 {
1843     if (isAnyWindows() || isJSCOnly()) {
1844         return ();
1845     }
1846     if (isAppleMacWebKit()) {
1847         return ("xcrun");
1848     }
1849     if (-e getJhbuildPath()) {
1850         my @prefix = (File::Spec->catfile(sourceDir(), "Tools", "jhbuild", "jhbuild-wrapper"));
1851         if (isEfl()) {
1852             push(@prefix, "--efl");
1853         } elsif (isGtk()) {
1854             push(@prefix, "--gtk");
1855         }
1856         push(@prefix, "run");
1857
1858         return @prefix;
1859     }
1860
1861     return ();
1862 }
1863
1864 sub cmakeCachePath()
1865 {
1866     return File::Spec->catdir(baseProductDir(), configuration(), "CMakeCache.txt");
1867 }
1868
1869 sub shouldRemoveCMakeCache(@)
1870 {
1871     my ($cacheFilePath, @buildArgs) = @_;
1872
1873     # We check this first, because we always want to create this file for a fresh build.
1874     my $productDir = File::Spec->catdir(baseProductDir(), configuration());
1875     my $optionsCache = File::Spec->catdir($productDir, "build-webkit-options.txt");
1876     my $joinedBuildArgs = join(" ", @buildArgs);
1877     if (isCachedArgumentfileOutOfDate($optionsCache, $joinedBuildArgs)) {
1878         File::Path::mkpath($productDir) unless -d $productDir;
1879         open(CACHED_ARGUMENTS, ">", $optionsCache);
1880         print CACHED_ARGUMENTS $joinedBuildArgs;
1881         close(CACHED_ARGUMENTS);
1882
1883         return 1;
1884     }
1885
1886     my $cmakeCache = cmakeCachePath();
1887     unless (-e $cmakeCache) {
1888         return 0;
1889     }
1890
1891     my $cacheFileModifiedTime = stat($cmakeCache)->mtime;
1892     my $platformConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "Options" . cmakeBasedPortName() . ".cmake");
1893     if ($cacheFileModifiedTime < stat($platformConfiguration)->mtime) {
1894         return 1;
1895     }
1896
1897     my $globalConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "OptionsCommon.cmake");
1898     if ($cacheFileModifiedTime < stat($globalConfiguration)->mtime) {
1899         return 1;
1900     }
1901
1902     my $inspectorUserInterfaceDircetory = File::Spec->catdir(sourceDir(), "Source", "WebInspectorUI", "UserInterface");
1903     if ($cacheFileModifiedTime < stat($inspectorUserInterfaceDircetory)->mtime) {
1904         return 1;
1905     }
1906
1907     return 0;
1908 }
1909
1910 sub removeCMakeCache(@)
1911 {
1912     my (@buildArgs) = @_;
1913     if (shouldRemoveCMakeCache(@buildArgs)) {
1914         my $cmakeCache = cmakeCachePath();
1915         unlink($cmakeCache) if -e $cmakeCache;
1916     }
1917 }
1918
1919 sub canUseNinja(@)
1920 {
1921     if (!defined($shouldNotUseNinja)) {
1922         $shouldNotUseNinja = checkForArgumentAndRemoveFromARGV("--no-ninja");
1923     }
1924
1925     if ($shouldNotUseNinja) {
1926         return 0;
1927     }
1928
1929     # Test both ninja and ninja-build. Fedora uses ninja-build and has patched CMake to also call ninja-build.
1930     return commandExists("ninja") || commandExists("ninja-build");
1931 }
1932
1933 sub canUseNinjaGenerator(@)
1934 {
1935     # Check that a Ninja generator is installed
1936     my $devnull = File::Spec->devnull();
1937     return exitStatus(system("cmake -N -G Ninja >$devnull 2>&1")) == 0;
1938 }
1939
1940 sub canUseEclipseNinjaGenerator(@)
1941 {
1942     # Check that eclipse and eclipse Ninja generator is installed
1943     my $devnull = File::Spec->devnull();
1944     return commandExists("eclipse") && exitStatus(system("cmake -N -G 'Eclipse CDT4 - Ninja' >$devnull 2>&1")) == 0;
1945 }
1946
1947 sub cmakeGeneratedBuildfile(@)
1948 {
1949     my ($willUseNinja) = @_;
1950     if ($willUseNinja) {
1951         return File::Spec->catfile(baseProductDir(), configuration(), "build.ninja")
1952     } elsif (isAnyWindows()) {
1953         return File::Spec->catfile(baseProductDir(), configuration(), "WebKit.sln")
1954     } else {
1955         return File::Spec->catfile(baseProductDir(), configuration(), "Makefile")
1956     }
1957 }
1958
1959 sub generateBuildSystemFromCMakeProject
1960 {
1961     my ($prefixPath, @cmakeArgs) = @_;
1962     my $config = configuration();
1963     my $port = cmakeBasedPortName();
1964     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1965     File::Path::mkpath($buildPath) unless -d $buildPath;
1966     my $originalWorkingDirectory = getcwd();
1967     chdir($buildPath) or die;
1968
1969     # We try to be smart about when to rerun cmake, so that we can have faster incremental builds.
1970     my $willUseNinja = canUseNinja() && canUseNinjaGenerator();
1971     if (-e cmakeCachePath() && -e cmakeGeneratedBuildfile($willUseNinja)) {
1972         return 0;
1973     }
1974
1975     my @args;
1976     push @args, "-DPORT=\"$port\"";
1977     push @args, "-DCMAKE_INSTALL_PREFIX=\"$prefixPath\"" if $prefixPath;
1978     push @args, "-DCMAKE_EXPORT_COMPILE_COMMANDS=ON" if isGtk();
1979     if ($config =~ /release/i) {
1980         push @args, "-DCMAKE_BUILD_TYPE=Release";
1981     } elsif ($config =~ /debug/i) {
1982         push @args, "-DCMAKE_BUILD_TYPE=Debug";
1983     }
1984
1985     if ($willUseNinja) {
1986         push @args, "-G";
1987         if (canUseEclipseNinjaGenerator()) {
1988             push @args, "'Eclipse CDT4 - Ninja'";
1989         } else {
1990             push @args, "Ninja";
1991         }
1992     } elsif (isAnyWindows() && isWin64()) {
1993         push @args, '-G "Visual Studio 14 2015 Win64"';
1994     }
1995
1996     # Some ports have production mode, but build-webkit should always use developer mode.
1997     push @args, "-DDEVELOPER_MODE=ON" if isEfl() || isGtk() || isJSCOnly();
1998
1999     # Don't warn variables which aren't used by cmake ports.
2000     push @args, "--no-warn-unused-cli";
2001     push @args, @cmakeArgs if @cmakeArgs;
2002
2003     my $cmakeSourceDir = isCygwin() ? windowsSourceDir() : sourceDir();
2004     push @args, '"' . $cmakeSourceDir . '"';
2005
2006     # Compiler options to keep floating point values consistent
2007     # between 32-bit and 64-bit architectures.
2008     determineArchitecture();
2009     if ($architecture ne "x86_64" && !isARM() && !isCrossCompilation() && !isAnyWindows()) {
2010         $ENV{'CXXFLAGS'} = "-march=pentium4 -msse2 -mfpmath=sse " . ($ENV{'CXXFLAGS'} || "");
2011     }
2012
2013     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
2014     # parsed for shell metacharacters.
2015     my $wrapper = join(" ", wrapperPrefixIfNeeded()) . " ";
2016     my $returnCode = system($wrapper . "cmake @args");
2017
2018     chdir($originalWorkingDirectory);
2019     return $returnCode;
2020 }
2021
2022 sub buildCMakeGeneratedProject($)
2023 {
2024     my ($makeArgs) = @_;
2025     my $config = configuration();
2026     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2027     if (! -d $buildPath) {
2028         die "Must call generateBuildSystemFromCMakeProject() before building CMake project.";
2029     }
2030
2031     my $command = "cmake";
2032     my @args = ("--build", $buildPath, "--config", $config);
2033     push @args, ("--", $makeArgs) if $makeArgs;
2034
2035     # GTK and JSCOnly can use a build script to preserve colors and pretty-printing.
2036     if ((isGtk() || isJSCOnly()) && -e "$buildPath/build.sh") {
2037         chdir "$buildPath" or die;
2038         $command = "$buildPath/build.sh";
2039         @args = ($makeArgs);
2040     }
2041
2042     if ($ENV{VERBOSE} && canUseNinja()) {
2043         push @args, "-v";
2044         push @args, "-d keeprsp" if (version->parse(determineNinjaVersion()) >= version->parse("1.4.0"));
2045     }
2046
2047     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
2048     # parsed for shell metacharacters. In particular, $makeArgs may contain such metacharacters.
2049     my $wrapper = join(" ", wrapperPrefixIfNeeded()) . " ";
2050     return system($wrapper . "$command @args");
2051 }
2052
2053 sub cleanCMakeGeneratedProject()
2054 {
2055     my $config = configuration();
2056     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2057     if (-d $buildPath) {
2058         return system("cmake", "--build", $buildPath, "--config", $config, "--target", "clean");
2059     }
2060     return 0;
2061 }
2062
2063 sub buildCMakeProjectOrExit($$$@)
2064 {
2065     my ($clean, $prefixPath, $makeArgs, @cmakeArgs) = @_;
2066     my $returnCode;
2067
2068     exit(exitStatus(cleanCMakeGeneratedProject())) if $clean;
2069
2070     if (isEfl() && checkForArgumentAndRemoveFromARGV("--update-efl")) {
2071         system("perl", "$sourceDir/Tools/Scripts/update-webkitefl-libs") == 0 or die $!;
2072     }
2073
2074     if (isGtk() && checkForArgumentAndRemoveFromARGV("--update-gtk")) {
2075         system("perl", "$sourceDir/Tools/Scripts/update-webkitgtk-libs") == 0 or die $!;
2076     }
2077
2078     $returnCode = exitStatus(generateBuildSystemFromCMakeProject($prefixPath, @cmakeArgs));
2079     exit($returnCode) if $returnCode;
2080
2081     $returnCode = exitStatus(buildCMakeGeneratedProject($makeArgs));
2082     exit($returnCode) if $returnCode;
2083     return 0;
2084 }
2085
2086 sub cmakeBasedPortArguments()
2087 {
2088     return ();
2089 }
2090
2091 sub cmakeBasedPortName()
2092 {
2093     return ucfirst portName();
2094 }
2095
2096 sub determineIsCMakeBuild()
2097 {
2098     return if defined($isCMakeBuild);
2099     $isCMakeBuild = checkForArgumentAndRemoveFromARGV("--cmake");
2100 }
2101
2102 sub isCMakeBuild()
2103 {
2104     return 1 unless isAppleMacWebKit();
2105     determineIsCMakeBuild();
2106     return $isCMakeBuild;
2107 }
2108
2109 sub promptUser
2110 {
2111     my ($prompt, $default) = @_;
2112     my $defaultValue = $default ? "[$default]" : "";
2113     print "$prompt $defaultValue: ";
2114     chomp(my $input = <STDIN>);
2115     return $input ? $input : $default;
2116 }
2117
2118 sub appleApplicationSupportPath
2119 {
2120     open INSTALL_DIR, "</proc/registry/HKEY_LOCAL_MACHINE/SOFTWARE/Apple\ Inc./Apple\ Application\ Support/InstallDir";
2121     my $path = <INSTALL_DIR>;
2122     $path =~ s/[\r\n\x00].*//;
2123     close INSTALL_DIR;
2124
2125     my $unixPath = `cygpath -u '$path'`;
2126     chomp $unixPath;
2127     return $unixPath;
2128 }
2129
2130 sub setPathForRunningWebKitApp
2131 {
2132     my ($env) = @_;
2133
2134     if (isAnyWindows()) {
2135         my $productBinaryDir = executableProductDir();
2136         if (isAppleWinWebKit()) {
2137             $env->{PATH} = join(':', $productBinaryDir, appleApplicationSupportPath(), $env->{PATH} || "");
2138         } elsif (isWinCairo()) {
2139             my $winCairoBin = sourceDir() . "/WebKitLibraries/win/" . (isWin64() ? "bin64/" : "bin32/");
2140             my $gstreamerBin = isWin64() ? $ENV{"GSTREAMER_1_0_ROOT_X86_64"} . "bin" : $ENV{"GSTREAMER_1_0_ROOT_X86"} . "bin";
2141             $env->{PATH} = join(':', $productBinaryDir, $winCairoBin, $gstreamerBin, $env->{PATH} || "");
2142         }
2143     }
2144 }
2145
2146 sub printHelpAndExitForRunAndDebugWebKitAppIfNeeded
2147 {
2148     return unless checkForArgumentAndRemoveFromARGV("--help");
2149
2150     my ($includeOptionsForDebugging) = @_;
2151
2152     print STDERR <<EOF;
2153 Usage: @{[basename($0)]} [options] [args ...]
2154   --help                            Show this help message
2155   --no-saved-state                  Launch the application without state restoration (OS X 10.7 and later)
2156   -g|--guard-malloc                 Enable Guard Malloc (OS X only)
2157 EOF
2158
2159     if ($includeOptionsForDebugging) {
2160         print STDERR <<EOF;
2161   --use-gdb                         Use GDB (this is the default when using Xcode 4.4 or earlier)
2162   --use-lldb                        Use LLDB (this is the default when using Xcode 4.5 or later)
2163 EOF
2164     }
2165
2166     exit(1);
2167 }
2168
2169 sub argumentsForRunAndDebugMacWebKitApp()
2170 {
2171     my @args = ();
2172     if (checkForArgumentAndRemoveFromARGV("--no-saved-state")) {
2173         push @args, ("-ApplePersistenceIgnoreStateQuietly", "YES");
2174         # FIXME: Don't set ApplePersistenceIgnoreState once all supported OS versions respect ApplePersistenceIgnoreStateQuietly (rdar://15032886).
2175         push @args, ("-ApplePersistenceIgnoreState", "YES");
2176     }
2177     unshift @args, @ARGV;
2178
2179     return @args;
2180 }
2181
2182 sub setupMacWebKitEnvironment($)
2183 {
2184     my ($dyldFrameworkPath) = @_;
2185
2186     $dyldFrameworkPath = File::Spec->rel2abs($dyldFrameworkPath);
2187
2188     prependToEnvironmentVariableList("DYLD_FRAMEWORK_PATH", $dyldFrameworkPath);
2189     prependToEnvironmentVariableList("__XPC_DYLD_FRAMEWORK_PATH", $dyldFrameworkPath);
2190     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2191
2192     setUpGuardMallocIfNeeded();
2193 }
2194
2195 sub setupIOSWebKitEnvironment($)
2196 {
2197     my ($dyldFrameworkPath) = @_;
2198     $dyldFrameworkPath = File::Spec->rel2abs($dyldFrameworkPath);
2199
2200     prependToEnvironmentVariableList("DYLD_FRAMEWORK_PATH", $dyldFrameworkPath);
2201     prependToEnvironmentVariableList("DYLD_LIBRARY_PATH", $dyldFrameworkPath);
2202
2203     setUpGuardMallocIfNeeded();
2204 }
2205
2206 sub iosSimulatorApplicationsPath()
2207 {
2208     return File::Spec->catdir(XcodeSDKPath(), "Applications");
2209 }
2210
2211 sub installedMobileSafariBundle()
2212 {
2213     return File::Spec->catfile(iosSimulatorApplicationsPath(), "MobileSafari.app");
2214 }
2215
2216 sub mobileSafariBundle()
2217 {
2218     determineConfigurationProductDir();
2219
2220     # Use MobileSafari.app in product directory if present.
2221     if (isAppleMacWebKit() && -d "$configurationProductDir/MobileSafari.app") {
2222         return "$configurationProductDir/MobileSafari.app";
2223     }
2224     return installedMobileSafariBundle();
2225 }
2226
2227 sub plistPathFromBundle($)
2228 {
2229     my ($appBundle) = @_;
2230     return "$appBundle/Info.plist" if -f "$appBundle/Info.plist"; # iOS app bundle
2231     return "$appBundle/Contents/Info.plist" if -f "$appBundle/Contents/Info.plist"; # Mac app bundle
2232     return "";
2233 }
2234
2235 sub appIdentifierFromBundle($)
2236 {
2237     my ($appBundle) = @_;
2238     my $plistPath = File::Spec->rel2abs(plistPathFromBundle($appBundle)); # defaults(1) will complain if the specified path is not absolute.
2239     chomp(my $bundleIdentifier = `defaults read '$plistPath' CFBundleIdentifier 2> /dev/null`);
2240     return $bundleIdentifier;
2241 }
2242
2243 sub appDisplayNameFromBundle($)
2244 {
2245     my ($appBundle) = @_;
2246     my $plistPath = File::Spec->rel2abs(plistPathFromBundle($appBundle)); # defaults(1) will complain if the specified path is not absolute.
2247     chomp(my $bundleDisplayName = `defaults read '$plistPath' CFBundleDisplayName 2> /dev/null`);
2248     return $bundleDisplayName;
2249 }
2250
2251 sub waitUntilIOSSimulatorDeviceIsInState($$)
2252 {
2253     my ($deviceUDID, $waitUntilState) = @_;
2254     my $device = iosSimulatorDeviceByUDID($deviceUDID);
2255     while ($device->{state} ne $waitUntilState) {
2256         usleep(500 * 1000); # Waiting 500ms between file system polls does not make script run-safari feel sluggish.
2257         $device = iosSimulatorDeviceByUDID($deviceUDID);
2258     }
2259 }
2260
2261 sub shutDownIOSSimulatorDevice($)
2262 {
2263     my ($simulatorDevice) = @_;
2264     system("xcrun --sdk iphonesimulator simctl shutdown $simulatorDevice->{UDID} > /dev/null 2>&1");
2265 }
2266
2267 sub restartIOSSimulatorDevice($)
2268 {
2269     my ($simulatorDevice) = @_;
2270     shutDownIOSSimulatorDevice($simulatorDevice);
2271
2272     exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "boot", $simulatorDevice->{UDID})) == 0 or die "Failed to boot simulator device $simulatorDevice->{UDID}";
2273 }
2274
2275 sub relaunchIOSSimulator($)
2276 {
2277     my ($simulatedDevice) = @_;
2278     quitIOSSimulator($simulatedDevice->{UDID});
2279
2280     # FIXME: <rdar://problem/20916140> Switch to using CoreSimulator.framework for launching and quitting iOS Simulator
2281     my $iosSimulatorBundleID = "com.apple.iphonesimulator";
2282     system("open", "-b", $iosSimulatorBundleID, "--args", "-CurrentDeviceUDID", $simulatedDevice->{UDID}) == 0 or die "Failed to open $iosSimulatorBundleID: $!";
2283
2284     waitUntilIOSSimulatorDeviceIsInState($simulatedDevice->{UDID}, SIMULATOR_DEVICE_STATE_BOOTED);
2285 }
2286
2287 sub quitIOSSimulator(;$)
2288 {
2289     my ($waitForShutdownOfSimulatedDeviceUDID) = @_;
2290     # FIXME: <rdar://problem/20916140> Switch to using CoreSimulator.framework for launching and quitting iOS Simulator
2291     exitStatus(system {"osascript"} "osascript", "-e", 'tell application id "com.apple.iphonesimulator" to quit') == 0 or die "Failed to quit iOS Simulator: $!";
2292     if (!defined($waitForShutdownOfSimulatedDeviceUDID)) {
2293         return;
2294     }
2295     # FIXME: We assume that $waitForShutdownOfSimulatedDeviceUDID was not booted using the simctl command line tool.
2296     #        Otherwise we will spin indefinitely since quiting the iOS Simulator will not shutdown this device. We
2297     #        should add a maximum time limit to wait for a device to shutdown and either return an error or die()
2298     #        on expiration of the time limit.
2299     waitUntilIOSSimulatorDeviceIsInState($waitForShutdownOfSimulatedDeviceUDID, SIMULATOR_DEVICE_STATE_SHUTDOWN);
2300 }
2301
2302 sub iosSimulatorDeviceByName($)
2303 {
2304     my ($simulatorName) = @_;
2305     my $simulatorRuntime = iosSimulatorRuntime();
2306     my @devices = iOSSimulatorDevices();
2307     for my $device (@devices) {
2308         if ($device->{name} eq $simulatorName && $device->{runtime} eq $simulatorRuntime) {
2309             return $device;
2310         }
2311     }
2312     return undef;
2313 }
2314
2315 sub iosSimulatorDeviceByUDID($)
2316 {
2317     my ($simulatedDeviceUDID) = @_;
2318     my $devicePlistPath = File::Spec->catfile(iOSSimulatorDevicesPath(), $simulatedDeviceUDID, "device.plist");
2319     if (!-f $devicePlistPath) {
2320         return;
2321     }
2322     # FIXME: We should parse the device.plist file ourself and map the dictionary keys in it to known
2323     #        dictionary keys so as to decouple our representation of the plist from the actual structure
2324     #        of the plist, which may change.
2325     eval "require Foundation";
2326     return Foundation::perlRefFromObjectRef(NSDictionary->dictionaryWithContentsOfFile_($devicePlistPath));
2327 }
2328
2329 sub iosSimulatorRuntime()
2330 {
2331     my $xcodeSDKVersion = xcodeSDKVersion();
2332     $xcodeSDKVersion =~ s/\./-/;
2333     return "com.apple.CoreSimulator.SimRuntime.iOS-$xcodeSDKVersion";
2334 }
2335
2336 sub findOrCreateSimulatorForIOSDevice($)
2337 {
2338     my ($simulatorNameSuffix) = @_;
2339     my $simulatorName;
2340     my $simulatorDeviceType;
2341     if (architecture() eq "x86_64") {
2342         $simulatorName = "iPhone 5s " . $simulatorNameSuffix;
2343         $simulatorDeviceType = "com.apple.CoreSimulator.SimDeviceType.iPhone-5s";
2344     } else {
2345         $simulatorName = "iPhone 5 " . $simulatorNameSuffix;
2346         $simulatorDeviceType = "com.apple.CoreSimulator.SimDeviceType.iPhone-5";
2347     }
2348     my $simulatedDevice = iosSimulatorDeviceByName($simulatorName);
2349     return $simulatedDevice if $simulatedDevice;
2350     return createiOSSimulatorDevice($simulatorName, $simulatorDeviceType, iosSimulatorRuntime());
2351 }
2352
2353 sub isIOSSimulatorSystemInstalledApp($)
2354 {
2355     my ($appBundle) = @_;
2356     my $simulatorApplicationsPath = realpath(iosSimulatorApplicationsPath());
2357     return substr(realpath($appBundle), 0, length($simulatorApplicationsPath)) eq $simulatorApplicationsPath;
2358 }
2359
2360 sub hasUserInstalledAppInSimulatorDevice($$)
2361 {
2362     my ($appIdentifier, $simulatedDeviceUDID) = @_;
2363     my $userInstalledAppPath = File::Spec->catfile($ENV{HOME}, "Library", "Developer", "CoreSimulator", "Devices", $simulatedDeviceUDID, "data", "Containers", "Bundle", "Application");
2364     if (!-d $userInstalledAppPath) {
2365         return 0; # No user installed apps.
2366     }
2367     local @::userInstalledAppBundles;
2368     my $wantedFunction = sub {
2369         my $file = $_;
2370
2371         # Ignore hidden files and directories.
2372         if ($file =~ /^\../) {
2373             $File::Find::prune = 1;
2374             return;
2375         }
2376
2377         return if !-d $file || $file !~ /\.app$/;
2378         push @::userInstalledAppBundles, $File::Find::name;
2379         $File::Find::prune = 1; # Do not traverse contents of app bundle.
2380     };
2381     find($wantedFunction, $userInstalledAppPath);
2382     for my $userInstalledAppBundle (@::userInstalledAppBundles) {
2383         if (appIdentifierFromBundle($userInstalledAppBundle) eq $appIdentifier) {
2384             return 1; # Has user installed app.
2385         }
2386     }
2387     return 0; # Does not have user installed app.
2388 }
2389
2390 sub isSimulatorDeviceBooted($)
2391 {
2392     my ($simulatedDeviceUDID) = @_;
2393     my $device = iosSimulatorDeviceByUDID($simulatedDeviceUDID);
2394     return $device && $device->{state} eq SIMULATOR_DEVICE_STATE_BOOTED;
2395 }
2396
2397 sub runIOSWebKitAppInSimulator($;$)
2398 {
2399     my ($appBundle, $simulatorOptions) = @_;
2400     my $productDir = productDir();
2401     my $appDisplayName = appDisplayNameFromBundle($appBundle);
2402     my $appIdentifier = appIdentifierFromBundle($appBundle);
2403     my $simulatedDevice = findOrCreateSimulatorForIOSDevice(SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT);
2404     my $simulatedDeviceUDID = $simulatedDevice->{UDID};
2405
2406     my $willUseSystemInstalledApp = isIOSSimulatorSystemInstalledApp($appBundle);
2407     if ($willUseSystemInstalledApp) {
2408         if (hasUserInstalledAppInSimulatorDevice($appIdentifier, $simulatedDeviceUDID)) {
2409             # Restore the system-installed app in the simulator device corresponding to $appBundle as it
2410             # was previously overwritten with a custom built version of the app.
2411             # FIXME: Only restore the system-installed version of the app instead of erasing all contents and settings.
2412             print "Quitting iOS Simulator...\n";
2413             quitIOSSimulator($simulatedDeviceUDID);
2414             print "Erasing contents and settings for simulator device \"$simulatedDevice->{name}\".\n";
2415             exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "erase", $simulatedDeviceUDID)) == 0 or die;
2416         }
2417         # FIXME: We assume that if $simulatedDeviceUDID is not booted then iOS Simulator is not open. However
2418         #        $simulatedDeviceUDID may have been booted using the simctl command line tool. If $simulatedDeviceUDID
2419         #        was booted using simctl then we should shutdown the device and launch iOS Simulator to boot it again.
2420         if (!isSimulatorDeviceBooted($simulatedDeviceUDID)) {
2421             print "Launching iOS Simulator...\n";
2422             relaunchIOSSimulator($simulatedDevice);
2423         }
2424     } else {
2425         # FIXME: We should killall(1) any running instances of $appBundle before installing it to ensure
2426         #        that simctl launch opens the latest installed version of the app. For now we quit and
2427         #        launch the iOS Simulator again to ensure there are no running instances of $appBundle.
2428         print "Quitting and launching iOS Simulator...\n";
2429         relaunchIOSSimulator($simulatedDevice);
2430
2431         print "Installing $appBundle.\n";
2432         # Install custom built app, overwriting an app with the same app identifier if one exists.
2433         exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "install", $simulatedDeviceUDID, $appBundle)) == 0 or die;
2434
2435     }
2436
2437     $simulatorOptions = {} unless $simulatorOptions;
2438
2439     my %simulatorENV;
2440     %simulatorENV = %{$simulatorOptions->{applicationEnvironment}} if $simulatorOptions->{applicationEnvironment};
2441     {
2442         local %ENV; # Shadow global-scope %ENV so that changes to it will not be seen outside of this scope.
2443         setupIOSWebKitEnvironment($productDir);
2444         %simulatorENV = %ENV;
2445     }
2446     my $applicationArguments = \@ARGV;
2447     $applicationArguments = $simulatorOptions->{applicationArguments} if $simulatorOptions && $simulatorOptions->{applicationArguments};
2448
2449     # Prefix the environment variables with SIMCTL_CHILD_ per `xcrun simctl help launch`.
2450     foreach my $key (keys %simulatorENV) {
2451         $ENV{"SIMCTL_CHILD_$key"} = $simulatorENV{$key};
2452     }
2453
2454     print "Starting $appDisplayName with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2455     return exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "launch", $simulatedDeviceUDID, $appIdentifier, @$applicationArguments));
2456 }
2457
2458 sub runIOSWebKitApp($)
2459 {
2460     my ($appBundle) = @_;
2461     if (willUseIOSDeviceSDK()) {
2462         die "Only running Safari in iOS Simulator is supported now.";
2463     }
2464     if (willUseIOSSimulatorSDK()) {
2465         return runIOSWebKitAppInSimulator($appBundle);
2466     }
2467     die "Not using an iOS SDK."
2468 }
2469
2470 sub runMacWebKitApp($;$)
2471 {
2472     my ($appPath, $useOpenCommand) = @_;
2473     my $productDir = productDir();
2474     print "Starting @{[basename($appPath)]} with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2475
2476     local %ENV = %ENV;
2477     setupMacWebKitEnvironment($productDir);
2478
2479     if (defined($useOpenCommand) && $useOpenCommand == USE_OPEN_COMMAND) {
2480         return system("open", "-W", "-a", $appPath, "--args", argumentsForRunAndDebugMacWebKitApp());
2481     }
2482     if (architecture()) {
2483         return system "arch", "-" . architecture(), $appPath, argumentsForRunAndDebugMacWebKitApp();
2484     }
2485     return system { $appPath } $appPath, argumentsForRunAndDebugMacWebKitApp();
2486 }
2487
2488 sub execMacWebKitAppForDebugging($)
2489 {
2490     my ($appPath) = @_;
2491     my $architectureSwitch;
2492     my $argumentsSeparator;
2493
2494     if (debugger() eq "lldb") {
2495         $architectureSwitch = "--arch";
2496         $argumentsSeparator = "--";
2497     } elsif (debugger() eq "gdb") {
2498         $architectureSwitch = "-arch";
2499         $argumentsSeparator = "--args";
2500     } else {
2501         die "Unknown debugger $debugger.\n";
2502     }
2503
2504     my $debuggerPath = `xcrun -find $debugger`;
2505     chomp $debuggerPath;
2506     die "Can't find the $debugger executable.\n" unless -x $debuggerPath;
2507
2508     my $productDir = productDir();
2509     setupMacWebKitEnvironment($productDir);
2510
2511     my @architectureFlags = ($architectureSwitch, architecture());
2512     print "Starting @{[basename($appPath)]} under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2513     exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $appPath, argumentsForRunAndDebugMacWebKitApp() or die;
2514 }
2515
2516 sub debugSafari
2517 {
2518     if (isAppleMacWebKit()) {
2519         checkFrameworks();
2520         execMacWebKitAppForDebugging(safariPath());
2521     }
2522
2523     return 1; # Unsupported platform; can't debug Safari on this platform.
2524 }
2525
2526 sub runSafari
2527 {
2528     if (isIOSWebKit()) {
2529         return runIOSWebKitApp(mobileSafariBundle());
2530     }
2531
2532     if (isAppleMacWebKit()) {
2533         return runMacWebKitApp(safariPath());
2534     }
2535
2536     if (isAppleWinWebKit()) {
2537         my $result;
2538         my $webKitLauncherPath = File::Spec->catfile(executableProductDir(), "MiniBrowser.exe");
2539         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2540     }
2541
2542     return 1; # Unsupported platform; can't run Safari on this platform.
2543 }
2544
2545 sub runMiniBrowser
2546 {
2547     if (isAppleMacWebKit()) {
2548         return runMacWebKitApp(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2549     } elsif (isAppleWinWebKit()) {
2550         my $result;
2551         my $webKitLauncherPath = File::Spec->catfile(executableProductDir(), "MiniBrowser.exe");
2552         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2553     }
2554
2555     return 1;
2556 }
2557
2558 sub debugMiniBrowser
2559 {
2560     if (isAppleMacWebKit()) {
2561         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2562     }
2563     
2564     return 1;
2565 }
2566
2567 sub runWebKitTestRunner
2568 {
2569     if (isAppleMacWebKit()) {
2570         return runMacWebKitApp(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2571     }
2572
2573     return 1;
2574 }
2575
2576 sub debugWebKitTestRunner
2577 {
2578     if (isAppleMacWebKit()) {
2579         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2580     }
2581
2582     return 1;
2583 }
2584
2585 sub readRegistryString
2586 {
2587     my ($valueName) = @_;
2588     chomp(my $string = `regtool --wow32 get "$valueName"`);
2589     return $string;
2590 }
2591
2592 sub writeRegistryString
2593 {
2594     my ($valueName, $string) = @_;
2595
2596     my $error = system "regtool", "--wow32", "set", "-s", $valueName, $string;
2597
2598     # On Windows Vista/7 with UAC enabled, regtool will fail to modify the registry, but will still
2599     # return a successful exit code. So we double-check here that the value we tried to write to the
2600     # registry was really written.
2601     return !$error && readRegistryString($valueName) eq $string;
2602 }
2603
2604 sub formatBuildTime($)
2605 {
2606     my ($buildTime) = @_;
2607
2608     my $buildHours = int($buildTime / 3600);
2609     my $buildMins = int(($buildTime - $buildHours * 3600) / 60);
2610     my $buildSecs = $buildTime - $buildHours * 3600 - $buildMins * 60;
2611
2612     if ($buildHours) {
2613         return sprintf("%dh:%02dm:%02ds", $buildHours, $buildMins, $buildSecs);
2614     }
2615     return sprintf("%02dm:%02ds", $buildMins, $buildSecs);
2616 }
2617
2618 sub runSvnUpdateAndResolveChangeLogs(@)
2619 {
2620     my @svnOptions = @_;
2621     my $openCommand = "svn update " . join(" ", @svnOptions);
2622     open my $update, "$openCommand |" or die "cannot execute command $openCommand";
2623     my @conflictedChangeLogs;
2624     while (my $line = <$update>) {
2625         print $line;
2626         $line =~ m/^C\s+(.+?)[\r\n]*$/;
2627         if ($1) {
2628           my $filename = normalizePath($1);
2629           push @conflictedChangeLogs, $filename if basename($filename) eq "ChangeLog";
2630         }
2631     }
2632     close $update or die;
2633
2634     if (@conflictedChangeLogs) {
2635         print "Attempting to merge conflicted ChangeLogs.\n";
2636         my $resolveChangeLogsPath = File::Spec->catfile(sourceDir(), "Tools", "Scripts", "resolve-ChangeLogs");
2637         (system($resolveChangeLogsPath, "--no-warnings", @conflictedChangeLogs) == 0)
2638             or die "Could not open resolve-ChangeLogs script: $!.\n";
2639     }
2640 }
2641
2642 sub runGitUpdate()
2643 {
2644     # Doing a git fetch first allows setups with svn-remote.svn.fetch = trunk:refs/remotes/origin/master
2645     # to perform the rebase much much faster.
2646     system("git", "fetch");
2647     if (isGitSVNDirectory(".")) {
2648         system("git", "svn", "rebase") == 0 or die;
2649     } else {
2650         # This will die if branch.$BRANCHNAME.merge isn't set, which is
2651         # almost certainly what we want.
2652         system("git", "pull") == 0 or die;
2653     }
2654 }
2655
2656 1;