4f742ddfdf1a95e23b41b11f84587b76be1b9d92
[WebKit-https.git] / Tools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005, 2006, 2007, 2010, 2011, 2012, 2013 Apple Inc. All rights reserved.
2 # Copyright (C) 2009 Google Inc. All rights reserved.
3 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
4 #
5 # Redistribution and use in source and binary forms, with or without
6 # modification, are permitted provided that the following conditions
7 # are met:
8 #
9 # 1.  Redistributions of source code must retain the above copyright
10 #     notice, this list of conditions and the following disclaimer. 
11 # 2.  Redistributions in binary form must reproduce the above copyright
12 #     notice, this list of conditions and the following disclaimer in the
13 #     documentation and/or other materials provided with the distribution. 
14 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
15 #     its contributors may be used to endorse or promote products derived
16 #     from this software without specific prior written permission. 
17 #
18 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
19 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
21 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
22 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
25 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29 # Module to share code to get to WebKit directories.
30
31 use strict;
32 use version;
33 use warnings;
34 use Config;
35 use Digest::MD5 qw(md5_hex);
36 use FindBin;
37 use File::Basename;
38 use File::Path qw(mkpath rmtree);
39 use File::Spec;
40 use File::stat;
41 use POSIX;
42 use VCSUtils;
43
44 BEGIN {
45    use Exporter   ();
46    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
47    $VERSION     = 1.00;
48    @ISA         = qw(Exporter);
49    @EXPORT      = qw(
50        &XcodeOptionString
51        &XcodeOptionStringNoConfig
52        &XcodeOptions
53        &baseProductDir
54        &chdirWebKit
55        &checkFrameworks
56        &cmakeBasedPortArguments
57        &cmakeBasedPortName
58        &currentSVNRevision
59        &debugSafari
60        &nmPath
61        &passedConfiguration
62        &printHelpAndExitForRunAndDebugWebKitAppIfNeeded
63        &productDir
64        &runMacWebKitApp
65        &safariPath
66        &setConfiguration
67        USE_OPEN_COMMAND
68    );
69    %EXPORT_TAGS = ( );
70    @EXPORT_OK   = ();
71 }
72
73 use constant USE_OPEN_COMMAND => 1; # Used in runMacWebKitApp().
74 use constant INCLUDE_OPTIONS_FOR_DEBUGGING => 1;
75
76 our @EXPORT_OK;
77
78 my $architecture;
79 my $numberOfCPUs;
80 my $baseProductDir;
81 my @baseProductDirOption;
82 my $configuration;
83 my $xcodeSDK;
84 my $configurationForVisualStudio;
85 my $configurationProductDir;
86 my $sourceDir;
87 my $currentSVNRevision;
88 my $debugger;
89 my $nmPath;
90 my $osXVersion;
91 my $generateDsym;
92 my $isGtk;
93 my $isWinCE;
94 my $isWinCairo;
95 my $isWin64;
96 my $isEfl;
97 my $isBlackBerry;
98 my $isInspectorFrontend;
99 my $isWK2;
100 my $shouldTargetWebProcess;
101 my $shouldUseXPCServiceForWebProcess;
102 my $shouldUseGuardMalloc;
103 my $xcodeVersion;
104
105 # Variables for Win32 support
106 my $programFilesPath;
107 my $vcBuildPath;
108 my $vsInstallDir;
109 my $vsVersion;
110 my $windowsSourceDir;
111 my $winVersion;
112 my $willUseVCExpressWhenBuilding = 0;
113
114 # Defined in VCSUtils.
115 sub exitStatus($);
116
117 sub findMatchingArguments($$);
118 sub hasArgument($$);
119
120 sub determineSourceDir
121 {
122     return if $sourceDir;
123     $sourceDir = $FindBin::Bin;
124     $sourceDir =~ s|/+$||; # Remove trailing '/' as we would die later
125
126     # walks up path checking each directory to see if it is the main WebKit project dir, 
127     # defined by containing Sources, WebCore, and WebKit
128     until ((-d "$sourceDir/Source" && -d "$sourceDir/Source/WebCore" && -d "$sourceDir/Source/WebKit") || (-d "$sourceDir/Internal" && -d "$sourceDir/OpenSource"))
129     {
130         if ($sourceDir !~ s|/[^/]+$||) {
131             die "Could not find top level webkit directory above source directory using FindBin.\n";
132         }
133     }
134
135     $sourceDir = "$sourceDir/OpenSource" if -d "$sourceDir/OpenSource";
136 }
137
138 sub currentPerlPath()
139 {
140     my $thisPerl = $^X;
141     if ($^O ne 'VMS') {
142         $thisPerl .= $Config{_exe} unless $thisPerl =~ m/$Config{_exe}$/i;
143     }
144     return $thisPerl;
145 }
146
147 # used for scripts which are stored in a non-standard location
148 sub setSourceDir($)
149 {
150     ($sourceDir) = @_;
151 }
152
153 sub determineXcodeVersion
154 {
155     return if defined $xcodeVersion;
156     my $xcodebuildVersionOutput = `xcodebuild -version`;
157     $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : "3.0";
158 }
159
160 sub readXcodeUserDefault($)
161 {
162     my ($unprefixedKey) = @_;
163
164     determineXcodeVersion();
165
166     my $xcodeDefaultsDomain = (eval "v$xcodeVersion" lt v4) ? "com.apple.Xcode" : "com.apple.dt.Xcode";
167     my $xcodeDefaultsPrefix = (eval "v$xcodeVersion" lt v4) ? "PBX" : "IDE";
168     my $devnull = File::Spec->devnull();
169
170     my $value = `defaults read $xcodeDefaultsDomain ${xcodeDefaultsPrefix}${unprefixedKey} 2> ${devnull}`;
171     return if $?;
172
173     chomp $value;
174     return $value;
175 }
176
177 sub determineBaseProductDir
178 {
179     return if defined $baseProductDir;
180     determineSourceDir();
181
182     my $setSharedPrecompsDir;
183     $baseProductDir = $ENV{"WEBKIT_OUTPUTDIR"};
184
185     if (!defined($baseProductDir) and isAppleMacWebKit()) {
186         # Silently remove ~/Library/Preferences/xcodebuild.plist which can
187         # cause build failure. The presence of
188         # ~/Library/Preferences/xcodebuild.plist can prevent xcodebuild from
189         # respecting global settings such as a custom build products directory
190         # (<rdar://problem/5585899>).
191         my $personalPlistFile = $ENV{HOME} . "/Library/Preferences/xcodebuild.plist";
192         if (-e $personalPlistFile) {
193             unlink($personalPlistFile) || die "Could not delete $personalPlistFile: $!";
194         }
195
196         determineXcodeVersion();
197
198         if (eval "v$xcodeVersion" ge v4) {
199             my $buildLocationStyle = join '', readXcodeUserDefault("BuildLocationStyle");
200             if ($buildLocationStyle eq "Custom") {
201                 my $buildLocationType = join '', readXcodeUserDefault("CustomBuildLocationType");
202                 # FIXME: Read CustomBuildIntermediatesPath and set OBJROOT accordingly.
203                 $baseProductDir = readXcodeUserDefault("CustomBuildProductsPath") if $buildLocationType eq "Absolute";
204             }
205
206             # DeterminedByTargets corresponds to a setting of "Legacy" in Xcode.
207             # It is the only build location style for which SHARED_PRECOMPS_DIR is not
208             # overridden when building from within Xcode.
209             $setSharedPrecompsDir = 1 if $buildLocationStyle ne "DeterminedByTargets";
210         }
211
212         if (!defined($baseProductDir)) {
213             $baseProductDir = join '', readXcodeUserDefault("ApplicationwideBuildSettings");
214             $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
215         }
216
217         undef $baseProductDir unless $baseProductDir =~ /^\//;
218     }
219
220     if (!defined($baseProductDir)) { # Port-specific checks failed, use default
221         $baseProductDir = "$sourceDir/WebKitBuild";
222     }
223
224     if (isBlackBerry()) {
225         my %archInfo = blackberryTargetArchitecture();
226         $baseProductDir = "$baseProductDir/" . $archInfo{"cpuDir"};
227     }
228
229     if (isGit() && isGitBranchBuild()) {
230         my $branch = gitBranch();
231         $baseProductDir = "$baseProductDir/$branch";
232     }
233
234     if (isAppleMacWebKit()) {
235         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
236         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
237         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
238         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
239         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
240         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir");
241         push(@baseProductDirOption, "SHARED_PRECOMPS_DIR=${baseProductDir}/PrecompiledHeaders") if $setSharedPrecompsDir;
242     }
243
244     if (isCygwin()) {
245         my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
246         chomp $dosBuildPath;
247         $ENV{"WEBKIT_OUTPUTDIR"} = $dosBuildPath;
248         my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
249         chomp $unixBuildPath;
250         $baseProductDir = $unixBuildPath;
251     }
252 }
253
254 sub setBaseProductDir($)
255 {
256     ($baseProductDir) = @_;
257 }
258
259 sub determineConfiguration
260 {
261     return if defined $configuration;
262     determineBaseProductDir();
263     if (open CONFIGURATION, "$baseProductDir/Configuration") {
264         $configuration = <CONFIGURATION>;
265         close CONFIGURATION;
266     }
267     if ($configuration) {
268         chomp $configuration;
269         # compatibility for people who have old Configuration files
270         $configuration = "Release" if $configuration eq "Deployment";
271         $configuration = "Debug" if $configuration eq "Development";
272     } else {
273         $configuration = "Release";
274     }
275
276     if ($configuration && isWinCairo()) {
277         unless ($configuration =~ /_WinCairo$/) {
278             $configuration .= "_WinCairo";
279         }
280     }
281 }
282
283 sub determineArchitecture
284 {
285     return if defined $architecture;
286     # make sure $architecture is defined in all cases
287     $architecture = "";
288
289     determineBaseProductDir();
290     determineXcodeSDK();
291
292     if (isGtk()) {
293         determineConfigurationProductDir();
294         my $host_triple = `grep -E '^host = ' $configurationProductDir/GNUmakefile 2> /dev/null`;
295         if ($host_triple =~ m/^host = ([^-]+)-/) {
296             # We have a configured build tree; use it.
297             $architecture = $1;
298         }
299     } elsif (isAppleMacWebKit()) {
300         if (open ARCHITECTURE, "$baseProductDir/Architecture") {
301             $architecture = <ARCHITECTURE>;
302             close ARCHITECTURE;
303         }
304         if ($architecture) {
305             chomp $architecture;
306         } else {
307             if (not defined $xcodeSDK or $xcodeSDK =~ /^(\/$|macosx)/) {
308                 my $supports64Bit = `sysctl -n hw.optional.x86_64`;
309                 chomp $supports64Bit;
310                 $architecture = 'x86_64' if $supports64Bit;
311             } elsif ($xcodeSDK =~ /^iphonesimulator/) {
312                 $architecture = 'i386';
313             } elsif ($xcodeSDK =~ /^iphoneos/) {
314                 $architecture = 'armv7';
315             }
316         }
317     } elsif (isEfl()) {
318         my $host_processor = "";
319         $host_processor = `cmake --system-information | grep CMAKE_SYSTEM_PROCESSOR`;
320         if ($host_processor =~ m/^CMAKE_SYSTEM_PROCESSOR \"([^"]+)\"/) {
321             # We have a configured build tree; use it.
322             $architecture = $1;
323             $architecture = 'x86_64' if $architecture eq 'amd64';
324         }
325     }
326
327     if (!$architecture && (isGtk() || isAppleMacWebKit() || isEfl())) {
328         # Fall back to output of `arch', if it is present.
329         $architecture = `arch`;
330         chomp $architecture;
331     }
332
333     if (!$architecture && (isGtk() || isAppleMacWebKit() || isEfl())) {
334         # Fall back to output of `uname -m', if it is present.
335         $architecture = `uname -m`;
336         chomp $architecture;
337     }
338 }
339
340 sub determineNumberOfCPUs
341 {
342     return if defined $numberOfCPUs;
343     if (defined($ENV{NUMBER_OF_PROCESSORS})) {
344         $numberOfCPUs = $ENV{NUMBER_OF_PROCESSORS};
345     } elsif (isLinux()) {
346         # First try the nproc utility, if it exists. If we get no
347         # results fall back to just interpretting /proc directly.
348         chomp($numberOfCPUs = `nproc --all 2> /dev/null`);
349         if ($numberOfCPUs eq "") {
350             $numberOfCPUs = (grep /processor/, `cat /proc/cpuinfo`);
351         }
352     } elsif (isWindows() || isCygwin()) {
353         # Assumes cygwin
354         $numberOfCPUs = `ls /proc/registry/HKEY_LOCAL_MACHINE/HARDWARE/DESCRIPTION/System/CentralProcessor | wc -w`;
355     } elsif (isDarwin() || isFreeBSD()) {
356         chomp($numberOfCPUs = `sysctl -n hw.ncpu`);
357     }
358 }
359
360 sub jscPath($)
361 {
362     my ($productDir) = @_;
363     my $jscName = "jsc";
364     $jscName .= "_debug"  if configuration() eq "Debug_All";
365     $jscName .= ".exe" if (isWindows() || isCygwin());
366     return "$productDir/$jscName" if -e "$productDir/$jscName";
367     return "$productDir/JavaScriptCore.framework/Resources/$jscName";
368 }
369
370 sub argumentsForConfiguration()
371 {
372     determineConfiguration();
373     determineArchitecture();
374
375     my @args = ();
376     push(@args, '--debug') if ($configuration =~ "^Debug");
377     push(@args, '--release') if ($configuration =~ "^Release");
378     push(@args, '--32-bit') if ($architecture ne "x86_64" and !isWin64());
379     push(@args, '--64-bit') if (isWin64());
380     push(@args, '--gtk') if isGtk();
381     push(@args, '--efl') if isEfl();
382     push(@args, '--wincairo') if isWinCairo();
383     push(@args, '--wince') if isWinCE();
384     push(@args, '--blackberry') if isBlackBerry();
385     push(@args, '--inspector-frontend') if isInspectorFrontend();
386     return @args;
387 }
388
389 sub determineXcodeSDK
390 {
391     return if defined $xcodeSDK;
392     my $sdk;
393     if (checkForArgumentAndRemoveFromARGVGettingValue("--sdk", \$sdk)) {
394         $xcodeSDK = $sdk;
395     } elsif (checkForArgumentAndRemoveFromARGV("--device")) {
396         $xcodeSDK = 'iphoneos.internal';
397     } elsif (checkForArgumentAndRemoveFromARGV("--sim") ||
398         checkForArgumentAndRemoveFromARGV("--simulator")) {
399         $xcodeSDK = 'iphonesimulator';
400     }
401 }
402
403 sub xcodeSDK
404 {
405     determineXcodeSDK();
406     return $xcodeSDK;
407 }
408
409 sub xcodeSDKPlatformName()
410 {
411     determineXcodeSDK();
412     return "" if !defined $xcodeSDK;
413     return "iphoneos" if $xcodeSDK =~ /iphoneos/i;
414     return "iphonesimulator" if $xcodeSDK =~ /iphonesimulator/i;
415     return "macosx" if $xcodeSDK =~ /macosx/i;
416     die "Couldn't determine platform name from Xcode SDK";
417 }
418
419 sub programFilesPath
420 {
421     return $programFilesPath if defined $programFilesPath;
422
423     $programFilesPath = $ENV{'PROGRAMFILES(X86)'} || $ENV{'PROGRAMFILES'} || "C:\\Program Files";
424
425     return $programFilesPath;
426 }
427
428 sub visualStudioInstallDir
429 {
430     return $vsInstallDir if defined $vsInstallDir;
431
432     if ($ENV{'VSINSTALLDIR'}) {
433         $vsInstallDir = $ENV{'VSINSTALLDIR'};
434         $vsInstallDir =~ s|[\\/]$||;
435     } else {
436         $vsInstallDir = File::Spec->catdir(programFilesPath(), "Microsoft Visual Studio 10.0");
437     }
438     chomp($vsInstallDir = `cygpath "$vsInstallDir"`) if isCygwin();
439
440     return $vsInstallDir;
441 }
442
443 sub visualStudioVersion
444 {
445     return $vsVersion if defined $vsVersion;
446
447     my $installDir = visualStudioInstallDir();
448
449     $vsVersion = ($installDir =~ /Microsoft Visual Studio ([0-9]+\.[0-9]*)/) ? $1 : "8";
450
451     return $vsVersion;
452 }
453
454 sub determineConfigurationForVisualStudio
455 {
456     return if defined $configurationForVisualStudio;
457     determineConfiguration();
458     # FIXME: We should detect when Debug_All or Production has been chosen.
459     $configurationForVisualStudio = $configuration . (isWin64() ? "|x64" : "|Win32");
460 }
461
462 sub usesPerConfigurationBuildDirectory
463 {
464     # [Gtk] We don't have Release/Debug configurations in straight
465     # autotool builds (non build-webkit). In this case and if
466     # WEBKIT_OUTPUTDIR exist, use that as our configuration dir. This will
467     # allows us to run run-webkit-tests without using build-webkit.
468     return ($ENV{"WEBKIT_OUTPUTDIR"} && isGtk()) || isAppleWinWebKit();
469 }
470
471 sub determineConfigurationProductDir
472 {
473     return if defined $configurationProductDir;
474     determineBaseProductDir();
475     determineConfiguration();
476     if (isAppleWinWebKit() || isWinCairo()) {
477         my $binDir = isWin64() ? "bin64" : "bin32";
478         $configurationProductDir = File::Spec->catdir($baseProductDir, $configuration, $binDir);
479     } else {
480         if (usesPerConfigurationBuildDirectory()) {
481             $configurationProductDir = "$baseProductDir";
482         } else {
483             $configurationProductDir = "$baseProductDir/$configuration";
484             $configurationProductDir .= "-" . xcodeSDKPlatformName() if isIOSWebKit();
485         }
486     }
487 }
488
489 sub setConfigurationProductDir($)
490 {
491     ($configurationProductDir) = @_;
492 }
493
494 sub determineCurrentSVNRevision
495 {
496     # We always update the current SVN revision here, and leave the caching
497     # to currentSVNRevision(), so that changes to the SVN revision while the
498     # script is running can be picked up by calling this function again.
499     determineSourceDir();
500     $currentSVNRevision = svnRevisionForDirectory($sourceDir);
501     return $currentSVNRevision;
502 }
503
504
505 sub chdirWebKit
506 {
507     determineSourceDir();
508     chdir $sourceDir or die;
509 }
510
511 sub baseProductDir
512 {
513     determineBaseProductDir();
514     return $baseProductDir;
515 }
516
517 sub sourceDir
518 {
519     determineSourceDir();
520     return $sourceDir;
521 }
522
523 sub productDir
524 {
525     determineConfigurationProductDir();
526     return $configurationProductDir;
527 }
528
529 sub jscProductDir
530 {
531     my $productDir = productDir();
532     $productDir .= "/bin" if isEfl();
533     $productDir .= "/Programs" if isGtk();
534
535     return $productDir;
536 }
537
538 sub configuration()
539 {
540     determineConfiguration();
541     return $configuration;
542 }
543
544 sub configurationForVisualStudio()
545 {
546     determineConfigurationForVisualStudio();
547     return $configurationForVisualStudio;
548 }
549
550 sub currentSVNRevision
551 {
552     determineCurrentSVNRevision() if not defined $currentSVNRevision;
553     return $currentSVNRevision;
554 }
555
556 sub generateDsym()
557 {
558     determineGenerateDsym();
559     return $generateDsym;
560 }
561
562 sub determineGenerateDsym()
563 {
564     return if defined($generateDsym);
565     $generateDsym = checkForArgumentAndRemoveFromARGV("--dsym");
566 }
567
568 sub argumentsForXcode()
569 {
570     my @args = ();
571     push @args, "DEBUG_INFORMATION_FORMAT=dwarf-with-dsym" if generateDsym();
572     return @args;
573 }
574
575 sub XcodeOptions
576 {
577     determineBaseProductDir();
578     determineConfiguration();
579     determineArchitecture();
580     determineXcodeSDK();
581
582     my @sdkOption = ($xcodeSDK ? "SDKROOT=$xcodeSDK" : ());
583     my @architectureOption = ($architecture ? "ARCHS=$architecture" : ());
584
585     return (@baseProductDirOption, "-configuration", $configuration, @architectureOption, @sdkOption, argumentsForXcode());
586 }
587
588 sub XcodeOptionString
589 {
590     return join " ", XcodeOptions();
591 }
592
593 sub XcodeOptionStringNoConfig
594 {
595     return join " ", @baseProductDirOption;
596 }
597
598 sub XcodeCoverageSupportOptions()
599 {
600     my @coverageSupportOptions = ();
601     push @coverageSupportOptions, "GCC_GENERATE_TEST_COVERAGE_FILES=YES";
602     push @coverageSupportOptions, "GCC_INSTRUMENT_PROGRAM_FLOW_ARCS=YES";
603     return @coverageSupportOptions;
604 }
605
606 my $passedConfiguration;
607 my $searchedForPassedConfiguration;
608 sub determinePassedConfiguration
609 {
610     return if $searchedForPassedConfiguration;
611     $searchedForPassedConfiguration = 1;
612     $passedConfiguration = undef;
613
614     if (checkForArgumentAndRemoveFromARGV("--debug")) {
615         $passedConfiguration = "Debug";
616     } elsif(checkForArgumentAndRemoveFromARGV("--release")) {
617         $passedConfiguration = "Release";
618     } elsif (checkForArgumentAndRemoveFromARGV("--profile") || checkForArgumentAndRemoveFromARGV("--profiling")) {
619         $passedConfiguration = "Profiling";
620     }
621
622     $passedConfiguration .= "_WinCairo" if (defined($passedConfiguration) && isWinCairo() && isCygwin());
623 }
624
625 sub passedConfiguration
626 {
627     determinePassedConfiguration();
628     return $passedConfiguration;
629 }
630
631 sub setConfiguration
632 {
633     setArchitecture();
634
635     if (my $config = shift @_) {
636         $configuration = $config;
637         return;
638     }
639
640     determinePassedConfiguration();
641     $configuration = $passedConfiguration if $passedConfiguration;
642 }
643
644
645 my $passedArchitecture;
646 my $searchedForPassedArchitecture;
647 sub determinePassedArchitecture
648 {
649     return if $searchedForPassedArchitecture;
650     $searchedForPassedArchitecture = 1;
651
652     $passedArchitecture = undef;
653     if (checkForArgumentAndRemoveFromARGV("--32-bit")) {
654         if (isAppleMacWebKit()) {
655             $passedArchitecture = `arch`;
656             chomp $passedArchitecture;
657         }
658     }
659 }
660
661 sub passedArchitecture
662 {
663     determinePassedArchitecture();
664     return $passedArchitecture;
665 }
666
667 sub architecture()
668 {
669     determineArchitecture();
670     return $architecture;
671 }
672
673 sub numberOfCPUs()
674 {
675     determineNumberOfCPUs();
676     return $numberOfCPUs;
677 }
678
679 sub setArchitecture
680 {
681     if (my $arch = shift @_) {
682         $architecture = $arch;
683         return;
684     }
685
686     determinePassedArchitecture();
687     $architecture = $passedArchitecture if $passedArchitecture;
688 }
689
690 sub skipSafariExecutableEntitlementChecks
691 {
692     return `defaults read /Library/Preferences/org.webkit.BuildConfiguration SkipSafariExecutableEntitlementChecks 2>/dev/null` eq "1\n";
693 }
694
695 sub executableHasEntitlements
696 {
697     my $executablePath = shift;
698     return (`codesign -d --entitlements - $executablePath 2>&1` =~ /<key>/);
699 }
700
701 sub safariPathFromSafariBundle
702 {
703     my ($safariBundle) = @_;
704
705     if (isAppleMacWebKit()) {
706         my $safariPath = "$safariBundle/Contents/MacOS/Safari";
707         return $safariPath if skipSafariExecutableEntitlementChecks();
708
709         my $safariForWebKitDevelopmentPath = "$safariBundle/Contents/MacOS/SafariForWebKitDevelopment";
710         return $safariForWebKitDevelopmentPath if -f $safariForWebKitDevelopmentPath && executableHasEntitlements($safariPath);
711
712         return $safariPath;
713     }
714     return $safariBundle if isAppleWinWebKit();
715 }
716
717 sub installedSafariPath
718 {
719     my $safariBundle;
720
721     if (isAppleMacWebKit()) {
722         $safariBundle = "/Applications/Safari.app";
723     } elsif (isAppleWinWebKit()) {
724         $safariBundle = readRegistryString("/HKLM/SOFTWARE/Apple Computer, Inc./Safari/InstallDir");
725         $safariBundle =~ s/[\r\n]+$//;
726         $safariBundle = `cygpath -u '$safariBundle'` if isCygwin();
727         $safariBundle =~ s/[\r\n]+$//;
728         $safariBundle .= "Safari.exe";
729     }
730
731     return safariPathFromSafariBundle($safariBundle);
732 }
733
734 # Locate Safari.
735 sub safariPath
736 {
737     # Use WEBKIT_SAFARI environment variable if present.
738     my $safariBundle = $ENV{WEBKIT_SAFARI};
739     if (!$safariBundle) {
740         determineConfigurationProductDir();
741         # Use Safari.app in product directory if present (good for Safari development team).
742         if (isAppleMacWebKit() && -d "$configurationProductDir/Safari.app") {
743             $safariBundle = "$configurationProductDir/Safari.app";
744         } elsif (isAppleWinWebKit()) {
745             my $path = "$configurationProductDir/Safari.exe";
746             my $debugPath = "$configurationProductDir/Safari_debug.exe";
747
748             if (configuration() eq "Debug_All" && -x $debugPath) {
749                 $safariBundle = $debugPath;
750             } elsif (-x $path) {
751                 $safariBundle = $path;
752             }
753         }
754         if (!$safariBundle) {
755             return installedSafariPath();
756         }
757     }
758     my $safariPath = safariPathFromSafariBundle($safariBundle);
759     die "Can't find executable at $safariPath.\n" if isAppleMacWebKit() && !-x $safariPath;
760     return $safariPath;
761 }
762
763 sub builtDylibPathForName
764 {
765     my $libraryName = shift;
766     determineConfigurationProductDir();
767
768     if (isBlackBerry()) {
769         my $libraryExtension = $libraryName =~ /^WebKit$/i ? ".so" : ".a";
770         return "$configurationProductDir/$libraryName/lib" . lc($libraryName) . $libraryExtension;
771     }
772     if (isGtk()) {
773         # WebKitGTK+ for GTK2, WebKitGTK+ for GTK3, and WebKit2 respectively.
774         my @libraries = ("libwebkitgtk-1.0", "libwebkitgtk-3.0", "libwebkit2gtk-3.0");
775         my $extension = isDarwin() ? ".dylib" : ".so";
776
777         foreach $libraryName (@libraries) {
778             my $libraryPath = "$configurationProductDir/.libs/" . $libraryName . $extension;
779             return $libraryPath if -e $libraryPath;
780         }
781         return "NotFound";
782     }
783     if (isEfl()) {
784         if (isWK2()) {
785             return "$configurationProductDir/lib/libewebkit2.so";
786         }
787         return "$configurationProductDir/lib/libewebkit.so";
788     }
789     if (isWinCE()) {
790         return "$configurationProductDir/$libraryName";
791     }
792     if (isIOSWebKit()) {
793         return "$configurationProductDir/$libraryName.framework/$libraryName";
794     }
795     if (isAppleMacWebKit()) {
796         return "$configurationProductDir/$libraryName.framework/Versions/A/$libraryName";
797     }
798     if (isAppleWinWebKit()) {
799         if ($libraryName eq "JavaScriptCore") {
800             return "$baseProductDir/lib/$libraryName.lib";
801         } else {
802             return "$baseProductDir/$libraryName.intermediate/$configuration/$libraryName.intermediate/$libraryName.lib";
803         }
804     }
805
806     die "Unsupported platform, can't determine built library locations.\nTry `build-webkit --help` for more information.\n";
807 }
808
809 # Check to see that all the frameworks are built.
810 sub checkFrameworks # FIXME: This is a poor name since only the Mac calls built WebCore a Framework.
811 {
812     return if isCygwin() || isWindows();
813     my @frameworks = ("JavaScriptCore", "WebCore");
814     push(@frameworks, "WebKit") if isAppleMacWebKit(); # FIXME: This seems wrong, all ports should have a WebKit these days.
815     for my $framework (@frameworks) {
816         my $path = builtDylibPathForName($framework);
817         die "Can't find built framework at \"$path\".\n" unless -e $path;
818     }
819 }
820
821 sub isInspectorFrontend()
822 {
823     determineIsInspectorFrontend();
824     return $isInspectorFrontend;
825 }
826
827 sub determineIsInspectorFrontend()
828 {
829     return if defined($isInspectorFrontend);
830     $isInspectorFrontend = checkForArgumentAndRemoveFromARGV("--inspector-frontend");
831 }
832
833 sub commandExists($)
834 {
835     my $command = shift;
836     my $devnull = File::Spec->devnull();
837     return `$command --version 2> $devnull`;
838 }
839
840 sub checkForArgumentAndRemoveFromARGV($)
841 {
842     my $argToCheck = shift;
843     return checkForArgumentAndRemoveFromArrayRef($argToCheck, \@ARGV);
844 }
845
846 sub checkForArgumentAndRemoveFromARGVGettingValue($$)
847 {
848     my ($argToCheck, $valueRef) = @_;
849     my @matchingIndices = findMatchingArguments($argToCheck, \@ARGV);
850     return 0 if ($#matchingIndices != 1);
851     splice(@ARGV, $matchingIndices[0], 1);
852     return $$valueRef = splice(@ARGV, $matchingIndices[0], 1);
853 }
854
855 sub findMatchingArguments($$)
856 {
857     my ($argToCheck, $arrayRef) = @_;
858     my @matchingIndices;
859     foreach my $index (0 .. $#$arrayRef) {
860         my $opt = $$arrayRef[$index];
861         if ($opt =~ /^$argToCheck$/i ) {
862             push(@matchingIndices, $index);
863         }
864     }
865     return @matchingIndices; 
866 }
867
868 sub hasArgument($$)
869 {
870     my ($argToCheck, $arrayRef) = @_;
871     my @matchingIndices = findMatchingArguments($argToCheck, $arrayRef);
872     return scalar @matchingIndices > 0;
873 }
874
875 sub checkForArgumentAndRemoveFromArrayRef
876 {
877     my ($argToCheck, $arrayRef) = @_;
878     my @indicesToRemove = findMatchingArguments($argToCheck, $arrayRef);
879     my $removeOffset = 0;
880     foreach my $index (@indicesToRemove) {
881         splice(@$arrayRef, $index - $removeOffset++, 1);
882     }
883     return scalar @indicesToRemove > 0;
884 }
885
886 sub isWK2()
887 {
888     if (defined($isWK2)) {
889         return $isWK2;
890     }
891     if (checkForArgumentAndRemoveFromARGV("-2")) {
892         $isWK2 = 1;
893     } else {
894         $isWK2 = 0;
895     }
896     return $isWK2;
897 }
898
899 sub isBlackBerry()
900 {
901     determineIsBlackBerry();
902     return $isBlackBerry;
903 }
904
905 sub determineIsBlackBerry()
906 {
907     return if defined($isBlackBerry);
908     $isBlackBerry = checkForArgumentAndRemoveFromARGV("--blackberry");
909 }
910
911 sub blackberryTargetArchitecture()
912 {
913     my $arch = $ENV{"BLACKBERRY_ARCH_TYPE"} ? $ENV{"BLACKBERRY_ARCH_TYPE"} : "arm";
914     my $cpu = $ENV{"BLACKBERRY_ARCH_CPU"} ? $ENV{"BLACKBERRY_ARCH_CPU"} : "";
915     my $cpuDir;
916     my $buSuffix;
917     if (($cpu eq "v7le") || ($cpu eq "a9")) {
918         $cpuDir = $arch . "le-v7";
919         $buSuffix = $arch . "v7";
920     } else {
921         $cpu = $arch;
922         $cpuDir = $arch;
923         $buSuffix = $arch;
924     }
925     return ("arch" => $arch,
926             "cpu" => $cpu,
927             "cpuDir" => $cpuDir,
928             "buSuffix" => $buSuffix);
929 }
930
931 sub blackberryCMakeArguments()
932 {
933     my %archInfo = blackberryTargetArchitecture();
934     my $arch = $archInfo{"arch"};
935     my $cpu = $archInfo{"cpu"};
936     my $cpuDir = $archInfo{"cpuDir"};
937     my $buSuffix = $archInfo{"buSuffix"};
938
939     my @cmakeExtraOptions;
940     if ($cpu eq "a9") {
941         $cpu = $arch . "v7le";
942         push @cmakeExtraOptions, '-DTARGETING_PLAYBOOK=1';
943     }
944
945     my $stageDir = $ENV{"STAGE_DIR"};
946     my $stageLib = File::Spec->catdir($stageDir, $cpuDir, "lib");
947     my $stageUsrLib = File::Spec->catdir($stageDir, $cpuDir, "usr", "lib");
948     my $stageInc = File::Spec->catdir($stageDir, "usr", "include");
949
950     my $qnxHost = $ENV{"QNX_HOST"};
951     my $ccCommand;
952     my $cxxCommand;
953     if ($ENV{"USE_ICECC"}) {
954         chomp($ccCommand = `which icecc`);
955         $cxxCommand = $ccCommand;
956     } else {
957         $ccCommand = File::Spec->catfile($qnxHost, "usr", "bin", "qcc");
958         $cxxCommand = $ccCommand;
959     }
960
961     if ($ENV{"CCWRAP"}) {
962         $ccCommand = $ENV{"CCWRAP"};
963         push @cmakeExtraOptions, "-DCMAKE_C_COMPILER_ARG1=qcc";
964         push @cmakeExtraOptions, "-DCMAKE_CXX_COMPILER_ARG1=qcc";
965     }
966
967     push @cmakeExtraOptions, "-DCMAKE_SKIP_RPATH='ON'" if isDarwin();
968     push @cmakeExtraOptions, "-DPUBLIC_BUILD=1" if $ENV{"PUBLIC_BUILD"};
969     push @cmakeExtraOptions, "-DENABLE_GLES2=1" unless $ENV{"DISABLE_GLES2"};
970
971     my @includeSystemDirectories;
972     push @includeSystemDirectories, File::Spec->catdir($stageInc, "harfbuzzng");
973     push @includeSystemDirectories, File::Spec->catdir($stageInc, "imf");
974     # We only use jpeg-turbo for device build
975     push @includeSystemDirectories, File::Spec->catdir($stageInc, "jpeg-turbo") if $arch=~/arm/;
976     push @includeSystemDirectories, $stageInc;
977     push @includeSystemDirectories, File::Spec->catdir($stageInc, "browser", "platform");
978     push @includeSystemDirectories, File::Spec->catdir($stageInc, "browser", "platform", "graphics");
979     push @includeSystemDirectories, File::Spec->catdir($stageInc, "browser", "qsk");
980     push @includeSystemDirectories, File::Spec->catdir($stageInc, "ots");
981     push @includeSystemDirectories, File::Spec->catdir($stageInc, "iType", "common");
982     push @includeSystemDirectories, File::Spec->catdir($stageInc, "iType", "port", "nto");
983
984     my @cxxFlags;
985     push @cxxFlags, "-Wl,-rpath-link,$stageLib";
986     push @cxxFlags, "-Wl,-rpath-link," . File::Spec->catfile($stageUsrLib, "torch-webkit");
987     push @cxxFlags, "-Wl,-rpath-link,$stageUsrLib";
988     push @cxxFlags, "-L$stageLib";
989     push @cxxFlags, "-L$stageUsrLib";
990
991     if ($ENV{"PROFILE"}) {
992         push @cmakeExtraOptions, "-DPROFILING=1";
993         push @cxxFlags, "-p";
994     }
995
996     my @cmakeArgs;
997     push @cmakeArgs, '-DCMAKE_SYSTEM_NAME="QNX"';
998     push @cmakeArgs, "-DCMAKE_SYSTEM_PROCESSOR=\"$cpuDir\"";
999     push @cmakeArgs, '-DCMAKE_SYSTEM_VERSION="1"';
1000     push @cmakeArgs, "-DCMAKE_C_COMPILER=\"$ccCommand\"";
1001     push @cmakeArgs, "-DCMAKE_CXX_COMPILER=\"$cxxCommand\"";
1002     push @cmakeArgs, "-DCMAKE_C_FLAGS=\"-Vgcc_nto${cpu} -g @cxxFlags\"";
1003     push @cmakeArgs, "-DCMAKE_CXX_FLAGS=\"-Vgcc_nto${cpu}_cpp-ne -g -lang-c++ @cxxFlags\"";
1004
1005     # We cannot use CMAKE_INCLUDE_PATH since this describes the search path for header files in user directories.
1006     # And the QNX system headers are in user directories on the host OS (i.e. they aren't installed in the host OS's
1007     # system header search path). So, we need to inform g++ that these user directories (@includeSystemDirectories)
1008     # are to be taken as the host OS's system header directories when building our port.
1009     #
1010     # Also, we cannot use CMAKE_SYSTEM_INCLUDE_PATH since that will override the entire system header path.
1011     # So, we define the additional system include paths in ADDITIONAL_SYSTEM_INCLUDE_PATH. This list will
1012     # be processed in OptionsBlackBerry.cmake.
1013     push @cmakeArgs, '-DADDITIONAL_SYSTEM_INCLUDE_PATH="' . join(';', @includeSystemDirectories) . '"';
1014
1015     # FIXME: Make this more general purpose such that we can pass a list of directories and files.
1016     push @cmakeArgs, '-DTHIRD_PARTY_ICU_DIR="' . File::Spec->catdir($stageInc, "unicode") . '"';
1017     push @cmakeArgs, '-DTHIRD_PARTY_UNICODE_FILE="' . File::Spec->catfile($stageInc, "unicode.h") . '"';
1018
1019     push @cmakeArgs, "-DCMAKE_LIBRARY_PATH=\"$stageLib;$stageUsrLib\"";
1020     push @cmakeArgs, '-DCMAKE_AR="' . File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ar") . '"';
1021     push @cmakeArgs, '-DCMAKE_RANLIB="' . File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ranlib") . '"';
1022     push @cmakeArgs, '-DCMAKE_LD="'. File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ld") . '"';
1023     push @cmakeArgs, '-DCMAKE_LINKER="' . File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ld") . '"';
1024     push @cmakeArgs, "-DECLIPSE_CDT4_GENERATE_SOURCE_PROJECT=TRUE";
1025     push @cmakeArgs, '-G"Eclipse CDT4 - Unix Makefiles"';
1026     push @cmakeArgs, @cmakeExtraOptions;
1027     return @cmakeArgs;
1028 }
1029
1030 sub determineIsEfl()
1031 {
1032     return if defined($isEfl);
1033     $isEfl = checkForArgumentAndRemoveFromARGV("--efl");
1034 }
1035
1036 sub isEfl()
1037 {
1038     determineIsEfl();
1039     return $isEfl;
1040 }
1041
1042 sub isGtk()
1043 {
1044     determineIsGtk();
1045     return $isGtk;
1046 }
1047
1048 sub determineIsGtk()
1049 {
1050     return if defined($isGtk);
1051     $isGtk = checkForArgumentAndRemoveFromARGV("--gtk");
1052 }
1053
1054 sub isWinCE()
1055 {
1056     determineIsWinCE();
1057     return $isWinCE;
1058 }
1059
1060 sub determineIsWinCE()
1061 {
1062     return if defined($isWinCE);
1063     $isWinCE = checkForArgumentAndRemoveFromARGV("--wince");
1064 }
1065
1066 # Determine if this is debian, ubuntu, linspire, or something similar.
1067 sub isDebianBased()
1068 {
1069     return -e "/etc/debian_version";
1070 }
1071
1072 sub isFedoraBased()
1073 {
1074     return -e "/etc/fedora-release";
1075 }
1076
1077 sub isWinCairo()
1078 {
1079     determineIsWinCairo();
1080     return $isWinCairo;
1081 }
1082
1083 sub determineIsWinCairo()
1084 {
1085     return if defined($isWinCairo);
1086     $isWinCairo = checkForArgumentAndRemoveFromARGV("--wincairo");
1087 }
1088
1089 sub isWin64()
1090 {
1091     determineIsWin64();
1092     return $isWin64;
1093 }
1094
1095 sub determineIsWin64()
1096 {
1097     return if defined($isWin64);
1098     $isWin64 = checkForArgumentAndRemoveFromARGV("--64-bit");
1099 }
1100
1101 sub isCygwin()
1102 {
1103     return ($^O eq "cygwin") || 0;
1104 }
1105
1106 sub isAnyWindows()
1107 {
1108     return isWindows() || isCygwin();
1109 }
1110
1111 sub determineWinVersion()
1112 {
1113     return if $winVersion;
1114
1115     if (!isAnyWindows()) {
1116         $winVersion = -1;
1117         return;
1118     }
1119
1120     my $versionString = `cmd /c ver`;
1121     $versionString =~ /(\d)\.(\d)\.(\d+)/;
1122
1123     $winVersion = {
1124         major => $1,
1125         minor => $2,
1126         build => $3,
1127     };
1128 }
1129
1130 sub winVersion()
1131 {
1132     determineWinVersion();
1133     return $winVersion;
1134 }
1135
1136 sub isWindows7SP0()
1137 {
1138     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 1 && winVersion()->{build} == 7600;
1139 }
1140
1141 sub isWindowsVista()
1142 {
1143     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 0;
1144 }
1145
1146 sub isWindowsXP()
1147 {
1148     return isAnyWindows() && winVersion()->{major} == 5 && winVersion()->{minor} == 1;
1149 }
1150
1151 sub isDarwin()
1152 {
1153     return ($^O eq "darwin") || 0;
1154 }
1155
1156 sub isWindows()
1157 {
1158     return ($^O eq "MSWin32") || 0;
1159 }
1160
1161 sub isLinux()
1162 {
1163     return ($^O eq "linux") || 0;
1164 }
1165
1166 sub isFreeBSD()
1167 {
1168     return ($^O eq "freebsd") || 0;
1169 }
1170
1171 sub isARM()
1172 {
1173     return $Config{archname} =~ /^arm[v\-]/;
1174 }
1175
1176 sub isCrossCompilation()
1177 {
1178   my $compiler = "";
1179   $compiler = $ENV{'CC'} if (defined($ENV{'CC'}));
1180   if ($compiler =~ /gcc/) {
1181       my $compiler_options = `$compiler -v 2>&1`;
1182       my @host = $compiler_options =~ m/--host=(.*?)\s/;
1183       my @target = $compiler_options =~ m/--target=(.*?)\s/;
1184
1185       return ($host[0] ne "" && $target[0] ne "" && $host[0] ne $target[0]);
1186   }
1187   return 0;
1188 }
1189
1190 sub isAppleWebKit()
1191 {
1192     return !(isGtk() or isEfl() or isWinCE() or isBlackBerry());
1193 }
1194
1195 sub isAppleMacWebKit()
1196 {
1197     return isAppleWebKit() && isDarwin();
1198 }
1199
1200 sub isAppleWinWebKit()
1201 {
1202     return isAppleWebKit() && (isCygwin() || isWindows()) && !isWinCairo();
1203 }
1204
1205 sub willUseIOSDeviceSDKWhenBuilding()
1206 {
1207     return xcodeSDKPlatformName() eq "iphoneos";
1208 }
1209
1210 sub willUseIOSSimulatorSDKWhenBuilding()
1211 {
1212     return xcodeSDKPlatformName() eq "iphonesimulator";
1213 }
1214
1215 sub isIOSWebKit()
1216 {
1217     determineXcodeSDK();
1218     return isAppleMacWebKit() && (willUseIOSDeviceSDKWhenBuilding() || willUseIOSSimulatorSDKWhenBuilding());
1219 }
1220
1221 sub isPerianInstalled()
1222 {
1223     if (!isAppleWebKit()) {
1224         return 0;
1225     }
1226
1227     if (-d "/Library/QuickTime/Perian.component") {
1228         return 1;
1229     }
1230
1231     if (-d "$ENV{HOME}/Library/QuickTime/Perian.component") {
1232         return 1;
1233     }
1234
1235     return 0;
1236 }
1237
1238 sub determineNmPath()
1239 {
1240     return if $nmPath;
1241
1242     if (isAppleMacWebKit()) {
1243         $nmPath = `xcrun -find nm`;
1244         chomp $nmPath;
1245     }
1246     $nmPath = "nm" if !$nmPath;
1247 }
1248
1249 sub nmPath()
1250 {
1251     determineNmPath();
1252     return $nmPath;
1253 }
1254
1255 sub determineOSXVersion()
1256 {
1257     return if $osXVersion;
1258
1259     if (!isDarwin()) {
1260         $osXVersion = -1;
1261         return;
1262     }
1263
1264     my $version = `sw_vers -productVersion`;
1265     my @splitVersion = split(/\./, $version);
1266     @splitVersion >= 2 or die "Invalid version $version";
1267     $osXVersion = {
1268             "major" => $splitVersion[0],
1269             "minor" => $splitVersion[1],
1270             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
1271     };
1272 }
1273
1274 sub osXVersion()
1275 {
1276     determineOSXVersion();
1277     return $osXVersion;
1278 }
1279
1280 sub isSnowLeopard()
1281 {
1282     return isDarwin() && osXVersion()->{"minor"} == 6;
1283 }
1284
1285 sub isLion()
1286 {
1287     return isDarwin() && osXVersion()->{"minor"} == 7;
1288 }
1289
1290 sub isWindowsNT()
1291 {
1292     return $ENV{'OS'} eq 'Windows_NT';
1293 }
1294
1295 sub shouldTargetWebProcess
1296 {
1297     determineShouldTargetWebProcess();
1298     return $shouldTargetWebProcess;
1299 }
1300
1301 sub determineShouldTargetWebProcess
1302 {
1303     return if defined($shouldTargetWebProcess);
1304     $shouldTargetWebProcess = checkForArgumentAndRemoveFromARGV("--target-web-process");
1305 }
1306
1307 sub shouldUseXPCServiceForWebProcess
1308 {
1309     determineShouldUseXPCServiceForWebProcess();
1310     return $shouldUseXPCServiceForWebProcess;
1311 }
1312
1313 sub determineShouldUseXPCServiceForWebProcess
1314 {
1315     return if defined($shouldUseXPCServiceForWebProcess);
1316     $shouldUseXPCServiceForWebProcess = checkForArgumentAndRemoveFromARGV("--use-web-process-xpc-service");
1317 }
1318
1319 sub debugger
1320 {
1321     determineDebugger();
1322     return $debugger;
1323 }
1324
1325 sub determineDebugger
1326 {
1327     return if defined($debugger);
1328
1329     determineXcodeVersion();
1330     if (eval "v$xcodeVersion" ge v4.5) {
1331         $debugger = "lldb";
1332     } else {
1333         $debugger = "gdb";
1334     }
1335
1336     if (checkForArgumentAndRemoveFromARGV("--use-lldb")) {
1337         $debugger = "lldb";
1338     }
1339
1340     if (checkForArgumentAndRemoveFromARGV("--use-gdb")) {
1341         $debugger = "gdb";
1342     }
1343 }
1344
1345 sub appendToEnvironmentVariableList
1346 {
1347     my ($environmentVariableName, $value) = @_;
1348
1349     if (defined($ENV{$environmentVariableName})) {
1350         $ENV{$environmentVariableName} .= ":" . $value;
1351     } else {
1352         $ENV{$environmentVariableName} = $value;
1353     }
1354 }
1355
1356 sub setUpGuardMallocIfNeeded
1357 {
1358     if (!isDarwin()) {
1359         return;
1360     }
1361
1362     if (!defined($shouldUseGuardMalloc)) {
1363         $shouldUseGuardMalloc = checkForArgumentAndRemoveFromARGV("--guard-malloc");
1364     }
1365
1366     if ($shouldUseGuardMalloc) {
1367         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", "/usr/lib/libgmalloc.dylib");
1368     }
1369 }
1370
1371 sub relativeScriptsDir()
1372 {
1373     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel($FindBin::Bin, getcwd()), "");
1374     if ($scriptDir eq "") {
1375         $scriptDir = ".";
1376     }
1377     return $scriptDir;
1378 }
1379
1380 sub launcherPath()
1381 {
1382     my $relativeScriptsPath = relativeScriptsDir();
1383     if (isGtk() || isEfl() || isWinCE()) {
1384         return "$relativeScriptsPath/run-launcher";
1385     } elsif (isAppleWebKit()) {
1386         return "$relativeScriptsPath/run-safari";
1387     }
1388 }
1389
1390 sub launcherName()
1391 {
1392     if (isGtk()) {
1393         return "GtkLauncher";
1394     } elsif (isAppleWebKit()) {
1395         return "Safari";
1396     } elsif (isEfl()) {
1397         return "EWebLauncher/MiniBrowser";
1398     } elsif (isWinCE()) {
1399         return "WinCELauncher";
1400     }
1401 }
1402
1403 sub checkRequiredSystemConfig
1404 {
1405     if (isDarwin()) {
1406         chomp(my $productVersion = `sw_vers -productVersion`);
1407         if (eval "v$productVersion" lt v10.7.5) {
1408             print "*************************************************************\n";
1409             print "Mac OS X Version 10.7.5 or later is required to build WebKit.\n";
1410             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
1411             print "*************************************************************\n";
1412         }
1413         my $xcodebuildVersionOutput = `xcodebuild -version`;
1414         my $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : undef;
1415         if (!$xcodeVersion || $xcodeVersion && eval "v$xcodeVersion" lt v4.6) {
1416             print "*************************************************************\n";
1417             print "Xcode Version 4.6 or later is required to build WebKit.\n";
1418             print "You have an earlier version of Xcode, thus the build will\n";
1419             print "most likely fail. The latest Xcode is available from the App Store.\n";
1420             print "*************************************************************\n";
1421         }
1422     } elsif (isGtk() or isEfl() or isWindows()) {
1423         my @cmds = qw(bison gperf flex);
1424         my @missing = ();
1425         my $oldPath = $ENV{PATH};
1426         foreach my $cmd (@cmds) {
1427             push @missing, $cmd if not commandExists($cmd);
1428         }
1429
1430         if (@missing) {
1431             my $list = join ", ", @missing;
1432             die "ERROR: $list missing but required to build WebKit.\n";
1433         }
1434     }
1435     # Win32 and other platforms may want to check for minimum config
1436 }
1437
1438 sub determineWindowsSourceDir()
1439 {
1440     return if $windowsSourceDir;
1441     $windowsSourceDir = sourceDir();
1442     chomp($windowsSourceDir = `cygpath -w '$windowsSourceDir'`) if isCygwin();
1443 }
1444
1445 sub windowsSourceDir()
1446 {
1447     determineWindowsSourceDir();
1448     return $windowsSourceDir;
1449 }
1450
1451 sub windowsSourceSourceDir()
1452 {
1453     return windowsSourceDir() . "\\Source";
1454 }
1455
1456 sub windowsLibrariesDir()
1457 {
1458     return windowsSourceDir() . "\\WebKitLibraries\\win";
1459 }
1460
1461 sub windowsOutputDir()
1462 {
1463     return windowsSourceDir() . "\\WebKitBuild";
1464 }
1465
1466 sub fontExists($)
1467 {
1468     my $font = shift;
1469     my $val = system qw(regtool get), '\\HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Fonts\\' . $font . ' (TrueType)';
1470     return 0 == $val;
1471 }
1472
1473 sub checkInstalledTools()
1474 {
1475     # SVN 1.7.10 is known to be compatible with current servers. SVN 1.8.x seems to be missing some authentication
1476     # protocols we use for svn.webkit.org:
1477     my $svnVersion = `svn --version | grep "\\sversion"`;
1478     chomp($svnVersion);
1479     if (!$? and $svnVersion =~ /1\.8\./) {
1480         print "svn 1.7.10 is known to be compatible with our servers. You are running $svnVersion,\nwhich may not work properly.\n"
1481     }
1482
1483     # Python 2.7.3 as shipped by Cygwin prevents the build from completing due to some issue with handling of
1484     # environment variables. Avoid until this is corrected.
1485     my $pythonVer = `python --version 2>&1`;
1486     die "You must have Python installed to build WebKit.\n" if ($?);
1487     die "Python 2.7.3 is not compatible with the WebKit build. Please downgrade to Python 2.6.8.\n" if ($pythonVer =~ /2\.7\.3/);
1488
1489     # MathML requires fonts that do not ship with Windows (at least through Windows 8). Warn the user if they are missing
1490     my @fonts = qw(STIXGeneral-Regular MathJax_Main-Regular);
1491     my @missing = ();
1492     foreach my $font (@fonts) {
1493         push @missing, $font if not fontExists($font);
1494     }
1495
1496     if (scalar @missing > 0) {
1497         print "*************************************************************\n";
1498         print "Mathematical fonts, such as STIX and MathJax, are needed to\n";
1499         print "use the MathML feature.  You do not appear to have these fonts\n";
1500         print "on your system.\n\n";
1501         print "You can download a suitable set of fonts from the following URL:\n";
1502         print "https://developer.mozilla.org/Mozilla/MathML_Projects/Fonts\n";
1503         print "*************************************************************\n";
1504     }
1505
1506     print "Installed tools are correct for the WebKit build.\n";
1507 }
1508
1509 sub setupAppleWinEnv()
1510 {
1511     return unless isAppleWinWebKit();
1512
1513     checkInstalledTools();
1514
1515     if (isWindowsNT()) {
1516         my $restartNeeded = 0;
1517         my %variablesToSet = ();
1518
1519         # FIXME: We should remove this explicit version check for cygwin once we stop supporting Cygwin 1.7.9 or older versions. 
1520         # https://bugs.webkit.org/show_bug.cgi?id=85791
1521         my $uname_version = (POSIX::uname())[2];
1522         $uname_version =~ s/\(.*\)//;  # Remove the trailing cygwin version, if any.
1523         if (version->parse($uname_version) < version->parse("1.7.10")) {
1524             # Setting the environment variable 'CYGWIN' to 'tty' makes cygwin enable extra support (i.e., termios)
1525             # for UNIX-like ttys in the Windows console
1526             $variablesToSet{CYGWIN} = "tty" unless $ENV{CYGWIN};
1527         }
1528         
1529         # Those environment variables must be set to be able to build inside Visual Studio.
1530         $variablesToSet{WEBKIT_LIBRARIES} = windowsLibrariesDir() unless $ENV{WEBKIT_LIBRARIES};
1531         $variablesToSet{WEBKIT_OUTPUTDIR} = windowsOutputDir() unless $ENV{WEBKIT_OUTPUTDIR};
1532
1533         foreach my $variable (keys %variablesToSet) {
1534             print "Setting the Environment Variable '" . $variable . "' to '" . $variablesToSet{$variable} . "'\n\n";
1535             system qw(regtool -s set), '\\HKEY_CURRENT_USER\\Environment\\' . $variable, $variablesToSet{$variable};
1536             $restartNeeded ||=  $variable eq "WEBKIT_LIBRARIES" || $variable eq "WEBKIT_OUTPUTDIR";
1537         }
1538
1539         if ($restartNeeded) {
1540             print "Please restart your computer before attempting to build inside Visual Studio.\n\n";
1541         }
1542     } else {
1543         if (!$ENV{'WEBKIT_LIBRARIES'}) {
1544             # VS2010 (and newer) version. This will replace the VS2005 version as part of
1545             # https://bugs.webkit.org/show_bug.cgi?id=109472. 
1546             print "Warning: You must set the 'WebKit_Libraries' environment variable\n";
1547             print "         to be able build WebKit from within Visual Studio 2010 and newer.\n";
1548             print "         Make sure that 'WebKit_Libraries' points to the\n";
1549             print "         'WebKitLibraries/win' directory, not the 'WebKitLibraries/' directory.\n\n";
1550         }
1551         if (!$ENV{'WEBKIT_OUTPUTDIR'}) {
1552             # VS2010 (and newer) version. This will replace the VS2005 version as part of
1553             # https://bugs.webkit.org/show_bug.cgi?id=109472. 
1554             print "Warning: You must set the 'WebKit_OutputDir' environment variable\n";
1555             print "         to be able build WebKit from within Visual Studio 2010 and newer.\n\n";
1556         }
1557     }
1558 }
1559
1560 sub setupCygwinEnv()
1561 {
1562     return if !isCygwin() && !isWindows();
1563     return if $vcBuildPath;
1564
1565     my $programFilesPath = programFilesPath();
1566     $vcBuildPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.com));
1567     if (-e $vcBuildPath) {
1568         # Visual Studio is installed;
1569         if (visualStudioVersion() eq "10") {
1570             $vcBuildPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.exe));
1571         }
1572     } else {
1573         # Visual Studio not found, try VC++ Express
1574         $vcBuildPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE VCExpress.exe));
1575         if (! -e $vcBuildPath) {
1576             print "*************************************************************\n";
1577             print "Cannot find '$vcBuildPath'\n";
1578             print "Please execute the file 'vcvars32.bat' from\n";
1579             print "'$programFilesPath\\Microsoft Visual Studio 8\\VC\\bin\\'\n";
1580             print "to setup the necessary environment variables.\n";
1581             print "*************************************************************\n";
1582             die;
1583         }
1584         $willUseVCExpressWhenBuilding = 1;
1585     }
1586
1587     print "Building results into: ", baseProductDir(), "\n";
1588     print "WEBKIT_OUTPUTDIR is set to: ", $ENV{"WEBKIT_OUTPUTDIR"}, "\n";
1589     print "WEBKIT_LIBRARIES is set to: ", $ENV{"WEBKIT_LIBRARIES"}, "\n";
1590 }
1591
1592 sub dieIfWindowsPlatformSDKNotInstalled
1593 {
1594     my $registry32Path = "/proc/registry/";
1595     my $registry64Path = "/proc/registry64/";
1596     my @windowsPlatformSDKRegistryEntries = (
1597         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0A",
1598         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0",
1599         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.1A",
1600         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.0A",
1601         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/MicrosoftSDK/InstalledSDKs/D2FF9F89-8AA2-4373-8A31-C838BF4DBBE1",
1602     );
1603
1604     # FIXME: It would be better to detect whether we are using 32- or 64-bit Windows
1605     # and only check the appropriate entry. But for now we just blindly check both.
1606     my $recommendedPlatformSDK = $windowsPlatformSDKRegistryEntries[0];
1607
1608     while (@windowsPlatformSDKRegistryEntries) {
1609         my $windowsPlatformSDKRegistryEntry = shift @windowsPlatformSDKRegistryEntries;
1610         return if (-e $registry32Path . $windowsPlatformSDKRegistryEntry) || (-e $registry64Path . $windowsPlatformSDKRegistryEntry);
1611     }
1612
1613     print "*************************************************************\n";
1614     print "Cannot find registry entry '$recommendedPlatformSDK'.\n";
1615     print "Please download and install the Microsoft Windows SDK\n";
1616     print "from <http://www.microsoft.com/en-us/download/details.aspx?id=8279>.\n\n";
1617     print "Then follow step 2 in the Windows section of the \"Installing Developer\n";
1618     print "Tools\" instructions at <http://www.webkit.org/building/tools.html>.\n";
1619     print "*************************************************************\n";
1620     die;
1621 }
1622
1623 sub copyInspectorFrontendFiles
1624 {
1625     my $productDir = productDir();
1626     my $sourceInspectorPath = sourceDir() . "/Source/WebCore/inspector/front-end/";
1627     my $inspectorResourcesDirPath = $ENV{"WEBKITINSPECTORRESOURCESDIR"};
1628
1629     if (!defined($inspectorResourcesDirPath)) {
1630         $inspectorResourcesDirPath = "";
1631     }
1632
1633     if (isAppleMacWebKit()) {
1634         if (isIOSWebKit()) {
1635             $inspectorResourcesDirPath = $productDir . "/WebCore.framework/inspector";
1636         } else {
1637             $inspectorResourcesDirPath = $productDir . "/WebCore.framework/Resources/inspector";
1638         }
1639     } elsif (isAppleWinWebKit() || isWinCairo()) {
1640         $inspectorResourcesDirPath = $productDir . "/WebKit.resources/inspector";
1641     } elsif (isGtk()) {
1642         my $prefix = $ENV{"WebKitInstallationPrefix"};
1643         $inspectorResourcesDirPath = (defined($prefix) ? $prefix : "/usr/share") . "/webkit-1.0/webinspector";
1644     } elsif (isEfl()) {
1645         my $prefix = $ENV{"WebKitInstallationPrefix"};
1646         $inspectorResourcesDirPath = (defined($prefix) ? $prefix : "/usr/share") . "/ewebkit/webinspector";
1647     }
1648
1649     if (! -d $inspectorResourcesDirPath) {
1650         print "*************************************************************\n";
1651         print "Cannot find '$inspectorResourcesDirPath'.\n" if (defined($inspectorResourcesDirPath));
1652         print "Make sure that you have built WebKit first.\n" if (! -d $productDir || defined($inspectorResourcesDirPath));
1653         print "Optionally, set the environment variable 'WebKitInspectorResourcesDir'\n";
1654         print "to point to the directory that contains the WebKit Inspector front-end\n";
1655         print "files for the built WebCore framework.\n";
1656         print "*************************************************************\n";
1657         die;
1658     }
1659
1660     if (isAppleMacWebKit()) {
1661         my $sourceLocalizedStrings = sourceDir() . "/Source/WebCore/English.lproj/localizedStrings.js";
1662         my $destinationLocalizedStrings;
1663         if (isIOSWebKit()) {
1664             $destinationLocalizedStrings = $productDir . "/WebCore.framework/English.lproj/localizedStrings.js";
1665         } else {
1666             $destinationLocalizedStrings = $productDir . "/WebCore.framework/Resources/English.lproj/localizedStrings.js";
1667         }
1668         system "ditto", $sourceLocalizedStrings, $destinationLocalizedStrings;
1669     }
1670
1671     my $exitStatus = system "rsync", "-aut", "--exclude=/.DS_Store", "--exclude=*.re2js", "--exclude=.svn/", $sourceInspectorPath, $inspectorResourcesDirPath;
1672     return $exitStatus if $exitStatus;
1673
1674     if (isIOSWebKit()) {
1675         chdir($productDir . "/WebCore.framework");
1676         return system "zip", "--quiet", "--exclude=*.qrc", "-r", "inspector-remote.zip", "inspector";
1677     }
1678
1679     return 0; # Success; did copy files.
1680 }
1681
1682 sub buildXCodeProject($$@)
1683 {
1684     my ($project, $clean, @extraOptions) = @_;
1685
1686     if ($clean) {
1687         push(@extraOptions, "-alltargets");
1688         push(@extraOptions, "clean");
1689     }
1690
1691     return system "xcodebuild", "-project", "$project.xcodeproj", @extraOptions;
1692 }
1693
1694 sub usingVisualStudioExpress()
1695 {
1696     setupCygwinEnv();
1697     return $willUseVCExpressWhenBuilding;
1698 }
1699
1700 sub buildVisualStudioProject
1701 {
1702     my ($project, $clean) = @_;
1703     setupCygwinEnv();
1704
1705     my $config = configurationForVisualStudio();
1706
1707     dieIfWindowsPlatformSDKNotInstalled() if $willUseVCExpressWhenBuilding;
1708
1709     chomp($project = `cygpath -w "$project"`) if isCygwin();
1710     
1711     my $action = "/build";
1712     if ($clean) {
1713         $action = "/clean";
1714     }
1715
1716     my @command = ($vcBuildPath, $project, $action, $config);
1717
1718     print join(" ", @command), "\n";
1719     return system @command;
1720 }
1721
1722 sub autotoolsFlag($$)
1723 {
1724     my ($flag, $feature) = @_;
1725     my $prefix = $flag ? "--enable" : "--disable";
1726
1727     return $prefix . '-' . $feature;
1728 }
1729
1730 sub runAutogenForAutotoolsProjectIfNecessary($@)
1731 {
1732     my ($dir, $prefix, $sourceDir, $project, $joinedOverridableFeatures, @buildArgs) = @_;
1733
1734     # Always enable introspection when building WebKitGTK+.
1735     unshift(@buildArgs, "--enable-introspection");
1736
1737     # Also, always enable developer mode for developer/test builds.
1738     unshift(@buildArgs, "--enable-developer-mode");
1739
1740     my $joinedBuildArgs = join(" ", @buildArgs);
1741
1742     if (-e "GNUmakefile") {
1743         # Just assume that build-jsc will never be used to reconfigure JSC. Later
1744         # we can go back and make this more complicated if the demand is there.
1745         if ($project ne "WebKit") {
1746             return;
1747         }
1748
1749         # Run autogen.sh again if either the features overrided by build-webkit or build arguments have changed.
1750         if (!mustReRunAutogen($sourceDir, "WebKitFeatureOverrides.txt", $joinedOverridableFeatures)
1751             && !mustReRunAutogen($sourceDir, "previous-autogen-arguments.txt", $joinedBuildArgs)) {
1752             return;
1753         }
1754     }
1755
1756     print "Calling autogen.sh in " . $dir . "\n\n";
1757     print "Installation prefix directory: $prefix\n" if(defined($prefix));
1758
1759     # Only for WebKit, write the autogen.sh arguments to a file so that we can detect
1760     # when they change and automatically re-run it.
1761     if ($project eq 'WebKit') {
1762         open(OVERRIDABLE_FEATURES, ">WebKitFeatureOverrides.txt");
1763         print OVERRIDABLE_FEATURES $joinedOverridableFeatures;
1764         close(OVERRIDABLE_FEATURES);
1765
1766         open(AUTOTOOLS_ARGUMENTS, ">previous-autogen-arguments.txt");
1767         print AUTOTOOLS_ARGUMENTS $joinedBuildArgs;
1768         close(AUTOTOOLS_ARGUMENTS);
1769     }
1770
1771     # Make the path relative since it will appear in all -I compiler flags.
1772     # Long argument lists cause bizarre slowdowns in libtool.
1773     my $relSourceDir = File::Spec->abs2rel($sourceDir) || ".";
1774
1775     # Compiler options to keep floating point values consistent
1776     # between 32-bit and 64-bit architectures. The options are also
1777     # used on Chromium build.
1778     determineArchitecture();
1779     if ($architecture ne "x86_64" && !isARM()) {
1780         $ENV{'CXXFLAGS'} = "-march=pentium4 -msse2 -mfpmath=sse " . ($ENV{'CXXFLAGS'} || "");
1781     }
1782
1783     # Prefix the command with jhbuild run.
1784     unshift(@buildArgs, "$relSourceDir/autogen.sh");
1785     unshift(@buildArgs, jhbuildWrapperPrefixIfNeeded());
1786     if (system(@buildArgs) ne 0) {
1787         die "Calling autogen.sh failed!\n";
1788     }
1789 }
1790
1791 sub getJhbuildPath()
1792 {
1793     my @jhbuildPath = File::Spec->splitdir(baseProductDir());
1794     if (isGit() && isGitBranchBuild() && gitBranch()) {
1795         pop(@jhbuildPath);
1796     }
1797     push(@jhbuildPath, "Dependencies");
1798     return File::Spec->catdir(@jhbuildPath);
1799 }
1800
1801 sub mustReRunAutogen($@)
1802 {
1803     my ($sourceDir, $filename, $currentContents) = @_;
1804
1805     if (! -e $filename) {
1806         return 1;
1807     }
1808
1809     open(CONTENTS_FILE, $filename);
1810     chomp(my $previousContents = <CONTENTS_FILE>);
1811     close(CONTENTS_FILE);
1812
1813     # We only care about the WebKit2 argument when we are building WebKit itself.
1814     # build-jsc never passes --enable-webkit2, so if we didn't do this, autogen.sh
1815     # would run for every single build on the bots, since it runs both build-webkit
1816     # and build-jsc.
1817     if ($previousContents ne $currentContents) {
1818         print "Contents for file $filename have changed.\n";
1819         print "Previous contents were: $previousContents\n\n";
1820         print "New contents are: $currentContents\n";
1821         return 1;
1822     }
1823
1824     return 0;
1825 }
1826
1827 sub buildAutotoolsProject($@)
1828 {
1829     my ($project, $clean, $prefix, $makeArgs, $noWebKit1, $noWebKit2, @features) = @_;
1830
1831     my $make = 'make';
1832     my $dir = productDir();
1833     my $config = passedConfiguration() || configuration();
1834
1835     # Use rm to clean the build directory since distclean may miss files
1836     if ($clean && -d $dir) {
1837         system "rm", "-rf", "$dir";
1838     }
1839
1840     if (! -d $dir) {
1841         File::Path::mkpath($dir) or die "Failed to create build directory " . $dir
1842     }
1843     chdir $dir or die "Failed to cd into " . $dir . "\n";
1844
1845     if ($clean) {
1846         return 0;
1847     }
1848
1849     my @buildArgs = @ARGV;
1850     if ($noWebKit1) {
1851         unshift(@buildArgs, "--disable-webkit1");
1852     }
1853     if ($noWebKit2) {
1854         unshift(@buildArgs, "--disable-webkit2");
1855     }
1856
1857     # Configurable features listed here should be kept in sync with the
1858     # features for which there exists a configuration option in configure.ac.
1859     my %configurableFeatures = (
1860         "battery-status" => 1,
1861         "gamepad" => 1,
1862         "geolocation" => 1,
1863         "svg" => 1,
1864         "svg-fonts" => 1,
1865         "video" => 1,
1866         "webgl" => 1,
1867         "web-audio" => 1,
1868     );
1869
1870     # These features are ones which build-webkit cannot control, typically because
1871     # they can only be active when we have the proper dependencies.
1872     my %unsetFeatures = (
1873         "accelerated-2d-canvas" => 1,
1874     );
1875
1876     my @overridableFeatures = ();
1877     foreach (@features) {
1878         if ($configurableFeatures{$_->{option}}) {
1879             push @buildArgs, autotoolsFlag(${$_->{value}}, $_->{option});;
1880         } elsif (!$unsetFeatures{$_->{option}}) {
1881             push @overridableFeatures, $_->{define} . "=" . (${$_->{value}} ? "1" : "0");
1882         }
1883     }
1884
1885     $makeArgs = $makeArgs || "";
1886     $makeArgs = $makeArgs . " " . $ENV{"WebKitMakeArguments"} if $ENV{"WebKitMakeArguments"};
1887
1888     # Automatically determine the number of CPUs for make only
1889     # if make arguments haven't already been specified.
1890     if ($makeArgs eq "") {
1891         $makeArgs = "-j" . numberOfCPUs();
1892     }
1893
1894     # WebKit is the default target, so we don't need to specify anything.
1895     if ($project eq "JavaScriptCore") {
1896         $makeArgs .= " jsc";
1897     } elsif ($project eq "WTF") {
1898         $makeArgs .= " libWTF.la";
1899     }
1900
1901     $prefix = $ENV{"WebKitInstallationPrefix"} if !defined($prefix);
1902     push @buildArgs, "--prefix=" . $prefix if defined($prefix);
1903
1904     # Check if configuration is Debug.
1905     my $debug = $config =~ m/debug/i;
1906     if ($debug) {
1907         push @buildArgs, "--enable-debug";
1908     } else {
1909         push @buildArgs, "--disable-debug";
1910     }
1911
1912     if (checkForArgumentAndRemoveFromArrayRef("--update-gtk", \@buildArgs)) {
1913         # Force autogen to run, to catch the possibly updated libraries.
1914         system("rm -f previous-autogen-arguments.txt");
1915
1916         system("perl", "$sourceDir/Tools/Scripts/update-webkitgtk-libs") == 0 or die $!;
1917     }
1918
1919     # If GNUmakefile exists, don't run autogen.sh unless its arguments
1920     # have changed. The makefile should be smart enough to track autotools
1921     # dependencies and re-run autogen.sh when build files change.
1922     my $joinedOverridableFeatures = join(" ", @overridableFeatures);
1923     runAutogenForAutotoolsProjectIfNecessary($dir, $prefix, $sourceDir, $project, $joinedOverridableFeatures, @buildArgs);
1924
1925     my $runWithJhbuild = join(" ", jhbuildWrapperPrefixIfNeeded());
1926     if (system("$runWithJhbuild $make $makeArgs") ne 0) {
1927         die "\nFailed to build WebKit using '$make'!\n";
1928     }
1929
1930     chdir ".." or die;
1931
1932     if ($project eq 'WebKit' && !isCrossCompilation() && !($noWebKit1 && $noWebKit2)) {
1933         my @docGenerationOptions = ("$sourceDir/Tools/gtk/generate-gtkdoc", "--skip-html");
1934         push(@docGenerationOptions, productDir());
1935
1936         unshift(@docGenerationOptions, jhbuildWrapperPrefixIfNeeded());
1937
1938         if (system(@docGenerationOptions)) {
1939             die "\n gtkdoc did not build without warnings\n";
1940         }
1941     }
1942
1943     return 0;
1944 }
1945
1946 sub jhbuildWrapperPrefixIfNeeded()
1947 {
1948     if (-e getJhbuildPath()) {
1949         my @prefix = (File::Spec->catfile(sourceDir(), "Tools", "jhbuild", "jhbuild-wrapper"));
1950         if (isEfl()) {
1951             push(@prefix, "--efl");
1952         } elsif (isGtk()) {
1953             push(@prefix, "--gtk");
1954         }
1955         push(@prefix, "run");
1956
1957         return @prefix;
1958     }
1959
1960     return ();
1961 }
1962
1963 sub removeCMakeCache()
1964 {
1965     my $cacheFilePath = File::Spec->catdir(baseProductDir(), configuration(), "CMakeCache.txt");
1966     unlink($cacheFilePath) if -e $cacheFilePath;
1967 }
1968
1969 sub generateBuildSystemFromCMakeProject
1970 {
1971     my ($port, $prefixPath, @cmakeArgs, $additionalCMakeArgs) = @_;
1972     my $config = configuration();
1973     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1974     File::Path::mkpath($buildPath) unless -d $buildPath;
1975     my $originalWorkingDirectory = getcwd();
1976     chdir($buildPath) or die;
1977
1978     my @args;
1979     push @args, "-DPORT=\"$port\"";
1980     push @args, "-DCMAKE_INSTALL_PREFIX=\"$prefixPath\"" if $prefixPath;
1981     push @args, "-DSHARED_CORE=ON" if isEfl() && $ENV{"ENABLE_DRT"};
1982     if ($config =~ /release/i) {
1983         push @args, "-DCMAKE_BUILD_TYPE=Release";
1984     } elsif ($config =~ /debug/i) {
1985         push @args, "-DCMAKE_BUILD_TYPE=Debug";
1986     }
1987     # Don't warn variables which aren't used by cmake ports.
1988     push @args, "--no-warn-unused-cli";
1989     push @args, @cmakeArgs if @cmakeArgs;
1990     push @args, $additionalCMakeArgs if $additionalCMakeArgs;
1991
1992     push @args, '"' . sourceDir() . '"';
1993
1994     # Compiler options to keep floating point values consistent
1995     # between 32-bit and 64-bit architectures.
1996     determineArchitecture();
1997     if ($architecture ne "x86_64" && !isARM()) {
1998         $ENV{'CXXFLAGS'} = "-march=pentium4 -msse2 -mfpmath=sse " . ($ENV{'CXXFLAGS'} || "");
1999     }
2000
2001     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
2002     # parsed for shell metacharacters.
2003     my $wrapper = join(" ", jhbuildWrapperPrefixIfNeeded()) . " ";
2004     my $returnCode = system($wrapper . "cmake @args");
2005
2006     chdir($originalWorkingDirectory);
2007     return $returnCode;
2008 }
2009
2010 sub buildCMakeGeneratedProject($)
2011 {
2012     my ($makeArgs) = @_;
2013     my $config = configuration();
2014     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2015     if (! -d $buildPath) {
2016         die "Must call generateBuildSystemFromCMakeProject() before building CMake project.";
2017     }
2018     my @args = ("--build", $buildPath, "--config", $config);
2019     push @args, ("--", $makeArgs) if $makeArgs;
2020
2021     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
2022     # parsed for shell metacharacters. In particular, $makeArgs may contain such metacharacters.
2023     my $wrapper = join(" ", jhbuildWrapperPrefixIfNeeded()) . " ";
2024     return system($wrapper . "cmake @args");
2025 }
2026
2027 sub cleanCMakeGeneratedProject()
2028 {
2029     my $config = configuration();
2030     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2031     if (-d $buildPath) {
2032         return system("cmake", "--build", $buildPath, "--config", $config, "--target", "clean");
2033     }
2034     return 0;
2035 }
2036
2037 sub buildCMakeProjectOrExit($$$$@)
2038 {
2039     my ($clean, $port, $prefixPath, $makeArgs, @cmakeArgs) = @_;
2040     my $returnCode;
2041
2042     exit(exitStatus(cleanCMakeGeneratedProject())) if $clean;
2043
2044     if (isEfl() && checkForArgumentAndRemoveFromARGV("--update-efl")) {
2045         system("perl", "$sourceDir/Tools/Scripts/update-webkitefl-libs") == 0 or die $!;
2046     }
2047
2048
2049     $returnCode = exitStatus(generateBuildSystemFromCMakeProject($port, $prefixPath, @cmakeArgs));
2050     exit($returnCode) if $returnCode;
2051     if (isBlackBerry()) {
2052         return 0 if (defined($ENV{"GENERATE_CMAKE_PROJECT_ONLY"}) eq '1');
2053     }
2054     $returnCode = exitStatus(buildCMakeGeneratedProject($makeArgs));
2055     exit($returnCode) if $returnCode;
2056     return 0;
2057 }
2058
2059 sub cmakeBasedPortArguments()
2060 {
2061     return blackberryCMakeArguments() if isBlackBerry();
2062     return ('-G "Visual Studio 8 2005 STANDARDSDK_500 (ARMV4I)"') if isWinCE();
2063     return ();
2064 }
2065
2066 sub cmakeBasedPortName()
2067 {
2068     return "BlackBerry" if isBlackBerry();
2069     return "Efl" if isEfl();
2070     return "WinCE" if isWinCE();
2071     return "";
2072 }
2073
2074 sub promptUser
2075 {
2076     my ($prompt, $default) = @_;
2077     my $defaultValue = $default ? "[$default]" : "";
2078     print "$prompt $defaultValue: ";
2079     chomp(my $input = <STDIN>);
2080     return $input ? $input : $default;
2081 }
2082
2083 sub buildGtkProject
2084 {
2085     my ($project, $clean, $prefix, $makeArgs, $noWebKit1, $noWebKit2, @features) = @_;
2086
2087     if ($project ne "WebKit" and $project ne "JavaScriptCore" and $project ne "WTF") {
2088         die "Unsupported project: $project. Supported projects: WebKit, JavaScriptCore, WTF\n";
2089     }
2090
2091     return buildAutotoolsProject($project, $clean, $prefix, $makeArgs, $noWebKit1, $noWebKit2, @features);
2092 }
2093
2094 sub appleApplicationSupportPath
2095 {
2096     open INSTALL_DIR, "</proc/registry/HKEY_LOCAL_MACHINE/SOFTWARE/Apple\ Inc./Apple\ Application\ Support/InstallDir";
2097     my $path = <INSTALL_DIR>;
2098     $path =~ s/[\r\n\x00].*//;
2099     close INSTALL_DIR;
2100
2101     my $unixPath = `cygpath -u '$path'`;
2102     chomp $unixPath;
2103     return $unixPath;
2104 }
2105
2106 sub setPathForRunningWebKitApp
2107 {
2108     my ($env) = @_;
2109
2110     if (isAppleWinWebKit()) {
2111         $env->{PATH} = join(':', productDir(), dirname(installedSafariPath()), appleApplicationSupportPath(), $env->{PATH} || "");
2112     } elsif (isWinCairo()) {
2113         my $winCairoBin = sourceDir() . "/WebKitLibraries/win/" . (isWin64() ? "bin64/" : "bin32/");
2114         $env->{PATH} = join(':', productDir(), $winCairoBin , $env->{PATH} || "");
2115     }
2116 }
2117
2118 sub printHelpAndExitForRunAndDebugWebKitAppIfNeeded
2119 {
2120     return unless checkForArgumentAndRemoveFromARGV("--help");
2121
2122     my ($includeOptionsForDebugging) = @_;
2123
2124     print STDERR <<EOF;
2125 Usage: @{[basename($0)]} [options] [args ...]
2126   --help                            Show this help message
2127   --no-saved-state                  Launch the application without state restoration (OS X 10.7 and later)
2128   --guard-malloc                    Enable Guard Malloc (OS X only)
2129   --use-web-process-xpc-service     Launch the Web Process as an XPC Service (OS X only)
2130 EOF
2131
2132     if ($includeOptionsForDebugging) {
2133         print STDERR <<EOF;
2134   --target-web-process              Debug the web process
2135   --use-gdb                         Use GDB (this is the default when using Xcode 4.4 or earlier)
2136   --use-lldb                        Use LLDB (this is the default when using Xcode 4.5 or later)
2137 EOF
2138     }
2139
2140     exit(1);
2141 }
2142
2143 sub argumentsForRunAndDebugMacWebKitApp()
2144 {
2145     my @args = ();
2146     push @args, ("-ApplePersistenceIgnoreState", "YES") if checkForArgumentAndRemoveFromARGV("--no-saved-state");
2147     push @args, ("-WebKit2UseXPCServiceForWebProcess", "YES") if shouldUseXPCServiceForWebProcess();
2148     unshift @args, @ARGV;
2149
2150     return @args;
2151 }
2152
2153 sub runMacWebKitApp($;$)
2154 {
2155     my ($appPath, $useOpenCommand) = @_;
2156     my $productDir = productDir();
2157     print "Starting @{[basename($appPath)]} with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2158     $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
2159     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2160
2161     setUpGuardMallocIfNeeded();
2162
2163     if (defined($useOpenCommand) && $useOpenCommand == USE_OPEN_COMMAND) {
2164         return system("open", "-W", "-a", $appPath, "--args", argumentsForRunAndDebugMacWebKitApp());
2165     }
2166     if (architecture()) {
2167         return system "arch", "-" . architecture(), $appPath, argumentsForRunAndDebugMacWebKitApp();
2168     }
2169     return system { $appPath } $appPath, argumentsForRunAndDebugMacWebKitApp();
2170 }
2171
2172 sub execMacWebKitAppForDebugging($)
2173 {
2174     my ($appPath) = @_;
2175     my $architectureSwitch;
2176     my $argumentsSeparator;
2177
2178     if (debugger() eq "lldb") {
2179         $architectureSwitch = "--arch";
2180         $argumentsSeparator = "--";
2181     } elsif (debugger() eq "gdb") {
2182         $architectureSwitch = "-arch";
2183         $argumentsSeparator = "--args";
2184     } else {
2185         die "Unknown debugger $debugger.\n";
2186     }
2187
2188     my $debuggerPath = `xcrun -find $debugger`;
2189     chomp $debuggerPath;
2190     die "Can't find the $debugger executable.\n" unless -x $debuggerPath;
2191
2192     my $productDir = productDir();
2193     $ENV{DYLD_FRAMEWORK_PATH} = $productDir;
2194     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2195
2196     setUpGuardMallocIfNeeded();
2197
2198     my @architectureFlags = ($architectureSwitch, architecture());
2199     if (!shouldTargetWebProcess()) {
2200         print "Starting @{[basename($appPath)]} under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2201         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $appPath, argumentsForRunAndDebugMacWebKitApp() or die;
2202     } else {
2203         if (shouldUseXPCServiceForWebProcess()) {
2204             die "Targetting the Web Process is not compatible with using an XPC Service for the Web Process at this time.";
2205         }
2206         
2207         my $webProcessShimPath = File::Spec->catfile($productDir, "SecItemShim.dylib");
2208         my $webProcessPath = File::Spec->catdir($productDir, "WebProcess.app");
2209         my $webKit2ExecutablePath = File::Spec->catfile($productDir, "WebKit2.framework", "WebKit2");
2210
2211         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", $webProcessShimPath);
2212
2213         print "Starting WebProcess under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2214         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $webProcessPath, $webKit2ExecutablePath, "-type", "webprocess", "-client-executable", $appPath or die;
2215     }
2216 }
2217
2218 sub debugSafari
2219 {
2220     if (isAppleMacWebKit()) {
2221         checkFrameworks();
2222         execMacWebKitAppForDebugging(safariPath());
2223     }
2224
2225     return 1; # Unsupported platform; can't debug Safari on this platform.
2226 }
2227
2228 sub runSafari
2229 {
2230
2231     if (isAppleMacWebKit()) {
2232         return runMacWebKitApp(safariPath());
2233     }
2234
2235     if (isAppleWinWebKit()) {
2236         my $result;
2237         my $productDir = productDir();
2238         my $webKitLauncherPath = File::Spec->catfile(productDir(), "WinLauncher.exe");
2239         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2240     }
2241
2242     return 1; # Unsupported platform; can't run Safari on this platform.
2243 }
2244
2245 sub runMiniBrowser
2246 {
2247     if (isAppleMacWebKit()) {
2248         return runMacWebKitApp(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2249     }
2250
2251     return 1;
2252 }
2253
2254 sub debugMiniBrowser
2255 {
2256     if (isAppleMacWebKit()) {
2257         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2258     }
2259     
2260     return 1;
2261 }
2262
2263 sub runWebKitTestRunner
2264 {
2265     if (isAppleMacWebKit()) {
2266         return runMacWebKitApp(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2267     } elsif (isGtk()) {
2268         my $productDir = productDir();
2269         my $injectedBundlePath = "$productDir/Libraries/.libs/libTestRunnerInjectedBundle";
2270         print "Starting WebKitTestRunner with TEST_RUNNER_INJECTED_BUNDLE_FILENAME set to point to $injectedBundlePath.\n";
2271         $ENV{TEST_RUNNER_INJECTED_BUNDLE_FILENAME} = $injectedBundlePath;
2272         my @args = ("$productDir/Programs/WebKitTestRunner", @ARGV);
2273         return system {$args[0] } @args;
2274     }
2275
2276     return 1;
2277 }
2278
2279 sub debugWebKitTestRunner
2280 {
2281     if (isAppleMacWebKit()) {
2282         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2283     }
2284
2285     return 1;
2286 }
2287
2288 sub runTestWebKitAPI
2289 {
2290     if (isAppleMacWebKit()) {
2291         return runMacWebKitApp(File::Spec->catfile(productDir(), "TestWebKitAPI"));
2292     }
2293
2294     return 1;
2295 }
2296
2297 sub readRegistryString
2298 {
2299     my ($valueName) = @_;
2300     chomp(my $string = `regtool --wow32 get "$valueName"`);
2301     return $string;
2302 }
2303
2304 sub writeRegistryString
2305 {
2306     my ($valueName, $string) = @_;
2307
2308     my $error = system "regtool", "--wow32", "set", "-s", $valueName, $string;
2309
2310     # On Windows Vista/7 with UAC enabled, regtool will fail to modify the registry, but will still
2311     # return a successful exit code. So we double-check here that the value we tried to write to the
2312     # registry was really written.
2313     return !$error && readRegistryString($valueName) eq $string;
2314 }
2315
2316 1;