Ensure old tab state is cleared between iterations of run-benchmark
[WebKit-https.git] / Tools / Scripts / sort-Xcode-project-file
1 #!/usr/bin/env perl
2
3 # Copyright (C) 2007, 2008, 2009, 2010 Apple Inc.  All rights reserved.
4 #
5 # Redistribution and use in source and binary forms, with or without
6 # modification, are permitted provided that the following conditions
7 # are met:
8 #
9 # 1.  Redistributions of source code must retain the above copyright
10 #     notice, this list of conditions and the following disclaimer. 
11 # 2.  Redistributions in binary form must reproduce the above copyright
12 #     notice, this list of conditions and the following disclaimer in the
13 #     documentation and/or other materials provided with the distribution. 
14 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
15 #     its contributors may be used to endorse or promote products derived
16 #     from this software without specific prior written permission. 
17 #
18 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
19 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
21 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
22 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
25 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28
29 # Script to sort "children" and "files" sections in Xcode project.pbxproj files
30
31 use strict;
32 use warnings;
33
34 use File::Basename;
35 use File::Spec;
36 use File::Temp qw(tempfile);
37 use Getopt::Long;
38
39 sub sortChildrenByFileName($$);
40 sub sortFilesByFileName($$);
41
42 # Files (or products) without extensions
43 my %isFile = map { $_ => 1 } qw(
44     create_hash_table
45     jsc
46     minidom
47     testapi
48     testjsglue
49 );
50
51 my $printWarnings = 1;
52 my $showHelp;
53
54 my $getOptionsResult = GetOptions(
55     'h|help'         => \$showHelp,
56     'w|warnings!'    => \$printWarnings,
57 );
58
59 if (scalar(@ARGV) == 0 && !$showHelp) {
60     print STDERR "ERROR: No Xcode project files (project.pbxproj) listed on command-line.\n";
61     undef $getOptionsResult;
62 }
63
64 if (!$getOptionsResult || $showHelp) {
65     print STDERR <<__END__;
66 Usage: @{[ basename($0) ]} [options] path/to/project.pbxproj [path/to/project.pbxproj ...]
67   -h|--help           show this help message
68   -w|--[no-]warnings  show or suppress warnings (default: show warnings)
69 __END__
70     exit 1;
71 }
72
73 for my $projectFile (@ARGV) {
74     if (basename($projectFile) =~ /\.xcodeproj$/) {
75         $projectFile = File::Spec->catfile($projectFile, "project.pbxproj");
76     }
77
78     if (basename($projectFile) ne "project.pbxproj") {
79         print STDERR "WARNING: Not an Xcode project file: $projectFile\n" if $printWarnings;
80         next;
81     }
82
83     # Grab the mainGroup for the project file.
84     my $mainGroup = "";
85     open(IN, "< $projectFile") || die "Could not open $projectFile: $!";
86     while (my $line = <IN>) {
87         $mainGroup = $2 if $line =~ m#^(\s*)mainGroup = ([0-9A-F]{24}( /\* .+ \*/)?);$#;
88     }
89     close(IN);
90
91     my ($OUT, $tempFileName) = tempfile(
92         basename($projectFile) . "-XXXXXXXX",
93         DIR => dirname($projectFile),
94         UNLINK => 0,
95     );
96
97     # Clean up temp file in case of die()
98     $SIG{__DIE__} = sub {
99         close(IN);
100         close($OUT);
101         unlink($tempFileName);
102     };
103
104     my @lastTwo = ();
105     open(IN, "< $projectFile") || die "Could not open $projectFile: $!";
106     while (my $line = <IN>) {
107         if ($line =~ /^(\s*)files = \(\s*$/) {
108             print $OUT $line;
109             my $endMarker = $1 . ");";
110             my @files;
111             while (my $fileLine = <IN>) {
112                 if ($fileLine =~ /^\Q$endMarker\E\s*$/) {
113                     $endMarker = $fileLine;
114                     last;
115                 }
116                 push @files, $fileLine;
117             }
118             print $OUT sort sortFilesByFileName @files;
119             print $OUT $endMarker;
120         } elsif ($line =~ /^(\s*)children = \(\s*$/) {
121             print $OUT $line;
122             my $endMarker = $1 . ");";
123             my @children;
124             while (my $childLine = <IN>) {
125                 if ($childLine =~ /^\Q$endMarker\E\s*$/) {
126                     $endMarker = $childLine;
127                     last;
128                 }
129                 push @children, $childLine;
130             }
131             if ($lastTwo[0] =~ m#^\s+\Q$mainGroup\E = \{$#) {
132                 # Don't sort mainGroup
133                 print $OUT @children;
134             } else {
135                 print $OUT sort sortChildrenByFileName @children;
136             }
137             print $OUT $endMarker;
138         } else {
139             print $OUT $line;
140         }
141
142         push @lastTwo, $line;
143         shift @lastTwo if scalar(@lastTwo) > 2;
144     }
145     close(IN);
146     close($OUT);
147
148     unlink($projectFile) || die "Could not delete $projectFile: $!";
149     rename($tempFileName, $projectFile) || die "Could not rename $tempFileName to $projectFile: $!";
150 }
151
152 exit 0;
153
154 sub sortChildrenByFileName($$)
155 {
156     my ($a, $b) = @_;
157     my $aFileName = $1 if $a =~ /^\s*[A-Z0-9]{24} \/\* (.+) \*\/,$/;
158     my $bFileName = $1 if $b =~ /^\s*[A-Z0-9]{24} \/\* (.+) \*\/,$/;
159     my $aSuffix = $1 if $aFileName =~ m/\.([^.]+)$/;
160     my $bSuffix = $1 if $bFileName =~ m/\.([^.]+)$/;
161     if ((!$aSuffix && !$isFile{$aFileName} && $bSuffix) || ($aSuffix && !$bSuffix && !$isFile{$bFileName})) {
162         return !$aSuffix ? -1 : 1;
163     }
164     if ($aFileName =~ /^UnifiedSource\d+/ && $bFileName =~ /^UnifiedSource\d+/) {
165         my $aNumber = $1 if $aFileName =~ /^UnifiedSource(\d+)/;
166         my $bNumber = $1 if $bFileName =~ /^UnifiedSource(\d+)/;
167         return $aNumber <=> $bNumber;
168     }
169     return lc($aFileName) cmp lc($bFileName);
170 }
171
172 sub sortFilesByFileName($$)
173 {
174     my ($a, $b) = @_;
175     my $aFileName = $1 if $a =~ /^\s*[A-Z0-9]{24} \/\* (.+) in /;
176     my $bFileName = $1 if $b =~ /^\s*[A-Z0-9]{24} \/\* (.+) in /;
177     if ($aFileName =~ /^UnifiedSource\d+/ && $bFileName =~ /^UnifiedSource\d+/) {
178         my $aNumber = $1 if $aFileName =~ /^UnifiedSource(\d+)/;
179         my $bNumber = $1 if $bFileName =~ /^UnifiedSource(\d+)/;
180         return $aNumber <=> $bNumber;
181     }
182     return lc($aFileName) cmp lc($bFileName);
183 }