26e069274756d79d48c3825f604f5e623150421f
[WebKit-https.git] / Tools / Scripts / webkitdirs.pm
1 # Copyright (C) 2005-2007, 2010-2015 Apple Inc. All rights reserved.
2 # Copyright (C) 2009 Google Inc. All rights reserved.
3 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
4 # Copyright (C) 2013 Nokia Corporation and/or its subsidiary(-ies).
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30 # Module to share code to get to WebKit directories.
31
32 use strict;
33 use version;
34 use warnings;
35 use Config;
36 use Cwd qw(realpath);
37 use Digest::MD5 qw(md5_hex);
38 use FindBin;
39 use File::Basename;
40 use File::Find;
41 use File::Path qw(make_path mkpath rmtree);
42 use File::Spec;
43 use File::stat;
44 use List::Util;
45 use POSIX;
46 use Time::HiRes qw(usleep);
47 use VCSUtils;
48
49 BEGIN {
50    use Exporter   ();
51    our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
52    $VERSION     = 1.00;
53    @ISA         = qw(Exporter);
54    @EXPORT      = qw(
55        &XcodeCoverageSupportOptions
56        &XcodeOptionString
57        &XcodeOptionStringNoConfig
58        &XcodeOptions
59        &XcodeStaticAnalyzerOption
60        &appDisplayNameFromBundle
61        &appendToEnvironmentVariableList
62        &baseProductDir
63        &chdirWebKit
64        &checkFrameworks
65        &cmakeBasedPortArguments
66        &currentSVNRevision
67        &debugSafari
68        &executableProductDir
69        &findOrCreateSimulatorForIOSDevice
70        &iosSimulatorDeviceByName
71        &nmPath
72        &passedConfiguration
73        &prependToEnvironmentVariableList
74        &printHelpAndExitForRunAndDebugWebKitAppIfNeeded
75        &productDir
76        &quitIOSSimulator
77        &relaunchIOSSimulator
78        &restartIOSSimulatorDevice
79        &runIOSWebKitApp
80        &runMacWebKitApp
81        &safariPath
82        &iosVersion
83        &setConfiguration
84        &setupMacWebKitEnvironment
85        &sharedCommandLineOptions
86        &sharedCommandLineOptionsUsage
87        &shutDownIOSSimulatorDevice
88        &willUseIOSDeviceSDK
89        &willUseIOSSimulatorSDK
90        SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT
91        USE_OPEN_COMMAND
92    );
93    %EXPORT_TAGS = ( );
94    @EXPORT_OK   = ();
95 }
96
97 # Ports
98 use constant {
99     AppleWin => "AppleWin",
100     GTK      => "GTK",
101     Efl      => "Efl",
102     iOS      => "iOS",
103     Mac      => "Mac",
104     WinCairo => "WinCairo"
105 };
106
107 use constant USE_OPEN_COMMAND => 1; # Used in runMacWebKitApp().
108 use constant INCLUDE_OPTIONS_FOR_DEBUGGING => 1;
109 use constant SIMULATOR_DEVICE_STATE_SHUTDOWN => "1";
110 use constant SIMULATOR_DEVICE_STATE_BOOTED => "3";
111 use constant SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT  => "For WebKit Development";
112
113 # See table "Certificate types and names" on <https://developer.apple.com/library/ios/documentation/IDEs/Conceptual/AppDistributionGuide/MaintainingCertificates/MaintainingCertificates.html#//apple_ref/doc/uid/TP40012582-CH31-SW41>.
114 use constant IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX => "iPhone Developer: ";
115
116 our @EXPORT_OK;
117
118 my $architecture;
119 my $asanIsEnabled;
120 my $numberOfCPUs;
121 my $maxCPULoad;
122 my $baseProductDir;
123 my @baseProductDirOption;
124 my $configuration;
125 my $xcodeSDK;
126 my $configurationForVisualStudio;
127 my $configurationProductDir;
128 my $sourceDir;
129 my $currentSVNRevision;
130 my $debugger;
131 my $didLoadIPhoneSimulatorNotification;
132 my $nmPath;
133 my $osXVersion;
134 my $iosVersion;
135 my $generateDsym;
136 my $isCMakeBuild;
137 my $isWin64;
138 my $isInspectorFrontend;
139 my $portName;
140 my $shouldTargetWebProcess;
141 my $shouldUseXPCServiceForWebProcess;
142 my $shouldUseGuardMalloc;
143 my $shouldNotUseNinja;
144 my $xcodeVersion;
145
146 # Variables for Win32 support
147 my $programFilesPath;
148 my $vcBuildPath;
149 my $vsInstallDir;
150 my $msBuildInstallDir;
151 my $vsVersion;
152 my $windowsSourceDir;
153 my $winVersion;
154 my $willUseVCExpressWhenBuilding = 0;
155
156 # Defined in VCSUtils.
157 sub exitStatus($);
158
159 sub findMatchingArguments($$);
160 sub hasArgument($$);
161
162 sub determineSourceDir
163 {
164     return if $sourceDir;
165     $sourceDir = $FindBin::Bin;
166     $sourceDir =~ s|/+$||; # Remove trailing '/' as we would die later
167
168     # walks up path checking each directory to see if it is the main WebKit project dir, 
169     # defined by containing Sources, WebCore, and WebKit
170     until ((-d File::Spec->catdir($sourceDir, "Source") && -d File::Spec->catdir($sourceDir, "Source", "WebCore") && -d File::Spec->catdir($sourceDir, "Source", "WebKit")) || (-d File::Spec->catdir($sourceDir, "Internal") && -d File::Spec->catdir($sourceDir, "OpenSource")))
171     {
172         if ($sourceDir !~ s|/[^/]+$||) {
173             die "Could not find top level webkit directory above source directory using FindBin.\n";
174         }
175     }
176
177     $sourceDir = File::Spec->catdir($sourceDir, "OpenSource") if -d File::Spec->catdir($sourceDir, "OpenSource");
178 }
179
180 sub currentPerlPath()
181 {
182     my $thisPerl = $^X;
183     if ($^O ne 'VMS') {
184         $thisPerl .= $Config{_exe} unless $thisPerl =~ m/$Config{_exe}$/i;
185     }
186     return $thisPerl;
187 }
188
189 # used for scripts which are stored in a non-standard location
190 sub setSourceDir($)
191 {
192     ($sourceDir) = @_;
193 }
194
195 sub determineNinjaVersion
196 {
197     chomp(my $ninjaVersion = `ninja --version`);
198     return $ninjaVersion;
199 }
200
201 sub determineXcodeVersion
202 {
203     return if defined $xcodeVersion;
204     my $xcodebuildVersionOutput = `xcodebuild -version`;
205     $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : "3.0";
206 }
207
208 sub readXcodeUserDefault($)
209 {
210     my ($unprefixedKey) = @_;
211
212     determineXcodeVersion();
213
214     my $xcodeDefaultsDomain = (eval "v$xcodeVersion" lt v4) ? "com.apple.Xcode" : "com.apple.dt.Xcode";
215     my $xcodeDefaultsPrefix = (eval "v$xcodeVersion" lt v4) ? "PBX" : "IDE";
216     my $devnull = File::Spec->devnull();
217
218     my $value = `defaults read $xcodeDefaultsDomain ${xcodeDefaultsPrefix}${unprefixedKey} 2> ${devnull}`;
219     return if $?;
220
221     chomp $value;
222     return $value;
223 }
224
225 sub determineBaseProductDir
226 {
227     return if defined $baseProductDir;
228     determineSourceDir();
229
230     my $setSharedPrecompsDir;
231     $baseProductDir = $ENV{"WEBKIT_OUTPUTDIR"};
232
233     if (!defined($baseProductDir) and isAppleMacWebKit()) {
234         # Silently remove ~/Library/Preferences/xcodebuild.plist which can
235         # cause build failure. The presence of
236         # ~/Library/Preferences/xcodebuild.plist can prevent xcodebuild from
237         # respecting global settings such as a custom build products directory
238         # (<rdar://problem/5585899>).
239         my $personalPlistFile = $ENV{HOME} . "/Library/Preferences/xcodebuild.plist";
240         if (-e $personalPlistFile) {
241             unlink($personalPlistFile) || die "Could not delete $personalPlistFile: $!";
242         }
243
244         determineXcodeVersion();
245
246         if (eval "v$xcodeVersion" ge v4) {
247             my $buildLocationStyle = join '', readXcodeUserDefault("BuildLocationStyle");
248             if ($buildLocationStyle eq "Custom") {
249                 my $buildLocationType = join '', readXcodeUserDefault("CustomBuildLocationType");
250                 # FIXME: Read CustomBuildIntermediatesPath and set OBJROOT accordingly.
251                 $baseProductDir = readXcodeUserDefault("CustomBuildProductsPath") if $buildLocationType eq "Absolute";
252             }
253
254             # DeterminedByTargets corresponds to a setting of "Legacy" in Xcode.
255             # It is the only build location style for which SHARED_PRECOMPS_DIR is not
256             # overridden when building from within Xcode.
257             $setSharedPrecompsDir = 1 if $buildLocationStyle ne "DeterminedByTargets";
258         }
259
260         if (!defined($baseProductDir)) {
261             $baseProductDir = join '', readXcodeUserDefault("ApplicationwideBuildSettings");
262             $baseProductDir = $1 if $baseProductDir =~ /SYMROOT\s*=\s*\"(.*?)\";/s;
263         }
264
265         undef $baseProductDir unless $baseProductDir =~ /^\//;
266     }
267
268     if (!defined($baseProductDir)) { # Port-specific checks failed, use default
269         $baseProductDir = File::Spec->catdir($sourceDir, "WebKitBuild");
270     }
271
272     if (isGit() && isGitBranchBuild()) {
273         my $branch = gitBranch();
274         $baseProductDir = "$baseProductDir/$branch";
275     }
276
277     if (isAppleMacWebKit()) {
278         $baseProductDir =~ s|^\Q$(SRCROOT)/..\E$|$sourceDir|;
279         $baseProductDir =~ s|^\Q$(SRCROOT)/../|$sourceDir/|;
280         $baseProductDir =~ s|^~/|$ENV{HOME}/|;
281         die "Can't handle Xcode product directory with a ~ in it.\n" if $baseProductDir =~ /~/;
282         die "Can't handle Xcode product directory with a variable in it.\n" if $baseProductDir =~ /\$/;
283         @baseProductDirOption = ("SYMROOT=$baseProductDir", "OBJROOT=$baseProductDir");
284         push(@baseProductDirOption, "SHARED_PRECOMPS_DIR=${baseProductDir}/PrecompiledHeaders") if $setSharedPrecompsDir;
285     }
286
287     if (isCygwin()) {
288         my $dosBuildPath = `cygpath --windows \"$baseProductDir\"`;
289         chomp $dosBuildPath;
290         $ENV{"WEBKIT_OUTPUTDIR"} = $dosBuildPath;
291         my $unixBuildPath = `cygpath --unix \"$baseProductDir\"`;
292         chomp $unixBuildPath;
293         $baseProductDir = $dosBuildPath;
294     }
295 }
296
297 sub setBaseProductDir($)
298 {
299     ($baseProductDir) = @_;
300 }
301
302 sub determineConfiguration
303 {
304     return if defined $configuration;
305     determineBaseProductDir();
306     if (open CONFIGURATION, "$baseProductDir/Configuration") {
307         $configuration = <CONFIGURATION>;
308         close CONFIGURATION;
309     }
310     if ($configuration) {
311         chomp $configuration;
312         # compatibility for people who have old Configuration files
313         $configuration = "Release" if $configuration eq "Deployment";
314         $configuration = "Debug" if $configuration eq "Development";
315     } else {
316         $configuration = "Release";
317     }
318 }
319
320 sub determineArchitecture
321 {
322     return if defined $architecture;
323     # make sure $architecture is defined in all cases
324     $architecture = "";
325
326     determineBaseProductDir();
327     determineXcodeSDK();
328
329     if (isAppleMacWebKit()) {
330         if (open ARCHITECTURE, "$baseProductDir/Architecture") {
331             $architecture = <ARCHITECTURE>;
332             close ARCHITECTURE;
333         }
334         if ($architecture) {
335             chomp $architecture;
336         } else {
337             if (not defined $xcodeSDK or $xcodeSDK =~ /^(\/$|macosx)/) {
338                 my $supports64Bit = `sysctl -n hw.optional.x86_64`;
339                 chomp $supports64Bit;
340                 $architecture = 'x86_64' if $supports64Bit;
341             } elsif ($xcodeSDK =~ /^iphonesimulator/) {
342                 $architecture = 'x86_64';
343             } elsif ($xcodeSDK =~ /^iphoneos/) {
344                 $architecture = 'armv7';
345             }
346         }
347     } elsif (isCMakeBuild()) {
348         my $host_processor = "";
349         if (open my $cmake_sysinfo, "cmake --system-information |") {
350             while (<$cmake_sysinfo>) {
351                 next unless index($_, 'CMAKE_SYSTEM_PROCESSOR') == 0;
352                 if (/^CMAKE_SYSTEM_PROCESSOR \"([^"]+)\"/) {
353                     $architecture = $1;
354                     $architecture = 'x86_64' if $architecture eq 'amd64';
355                     last;
356                 }
357             }
358             close $cmake_sysinfo;
359         }
360     }
361
362     if (!isAnyWindows()) {
363         if (!$architecture) {
364             # Fall back to output of `arch', if it is present.
365             $architecture = `arch`;
366             chomp $architecture;
367         }
368
369         if (!$architecture) {
370             # Fall back to output of `uname -m', if it is present.
371             $architecture = `uname -m`;
372             chomp $architecture;
373         }
374     }
375
376     $architecture = 'x86_64' if ($architecture =~ /amd64/ && isBSD());
377 }
378
379 sub determineASanIsEnabled
380 {
381     return if defined $asanIsEnabled;
382     determineBaseProductDir();
383
384     $asanIsEnabled = 0;
385     my $asanConfigurationValue;
386
387     if (open ASAN, "$baseProductDir/ASan") {
388         $asanConfigurationValue = <ASAN>;
389         close ASAN;
390         chomp $asanConfigurationValue;
391         $asanIsEnabled = 1 if $asanConfigurationValue eq "YES";
392     }
393 }
394
395 sub determineNumberOfCPUs
396 {
397     return if defined $numberOfCPUs;
398     if (defined($ENV{NUMBER_OF_PROCESSORS})) {
399         $numberOfCPUs = $ENV{NUMBER_OF_PROCESSORS};
400     } elsif (isLinux()) {
401         # First try the nproc utility, if it exists. If we get no
402         # results fall back to just interpretting /proc directly.
403         chomp($numberOfCPUs = `nproc --all 2> /dev/null`);
404         if ($numberOfCPUs eq "") {
405             $numberOfCPUs = (grep /processor/, `cat /proc/cpuinfo`);
406         }
407     } elsif (isWindows() || isCygwin()) {
408         # Assumes cygwin
409         $numberOfCPUs = `ls /proc/registry/HKEY_LOCAL_MACHINE/HARDWARE/DESCRIPTION/System/CentralProcessor | wc -w`;
410     } elsif (isDarwin() || isBSD()) {
411         chomp($numberOfCPUs = `sysctl -n hw.ncpu`);
412     }
413 }
414
415 sub determineMaxCPULoad
416 {
417     return if defined $maxCPULoad;
418     if (defined($ENV{MAX_CPU_LOAD})) {
419         $maxCPULoad = $ENV{MAX_CPU_LOAD};
420     }
421 }
422
423 sub jscPath($)
424 {
425     my ($productDir) = @_;
426     my $jscName = "jsc";
427     $jscName .= "_debug"  if configuration() eq "Debug_All";
428     $jscName .= ".exe" if (isWindows() || isCygwin());
429     return "$productDir/$jscName" if -e "$productDir/$jscName";
430     return "$productDir/JavaScriptCore.framework/Resources/$jscName";
431 }
432
433 sub argumentsForConfiguration()
434 {
435     determineConfiguration();
436     determineArchitecture();
437     determineXcodeSDK();
438
439     my @args = ();
440     # FIXME: Is it necessary to pass --debug, --release, --32-bit or --64-bit?
441     # These are determined automatically from stored configuration.
442     push(@args, '--debug') if ($configuration =~ "^Debug");
443     push(@args, '--release') if ($configuration =~ "^Release");
444     push(@args, '--device') if (defined $xcodeSDK && $xcodeSDK =~ /^iphoneos/);
445     push(@args, '--ios-simulator') if (defined $xcodeSDK && $xcodeSDK =~ /^iphonesimulator/);
446     push(@args, '--32-bit') if ($architecture ne "x86_64" and !isWin64());
447     push(@args, '--64-bit') if (isWin64());
448     push(@args, '--gtk') if isGtk();
449     push(@args, '--efl') if isEfl();
450     push(@args, '--wincairo') if isWinCairo();
451     push(@args, '--inspector-frontend') if isInspectorFrontend();
452     return @args;
453 }
454
455 sub determineXcodeSDK
456 {
457     return if defined $xcodeSDK;
458     my $sdk;
459     if (checkForArgumentAndRemoveFromARGVGettingValue("--sdk", \$sdk)) {
460         $xcodeSDK = $sdk;
461     }
462     if (checkForArgumentAndRemoveFromARGV("--device")) {
463         my $hasInternalSDK = exitStatus(system("xcrun --sdk iphoneos.internal --show-sdk-version > /dev/null 2>&1")) == 0;
464         $xcodeSDK ||= $hasInternalSDK ? "iphoneos.internal" : "iphoneos";
465     }
466     if (checkForArgumentAndRemoveFromARGV("--ios-simulator")) {
467         $xcodeSDK ||= 'iphonesimulator';
468     }
469 }
470
471 sub xcodeSDK
472 {
473     determineXcodeSDK();
474     return $xcodeSDK;
475 }
476
477 sub setXcodeSDK($)
478 {
479     ($xcodeSDK) = @_;
480 }
481
482
483 sub xcodeSDKPlatformName()
484 {
485     determineXcodeSDK();
486     return "" if !defined $xcodeSDK;
487     return "iphoneos" if $xcodeSDK =~ /iphoneos/i;
488     return "iphonesimulator" if $xcodeSDK =~ /iphonesimulator/i;
489     return "macosx" if $xcodeSDK =~ /macosx/i;
490     die "Couldn't determine platform name from Xcode SDK";
491 }
492
493 sub XcodeSDKPath
494 {
495     determineXcodeSDK();
496
497     die "Can't find the SDK path because no Xcode SDK was specified" if not $xcodeSDK;
498
499     my $sdkPath = `xcrun --sdk $xcodeSDK --show-sdk-path` if $xcodeSDK;
500     die 'Failed to get SDK path from xcrun' if $?;
501     chomp $sdkPath;
502
503     return $sdkPath;
504 }
505
506 sub xcodeSDKVersion
507 {
508     determineXcodeSDK();
509
510     die "Can't find the SDK version because no Xcode SDK was specified" if !$xcodeSDK;
511
512     chomp(my $sdkVersion = `xcrun --sdk $xcodeSDK --show-sdk-version`);
513     die "Failed to get SDK version from xcrun" if exitStatus($?);
514
515     return $sdkVersion;
516 }
517
518 sub programFilesPath
519 {
520     return $programFilesPath if defined $programFilesPath;
521
522     $programFilesPath = $ENV{'PROGRAMFILES(X86)'} || $ENV{'PROGRAMFILES'} || "C:\\Program Files";
523
524     return $programFilesPath;
525 }
526
527 sub visualStudioInstallDir
528 {
529     return $vsInstallDir if defined $vsInstallDir;
530
531     if ($ENV{'VSINSTALLDIR'}) {
532         $vsInstallDir = $ENV{'VSINSTALLDIR'};
533         $vsInstallDir =~ s|[\\/]$||;
534     } else {
535         $vsInstallDir = File::Spec->catdir(programFilesPath(), "Microsoft Visual Studio 14.0");
536     }
537     chomp($vsInstallDir = `cygpath "$vsInstallDir"`) if isCygwin();
538
539     print "Using Visual Studio: $vsInstallDir\n";
540     return $vsInstallDir;
541 }
542
543 sub msBuildInstallDir
544 {
545     return $msBuildInstallDir if defined $msBuildInstallDir;
546
547     $msBuildInstallDir = File::Spec->catdir(programFilesPath(), "MSBuild", "14.0", "Bin");
548    
549     chomp($msBuildInstallDir = `cygpath "$msBuildInstallDir"`) if isCygwin();
550
551     print "Using MSBuild: $msBuildInstallDir\n";
552     return $msBuildInstallDir;
553 }
554
555 sub visualStudioVersion
556 {
557     return $vsVersion if defined $vsVersion;
558
559     my $installDir = visualStudioInstallDir();
560
561     $vsVersion = ($installDir =~ /Microsoft Visual Studio ([0-9]+\.[0-9]*)/) ? $1 : "14";
562
563     print "Using Visual Studio $vsVersion\n";
564     return $vsVersion;
565 }
566
567 sub determineConfigurationForVisualStudio
568 {
569     return if defined $configurationForVisualStudio;
570     determineConfiguration();
571     # FIXME: We should detect when Debug_All or Production has been chosen.
572     $configurationForVisualStudio = "/p:Configuration=" . $configuration;
573 }
574
575 sub usesPerConfigurationBuildDirectory
576 {
577     # [Gtk] We don't have Release/Debug configurations in straight
578     # autotool builds (non build-webkit). In this case and if
579     # WEBKIT_OUTPUTDIR exist, use that as our configuration dir. This will
580     # allows us to run run-webkit-tests without using build-webkit.
581     return ($ENV{"WEBKIT_OUTPUTDIR"} && isGtk()) || isAppleWinWebKit();
582 }
583
584 sub determineConfigurationProductDir
585 {
586     return if defined $configurationProductDir;
587     determineBaseProductDir();
588     determineConfiguration();
589     if (isAppleWinWebKit() || isWinCairo()) {
590         $configurationProductDir = File::Spec->catdir($baseProductDir, $configuration);
591     } else {
592         if (usesPerConfigurationBuildDirectory()) {
593             $configurationProductDir = "$baseProductDir";
594         } else {
595             $configurationProductDir = "$baseProductDir/$configuration";
596             $configurationProductDir .= "-" . xcodeSDKPlatformName() if isIOSWebKit();
597         }
598     }
599 }
600
601 sub setConfigurationProductDir($)
602 {
603     ($configurationProductDir) = @_;
604 }
605
606 sub determineCurrentSVNRevision
607 {
608     # We always update the current SVN revision here, and leave the caching
609     # to currentSVNRevision(), so that changes to the SVN revision while the
610     # script is running can be picked up by calling this function again.
611     determineSourceDir();
612     $currentSVNRevision = svnRevisionForDirectory($sourceDir);
613     return $currentSVNRevision;
614 }
615
616
617 sub chdirWebKit
618 {
619     determineSourceDir();
620     chdir $sourceDir or die;
621 }
622
623 sub baseProductDir
624 {
625     determineBaseProductDir();
626     return $baseProductDir;
627 }
628
629 sub sourceDir
630 {
631     determineSourceDir();
632     return $sourceDir;
633 }
634
635 sub productDir
636 {
637     determineConfigurationProductDir();
638     return $configurationProductDir;
639 }
640
641 sub executableProductDir
642 {
643     my $productDirectory = productDir();
644
645     my $binaryDirectory;
646     if (isEfl() || isGtk()) {
647         $binaryDirectory = "bin";
648     } elsif (isAnyWindows()) {
649         $binaryDirectory = isWin64() ? "bin64" : "bin32";
650     } else {
651         return $productDirectory;
652     }
653
654     return File::Spec->catdir($productDirectory, $binaryDirectory);
655 }
656
657 sub jscProductDir
658 {
659     return executableProductDir();
660 }
661
662 sub configuration()
663 {
664     determineConfiguration();
665     return $configuration;
666 }
667
668 sub asanIsEnabled()
669 {
670     determineASanIsEnabled();
671     return $asanIsEnabled;
672 }
673
674 sub configurationForVisualStudio()
675 {
676     determineConfigurationForVisualStudio();
677     return $configurationForVisualStudio;
678 }
679
680 sub currentSVNRevision
681 {
682     determineCurrentSVNRevision() if not defined $currentSVNRevision;
683     return $currentSVNRevision;
684 }
685
686 sub generateDsym()
687 {
688     determineGenerateDsym();
689     return $generateDsym;
690 }
691
692 sub determineGenerateDsym()
693 {
694     return if defined($generateDsym);
695     $generateDsym = checkForArgumentAndRemoveFromARGV("--dsym");
696 }
697
698 sub hasIOSDevelopmentCertificate()
699 {
700     return !exitStatus(system("security find-identity -p codesigning | grep '" . IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX . "' > /dev/null 2>&1"));
701 }
702
703 sub argumentsForXcode()
704 {
705     my @args = ();
706     push @args, "DEBUG_INFORMATION_FORMAT=dwarf-with-dsym" if generateDsym();
707     return @args;
708 }
709
710 sub XcodeOptions
711 {
712     determineBaseProductDir();
713     determineConfiguration();
714     determineArchitecture();
715     determineASanIsEnabled();
716     determineXcodeSDK();
717
718     my @options;
719     push @options, "-UseSanitizedBuildSystemEnvironment=YES";
720     push @options, ("-configuration", $configuration);
721     push @options, ("-xcconfig", sourceDir() . "/Tools/asan/asan.xcconfig", "ASAN_IGNORE=" . sourceDir() . "/Tools/asan/webkit-asan-ignore.txt") if $asanIsEnabled;
722     push @options, @baseProductDirOption;
723     push @options, "ARCHS=$architecture" if $architecture;
724     push @options, "SDKROOT=$xcodeSDK" if $xcodeSDK;
725     if (willUseIOSDeviceSDK()) {
726         push @options, "ENABLE_BITCODE=NO";
727         if (hasIOSDevelopmentCertificate()) {
728             # FIXME: May match more than one installed development certificate.
729             push @options, "CODE_SIGN_IDENTITY=" . IOS_DEVELOPMENT_CERTIFICATE_NAME_PREFIX;
730         } else {
731             push @options, "CODE_SIGN_IDENTITY="; # No identity
732             push @options, "CODE_SIGNING_REQUIRED=NO";
733         }
734     }
735     push @options, argumentsForXcode();
736     return @options;
737 }
738
739 sub XcodeOptionString
740 {
741     return join " ", XcodeOptions();
742 }
743
744 sub XcodeOptionStringNoConfig
745 {
746     return join " ", @baseProductDirOption;
747 }
748
749 sub XcodeCoverageSupportOptions()
750 {
751     my @coverageSupportOptions = ();
752     push @coverageSupportOptions, "GCC_GENERATE_TEST_COVERAGE_FILES=YES";
753     push @coverageSupportOptions, "GCC_INSTRUMENT_PROGRAM_FLOW_ARCS=YES";
754     return @coverageSupportOptions;
755 }
756
757 sub XcodeStaticAnalyzerOption()
758 {
759     return "RUN_CLANG_STATIC_ANALYZER=YES";
760 }
761
762 my $passedConfiguration;
763 my $searchedForPassedConfiguration;
764 sub determinePassedConfiguration
765 {
766     return if $searchedForPassedConfiguration;
767     $searchedForPassedConfiguration = 1;
768     $passedConfiguration = undef;
769
770     if (checkForArgumentAndRemoveFromARGV("--debug")) {
771         $passedConfiguration = "Debug";
772     } elsif(checkForArgumentAndRemoveFromARGV("--release")) {
773         $passedConfiguration = "Release";
774     } elsif (checkForArgumentAndRemoveFromARGV("--profile") || checkForArgumentAndRemoveFromARGV("--profiling")) {
775         $passedConfiguration = "Profiling";
776     }
777 }
778
779 sub passedConfiguration
780 {
781     determinePassedConfiguration();
782     return $passedConfiguration;
783 }
784
785 sub setConfiguration
786 {
787     setArchitecture();
788
789     if (my $config = shift @_) {
790         $configuration = $config;
791         return;
792     }
793
794     determinePassedConfiguration();
795     $configuration = $passedConfiguration if $passedConfiguration;
796 }
797
798
799 my $passedArchitecture;
800 my $searchedForPassedArchitecture;
801 sub determinePassedArchitecture
802 {
803     return if $searchedForPassedArchitecture;
804     $searchedForPassedArchitecture = 1;
805
806     $passedArchitecture = undef;
807     if (checkForArgumentAndRemoveFromARGV("--32-bit")) {
808         if (isAppleMacWebKit()) {
809             # PLATFORM_IOS: Don't run `arch` command inside Simulator environment
810             local %ENV = %ENV;
811             delete $ENV{DYLD_ROOT_PATH};
812             delete $ENV{DYLD_FRAMEWORK_PATH};
813
814             $passedArchitecture = `arch`;
815             chomp $passedArchitecture;
816         }
817     }
818 }
819
820 sub passedArchitecture
821 {
822     determinePassedArchitecture();
823     return $passedArchitecture;
824 }
825
826 sub architecture()
827 {
828     determineArchitecture();
829     return $architecture;
830 }
831
832 sub numberOfCPUs()
833 {
834     determineNumberOfCPUs();
835     return $numberOfCPUs;
836 }
837
838 sub maxCPULoad()
839 {
840     determineMaxCPULoad();
841     return $maxCPULoad;
842 }
843
844 sub setArchitecture
845 {
846     if (my $arch = shift @_) {
847         $architecture = $arch;
848         return;
849     }
850
851     determinePassedArchitecture();
852     $architecture = $passedArchitecture if $passedArchitecture;
853 }
854
855 sub skipSafariExecutableEntitlementChecks
856 {
857     return `defaults read /Library/Preferences/org.webkit.BuildConfiguration SkipSafariExecutableEntitlementChecks 2>/dev/null` eq "1\n";
858 }
859
860 sub executableHasEntitlements
861 {
862     my $executablePath = shift;
863     return (`codesign -d --entitlements - $executablePath 2>&1` =~ /<key>/);
864 }
865
866 sub safariPathFromSafariBundle
867 {
868     my ($safariBundle) = @_;
869
870     die "Safari path is only relevant on Apple Mac platform\n" unless isAppleMacWebKit();
871
872     my $safariPath = "$safariBundle/Contents/MacOS/Safari";
873     return $safariPath if skipSafariExecutableEntitlementChecks();
874
875     my $safariForWebKitDevelopmentPath = "$safariBundle/Contents/MacOS/SafariForWebKitDevelopment";
876     return $safariForWebKitDevelopmentPath if -f $safariForWebKitDevelopmentPath && executableHasEntitlements($safariPath);
877
878     return $safariPath;
879 }
880
881 sub installedSafariPath
882 {
883     return safariPathFromSafariBundle("/Applications/Safari.app");
884 }
885
886 # Locate Safari.
887 sub safariPath
888 {
889     die "Safari path is only relevant on Apple Mac platform\n" unless isAppleMacWebKit();
890
891     # Use WEBKIT_SAFARI environment variable if present.
892     my $safariBundle = $ENV{WEBKIT_SAFARI};
893     if (!$safariBundle) {
894         determineConfigurationProductDir();
895         # Use Safari.app in product directory if present (good for Safari development team).
896         if (-d "$configurationProductDir/Safari.app") {
897             $safariBundle = "$configurationProductDir/Safari.app";
898         }
899         if (!$safariBundle) {
900             return installedSafariPath();
901         }
902     }
903     my $safariPath = safariPathFromSafariBundle($safariBundle);
904     die "Can't find executable at $safariPath.\n" if !-x $safariPath;
905     return $safariPath;
906 }
907
908 sub builtDylibPathForName
909 {
910     my $libraryName = shift;
911     determineConfigurationProductDir();
912
913     if (isGtk()) {
914         my $extension = isDarwin() ? ".dylib" : ".so";
915         return "$configurationProductDir/lib/libwebkit2gtk-4.0" . $extension;
916     }
917     if (isEfl()) {
918         return "$configurationProductDir/lib/libewebkit2.so";
919     }
920     if (isIOSWebKit()) {
921         return "$configurationProductDir/$libraryName.framework/$libraryName";
922     }
923     if (isAppleMacWebKit()) {
924         return "$configurationProductDir/$libraryName.framework/Versions/A/$libraryName";
925     }
926     if (isAppleWinWebKit()) {
927         if ($libraryName eq "JavaScriptCore") {
928             return "$baseProductDir/lib/$libraryName.lib";
929         } else {
930             return "$baseProductDir/$libraryName.intermediate/$configuration/$libraryName.intermediate/$libraryName.lib";
931         }
932     }
933
934     die "Unsupported platform, can't determine built library locations.\nTry `build-webkit --help` for more information.\n";
935 }
936
937 # Check to see that all the frameworks are built.
938 sub checkFrameworks # FIXME: This is a poor name since only the Mac calls built WebCore a Framework.
939 {
940     return if isCygwin() || isWindows();
941     my @frameworks = ("JavaScriptCore", "WebCore");
942     push(@frameworks, "WebKit") if isAppleMacWebKit(); # FIXME: This seems wrong, all ports should have a WebKit these days.
943     for my $framework (@frameworks) {
944         my $path = builtDylibPathForName($framework);
945         die "Can't find built framework at \"$path\".\n" unless -e $path;
946     }
947 }
948
949 sub isInspectorFrontend()
950 {
951     determineIsInspectorFrontend();
952     return $isInspectorFrontend;
953 }
954
955 sub determineIsInspectorFrontend()
956 {
957     return if defined($isInspectorFrontend);
958     $isInspectorFrontend = checkForArgumentAndRemoveFromARGV("--inspector-frontend");
959 }
960
961 sub commandExists($)
962 {
963     my $command = shift;
964     my $devnull = File::Spec->devnull();
965
966     if (isAnyWindows()) {
967         return exitStatus(system("where /q $command >$devnull 2>&1")) == 0;
968     }
969     return exitStatus(system("which $command >$devnull 2>&1")) == 0;
970 }
971
972 sub checkForArgumentAndRemoveFromARGV($)
973 {
974     my $argToCheck = shift;
975     return checkForArgumentAndRemoveFromArrayRef($argToCheck, \@ARGV);
976 }
977
978 sub checkForArgumentAndRemoveFromArrayRefGettingValue($$$)
979 {
980     my ($argToCheck, $valueRef, $arrayRef) = @_;
981     my $argumentStartRegEx = qr#^$argToCheck(?:=\S|$)#;
982     my $i = 0;
983     for (; $i < @$arrayRef; ++$i) {
984         last if $arrayRef->[$i] =~ $argumentStartRegEx;
985     }
986     if ($i >= @$arrayRef) {
987         return $$valueRef = undef;
988     }
989     my ($key, $value) = split("=", $arrayRef->[$i]);
990     splice(@$arrayRef, $i, 1);
991     if (defined($value)) {
992         # e.g. --sdk=iphonesimulator
993         return $$valueRef = $value;
994     }
995     return $$valueRef = splice(@$arrayRef, $i, 1); # e.g. --sdk iphonesimulator
996 }
997
998 sub checkForArgumentAndRemoveFromARGVGettingValue($$)
999 {
1000     my ($argToCheck, $valueRef) = @_;
1001     return checkForArgumentAndRemoveFromArrayRefGettingValue($argToCheck, $valueRef, \@ARGV);
1002 }
1003
1004 sub findMatchingArguments($$)
1005 {
1006     my ($argToCheck, $arrayRef) = @_;
1007     my @matchingIndices;
1008     foreach my $index (0 .. $#$arrayRef) {
1009         my $opt = $$arrayRef[$index];
1010         if ($opt =~ /^$argToCheck$/i ) {
1011             push(@matchingIndices, $index);
1012         }
1013     }
1014     return @matchingIndices; 
1015 }
1016
1017 sub hasArgument($$)
1018 {
1019     my ($argToCheck, $arrayRef) = @_;
1020     my @matchingIndices = findMatchingArguments($argToCheck, $arrayRef);
1021     return scalar @matchingIndices > 0;
1022 }
1023
1024 sub checkForArgumentAndRemoveFromArrayRef
1025 {
1026     my ($argToCheck, $arrayRef) = @_;
1027     my @indicesToRemove = findMatchingArguments($argToCheck, $arrayRef);
1028     my $removeOffset = 0;
1029     foreach my $index (@indicesToRemove) {
1030         splice(@$arrayRef, $index - $removeOffset++, 1);
1031     }
1032     return scalar @indicesToRemove > 0;
1033 }
1034
1035 sub determinePortName()
1036 {
1037     return if defined $portName;
1038
1039     my %argToPortName = (
1040         efl => Efl,
1041         gtk => GTK,
1042         wincairo => WinCairo
1043     );
1044
1045     for my $arg (sort keys %argToPortName) {
1046         if (checkForArgumentAndRemoveFromARGV("--$arg")) {
1047             die "Argument '--$arg' conflicts with selected port '$portName'"
1048                 if defined $portName;
1049
1050             $portName = $argToPortName{$arg};
1051         }
1052     }
1053
1054     return if defined $portName;
1055
1056     # Port was not selected via command line, use appropriate default value
1057
1058     if (isAnyWindows()) {
1059         $portName = AppleWin;
1060     } elsif (isDarwin()) {
1061         determineXcodeSDK();
1062         if (willUseIOSDeviceSDK() || willUseIOSSimulatorSDK()) {
1063             $portName = iOS;
1064         } else {
1065             $portName = Mac;
1066         }
1067     } else {
1068         die "Please choose which WebKit port to build";
1069     }
1070 }
1071
1072 sub portName()
1073 {
1074     determinePortName();
1075     return $portName;
1076 }
1077
1078 sub isEfl()
1079 {
1080     return portName() eq Efl;
1081 }
1082
1083 sub isGtk()
1084 {
1085     return portName() eq GTK;
1086 }
1087
1088 # Determine if this is debian, ubuntu, linspire, or something similar.
1089 sub isDebianBased()
1090 {
1091     return -e "/etc/debian_version";
1092 }
1093
1094 sub isFedoraBased()
1095 {
1096     return -e "/etc/fedora-release";
1097 }
1098
1099 sub isWinCairo()
1100 {
1101     return portName() eq WinCairo;
1102 }
1103
1104 sub isWin64()
1105 {
1106     determineIsWin64();
1107     return $isWin64;
1108 }
1109
1110 sub determineIsWin64()
1111 {
1112     return if defined($isWin64);
1113     $isWin64 = checkForArgumentAndRemoveFromARGV("--64-bit");
1114 }
1115
1116 sub determineIsWin64FromArchitecture($)
1117 {
1118     my $arch = shift;
1119     $isWin64 = ($arch eq "x86_64");
1120     return $isWin64;
1121 }
1122
1123 sub isCygwin()
1124 {
1125     return ($^O eq "cygwin") || 0;
1126 }
1127
1128 sub isAnyWindows()
1129 {
1130     return isWindows() || isCygwin();
1131 }
1132
1133 sub determineWinVersion()
1134 {
1135     return if $winVersion;
1136
1137     if (!isAnyWindows()) {
1138         $winVersion = -1;
1139         return;
1140     }
1141
1142     my $versionString = `cmd /c ver`;
1143     $versionString =~ /(\d)\.(\d)\.(\d+)/;
1144
1145     $winVersion = {
1146         major => $1,
1147         minor => $2,
1148         build => $3,
1149     };
1150 }
1151
1152 sub winVersion()
1153 {
1154     determineWinVersion();
1155     return $winVersion;
1156 }
1157
1158 sub isWindows7SP0()
1159 {
1160     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 1 && winVersion()->{build} == 7600;
1161 }
1162
1163 sub isWindowsVista()
1164 {
1165     return isAnyWindows() && winVersion()->{major} == 6 && winVersion()->{minor} == 0;
1166 }
1167
1168 sub isWindowsXP()
1169 {
1170     return isAnyWindows() && winVersion()->{major} == 5 && winVersion()->{minor} == 1;
1171 }
1172
1173 sub isDarwin()
1174 {
1175     return ($^O eq "darwin") || 0;
1176 }
1177
1178 sub isWindows()
1179 {
1180     return ($^O eq "MSWin32") || 0;
1181 }
1182
1183 sub isLinux()
1184 {
1185     return ($^O eq "linux") || 0;
1186 }
1187
1188 sub isBSD()
1189 {
1190     return ($^O eq "freebsd") || ($^O eq "openbsd") || ($^O eq "netbsd") || 0;
1191 }
1192
1193 sub isARM()
1194 {
1195     return ($Config{archname} =~ /^arm[v\-]/) || ($Config{archname} =~ /^aarch64[v\-]/);
1196 }
1197
1198 sub isX86_64()
1199 {
1200     return (architecture() eq "x86_64") || 0;
1201 }
1202
1203 sub isCrossCompilation()
1204 {
1205   my $compiler = "";
1206   $compiler = $ENV{'CC'} if (defined($ENV{'CC'}));
1207   if ($compiler =~ /gcc/) {
1208       my $compiler_options = `$compiler -v 2>&1`;
1209       my @host = $compiler_options =~ m/--host=(.*?)\s/;
1210       my @target = $compiler_options =~ m/--target=(.*?)\s/;
1211
1212       return ($host[0] ne "" && $target[0] ne "" && $host[0] ne $target[0]);
1213   }
1214   return 0;
1215 }
1216
1217 sub isAppleWebKit()
1218 {
1219     return isAppleMacWebKit() || isAppleWinWebKit();
1220 }
1221
1222 sub isAppleMacWebKit()
1223 {
1224     return (portName() eq Mac) || isIOSWebKit();
1225 }
1226
1227 sub isAppleWinWebKit()
1228 {
1229     return portName() eq AppleWin;
1230 }
1231
1232 sub iOSSimulatorDevicesPath
1233 {
1234     return "$ENV{HOME}/Library/Developer/CoreSimulator/Devices";
1235 }
1236
1237 sub iOSSimulatorDevices
1238 {
1239     eval "require Foundation";
1240     my $devicesPath = iOSSimulatorDevicesPath();
1241     opendir(DEVICES, $devicesPath);
1242     my @udids = grep {
1243         $_ =~ m/[0-9A-F]{8}-([0-9A-F]{4}-){3}[0-9A-F]{12}/;
1244     } readdir(DEVICES);
1245     close(DEVICES);
1246
1247     # FIXME: We should parse the device.plist file ourself and map the dictionary keys in it to known
1248     #        dictionary keys so as to decouple our representation of the plist from the actual structure
1249     #        of the plist, which may change.
1250     my @devices = map {
1251         Foundation::perlRefFromObjectRef(NSDictionary->dictionaryWithContentsOfFile_("$devicesPath/$_/device.plist"));
1252     } @udids;
1253
1254     return @devices;
1255 }
1256
1257 sub createiOSSimulatorDevice
1258 {
1259     my $name = shift;
1260     my $deviceTypeId = shift;
1261     my $runtimeId = shift;
1262
1263     my $created = system("xcrun", "--sdk", "iphonesimulator", "simctl", "create", $name, $deviceTypeId, $runtimeId) == 0;
1264     die "Couldn't create simulator device: $name $deviceTypeId $runtimeId" if not $created;
1265
1266     system("xcrun", "--sdk", "iphonesimulator", "simctl", "list");
1267
1268     print "Waiting for device to be created ...\n";
1269     sleep 5;
1270     for (my $tries = 0; $tries < 5; $tries++){
1271         my @devices = iOSSimulatorDevices();
1272         foreach my $device (@devices) {
1273             return $device if $device->{name} eq $name and $device->{deviceType} eq $deviceTypeId and $device->{runtime} eq $runtimeId;
1274         }
1275         sleep 5;
1276     }
1277     die "Device $name $deviceTypeId $runtimeId wasn't found in " . iOSSimulatorDevicesPath();
1278 }
1279
1280 sub willUseIOSDeviceSDK()
1281 {
1282     return xcodeSDKPlatformName() eq "iphoneos";
1283 }
1284
1285 sub willUseIOSSimulatorSDK()
1286 {
1287     return xcodeSDKPlatformName() eq "iphonesimulator";
1288 }
1289
1290 sub isIOSWebKit()
1291 {
1292     return portName() eq iOS;
1293 }
1294
1295 sub determineNmPath()
1296 {
1297     return if $nmPath;
1298
1299     if (isAppleMacWebKit()) {
1300         $nmPath = `xcrun -find nm`;
1301         chomp $nmPath;
1302     }
1303     $nmPath = "nm" if !$nmPath;
1304 }
1305
1306 sub nmPath()
1307 {
1308     determineNmPath();
1309     return $nmPath;
1310 }
1311
1312 sub splitVersionString
1313 {
1314     my $versionString = shift;
1315     my @splitVersion = split(/\./, $versionString);
1316     @splitVersion >= 2 or die "Invalid version $versionString";
1317     $osXVersion = {
1318             "major" => $splitVersion[0],
1319             "minor" => $splitVersion[1],
1320             "subminor" => (defined($splitVersion[2]) ? $splitVersion[2] : 0),
1321     };
1322 }
1323
1324 sub determineOSXVersion()
1325 {
1326     return if $osXVersion;
1327
1328     if (!isDarwin()) {
1329         $osXVersion = -1;
1330         return;
1331     }
1332
1333     my $versionString = `sw_vers -productVersion`;
1334     $osXVersion = splitVersionString($versionString);
1335 }
1336
1337 sub osXVersion()
1338 {
1339     determineOSXVersion();
1340     return $osXVersion;
1341 }
1342
1343 sub determineIOSVersion()
1344 {
1345     return if $iosVersion;
1346
1347     if (!isIOSWebKit()) {
1348         $iosVersion = -1;
1349         return;
1350     }
1351
1352     my $versionString = xcodeSDKVersion();
1353     $iosVersion = splitVersionString($versionString);
1354 }
1355
1356 sub iosVersion()
1357 {
1358     determineIOSVersion();
1359     return $iosVersion;
1360 }
1361
1362 sub isWindowsNT()
1363 {
1364     return $ENV{'OS'} eq 'Windows_NT';
1365 }
1366
1367 sub shouldTargetWebProcess
1368 {
1369     determineShouldTargetWebProcess();
1370     return $shouldTargetWebProcess;
1371 }
1372
1373 sub determineShouldTargetWebProcess
1374 {
1375     return if defined($shouldTargetWebProcess);
1376     $shouldTargetWebProcess = checkForArgumentAndRemoveFromARGV("--target-web-process");
1377 }
1378
1379 sub shouldUseXPCServiceForWebProcess
1380 {
1381     determineShouldUseXPCServiceForWebProcess();
1382     return $shouldUseXPCServiceForWebProcess;
1383 }
1384
1385 sub determineShouldUseXPCServiceForWebProcess
1386 {
1387     return if defined($shouldUseXPCServiceForWebProcess);
1388     $shouldUseXPCServiceForWebProcess = checkForArgumentAndRemoveFromARGV("--use-web-process-xpc-service");
1389 }
1390
1391 sub debugger
1392 {
1393     determineDebugger();
1394     return $debugger;
1395 }
1396
1397 sub determineDebugger
1398 {
1399     return if defined($debugger);
1400
1401     determineXcodeVersion();
1402     if (eval "v$xcodeVersion" ge v4.5) {
1403         $debugger = "lldb";
1404     } else {
1405         $debugger = "gdb";
1406     }
1407
1408     if (checkForArgumentAndRemoveFromARGV("--use-lldb")) {
1409         $debugger = "lldb";
1410     }
1411
1412     if (checkForArgumentAndRemoveFromARGV("--use-gdb")) {
1413         $debugger = "gdb";
1414     }
1415 }
1416
1417 sub appendToEnvironmentVariableList($$)
1418 {
1419     my ($name, $value) = @_;
1420
1421     if (defined($ENV{$name})) {
1422         $ENV{$name} .= $Config{path_sep} . $value;
1423     } else {
1424         $ENV{$name} = $value;
1425     }
1426 }
1427
1428 sub prependToEnvironmentVariableList($$)
1429 {
1430     my ($name, $value) = @_;
1431
1432     if (defined($ENV{$name})) {
1433         $ENV{$name} = $value . $Config{path_sep} . $ENV{$name};
1434     } else {
1435         $ENV{$name} = $value;
1436     }
1437 }
1438
1439 sub sharedCommandLineOptions()
1440 {
1441     return (
1442         "g|guard-malloc" => \$shouldUseGuardMalloc,
1443     );
1444 }
1445
1446 sub sharedCommandLineOptionsUsage
1447 {
1448     my %opts = @_;
1449
1450     my %switches = (
1451         '-g|--guard-malloc' => 'Use guardmalloc when running executable',
1452     );
1453
1454     my $indent = " " x ($opts{indent} || 2);
1455     my $switchWidth = List::Util::max(int($opts{switchWidth}), List::Util::max(map { length($_) } keys %switches) + ($opts{brackets} ? 2 : 0));
1456
1457     my $result = "Common switches:\n";
1458
1459     for my $switch (keys %switches) {
1460         my $switchName = $opts{brackets} ? "[" . $switch . "]" : $switch;
1461         $result .= sprintf("%s%-" . $switchWidth . "s %s\n", $indent, $switchName, $switches{$switch});
1462     }
1463
1464     return $result;
1465 }
1466
1467 sub setUpGuardMallocIfNeeded
1468 {
1469     if (!isDarwin()) {
1470         return;
1471     }
1472
1473     if (!defined($shouldUseGuardMalloc)) {
1474         $shouldUseGuardMalloc = checkForArgumentAndRemoveFromARGV("-g") || checkForArgumentAndRemoveFromARGV("--guard-malloc");
1475     }
1476
1477     if ($shouldUseGuardMalloc) {
1478         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", "/usr/lib/libgmalloc.dylib");
1479     }
1480 }
1481
1482 sub relativeScriptsDir()
1483 {
1484     my $scriptDir = File::Spec->catpath("", File::Spec->abs2rel($FindBin::Bin, getcwd()), "");
1485     if ($scriptDir eq "") {
1486         $scriptDir = ".";
1487     }
1488     return $scriptDir;
1489 }
1490
1491 sub launcherPath()
1492 {
1493     my $relativeScriptsPath = relativeScriptsDir();
1494     if (isGtk() || isEfl()) {
1495         return "$relativeScriptsPath/run-minibrowser";
1496     } elsif (isAppleWebKit()) {
1497         return "$relativeScriptsPath/run-safari";
1498     }
1499 }
1500
1501 sub launcherName()
1502 {
1503     if (isGtk() || isEfl()) {
1504         return "MiniBrowser";
1505     } elsif (isAppleMacWebKit()) {
1506         return "Safari";
1507     } elsif (isAppleWinWebKit()) {
1508         return "MiniBrowser";
1509     }
1510 }
1511
1512 sub checkRequiredSystemConfig
1513 {
1514     if (isDarwin()) {
1515         chomp(my $productVersion = `sw_vers -productVersion`);
1516         if (eval "v$productVersion" lt v10.7.5) {
1517             print "*************************************************************\n";
1518             print "Mac OS X Version 10.7.5 or later is required to build WebKit.\n";
1519             print "You have " . $productVersion . ", thus the build will most likely fail.\n";
1520             print "*************************************************************\n";
1521         }
1522         my $xcodebuildVersionOutput = `xcodebuild -version`;
1523         my $xcodeVersion = ($xcodebuildVersionOutput =~ /Xcode ([0-9](\.[0-9]+)*)/) ? $1 : undef;
1524         if (!$xcodeVersion || $xcodeVersion && eval "v$xcodeVersion" lt v4.6) {
1525             print "*************************************************************\n";
1526             print "Xcode Version 4.6 or later is required to build WebKit.\n";
1527             print "You have an earlier version of Xcode, thus the build will\n";
1528             print "most likely fail. The latest Xcode is available from the App Store.\n";
1529             print "*************************************************************\n";
1530         }
1531     }
1532 }
1533
1534 sub determineWindowsSourceDir()
1535 {
1536     return if $windowsSourceDir;
1537     $windowsSourceDir = sourceDir();
1538     chomp($windowsSourceDir = `cygpath -w '$windowsSourceDir'`) if isCygwin();
1539 }
1540
1541 sub windowsSourceDir()
1542 {
1543     determineWindowsSourceDir();
1544     return $windowsSourceDir;
1545 }
1546
1547 sub windowsSourceSourceDir()
1548 {
1549     return File::Spec->catdir(windowsSourceDir(), "Source");
1550 }
1551
1552 sub windowsLibrariesDir()
1553 {
1554     return File::Spec->catdir(windowsSourceDir(), "WebKitLibraries", "win");
1555 }
1556
1557 sub windowsOutputDir()
1558 {
1559     return File::Spec->catdir(windowsSourceDir(), "WebKitBuild");
1560 }
1561
1562 sub fontExists($)
1563 {
1564     my $font = shift;
1565     my $cmd = "reg query \"HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Fonts\\" . $font ."\" 2>&1";
1566     my $val = `$cmd`;
1567     return $? == 0;
1568 }
1569
1570 sub checkInstalledTools()
1571 {
1572     # environment variables. Avoid until this is corrected.
1573     my $pythonVer = `python --version 2>&1`;
1574     die "You must have Python installed to build WebKit.\n" if ($?);
1575
1576     # cURL 7.34.0 has a bug that prevents authentication with opensource.apple.com (and other things using SSL3).
1577     my $curlVer = `curl --version 2> NUL`;
1578     if (!$? and $curlVer =~ "(.*curl.*)") {
1579         $curlVer = $1;
1580         if ($curlVer =~ /libcurl\/7\.34\.0/) {
1581             print "cURL version 7.34.0 has a bug that prevents authentication with SSL v2 or v3.\n";
1582             print "cURL 7.33.0 is known to work. The cURL projects is preparing an update to\n";
1583             print "correct this problem.\n\n";
1584             die "Please install a working cURL and try again.\n";
1585         }
1586     }
1587
1588     # MathML requires fonts that do not ship with Windows (at least through Windows 8). Warn the user if they are missing
1589     my @fonts = qw(STIXGeneral-Regular MathJax_Main-Regular);
1590     my @missing = ();
1591     foreach my $font (@fonts) {
1592         push @missing, $font if not fontExists($font);
1593     }
1594
1595     if (scalar @missing > 0) {
1596         print "*************************************************************\n";
1597         print "Mathematical fonts, such as STIX and MathJax, are needed to\n";
1598         print "use the MathML feature.  You do not appear to have these fonts\n";
1599         print "on your system.\n\n";
1600         print "You can download a suitable set of fonts from the following URL:\n";
1601         print "https://developer.mozilla.org/Mozilla/MathML_Projects/Fonts\n";
1602         print "*************************************************************\n";
1603     }
1604
1605     print "Installed tools are correct for the WebKit build.\n";
1606 }
1607
1608 sub setupAppleWinEnv()
1609 {
1610     return unless isAppleWinWebKit();
1611
1612     checkInstalledTools();
1613
1614     if (isWindowsNT()) {
1615         my $restartNeeded = 0;
1616         my %variablesToSet = ();
1617
1618         # FIXME: We should remove this explicit version check for cygwin once we stop supporting Cygwin 1.7.9 or older versions. 
1619         # https://bugs.webkit.org/show_bug.cgi?id=85791
1620         my $uname_version = (POSIX::uname())[2];
1621         $uname_version =~ s/\(.*\)//;  # Remove the trailing cygwin version, if any.
1622         $uname_version =~ s/\-.*$//; # Remove trailing dash-version content, if any
1623         if (version->parse($uname_version) < version->parse("1.7.10")) {
1624             # Setting the environment variable 'CYGWIN' to 'tty' makes cygwin enable extra support (i.e., termios)
1625             # for UNIX-like ttys in the Windows console
1626             $variablesToSet{CYGWIN} = "tty" unless $ENV{CYGWIN};
1627         }
1628         
1629         # Those environment variables must be set to be able to build inside Visual Studio.
1630         $variablesToSet{WEBKIT_LIBRARIES} = windowsLibrariesDir() unless $ENV{WEBKIT_LIBRARIES};
1631         $variablesToSet{WEBKIT_OUTPUTDIR} = windowsOutputDir() unless $ENV{WEBKIT_OUTPUTDIR};
1632         $variablesToSet{MSBUILDDISABLENODEREUSE} = "1" unless $ENV{MSBUILDDISABLENODEREUSE};
1633         $variablesToSet{_IsNativeEnvironment} = "true" unless $ENV{_IsNativeEnvironment};
1634         $variablesToSet{PreferredToolArchitecture} = "x64" unless $ENV{PreferredToolArchitecture};
1635
1636         foreach my $variable (keys %variablesToSet) {
1637             print "Setting the Environment Variable '" . $variable . "' to '" . $variablesToSet{$variable} . "'\n\n";
1638             my $ret = system "setx", $variable, $variablesToSet{$variable};
1639             if ($ret != 0) {
1640                 system qw(regtool -s set), '\\HKEY_CURRENT_USER\\Environment\\' . $variable, $variablesToSet{$variable};
1641             }
1642             $restartNeeded ||=  $variable eq "WEBKIT_LIBRARIES" || $variable eq "WEBKIT_OUTPUTDIR";
1643         }
1644
1645         if ($restartNeeded) {
1646             print "Please restart your computer before attempting to build inside Visual Studio.\n\n";
1647         }
1648     } else {
1649         if (!defined $ENV{'WEBKIT_LIBRARIES'} || !$ENV{'WEBKIT_LIBRARIES'}) {
1650             print "Warning: You must set the 'WebKit_Libraries' environment variable\n";
1651             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n";
1652             print "         Make sure that 'WebKit_Libraries' points to the\n";
1653             print "         'WebKitLibraries/win' directory, not the 'WebKitLibraries/' directory.\n\n";
1654         }
1655         if (!defined $ENV{'WEBKIT_OUTPUTDIR'} || !$ENV{'WEBKIT_OUTPUTDIR'}) {
1656             print "Warning: You must set the 'WebKit_OutputDir' environment variable\n";
1657             print "         to be able build WebKit from within Visual Studio 2013 and newer.\n\n";
1658         }
1659         if (!defined $ENV{'MSBUILDDISABLENODEREUSE'} || !$ENV{'MSBUILDDISABLENODEREUSE'}) {
1660             print "Warning: You should set the 'MSBUILDDISABLENODEREUSE' environment variable to '1'\n";
1661             print "         to avoid periodic locked log files when building.\n\n";
1662         }
1663     }
1664     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1665     if (isWin64() and !$ENV{'WEBKIT_64_SUPPORT'}) {
1666         print "Warning: You must set the 'WEBKIT_64_SUPPORT' environment variable\n";
1667         print "         to be able run WebKit or JavaScriptCore tests.\n\n";
1668     }
1669 }
1670
1671 sub setupCygwinEnv()
1672 {
1673     return if !isCygwin() && !isWindows();
1674     return if $vcBuildPath;
1675
1676     my $programFilesPath = programFilesPath();
1677     my $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.com));
1678     if (-e $visualStudioPath) {
1679         # Visual Studio is installed;
1680         if (visualStudioVersion() eq "12") {
1681             $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE devenv.exe));
1682         }
1683     } else {
1684         # Visual Studio not found, try VC++ Express
1685         $visualStudioPath = File::Spec->catfile(visualStudioInstallDir(), qw(Common7 IDE WDExpress.exe));
1686         if (! -e $visualStudioPath) {
1687             print "*************************************************************\n";
1688             print "Cannot find '$visualStudioPath'\n";
1689             print "Please execute the file 'vcvars32.bat' from\n";
1690             print "'$programFilesPath\\Microsoft Visual Studio 14.0\\VC\\bin\\'\n";
1691             print "to setup the necessary environment variables.\n";
1692             print "*************************************************************\n";
1693             die;
1694         }
1695         $willUseVCExpressWhenBuilding = 1;
1696     }
1697
1698     print "Building results into: ", baseProductDir(), "\n";
1699     print "WEBKIT_OUTPUTDIR is set to: ", $ENV{"WEBKIT_OUTPUTDIR"}, "\n";
1700     print "WEBKIT_LIBRARIES is set to: ", $ENV{"WEBKIT_LIBRARIES"}, "\n";
1701     # FIXME (125180): Remove the following temporary 64-bit support once official support is available.
1702     print "WEBKIT_64_SUPPORT is set to: ", $ENV{"WEBKIT_64_SUPPORT"}, "\n" if isWin64();
1703
1704     # We will actually use MSBuild to build WebKit, but we need to find the Visual Studio install (above) to make
1705     # sure we use the right options.
1706     $vcBuildPath = File::Spec->catfile(msBuildInstallDir(), qw(MSBuild.exe));
1707     if (! -e $vcBuildPath) {
1708         print "*************************************************************\n";
1709         print "Cannot find '$vcBuildPath'\n";
1710         print "Please make sure execute that the Microsoft .NET Framework SDK\n";
1711         print "is installed on this machine.\n";
1712         print "*************************************************************\n";
1713         die;
1714     }
1715 }
1716
1717 sub dieIfWindowsPlatformSDKNotInstalled
1718 {
1719     my $registry32Path = "/proc/registry/";
1720     my $registry64Path = "/proc/registry64/";
1721     my @windowsPlatformSDKRegistryEntries = (
1722         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0A",
1723         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v8.0",
1724         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.1A",
1725         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Microsoft SDKs/Windows/v7.0A",
1726         "HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/MicrosoftSDK/InstalledSDKs/D2FF9F89-8AA2-4373-8A31-C838BF4DBBE1",
1727     );
1728
1729     # FIXME: It would be better to detect whether we are using 32- or 64-bit Windows
1730     # and only check the appropriate entry. But for now we just blindly check both.
1731     my $recommendedPlatformSDK = $windowsPlatformSDKRegistryEntries[0];
1732
1733     while (@windowsPlatformSDKRegistryEntries) {
1734         my $windowsPlatformSDKRegistryEntry = shift @windowsPlatformSDKRegistryEntries;
1735         return if (-e $registry32Path . $windowsPlatformSDKRegistryEntry) || (-e $registry64Path . $windowsPlatformSDKRegistryEntry);
1736     }
1737
1738     print "*************************************************************\n";
1739     print "Cannot find registry entry '$recommendedPlatformSDK'.\n";
1740     print "Please download and install the Microsoft Windows SDK\n";
1741     print "from <http://www.microsoft.com/en-us/download/details.aspx?id=8279>.\n\n";
1742     print "Then follow step 2 in the Windows section of the \"Installing Developer\n";
1743     print "Tools\" instructions at <http://www.webkit.org/building/tools.html>.\n";
1744     print "*************************************************************\n";
1745     die;
1746 }
1747
1748 sub buildXCodeProject($$@)
1749 {
1750     my ($project, $clean, @extraOptions) = @_;
1751
1752     if ($clean) {
1753         push(@extraOptions, "-alltargets");
1754         push(@extraOptions, "clean");
1755     }
1756
1757     push(@extraOptions, ("-sdk", xcodeSDK())) if isIOSWebKit();
1758
1759     chomp($ENV{DSYMUTIL_NUM_THREADS} = `sysctl -n hw.activecpu`);
1760     return system "xcodebuild", "-project", "$project.xcodeproj", @extraOptions;
1761 }
1762
1763 sub usingVisualStudioExpress()
1764 {
1765     setupCygwinEnv();
1766     return $willUseVCExpressWhenBuilding;
1767 }
1768
1769 sub buildVisualStudioProject
1770 {
1771     my ($project, $clean) = @_;
1772     setupCygwinEnv();
1773
1774     my $config = configurationForVisualStudio();
1775
1776     dieIfWindowsPlatformSDKNotInstalled() if $willUseVCExpressWhenBuilding;
1777
1778     chomp($project = `cygpath -w "$project"`) if isCygwin();
1779
1780     my $action = "/t:build";
1781     if ($clean) {
1782         $action = "/t:clean";
1783     }
1784
1785     my $platform = "/p:Platform=" . (isWin64() ? "x64" : "Win32");
1786     my $logPath = File::Spec->catdir($baseProductDir, $configuration);
1787     make_path($logPath) unless -d $logPath or $logPath eq ".";
1788
1789     my $errorLogFile = File::Spec->catfile($logPath, "webkit_errors.log");
1790     chomp($errorLogFile = `cygpath -w "$errorLogFile"`) if isCygwin();
1791     my $errorLogging = "/flp:LogFile=" . $errorLogFile . ";ErrorsOnly";
1792
1793     my $warningLogFile = File::Spec->catfile($logPath, "webkit_warnings.log");
1794     chomp($warningLogFile = `cygpath -w "$warningLogFile"`) if isCygwin();
1795     my $warningLogging = "/flp1:LogFile=" . $warningLogFile . ";WarningsOnly";
1796
1797     my @command = ($vcBuildPath, "/verbosity:minimal", $project, $action, $config, $platform, "/fl", $errorLogging, "/fl1", $warningLogging);
1798     print join(" ", @command), "\n";
1799     return system @command;
1800 }
1801
1802 sub getJhbuildPath()
1803 {
1804     my @jhbuildPath = File::Spec->splitdir(baseProductDir());
1805     if (isGit() && isGitBranchBuild() && gitBranch()) {
1806         pop(@jhbuildPath);
1807     }
1808     if (isEfl()) {
1809         push(@jhbuildPath, "DependenciesEFL");
1810     } elsif (isGtk()) {
1811         push(@jhbuildPath, "DependenciesGTK");
1812     } else {
1813         die "Cannot get JHBuild path for platform that isn't GTK+ or EFL.\n";
1814     }
1815     return File::Spec->catdir(@jhbuildPath);
1816 }
1817
1818 sub isCachedArgumentfileOutOfDate($@)
1819 {
1820     my ($filename, $currentContents) = @_;
1821
1822     if (! -e $filename) {
1823         return 1;
1824     }
1825
1826     open(CONTENTS_FILE, $filename);
1827     chomp(my $previousContents = <CONTENTS_FILE>);
1828     close(CONTENTS_FILE);
1829
1830     if ($previousContents ne $currentContents) {
1831         print "Contents for file $filename have changed.\n";
1832         print "Previous contents were: $previousContents\n\n";
1833         print "New contents are: $currentContents\n";
1834         return 1;
1835     }
1836
1837     return 0;
1838 }
1839
1840 sub wrapperPrefixIfNeeded()
1841 {
1842     if (isWindows() || isCygwin()) {
1843         return ();
1844     }
1845     if (isAppleMacWebKit()) {
1846         return ("xcrun");
1847     }
1848     if (-e getJhbuildPath()) {
1849         my @prefix = (File::Spec->catfile(sourceDir(), "Tools", "jhbuild", "jhbuild-wrapper"));
1850         if (isEfl()) {
1851             push(@prefix, "--efl");
1852         } elsif (isGtk()) {
1853             push(@prefix, "--gtk");
1854         }
1855         push(@prefix, "run");
1856
1857         return @prefix;
1858     }
1859
1860     return ();
1861 }
1862
1863 sub cmakeCachePath()
1864 {
1865     return File::Spec->catdir(baseProductDir(), configuration(), "CMakeCache.txt");
1866 }
1867
1868 sub shouldRemoveCMakeCache(@)
1869 {
1870     my ($cacheFilePath, @buildArgs) = @_;
1871
1872     # We check this first, because we always want to create this file for a fresh build.
1873     my $productDir = File::Spec->catdir(baseProductDir(), configuration());
1874     my $optionsCache = File::Spec->catdir($productDir, "build-webkit-options.txt");
1875     my $joinedBuildArgs = join(" ", @buildArgs);
1876     if (isCachedArgumentfileOutOfDate($optionsCache, $joinedBuildArgs)) {
1877         File::Path::mkpath($productDir) unless -d $productDir;
1878         open(CACHED_ARGUMENTS, ">", $optionsCache);
1879         print CACHED_ARGUMENTS $joinedBuildArgs;
1880         close(CACHED_ARGUMENTS);
1881
1882         return 1;
1883     }
1884
1885     my $cmakeCache = cmakeCachePath();
1886     unless (-e $cmakeCache) {
1887         return 0;
1888     }
1889
1890     my $cacheFileModifiedTime = stat($cmakeCache)->mtime;
1891     my $platformConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "Options" . cmakeBasedPortName() . ".cmake");
1892     if ($cacheFileModifiedTime < stat($platformConfiguration)->mtime) {
1893         return 1;
1894     }
1895
1896     my $globalConfiguration = File::Spec->catdir(sourceDir(), "Source", "cmake", "OptionsCommon.cmake");
1897     if ($cacheFileModifiedTime < stat($globalConfiguration)->mtime) {
1898         return 1;
1899     }
1900
1901     my $inspectorUserInterfaceDircetory = File::Spec->catdir(sourceDir(), "Source", "WebInspectorUI", "UserInterface");
1902     if ($cacheFileModifiedTime < stat($inspectorUserInterfaceDircetory)->mtime) {
1903         return 1;
1904     }
1905
1906     return 0;
1907 }
1908
1909 sub removeCMakeCache(@)
1910 {
1911     my (@buildArgs) = @_;
1912     if (shouldRemoveCMakeCache(@buildArgs)) {
1913         my $cmakeCache = cmakeCachePath();
1914         unlink($cmakeCache) if -e $cmakeCache;
1915     }
1916 }
1917
1918 sub canUseNinja(@)
1919 {
1920     if (!defined($shouldNotUseNinja)) {
1921         $shouldNotUseNinja = checkForArgumentAndRemoveFromARGV("--no-ninja");
1922     }
1923
1924     if ($shouldNotUseNinja) {
1925         return 0;
1926     }
1927
1928     # Test both ninja and ninja-build. Fedora uses ninja-build and has patched CMake to also call ninja-build.
1929     return commandExists("ninja") || commandExists("ninja-build");
1930 }
1931
1932 sub canUseNinjaGenerator(@)
1933 {
1934     # Check that a Ninja generator is installed
1935     my $devnull = File::Spec->devnull();
1936     return exitStatus(system("cmake -N -G Ninja >$devnull 2>&1")) == 0;
1937 }
1938
1939 sub canUseEclipseNinjaGenerator(@)
1940 {
1941     # Check that eclipse and eclipse Ninja generator is installed
1942     my $devnull = File::Spec->devnull();
1943     return commandExists("eclipse") && exitStatus(system("cmake -N -G 'Eclipse CDT4 - Ninja' >$devnull 2>&1")) == 0;
1944 }
1945
1946 sub cmakeGeneratedBuildfile(@)
1947 {
1948     my ($willUseNinja) = @_;
1949     if ($willUseNinja) {
1950         return File::Spec->catfile(baseProductDir(), configuration(), "build.ninja")
1951     } elsif (isWindows() || isCygwin()) {
1952         return File::Spec->catfile(baseProductDir(), configuration(), "WebKit.sln")
1953     } else {
1954         return File::Spec->catfile(baseProductDir(), configuration(), "Makefile")
1955     }
1956 }
1957
1958 sub generateBuildSystemFromCMakeProject
1959 {
1960     my ($prefixPath, @cmakeArgs, $additionalCMakeArgs) = @_;
1961     my $config = configuration();
1962     my $port = cmakeBasedPortName();
1963     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
1964     File::Path::mkpath($buildPath) unless -d $buildPath;
1965     my $originalWorkingDirectory = getcwd();
1966     chdir($buildPath) or die;
1967
1968     # We try to be smart about when to rerun cmake, so that we can have faster incremental builds.
1969     my $willUseNinja = canUseNinja() && canUseNinjaGenerator();
1970     if (-e cmakeCachePath() && -e cmakeGeneratedBuildfile($willUseNinja)) {
1971         return 0;
1972     }
1973
1974     my @args;
1975     push @args, "-DPORT=\"$port\"";
1976     push @args, "-DCMAKE_INSTALL_PREFIX=\"$prefixPath\"" if $prefixPath;
1977     push @args, "-DCMAKE_EXPORT_COMPILE_COMMANDS=ON" if isGtk();
1978     if ($config =~ /release/i) {
1979         push @args, "-DCMAKE_BUILD_TYPE=Release";
1980     } elsif ($config =~ /debug/i) {
1981         push @args, "-DCMAKE_BUILD_TYPE=Debug";
1982     }
1983
1984     if ($willUseNinja) {
1985         push @args, "-G";
1986         if (canUseEclipseNinjaGenerator()) {
1987             push @args, "'Eclipse CDT4 - Ninja'";
1988         } else {
1989             push @args, "Ninja";
1990         }
1991     } elsif (isAnyWindows() && isWin64()) {
1992         push @args, '-G "Visual Studio 14 2015 Win64"';
1993     }
1994
1995     # GTK+ has a production mode, but build-webkit should always use developer mode.
1996     push @args, "-DDEVELOPER_MODE=ON" if isEfl() || isGtk();
1997
1998     # Don't warn variables which aren't used by cmake ports.
1999     push @args, "--no-warn-unused-cli";
2000     push @args, @cmakeArgs if @cmakeArgs;
2001     push @args, $additionalCMakeArgs if $additionalCMakeArgs;
2002
2003     my $cmakeSourceDir = isCygwin() ? windowsSourceDir() : sourceDir();
2004     push @args, '"' . $cmakeSourceDir . '"';
2005
2006     # Compiler options to keep floating point values consistent
2007     # between 32-bit and 64-bit architectures.
2008     determineArchitecture();
2009     if ($architecture ne "x86_64" && !isARM() && !isCrossCompilation() && !isWindows() && !isCygwin()) {
2010         $ENV{'CXXFLAGS'} = "-march=pentium4 -msse2 -mfpmath=sse " . ($ENV{'CXXFLAGS'} || "");
2011     }
2012
2013     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
2014     # parsed for shell metacharacters.
2015     my $wrapper = join(" ", wrapperPrefixIfNeeded()) . " ";
2016     my $returnCode = system($wrapper . "cmake @args");
2017
2018     chdir($originalWorkingDirectory);
2019     return $returnCode;
2020 }
2021
2022 sub buildCMakeGeneratedProject($)
2023 {
2024     my ($makeArgs) = @_;
2025     my $config = configuration();
2026     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2027     if (! -d $buildPath) {
2028         die "Must call generateBuildSystemFromCMakeProject() before building CMake project.";
2029     }
2030
2031     my $command = "cmake";
2032     my @args = ("--build", $buildPath, "--config", $config);
2033     push @args, ("--", $makeArgs) if $makeArgs;
2034
2035     # GTK can use a build script to preserve colors and pretty-printing.
2036     if (isGtk() && -e "$buildPath/build.sh") {
2037         chdir "$buildPath" or die;
2038         $command = "$buildPath/build.sh";
2039         @args = ($makeArgs);
2040     }
2041
2042     if ($ENV{VERBOSE} && canUseNinja()) {
2043         push @args, "-v";
2044         push @args, "-d keeprsp" if (version->parse(determineNinjaVersion()) >= version->parse("1.4.0"));
2045     }
2046
2047     # We call system("cmake @args") instead of system("cmake", @args) so that @args is
2048     # parsed for shell metacharacters. In particular, $makeArgs may contain such metacharacters.
2049     my $wrapper = join(" ", wrapperPrefixIfNeeded()) . " ";
2050     return system($wrapper . "$command @args");
2051 }
2052
2053 sub cleanCMakeGeneratedProject()
2054 {
2055     my $config = configuration();
2056     my $buildPath = File::Spec->catdir(baseProductDir(), $config);
2057     if (-d $buildPath) {
2058         return system("cmake", "--build", $buildPath, "--config", $config, "--target", "clean");
2059     }
2060     return 0;
2061 }
2062
2063 sub buildCMakeProjectOrExit($$$@)
2064 {
2065     my ($clean, $prefixPath, $makeArgs, @cmakeArgs) = @_;
2066     my $returnCode;
2067
2068     exit(exitStatus(cleanCMakeGeneratedProject())) if $clean;
2069
2070     if (isEfl() && checkForArgumentAndRemoveFromARGV("--update-efl")) {
2071         system("perl", "$sourceDir/Tools/Scripts/update-webkitefl-libs") == 0 or die $!;
2072     }
2073
2074     if (isGtk() && checkForArgumentAndRemoveFromARGV("--update-gtk")) {
2075         system("perl", "$sourceDir/Tools/Scripts/update-webkitgtk-libs") == 0 or die $!;
2076     }
2077
2078     $returnCode = exitStatus(generateBuildSystemFromCMakeProject($prefixPath, @cmakeArgs));
2079     exit($returnCode) if $returnCode;
2080
2081     $returnCode = exitStatus(buildCMakeGeneratedProject($makeArgs));
2082     exit($returnCode) if $returnCode;
2083     return 0;
2084 }
2085
2086 sub cmakeBasedPortArguments()
2087 {
2088     return ();
2089 }
2090
2091 sub cmakeBasedPortName()
2092 {
2093     return portName();
2094 }
2095
2096 sub determineIsCMakeBuild()
2097 {
2098     return if defined($isCMakeBuild);
2099     $isCMakeBuild = checkForArgumentAndRemoveFromARGV("--cmake");
2100 }
2101
2102 sub isCMakeBuild()
2103 {
2104     return 1 unless isAppleMacWebKit();
2105     determineIsCMakeBuild();
2106     return $isCMakeBuild;
2107 }
2108
2109 sub promptUser
2110 {
2111     my ($prompt, $default) = @_;
2112     my $defaultValue = $default ? "[$default]" : "";
2113     print "$prompt $defaultValue: ";
2114     chomp(my $input = <STDIN>);
2115     return $input ? $input : $default;
2116 }
2117
2118 sub appleApplicationSupportPath
2119 {
2120     open INSTALL_DIR, "</proc/registry/HKEY_LOCAL_MACHINE/SOFTWARE/Apple\ Inc./Apple\ Application\ Support/InstallDir";
2121     my $path = <INSTALL_DIR>;
2122     $path =~ s/[\r\n\x00].*//;
2123     close INSTALL_DIR;
2124
2125     my $unixPath = `cygpath -u '$path'`;
2126     chomp $unixPath;
2127     return $unixPath;
2128 }
2129
2130 sub setPathForRunningWebKitApp
2131 {
2132     my ($env) = @_;
2133
2134     if (isAnyWindows()) {
2135         my $productBinaryDir = executableProductDir();
2136         if (isAppleWinWebKit()) {
2137             $env->{PATH} = join(':', $productBinaryDir, appleApplicationSupportPath(), $env->{PATH} || "");
2138         } elsif (isWinCairo()) {
2139             my $winCairoBin = sourceDir() . "/WebKitLibraries/win/" . (isWin64() ? "bin64/" : "bin32/");
2140             my $gstreamerBin = isWin64() ? $ENV{"GSTREAMER_1_0_ROOT_X86_64"} . "bin" : $ENV{"GSTREAMER_1_0_ROOT_X86"} . "bin";
2141             $env->{PATH} = join(':', $productBinaryDir, $winCairoBin, $gstreamerBin, $env->{PATH} || "");
2142         }
2143     }
2144 }
2145
2146 sub printHelpAndExitForRunAndDebugWebKitAppIfNeeded
2147 {
2148     return unless checkForArgumentAndRemoveFromARGV("--help");
2149
2150     my ($includeOptionsForDebugging) = @_;
2151
2152     print STDERR <<EOF;
2153 Usage: @{[basename($0)]} [options] [args ...]
2154   --help                            Show this help message
2155   --no-saved-state                  Launch the application without state restoration (OS X 10.7 and later)
2156   -g|--guard-malloc                 Enable Guard Malloc (OS X only)
2157   --use-web-process-xpc-service     Launch the Web Process as an XPC Service (OS X only)
2158 EOF
2159
2160     if ($includeOptionsForDebugging) {
2161         print STDERR <<EOF;
2162   --target-web-process              Debug the web process
2163   --use-gdb                         Use GDB (this is the default when using Xcode 4.4 or earlier)
2164   --use-lldb                        Use LLDB (this is the default when using Xcode 4.5 or later)
2165 EOF
2166     }
2167
2168     exit(1);
2169 }
2170
2171 sub argumentsForRunAndDebugMacWebKitApp()
2172 {
2173     my @args = ();
2174     if (checkForArgumentAndRemoveFromARGV("--no-saved-state")) {
2175         push @args, ("-ApplePersistenceIgnoreStateQuietly", "YES");
2176         # FIXME: Don't set ApplePersistenceIgnoreState once all supported OS versions respect ApplePersistenceIgnoreStateQuietly (rdar://15032886).
2177         push @args, ("-ApplePersistenceIgnoreState", "YES");
2178     }
2179     push @args, ("-WebKit2UseXPCServiceForWebProcess", "YES") if shouldUseXPCServiceForWebProcess();
2180     unshift @args, @ARGV;
2181
2182     return @args;
2183 }
2184
2185 sub setupMacWebKitEnvironment($)
2186 {
2187     my ($dyldFrameworkPath) = @_;
2188
2189     $dyldFrameworkPath = File::Spec->rel2abs($dyldFrameworkPath);
2190
2191     prependToEnvironmentVariableList("DYLD_FRAMEWORK_PATH", $dyldFrameworkPath);
2192     prependToEnvironmentVariableList("__XPC_DYLD_FRAMEWORK_PATH", $dyldFrameworkPath);
2193     $ENV{WEBKIT_UNSET_DYLD_FRAMEWORK_PATH} = "YES";
2194
2195     setUpGuardMallocIfNeeded();
2196 }
2197
2198 sub setupIOSWebKitEnvironment($)
2199 {
2200     my ($dyldFrameworkPath) = @_;
2201     $dyldFrameworkPath = File::Spec->rel2abs($dyldFrameworkPath);
2202
2203     prependToEnvironmentVariableList("DYLD_FRAMEWORK_PATH", $dyldFrameworkPath);
2204     prependToEnvironmentVariableList("DYLD_LIBRARY_PATH", $dyldFrameworkPath);
2205
2206     setUpGuardMallocIfNeeded();
2207 }
2208
2209 sub iosSimulatorApplicationsPath()
2210 {
2211     return File::Spec->catdir(XcodeSDKPath(), "Applications");
2212 }
2213
2214 sub installedMobileSafariBundle()
2215 {
2216     return File::Spec->catfile(iosSimulatorApplicationsPath(), "MobileSafari.app");
2217 }
2218
2219 sub mobileSafariBundle()
2220 {
2221     determineConfigurationProductDir();
2222
2223     # Use MobileSafari.app in product directory if present.
2224     if (isAppleMacWebKit() && -d "$configurationProductDir/MobileSafari.app") {
2225         return "$configurationProductDir/MobileSafari.app";
2226     }
2227     return installedMobileSafariBundle();
2228 }
2229
2230 sub plistPathFromBundle($)
2231 {
2232     my ($appBundle) = @_;
2233     return "$appBundle/Info.plist" if -f "$appBundle/Info.plist"; # iOS app bundle
2234     return "$appBundle/Contents/Info.plist" if -f "$appBundle/Contents/Info.plist"; # Mac app bundle
2235     return "";
2236 }
2237
2238 sub appIdentifierFromBundle($)
2239 {
2240     my ($appBundle) = @_;
2241     my $plistPath = File::Spec->rel2abs(plistPathFromBundle($appBundle)); # defaults(1) will complain if the specified path is not absolute.
2242     chomp(my $bundleIdentifier = `defaults read '$plistPath' CFBundleIdentifier 2> /dev/null`);
2243     return $bundleIdentifier;
2244 }
2245
2246 sub appDisplayNameFromBundle($)
2247 {
2248     my ($appBundle) = @_;
2249     my $plistPath = File::Spec->rel2abs(plistPathFromBundle($appBundle)); # defaults(1) will complain if the specified path is not absolute.
2250     chomp(my $bundleDisplayName = `defaults read '$plistPath' CFBundleDisplayName 2> /dev/null`);
2251     return $bundleDisplayName;
2252 }
2253
2254 sub waitUntilIOSSimulatorDeviceIsInState($$)
2255 {
2256     my ($deviceUDID, $waitUntilState) = @_;
2257     my $device = iosSimulatorDeviceByUDID($deviceUDID);
2258     while ($device->{state} ne $waitUntilState) {
2259         usleep(500 * 1000); # Waiting 500ms between file system polls does not make script run-safari feel sluggish.
2260         $device = iosSimulatorDeviceByUDID($deviceUDID);
2261     }
2262 }
2263
2264 sub shutDownIOSSimulatorDevice($)
2265 {
2266     my ($simulatorDevice) = @_;
2267     system("xcrun --sdk iphonesimulator simctl shutdown $simulatorDevice->{UDID} > /dev/null 2>&1");
2268 }
2269
2270 sub restartIOSSimulatorDevice($)
2271 {
2272     my ($simulatorDevice) = @_;
2273     shutDownIOSSimulatorDevice($simulatorDevice);
2274
2275     exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "boot", $simulatorDevice->{UDID})) == 0 or die "Failed to boot simulator device $simulatorDevice->{UDID}";
2276 }
2277
2278 sub relaunchIOSSimulator($)
2279 {
2280     my ($simulatedDevice) = @_;
2281     quitIOSSimulator($simulatedDevice->{UDID});
2282
2283     # FIXME: <rdar://problem/20916140> Switch to using CoreSimulator.framework for launching and quitting iOS Simulator
2284     my $iosSimulatorBundleID = "com.apple.iphonesimulator";
2285     system("open", "-b", $iosSimulatorBundleID, "--args", "-CurrentDeviceUDID", $simulatedDevice->{UDID}) == 0 or die "Failed to open $iosSimulatorBundleID: $!";
2286
2287     waitUntilIOSSimulatorDeviceIsInState($simulatedDevice->{UDID}, SIMULATOR_DEVICE_STATE_BOOTED);
2288 }
2289
2290 sub quitIOSSimulator(;$)
2291 {
2292     my ($waitForShutdownOfSimulatedDeviceUDID) = @_;
2293     # FIXME: <rdar://problem/20916140> Switch to using CoreSimulator.framework for launching and quitting iOS Simulator
2294     exitStatus(system {"osascript"} "osascript", "-e", 'tell application id "com.apple.iphonesimulator" to quit') == 0 or die "Failed to quit iOS Simulator: $!";
2295     if (!defined($waitForShutdownOfSimulatedDeviceUDID)) {
2296         return;
2297     }
2298     # FIXME: We assume that $waitForShutdownOfSimulatedDeviceUDID was not booted using the simctl command line tool.
2299     #        Otherwise we will spin indefinitely since quiting the iOS Simulator will not shutdown this device. We
2300     #        should add a maximum time limit to wait for a device to shutdown and either return an error or die()
2301     #        on expiration of the time limit.
2302     waitUntilIOSSimulatorDeviceIsInState($waitForShutdownOfSimulatedDeviceUDID, SIMULATOR_DEVICE_STATE_SHUTDOWN);
2303 }
2304
2305 sub iosSimulatorDeviceByName($)
2306 {
2307     my ($simulatorName) = @_;
2308     my $simulatorRuntime = iosSimulatorRuntime();
2309     my @devices = iOSSimulatorDevices();
2310     for my $device (@devices) {
2311         if ($device->{name} eq $simulatorName && $device->{runtime} eq $simulatorRuntime) {
2312             return $device;
2313         }
2314     }
2315     return undef;
2316 }
2317
2318 sub iosSimulatorDeviceByUDID($)
2319 {
2320     my ($simulatedDeviceUDID) = @_;
2321     my $devicePlistPath = File::Spec->catfile(iOSSimulatorDevicesPath(), $simulatedDeviceUDID, "device.plist");
2322     if (!-f $devicePlistPath) {
2323         return;
2324     }
2325     # FIXME: We should parse the device.plist file ourself and map the dictionary keys in it to known
2326     #        dictionary keys so as to decouple our representation of the plist from the actual structure
2327     #        of the plist, which may change.
2328     eval "require Foundation";
2329     return Foundation::perlRefFromObjectRef(NSDictionary->dictionaryWithContentsOfFile_($devicePlistPath));
2330 }
2331
2332 sub iosSimulatorRuntime()
2333 {
2334     my $xcodeSDKVersion = xcodeSDKVersion();
2335     $xcodeSDKVersion =~ s/\./-/;
2336     return "com.apple.CoreSimulator.SimRuntime.iOS-$xcodeSDKVersion";
2337 }
2338
2339 sub findOrCreateSimulatorForIOSDevice($)
2340 {
2341     my ($simulatorNameSuffix) = @_;
2342     my $simulatorName;
2343     my $simulatorDeviceType;
2344     if (architecture() eq "x86_64") {
2345         $simulatorName = "iPhone 5s " . $simulatorNameSuffix;
2346         $simulatorDeviceType = "com.apple.CoreSimulator.SimDeviceType.iPhone-5s";
2347     } else {
2348         $simulatorName = "iPhone 5 " . $simulatorNameSuffix;
2349         $simulatorDeviceType = "com.apple.CoreSimulator.SimDeviceType.iPhone-5";
2350     }
2351     my $simulatedDevice = iosSimulatorDeviceByName($simulatorName);
2352     return $simulatedDevice if $simulatedDevice;
2353     return createiOSSimulatorDevice($simulatorName, $simulatorDeviceType, iosSimulatorRuntime());
2354 }
2355
2356 sub isIOSSimulatorSystemInstalledApp($)
2357 {
2358     my ($appBundle) = @_;
2359     my $simulatorApplicationsPath = realpath(iosSimulatorApplicationsPath());
2360     return substr(realpath($appBundle), 0, length($simulatorApplicationsPath)) eq $simulatorApplicationsPath;
2361 }
2362
2363 sub hasUserInstalledAppInSimulatorDevice($$)
2364 {
2365     my ($appIdentifier, $simulatedDeviceUDID) = @_;
2366     my $userInstalledAppPath = File::Spec->catfile($ENV{HOME}, "Library", "Developer", "CoreSimulator", "Devices", $simulatedDeviceUDID, "data", "Containers", "Bundle", "Application");
2367     if (!-d $userInstalledAppPath) {
2368         return 0; # No user installed apps.
2369     }
2370     local @::userInstalledAppBundles;
2371     my $wantedFunction = sub {
2372         my $file = $_;
2373
2374         # Ignore hidden files and directories.
2375         if ($file =~ /^\../) {
2376             $File::Find::prune = 1;
2377             return;
2378         }
2379
2380         return if !-d $file || $file !~ /\.app$/;
2381         push @::userInstalledAppBundles, $File::Find::name;
2382         $File::Find::prune = 1; # Do not traverse contents of app bundle.
2383     };
2384     find($wantedFunction, $userInstalledAppPath);
2385     for my $userInstalledAppBundle (@::userInstalledAppBundles) {
2386         if (appIdentifierFromBundle($userInstalledAppBundle) eq $appIdentifier) {
2387             return 1; # Has user installed app.
2388         }
2389     }
2390     return 0; # Does not have user installed app.
2391 }
2392
2393 sub isSimulatorDeviceBooted($)
2394 {
2395     my ($simulatedDeviceUDID) = @_;
2396     my $device = iosSimulatorDeviceByUDID($simulatedDeviceUDID);
2397     return $device && $device->{state} eq SIMULATOR_DEVICE_STATE_BOOTED;
2398 }
2399
2400 sub runIOSWebKitAppInSimulator($;$)
2401 {
2402     my ($appBundle, $simulatorOptions) = @_;
2403     my $productDir = productDir();
2404     my $appDisplayName = appDisplayNameFromBundle($appBundle);
2405     my $appIdentifier = appIdentifierFromBundle($appBundle);
2406     my $simulatedDevice = findOrCreateSimulatorForIOSDevice(SIMULATOR_DEVICE_SUFFIX_FOR_WEBKIT_DEVELOPMENT);
2407     my $simulatedDeviceUDID = $simulatedDevice->{UDID};
2408
2409     my $willUseSystemInstalledApp = isIOSSimulatorSystemInstalledApp($appBundle);
2410     if ($willUseSystemInstalledApp) {
2411         if (hasUserInstalledAppInSimulatorDevice($appIdentifier, $simulatedDeviceUDID)) {
2412             # Restore the system-installed app in the simulator device corresponding to $appBundle as it
2413             # was previously overwritten with a custom built version of the app.
2414             # FIXME: Only restore the system-installed version of the app instead of erasing all contents and settings.
2415             print "Quitting iOS Simulator...\n";
2416             quitIOSSimulator($simulatedDeviceUDID);
2417             print "Erasing contents and settings for simulator device \"$simulatedDevice->{name}\".\n";
2418             exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "erase", $simulatedDeviceUDID)) == 0 or die;
2419         }
2420         # FIXME: We assume that if $simulatedDeviceUDID is not booted then iOS Simulator is not open. However
2421         #        $simulatedDeviceUDID may have been booted using the simctl command line tool. If $simulatedDeviceUDID
2422         #        was booted using simctl then we should shutdown the device and launch iOS Simulator to boot it again.
2423         if (!isSimulatorDeviceBooted($simulatedDeviceUDID)) {
2424             print "Launching iOS Simulator...\n";
2425             relaunchIOSSimulator($simulatedDevice);
2426         }
2427     } else {
2428         # FIXME: We should killall(1) any running instances of $appBundle before installing it to ensure
2429         #        that simctl launch opens the latest installed version of the app. For now we quit and
2430         #        launch the iOS Simulator again to ensure there are no running instances of $appBundle.
2431         print "Quitting and launching iOS Simulator...\n";
2432         relaunchIOSSimulator($simulatedDevice);
2433
2434         print "Installing $appBundle.\n";
2435         # Install custom built app, overwriting an app with the same app identifier if one exists.
2436         exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "install", $simulatedDeviceUDID, $appBundle)) == 0 or die;
2437
2438     }
2439
2440     $simulatorOptions = {} unless $simulatorOptions;
2441
2442     my %simulatorENV;
2443     %simulatorENV = %{$simulatorOptions->{applicationEnvironment}} if $simulatorOptions->{applicationEnvironment};
2444     {
2445         local %ENV; # Shadow global-scope %ENV so that changes to it will not be seen outside of this scope.
2446         setupIOSWebKitEnvironment($productDir);
2447         %simulatorENV = %ENV;
2448     }
2449     my $applicationArguments = \@ARGV;
2450     $applicationArguments = $simulatorOptions->{applicationArguments} if $simulatorOptions && $simulatorOptions->{applicationArguments};
2451
2452     # Prefix the environment variables with SIMCTL_CHILD_ per `xcrun simctl help launch`.
2453     foreach my $key (keys %simulatorENV) {
2454         $ENV{"SIMCTL_CHILD_$key"} = $simulatorENV{$key};
2455     }
2456
2457     print "Starting $appDisplayName with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2458     return exitStatus(system("xcrun", "--sdk", "iphonesimulator", "simctl", "launch", $simulatedDeviceUDID, $appIdentifier, @$applicationArguments));
2459 }
2460
2461 sub runIOSWebKitApp($)
2462 {
2463     my ($appBundle) = @_;
2464     if (willUseIOSDeviceSDK()) {
2465         die "Only running Safari in iOS Simulator is supported now.";
2466     }
2467     if (willUseIOSSimulatorSDK()) {
2468         return runIOSWebKitAppInSimulator($appBundle);
2469     }
2470     die "Not using an iOS SDK."
2471 }
2472
2473 sub runMacWebKitApp($;$)
2474 {
2475     my ($appPath, $useOpenCommand) = @_;
2476     my $productDir = productDir();
2477     print "Starting @{[basename($appPath)]} with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2478
2479     local %ENV = %ENV;
2480     setupMacWebKitEnvironment($productDir);
2481
2482     if (defined($useOpenCommand) && $useOpenCommand == USE_OPEN_COMMAND) {
2483         return system("open", "-W", "-a", $appPath, "--args", argumentsForRunAndDebugMacWebKitApp());
2484     }
2485     if (architecture()) {
2486         return system "arch", "-" . architecture(), $appPath, argumentsForRunAndDebugMacWebKitApp();
2487     }
2488     return system { $appPath } $appPath, argumentsForRunAndDebugMacWebKitApp();
2489 }
2490
2491 sub execMacWebKitAppForDebugging($)
2492 {
2493     my ($appPath) = @_;
2494     my $architectureSwitch;
2495     my $argumentsSeparator;
2496
2497     if (debugger() eq "lldb") {
2498         $architectureSwitch = "--arch";
2499         $argumentsSeparator = "--";
2500     } elsif (debugger() eq "gdb") {
2501         $architectureSwitch = "-arch";
2502         $argumentsSeparator = "--args";
2503     } else {
2504         die "Unknown debugger $debugger.\n";
2505     }
2506
2507     my $debuggerPath = `xcrun -find $debugger`;
2508     chomp $debuggerPath;
2509     die "Can't find the $debugger executable.\n" unless -x $debuggerPath;
2510
2511     my $productDir = productDir();
2512     setupMacWebKitEnvironment($productDir);
2513
2514     my @architectureFlags = ($architectureSwitch, architecture());
2515     if (!shouldTargetWebProcess()) {
2516         print "Starting @{[basename($appPath)]} under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2517         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $appPath, argumentsForRunAndDebugMacWebKitApp() or die;
2518     } else {
2519         if (shouldUseXPCServiceForWebProcess()) {
2520             die "Targeting the Web Process is not compatible with using an XPC Service for the Web Process at this time.";
2521         }
2522         
2523         my $webProcessShimPath = File::Spec->catfile($productDir, "SecItemShim.dylib");
2524         my $webProcessPath = File::Spec->catdir($productDir, "WebProcess.app");
2525         my $webKit2ExecutablePath = File::Spec->catfile($productDir, "WebKit2.framework", "WebKit2");
2526
2527         appendToEnvironmentVariableList("DYLD_INSERT_LIBRARIES", $webProcessShimPath);
2528
2529         print "Starting WebProcess under $debugger with DYLD_FRAMEWORK_PATH set to point to built WebKit in $productDir.\n";
2530         exec { $debuggerPath } $debuggerPath, @architectureFlags, $argumentsSeparator, $webProcessPath, $webKit2ExecutablePath, "-type", "webprocess", "-client-executable", $appPath or die;
2531     }
2532 }
2533
2534 sub debugSafari
2535 {
2536     if (isAppleMacWebKit()) {
2537         checkFrameworks();
2538         execMacWebKitAppForDebugging(safariPath());
2539     }
2540
2541     return 1; # Unsupported platform; can't debug Safari on this platform.
2542 }
2543
2544 sub runSafari
2545 {
2546     if (isIOSWebKit()) {
2547         return runIOSWebKitApp(mobileSafariBundle());
2548     }
2549
2550     if (isAppleMacWebKit()) {
2551         return runMacWebKitApp(safariPath());
2552     }
2553
2554     if (isAppleWinWebKit()) {
2555         my $result;
2556         my $webKitLauncherPath = File::Spec->catfile(executableProductDir(), "MiniBrowser.exe");
2557         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2558     }
2559
2560     return 1; # Unsupported platform; can't run Safari on this platform.
2561 }
2562
2563 sub runMiniBrowser
2564 {
2565     if (isAppleMacWebKit()) {
2566         return runMacWebKitApp(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2567     } elsif (isAppleWinWebKit()) {
2568         my $result;
2569         my $webKitLauncherPath = File::Spec->catfile(executableProductDir(), "MiniBrowser.exe");
2570         return system { $webKitLauncherPath } $webKitLauncherPath, @ARGV;
2571     }
2572
2573     return 1;
2574 }
2575
2576 sub debugMiniBrowser
2577 {
2578     if (isAppleMacWebKit()) {
2579         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "MiniBrowser.app", "Contents", "MacOS", "MiniBrowser"));
2580     }
2581     
2582     return 1;
2583 }
2584
2585 sub runWebKitTestRunner
2586 {
2587     if (isAppleMacWebKit()) {
2588         return runMacWebKitApp(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2589     }
2590
2591     return 1;
2592 }
2593
2594 sub debugWebKitTestRunner
2595 {
2596     if (isAppleMacWebKit()) {
2597         execMacWebKitAppForDebugging(File::Spec->catfile(productDir(), "WebKitTestRunner"));
2598     }
2599
2600     return 1;
2601 }
2602
2603 sub readRegistryString
2604 {
2605     my ($valueName) = @_;
2606     chomp(my $string = `regtool --wow32 get "$valueName"`);
2607     return $string;
2608 }
2609
2610 sub writeRegistryString
2611 {
2612     my ($valueName, $string) = @_;
2613
2614     my $error = system "regtool", "--wow32", "set", "-s", $valueName, $string;
2615
2616     # On Windows Vista/7 with UAC enabled, regtool will fail to modify the registry, but will still
2617     # return a successful exit code. So we double-check here that the value we tried to write to the
2618     # registry was really written.
2619     return !$error && readRegistryString($valueName) eq $string;
2620 }
2621
2622 sub formatBuildTime($)
2623 {
2624     my ($buildTime) = @_;
2625
2626     my $buildHours = int($buildTime / 3600);
2627     my $buildMins = int(($buildTime - $buildHours * 3600) / 60);
2628     my $buildSecs = $buildTime - $buildHours * 3600 - $buildMins * 60;
2629
2630     if ($buildHours) {
2631         return sprintf("%dh:%02dm:%02ds", $buildHours, $buildMins, $buildSecs);
2632     }
2633     return sprintf("%02dm:%02ds", $buildMins, $buildSecs);
2634 }
2635
2636 sub runSvnUpdateAndResolveChangeLogs(@)
2637 {
2638     my @svnOptions = @_;
2639     my $openCommand = "svn update " . join(" ", @svnOptions);
2640     open my $update, "$openCommand |" or die "cannot execute command $openCommand";
2641     my @conflictedChangeLogs;
2642     while (my $line = <$update>) {
2643         print $line;
2644         $line =~ m/^C\s+(.+?)[\r\n]*$/;
2645         if ($1) {
2646           my $filename = normalizePath($1);
2647           push @conflictedChangeLogs, $filename if basename($filename) eq "ChangeLog";
2648         }
2649     }
2650     close $update or die;
2651
2652     if (@conflictedChangeLogs) {
2653         print "Attempting to merge conflicted ChangeLogs.\n";
2654         my $resolveChangeLogsPath = File::Spec->catfile(sourceDir(), "Tools", "Scripts", "resolve-ChangeLogs");
2655         (system($resolveChangeLogsPath, "--no-warnings", @conflictedChangeLogs) == 0)
2656             or die "Could not open resolve-ChangeLogs script: $!.\n";
2657     }
2658 }
2659
2660 sub runGitUpdate()
2661 {
2662     # Doing a git fetch first allows setups with svn-remote.svn.fetch = trunk:refs/remotes/origin/master
2663     # to perform the rebase much much faster.
2664     system("git", "fetch");
2665     if (isGitSVNDirectory(".")) {
2666         system("git", "svn", "rebase") == 0 or die;
2667     } else {
2668         # This will die if branch.$BRANCHNAME.merge isn't set, which is
2669         # almost certainly what we want.
2670         system("git", "pull") == 0 or die;
2671     }
2672 }
2673
2674 1;