Rename WebKitTools to Tools
[WebKit-https.git] / Tools / Scripts / old-run-webkit-tests
1 #!/usr/bin/perl
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009, 2010 Apple Inc. All rights reserved.
4 # Copyright (C) 2006 Alexey Proskuryakov (ap@nypop.com)
5 # Copyright (C) 2007 Matt Lilek (pewtermoose@gmail.com)
6 # Copyright (C) 2007 Eric Seidel <eric@webkit.org>
7 # Copyright (C) 2009 Google Inc. All rights reserved.
8 # Copyright (C) 2009 Andras Becsi (becsi.andras@stud.u-szeged.hu), University of Szeged
9 #
10 # Redistribution and use in source and binary forms, with or without
11 # modification, are permitted provided that the following conditions
12 # are met:
13 #
14 # 1.  Redistributions of source code must retain the above copyright
15 #     notice, this list of conditions and the following disclaimer. 
16 # 2.  Redistributions in binary form must reproduce the above copyright
17 #     notice, this list of conditions and the following disclaimer in the
18 #     documentation and/or other materials provided with the distribution. 
19 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
20 #     its contributors may be used to endorse or promote products derived
21 #     from this software without specific prior written permission. 
22 #
23 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
24 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
25 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
26 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
27 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
28 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
29 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
30 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
31 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
32 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
33
34 # Script to run the WebKit Open Source Project layout tests.
35
36 # Run all the tests passed in on the command line.
37 # If no tests are passed, find all the .html, .shtml, .xml, .xhtml, .xhtmlmp, .pl, .php (and svg) files in the test directory.
38
39 # Run each text.
40 # Compare against the existing file xxx-expected.txt.
41 # If there is a mismatch, generate xxx-actual.txt and xxx-diffs.txt.
42
43 # At the end, report:
44 #   the number of tests that got the expected results
45 #   the number of tests that ran, but did not get the expected results
46 #   the number of tests that failed to run
47 #   the number of tests that were run but had no expected results to compare against
48
49 use strict;
50 use warnings;
51
52 use Config;
53 use Cwd;
54 use Data::Dumper;
55 use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
56 use File::Basename;
57 use File::Copy;
58 use File::Find;
59 use File::Path;
60 use File::Spec;
61 use File::Spec::Functions;
62 use File::Temp;
63 use FindBin;
64 use Getopt::Long;
65 use IPC::Open2;
66 use IPC::Open3;
67 use Time::HiRes qw(time usleep);
68
69 use List::Util 'shuffle';
70
71 use lib $FindBin::Bin;
72 use webkitperl::features;
73 use webkitperl::httpd;
74 use webkitdirs;
75 use VCSUtils;
76 use POSIX;
77
78 sub buildPlatformResultHierarchy();
79 sub buildPlatformTestHierarchy(@);
80 sub checkPythonVersion();
81 sub closeCygpaths();
82 sub closeDumpTool();
83 sub closeWebSocketServer();
84 sub configureAndOpenHTTPDIfNeeded();
85 sub countAndPrintLeaks($$$);
86 sub countFinishedTest($$$$);
87 sub deleteExpectedAndActualResults($);
88 sub dumpToolDidCrash();
89 sub epiloguesAndPrologues($$);
90 sub expectedDirectoryForTest($;$;$);
91 sub fileNameWithNumber($$);
92 sub htmlForResultsSection(\@$&);
93 sub isTextOnlyTest($);
94 sub launchWithEnv(\@\%);
95 sub resolveAndMakeTestResultsDirectory();
96 sub numericcmp($$);
97 sub openDiffTool();
98 sub buildDumpTool($);
99 sub openDumpTool();
100 sub parseLeaksandPrintUniqueLeaks();
101 sub openWebSocketServerIfNeeded();
102 sub pathcmp($$);
103 sub printFailureMessageForTest($$);
104 sub processIgnoreTests($$);
105 sub readFromDumpToolWithTimer(**);
106 sub readSkippedFiles($);
107 sub recordActualResultsAndDiff($$);
108 sub sampleDumpTool();
109 sub setFileHandleNonBlocking(*$);
110 sub setUpWindowsCrashLogSaving();
111 sub slowestcmp($$);
112 sub splitpath($);
113 sub stopRunningTestsEarlyIfNeeded();
114 sub stripExtension($);
115 sub stripMetrics($$);
116 sub testCrashedOrTimedOut($$$$$);
117 sub toCygwinPath($);
118 sub toURL($);
119 sub toWindowsPath($);
120 sub validateSkippedArg($$;$);
121 sub writeToFile($$);
122
123 # Argument handling
124 my $addPlatformExceptions = 0;
125 my $complexText = 0;
126 my $exitAfterNFailures = 0;
127 my $exitAfterNCrashesOrTimeouts = 0;
128 my $generateNewResults = isAppleMacWebKit() ? 1 : 0;
129 my $guardMalloc = '';
130 # FIXME: Dynamic HTTP-port configuration in this file is wrong.  The various
131 # apache config files in LayoutTests/http/config govern the port numbers.
132 # Dynamic configuration as-written will also cause random failures in
133 # an IPv6 environment.  See https://bugs.webkit.org/show_bug.cgi?id=37104.
134 my $httpdPort = 8000;
135 my $httpdSSLPort = 8443;
136 my $ignoreMetrics = 0;
137 my $webSocketPort = 8880;
138 # wss is disabled until all platforms support pyOpenSSL.
139 # my $webSocketSecurePort = 9323;
140 my $ignoreTests = '';
141 my $iterations = 1;
142 my $launchSafari = 1;
143 my $mergeDepth;
144 my $pixelTests = '';
145 my $platform;
146 my $quiet = '';
147 my $randomizeTests = 0;
148 my $repeatEach = 1;
149 my $report10Slowest = 0;
150 my $resetResults = 0;
151 my $reverseTests = 0;
152 my $root;
153 my $runSample = 1;
154 my $shouldCheckLeaks = 0;
155 my $showHelp = 0;
156 my $stripEditingCallbacks;
157 my $testHTTP = 1;
158 my $testWebSocket = 1;
159 my $testMedia = 1;
160 my $tmpDir = "/tmp";
161 my $testResultsDirectory = File::Spec->catdir($tmpDir, "layout-test-results");
162 my $testsPerDumpTool = 1000;
163 my $threaded = 0;
164 # DumpRenderTree has an internal timeout of 30 seconds, so this must be > 30.
165 my $timeoutSeconds = 35;
166 my $tolerance = 0;
167 my $treatSkipped = "default";
168 my $useRemoteLinksToTests = 0;
169 my $useValgrind = 0;
170 my $verbose = 0;
171 my $shouldWaitForHTTPD = 0;
172 my $useWebKitTestRunner = 0;
173
174 my @leaksFilenames;
175
176 if (isWindows() || isMsys()) {
177     print "This script has to be run under Cygwin to function correctly.\n";
178     exit 1;
179 }
180
181 # Default to --no-http for wx for now.
182 $testHTTP = 0 if (isWx());
183
184 my $perlInterpreter = "perl";
185
186 my $expectedTag = "expected";
187 my $actualTag = "actual";
188 my $prettyDiffTag = "pretty-diff";
189 my $diffsTag = "diffs";
190 my $errorTag = "stderr";
191
192 # These are defined here instead of closer to where they are used so that they
193 # will always be accessible from the END block that uses them, even if the user
194 # presses Ctrl-C before Perl has finished evaluating this whole file.
195 my $windowsPostMortemDebuggerKey = "/HKLM/SOFTWARE/Microsoft/Windows NT/CurrentVersion/AeDebug";
196 my %previousWindowsPostMortemDebuggerValues;
197
198 my $realPlatform;
199
200 my @macPlatforms = ("mac-tiger", "mac-leopard", "mac-snowleopard", "mac");
201 my @winPlatforms = ("win-xp", "win-vista", "win-7", "win");
202
203 if (isAppleMacWebKit()) {
204     if (isTiger()) {
205         $platform = "mac-tiger";
206         $tolerance = 1.0;
207     } elsif (isLeopard()) {
208         $platform = "mac-leopard";
209         $tolerance = 0.1;
210     } elsif (isSnowLeopard()) {
211         $platform = "mac-snowleopard";
212         $tolerance = 0.1;
213     } else {
214         $platform = "mac";
215     }
216 } elsif (isQt()) {
217     if (isDarwin()) {
218         $platform = "qt-mac";
219     } elsif (isLinux()) {
220         $platform = "qt-linux";
221     } elsif (isWindows() || isCygwin()) {
222         $platform = "qt-win";
223     } else {
224         $platform = "qt";
225     }
226 } elsif (isGtk()) {
227     $platform = "gtk";
228 } elsif (isWx()) {
229     $platform = "wx";
230 } elsif (isCygwin() || isWindows()) {
231     if (isWindowsXP()) {
232         $platform = "win-xp";
233     } elsif (isWindowsVista()) {
234         $platform = "win-vista";
235     } elsif (isWindows7()) {
236         $platform = "win-7";
237     } else {
238         $platform = "win";
239     }
240 }
241
242 if (isQt() || isAppleWinWebKit()) {
243     my $testfontPath = $ENV{"WEBKIT_TESTFONTS"};
244     if (!$testfontPath || !-d "$testfontPath") {
245         print "The WEBKIT_TESTFONTS environment variable is not defined or not set properly\n";
246         print "You must set it before running the tests.\n";
247         print "Use git to grab the actual fonts from http://gitorious.org/qtwebkit/testfonts\n";
248         exit 1;
249     }
250 }
251
252 if (!defined($platform)) {
253     print "WARNING: Your platform is not recognized. Any platform-specific results will be generated in platform/undefined.\n";
254     $platform = "undefined";
255 }
256
257 if (!checkPythonVersion()) {
258     print "WARNING: Your platform does not have Python 2.5+, which is required to run websocket server, so disabling websocket/tests.\n";
259     $testWebSocket = 0;
260 }
261
262 my $programName = basename($0);
263 my $launchSafariDefault = $launchSafari ? "launch" : "do not launch";
264 my $httpDefault = $testHTTP ? "run" : "do not run";
265 my $sampleDefault = $runSample ? "run" : "do not run";
266
267 my $usage = <<EOF;
268 Usage: $programName [options] [testdir|testpath ...]
269   --add-platform-exceptions       Put new results for non-platform-specific failing tests into the platform-specific results directory
270   --complex-text                  Use the complex text code path for all text (Mac OS X and Windows only)
271   -c|--configuration config       Set DumpRenderTree build configuration
272   -g|--guard-malloc               Enable malloc guard
273   --exit-after-n-failures N       Exit after the first N failures (includes crashes) instead of running all tests
274   --exit-after-n-crashes-or-timeouts N
275                                   Exit after the first N crashes instead of running all tests
276   -h|--help                       Show this help message
277   --[no-]http                     Run (or do not run) http tests (default: $httpDefault)
278   --[no-]wait-for-httpd           Wait for httpd if some other test session is using it already (same as WEBKIT_WAIT_FOR_HTTPD=1). (default: $shouldWaitForHTTPD) 
279   -i|--ignore-tests               Comma-separated list of directories or tests to ignore
280   --iterations n                  Number of times to run the set of tests (e.g. ABCABCABC)
281   --[no-]launch-safari            Launch (or do not launch) Safari to display test results (default: $launchSafariDefault)
282   -l|--leaks                      Enable leaks checking
283   --[no-]new-test-results         Generate results for new tests
284   --nthly n                       Restart DumpRenderTree every n tests (default: $testsPerDumpTool)
285   -p|--pixel-tests                Enable pixel tests
286   --tolerance t                   Ignore image differences less than this percentage (default: $tolerance)
287   --platform                      Override the detected platform to use for tests and results (default: $platform)
288   --port                          Web server port to use with http tests
289   -q|--quiet                      Less verbose output
290   --reset-results                 Reset ALL results (including pixel tests if --pixel-tests is set)
291   -o|--results-directory          Output results directory (default: $testResultsDirectory)
292   --random                        Run the tests in a random order
293   --repeat-each n                 Number of times to run each test (e.g. AAABBBCCC)
294   --reverse                       Run the tests in reverse alphabetical order
295   --root                          Path to root tools build
296   --[no-]sample-on-timeout        Run sample on timeout (default: $sampleDefault) (Mac OS X only)
297   -1|--singly                     Isolate each test case run (implies --nthly 1 --verbose)
298   --skipped=[default|ignore|only] Specifies how to treat the Skipped file
299                                      default: Tests/directories listed in the Skipped file are not tested
300                                      ignore:  The Skipped file is ignored
301                                      only:    Only those tests/directories listed in the Skipped file will be run
302   --slowest                       Report the 10 slowest tests
303   --ignore-metrics                Ignore metrics in tests
304   --[no-]strip-editing-callbacks  Remove editing callbacks from expected results
305   -t|--threaded                   Run a concurrent JavaScript thead with each test
306   --timeout t                     Sets the number of seconds before a test times out (default: $timeoutSeconds)
307   --valgrind                      Run DumpRenderTree inside valgrind (Qt/Linux only)
308   -v|--verbose                    More verbose output (overrides --quiet)
309   -m|--merge-leak-depth arg       Merges leak callStacks and prints the number of unique leaks beneath a callstack depth of arg.  Defaults to 5.
310   --use-remote-links-to-tests     Link to test files within the SVN repository in the results.
311   -2|--webkit-test-runner         Use WebKitTestRunner rather than DumpRenderTree.
312 EOF
313
314 setConfiguration();
315
316 my $getOptionsResult = GetOptions(
317     'add-platform-exceptions' => \$addPlatformExceptions,
318     'complex-text' => \$complexText,
319     'exit-after-n-failures=i' => \$exitAfterNFailures,
320     'exit-after-n-crashes-or-timeouts=i' => \$exitAfterNCrashesOrTimeouts,
321     'guard-malloc|g' => \$guardMalloc,
322     'help|h' => \$showHelp,
323     'http!' => \$testHTTP,
324     'wait-for-httpd!' => \$shouldWaitForHTTPD,
325     'ignore-metrics!' => \$ignoreMetrics,
326     'ignore-tests|i=s' => \$ignoreTests,
327     'iterations=i' => \$iterations,
328     'launch-safari!' => \$launchSafari,
329     'leaks|l' => \$shouldCheckLeaks,
330     'merge-leak-depth|m:5' => \$mergeDepth,
331     'new-test-results!' => \$generateNewResults,
332     'nthly=i' => \$testsPerDumpTool,
333     'pixel-tests|p' => \$pixelTests,
334     'platform=s' => \$platform,
335     'port=i' => \$httpdPort,
336     'quiet|q' => \$quiet,
337     'random' => \$randomizeTests,
338     'repeat-each=i' => \$repeatEach,
339     'reset-results' => \$resetResults,
340     'results-directory|o=s' => \$testResultsDirectory,
341     'reverse' => \$reverseTests,
342     'root=s' => \$root,
343     'sample-on-timeout!' => \$runSample,
344     'singly|1' => sub { $testsPerDumpTool = 1; },
345     'skipped=s' => \&validateSkippedArg,
346     'slowest' => \$report10Slowest,
347     'strip-editing-callbacks!' => \$stripEditingCallbacks,
348     'threaded|t' => \$threaded,
349     'timeout=i' => \$timeoutSeconds,
350     'tolerance=f' => \$tolerance,
351     'use-remote-links-to-tests' => \$useRemoteLinksToTests,
352     'valgrind' => \$useValgrind,
353     'verbose|v' => \$verbose,
354     'webkit-test-runner|2' => \$useWebKitTestRunner,
355 );
356
357 if (!$getOptionsResult || $showHelp) {
358     print STDERR $usage;
359     exit 1;
360 }
361
362 if ($useWebKitTestRunner) {
363     if (isAppleMacWebKit()) {
364         $realPlatform = $platform;
365         $platform = "mac-wk2";
366     } elsif (isAppleWinWebKit()) {
367         $stripEditingCallbacks = 0 unless defined $stripEditingCallbacks;
368         $realPlatform = $platform;
369         $platform = "win-wk2";
370     } elsif (isQt()) {
371         $realPlatform = $platform;
372         $platform = "qt-wk2";
373     }
374 }
375
376 $timeoutSeconds *= 10 if $guardMalloc;
377
378 $stripEditingCallbacks = isCygwin() unless defined $stripEditingCallbacks;
379
380 my $ignoreSkipped = $treatSkipped eq "ignore";
381 my $skippedOnly = $treatSkipped eq "only";
382
383 my $configuration = configuration();
384
385 # We need an environment variable to be able to enable the feature per-slave
386 $shouldWaitForHTTPD = $ENV{"WEBKIT_WAIT_FOR_HTTPD"} unless ($shouldWaitForHTTPD);
387 $verbose = 1 if $testsPerDumpTool == 1;
388
389 if ($shouldCheckLeaks && $testsPerDumpTool > 1000) {
390     print STDERR "\nWARNING: Running more than 1000 tests at a time with MallocStackLogging enabled may cause a crash.\n\n";
391 }
392
393 # Stack logging does not play well with QuickTime on Tiger (rdar://problem/5537157)
394 $testMedia = 0 if $shouldCheckLeaks && isTiger();
395
396 # Generating remote links causes a lot of unnecessary spew on GTK build bot
397 $useRemoteLinksToTests = 0 if isGtk();
398
399 setUpWindowsCrashLogSaving() if isCygwin();
400
401 setConfigurationProductDir(Cwd::abs_path($root)) if (defined($root));
402 my $productDir = productDir();
403 $productDir .= "/bin" if isQt();
404 $productDir .= "/Programs" if isGtk();
405
406 chdirWebKit();
407
408 if (!defined($root)) {
409     # FIXME: We build both DumpRenderTree and WebKitTestRunner for
410     # WebKitTestRunner runs becuase DumpRenderTree still includes
411     # the DumpRenderTreeSupport module and the TestNetscapePlugin.
412     # These two projects should be factored out into their own
413     # projects.
414     buildDumpTool("DumpRenderTree");
415     buildDumpTool("WebKitTestRunner") if $useWebKitTestRunner;
416 }
417
418 my $dumpToolName = $useWebKitTestRunner ? "WebKitTestRunner" : "DumpRenderTree";
419
420 if (isAppleWinWebKit()) {
421     $dumpToolName .= "_debug" if configurationForVisualStudio() eq "Debug_All";
422     $dumpToolName .= $Config{_exe};
423 }
424 my $dumpTool = File::Spec->catfile($productDir, $dumpToolName);
425 die "can't find executable $dumpToolName (looked in $productDir)\n" unless -x $dumpTool;
426
427 my $imageDiffTool = "$productDir/ImageDiff";
428 $imageDiffTool .= "_debug" if isCygwin() && configurationForVisualStudio() eq "Debug_All";
429 die "can't find executable $imageDiffTool (looked in $productDir)\n" if $pixelTests && !-x $imageDiffTool;
430
431 checkFrameworks() unless isCygwin();
432
433 if (isAppleMacWebKit()) {
434     push @INC, $productDir;
435     require DumpRenderTreeSupport;
436 }
437
438 my $layoutTestsName = "LayoutTests";
439 my $testDirectory = File::Spec->rel2abs($layoutTestsName);
440 my $expectedDirectory = $testDirectory;
441 my $platformBaseDirectory = catdir($testDirectory, "platform");
442 my $platformTestDirectory = catdir($platformBaseDirectory, $platform);
443 my @platformResultHierarchy = buildPlatformResultHierarchy();
444 my @platformTestHierarchy = buildPlatformTestHierarchy(@platformResultHierarchy);
445
446 $expectedDirectory = $ENV{"WebKitExpectedTestResultsDirectory"} if $ENV{"WebKitExpectedTestResultsDirectory"};
447
448 $testResultsDirectory = File::Spec->rel2abs($testResultsDirectory);
449 my $testResults = File::Spec->catfile($testResultsDirectory, "results.html");
450
451 if (isAppleMacWebKit()) {
452     print STDERR "Compiling Java tests\n";
453     my $javaTestsDirectory = catdir($testDirectory, "java");
454
455     if (system("/usr/bin/make", "-C", "$javaTestsDirectory")) {
456         exit 1;
457     }
458 }
459
460
461 print "Running tests from $testDirectory\n";
462 if ($pixelTests) {
463     print "Enabling pixel tests with a tolerance of $tolerance%\n";
464     if (isDarwin()) {
465         print "WARNING: Temporarily changing the main display color profile:\n";
466         print "\tThe colors on your screen will change for the duration of the testing.\n";
467         print "\tThis allows the pixel tests to have consistent color values across all machines.\n";
468         
469         if (isPerianInstalled()) {
470             print "WARNING: Perian's QuickTime component is installed and this may affect pixel test results!\n";
471             print "\tYou should avoid generating new pixel results in this environment.\n";
472             print "\tSee https://bugs.webkit.org/show_bug.cgi?id=22615 for details.\n";
473         }
474     }
475 }
476
477 system "ln", "-s", $testDirectory, "/tmp/LayoutTests" unless -x "/tmp/LayoutTests";
478
479 my %ignoredFiles = ( "results.html" => 1 );
480 my %ignoredDirectories = map { $_ => 1 } qw(platform);
481 my %ignoredLocalDirectories = map { $_ => 1 } qw(.svn _svn resources script-tests);
482 my %supportedFileExtensions = map { $_ => 1 } qw(html shtml xml xhtml xhtmlmp pl php);
483
484 if (!checkWebCoreFeatureSupport("MathML", 0)) {
485     $ignoredDirectories{'mathml'} = 1;
486 }
487
488 # FIXME: We should fix webkitperl/features.pm:hasFeature() to do the correct feature detection for Cygwin.
489 if (checkWebCoreFeatureSupport("SVG", 0)) {
490     $supportedFileExtensions{'svg'} = 1;
491 } elsif (isCygwin()) {
492     $supportedFileExtensions{'svg'} = 1;
493 } else {
494     $ignoredLocalDirectories{'svg'} = 1;
495 }
496
497 if (!$testHTTP) {
498     $ignoredDirectories{'http'} = 1;
499     $ignoredDirectories{'websocket'} = 1;
500 }
501 if (!$testWebSocket) {
502     $ignoredDirectories{'websocket'} = 1;
503 }
504
505 if (!$testMedia) {
506     $ignoredDirectories{'media'} = 1;
507     $ignoredDirectories{'http/tests/media'} = 1;
508 }
509
510 my $supportedFeaturesResult = "";
511
512 if (isCygwin()) {
513     # Collect supported features list
514     setPathForRunningWebKitApp(\%ENV);
515     my $supportedFeaturesCommand = "\"$dumpTool\" --print-supported-features 2>&1";
516     $supportedFeaturesResult = `$supportedFeaturesCommand 2>&1`;
517 }
518
519 my $hasAcceleratedCompositing = 0;
520 my $has3DRendering = 0;
521
522 if (isCygwin()) {
523     $hasAcceleratedCompositing = $supportedFeaturesResult =~ /AcceleratedCompositing/;
524     $has3DRendering = $supportedFeaturesResult =~ /3DRendering/;
525 } else {
526     $hasAcceleratedCompositing = checkWebCoreFeatureSupport("Accelerated Compositing", 0);
527     $has3DRendering = checkWebCoreFeatureSupport("3D Rendering", 0);
528 }
529
530 if (!$hasAcceleratedCompositing) {
531     $ignoredDirectories{'compositing'} = 1;
532
533     # This test has slightly different floating-point rounding when accelerated
534     # compositing is enabled.
535     $ignoredFiles{'svg/custom/use-on-symbol-inside-pattern.svg'} = 1;
536
537     if (isAppleWebKit()) {
538         # In Apple's ports, the default controls for <video> contain a "full
539         # screen" button only if accelerated compositing is enabled.
540         $ignoredFiles{'media/controls-after-reload.html'} = 1;
541         $ignoredFiles{'media/controls-drag-timebar.html'} = 1;
542         $ignoredFiles{'media/controls-strict.html'} = 1;
543         $ignoredFiles{'media/controls-styling.html'} = 1;
544         $ignoredFiles{'media/video-controls-rendering.html'} = 1;
545         $ignoredFiles{'media/video-display-toggle.html'} = 1;
546         $ignoredFiles{'media/video-no-audio.html'} = 1;
547     }
548
549     # Here we're using !$hasAcceleratedCompositing as a proxy for "is a headless XP machine" (like
550     # our test slaves). Headless XP machines can neither support accelerated compositing nor pass
551     # this test, so skipping the test here is expedient, if a little sloppy. See
552     # <http://webkit.org/b/48333>.
553     $ignoredFiles{'platform/win/plugins/npn-invalidate-rect-invalidates-window.html'} = 1 if isAppleWinWebKit();
554 }
555
556 if (!$has3DRendering) {
557     $ignoredDirectories{'animations/3d'} = 1;
558     $ignoredDirectories{'transforms/3d'} = 1;
559
560     # These tests use the -webkit-transform-3d media query.
561     $ignoredFiles{'fast/media/mq-transform-02.html'} = 1;
562     $ignoredFiles{'fast/media/mq-transform-03.html'} = 1;
563 }
564
565 if (!checkWebCoreFeatureSupport("3D Canvas", 0)) {
566     $ignoredDirectories{'fast/canvas/webgl'} = 1;
567     $ignoredDirectories{'compositing/webgl'} = 1;
568     $ignoredDirectories{'http/tests/canvas/webgl'} = 1;
569 }
570
571 if (checkWebCoreFeatureSupport("WML", 0)) {
572     $supportedFileExtensions{'wml'} = 1;
573 } else {
574     $ignoredDirectories{'http/tests/wml'} = 1;
575     $ignoredDirectories{'fast/wml'} = 1;
576     $ignoredDirectories{'wml'} = 1;
577 }
578
579 if (!checkWebCoreFeatureSupport("WCSS", 0)) {
580     $ignoredDirectories{'fast/wcss'} = 1;
581 }
582
583 if (!checkWebCoreFeatureSupport("XHTMLMP", 0)) {
584     $ignoredDirectories{'fast/xhtmlmp'} = 1;
585 }
586
587 processIgnoreTests($ignoreTests, "ignore-tests") if $ignoreTests;
588 if (!$ignoreSkipped) {
589     if (!$skippedOnly || @ARGV == 0) {
590         readSkippedFiles("");
591     } else {
592         # Since readSkippedFiles() appends to @ARGV, we must use a foreach
593         # loop so that we only iterate over the original argument list.
594         foreach my $argnum (0 .. $#ARGV) {
595             readSkippedFiles(shift @ARGV);
596         }
597     }
598 }
599
600 my @tests = findTestsToRun();
601
602 die "no tests to run\n" if !@tests;
603
604 my %counts;
605 my %tests;
606 my %imagesPresent;
607 my %imageDifferences;
608 my %durations;
609 my $count = 0;
610 my $leaksOutputFileNumber = 1;
611 my $totalLeaks = 0;
612
613 my @toolArgs = ();
614 push @toolArgs, "--pixel-tests" if $pixelTests;
615 push @toolArgs, "--threaded" if $threaded;
616 push @toolArgs, "--complex-text" if $complexText;
617 push @toolArgs, "-";
618
619 my @diffToolArgs = ();
620 push @diffToolArgs, "--tolerance", $tolerance;
621
622 $| = 1;
623
624 my $dumpToolPID;
625 my $isDumpToolOpen = 0;
626 my $dumpToolCrashed = 0;
627 my $imageDiffToolPID;
628 my $isDiffToolOpen = 0;
629
630 my $atLineStart = 1;
631 my $lastDirectory = "";
632
633 my $isHttpdOpen = 0;
634 my $isWebSocketServerOpen = 0;
635 my $webSocketServerPidFile = 0;
636 my $failedToStartWebSocketServer = 0;
637 # wss is disabled until all platforms support pyOpenSSL.
638 # my $webSocketSecureServerPID = 0;
639
640 sub catch_pipe { $dumpToolCrashed = 1; }
641 $SIG{"PIPE"} = "catch_pipe";
642
643 print "Testing ", scalar @tests, " test cases";
644 print " $iterations times" if ($iterations > 1);
645 print ", repeating each test $repeatEach times" if ($repeatEach > 1);
646 print ".\n";
647
648 my $overallStartTime = time;
649
650 my %expectedResultPaths;
651
652 my @originalTests = @tests;
653 # Add individual test repetitions
654 if ($repeatEach > 1) {
655     @tests = ();
656     foreach my $test (@originalTests) {
657         for (my $i = 0; $i < $repeatEach; $i++) {
658             push(@tests, $test);
659         }
660     }
661 }
662 # Add test set repetitions
663 for (my $i = 1; $i < $iterations; $i++) {
664     push(@tests, @originalTests);
665 }
666
667 for my $test (@tests) {
668     my $newDumpTool = not $isDumpToolOpen;
669     openDumpTool();
670
671     my $base = stripExtension($test);
672     my $expectedExtension = ".txt";
673     
674     my $dir = $base;
675     $dir =~ s|/[^/]+$||;
676
677     if ($newDumpTool || $dir ne $lastDirectory) {
678         foreach my $logue (epiloguesAndPrologues($newDumpTool ? "" : $lastDirectory, $dir)) {
679             if (isCygwin()) {
680                 $logue = toWindowsPath($logue);
681             } else {
682                 $logue = canonpath($logue);
683             }
684             if ($verbose) {
685                 print "running epilogue or prologue $logue\n";
686             }
687             print OUT "$logue\n";
688             # Throw away output from DumpRenderTree.
689             # Once for the test output and once for pixel results (empty)
690             while (<IN>) {
691                 last if /#EOF/;
692             }
693             while (<IN>) {
694                 last if /#EOF/;
695             }
696         }
697     }
698
699     if ($verbose) {
700         print "running $test -> ";
701         $atLineStart = 0;
702     } elsif (!$quiet) {
703         if ($dir ne $lastDirectory) {
704             print "\n" unless $atLineStart;
705             print "$dir ";
706         }
707         print ".";
708         $atLineStart = 0;
709     }
710
711     $lastDirectory = $dir;
712
713     my $result;
714
715     my $startTime = time if $report10Slowest;
716
717     # Try to read expected hash file for pixel tests
718     my $suffixExpectedHash = "";
719     if ($pixelTests && !$resetResults) {
720         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
721         if (open EXPECTEDHASH, File::Spec->catfile($expectedPixelDir, "$base-$expectedTag.checksum")) {
722             my $expectedHash = <EXPECTEDHASH>;
723             chomp($expectedHash);
724             close EXPECTEDHASH;
725             
726             # Format expected hash into a suffix string that is appended to the path / URL passed to DRT
727             $suffixExpectedHash = "'$expectedHash";
728         }
729     }
730
731     if ($test =~ /^http\//) {
732         configureAndOpenHTTPDIfNeeded();
733         if ($test =~ /^http\/tests\/websocket\//) {
734             if ($test =~ /^websocket\/tests\/local\//) {
735                 my $testPath = "$testDirectory/$test";
736                 if (isCygwin()) {
737                     $testPath = toWindowsPath($testPath);
738                 } else {
739                     $testPath = canonpath($testPath);
740                 }
741                 print OUT "$testPath\n";
742             } else {
743                 if (openWebSocketServerIfNeeded()) {
744                     my $path = canonpath($test);
745                     if ($test =~ /^http\/tests\/websocket\/tests\/ssl\//) {
746                         # wss is disabled until all platforms support pyOpenSSL.
747                         print STDERR "Error: wss is disabled until all platforms support pyOpenSSL.";
748                     } else {
749                         $path =~ s/^http\/tests\///;
750                         print OUT "http://127.0.0.1:$httpdPort/$path\n";
751                     }
752                 } else {
753                     # We failed to launch the WebSocket server.  Display a useful error message rather than attempting
754                     # to run tests that expect the server to be available.
755                     my $errorMessagePath = "$testDirectory/http/tests/websocket/resources/server-failed-to-start.html";
756                     $errorMessagePath = isCygwin() ? toWindowsPath($errorMessagePath) : canonpath($errorMessagePath);
757                     print OUT "$errorMessagePath\n";
758                 }
759             }
760         } elsif ($test !~ /^http\/tests\/local\// && $test !~ /^http\/tests\/ssl\// && $test !~ /^http\/tests\/wml\// && $test !~ /^http\/tests\/media\//) {
761             my $path = canonpath($test);
762             $path =~ s/^http\/tests\///;
763             print OUT "http://127.0.0.1:$httpdPort/$path$suffixExpectedHash\n";
764         } elsif ($test =~ /^http\/tests\/ssl\//) {
765             my $path = canonpath($test);
766             $path =~ s/^http\/tests\///;
767             print OUT "https://127.0.0.1:$httpdSSLPort/$path$suffixExpectedHash\n";
768         } else {
769             my $testPath = "$testDirectory/$test";
770             if (isCygwin()) {
771                 $testPath = toWindowsPath($testPath);
772             } else {
773                 $testPath = canonpath($testPath);
774             }
775             print OUT "$testPath$suffixExpectedHash\n";
776         }
777     } else {
778         my $testPath = "$testDirectory/$test";
779         if (isCygwin()) {
780             $testPath = toWindowsPath($testPath);
781         } else {
782             $testPath = canonpath($testPath);
783         }
784         print OUT "$testPath$suffixExpectedHash\n" if defined $testPath;
785     }
786
787     # DumpRenderTree is expected to dump two "blocks" to stdout for each test.
788     # Each block is terminated by a #EOF on a line by itself.
789     # The first block is the output of the test (in text, RenderTree or other formats).
790     # The second block is for optional pixel data in PNG format, and may be empty if
791     # pixel tests are not being run, or the test does not dump pixels (e.g. text tests).
792     my $readResults = readFromDumpToolWithTimer(IN, ERROR);
793
794     my $actual = $readResults->{output};
795     my $error = $readResults->{error};
796
797     $expectedExtension = $readResults->{extension};
798     my $expectedFileName = "$base-$expectedTag.$expectedExtension";
799
800     my $isText = isTextOnlyTest($actual);
801
802     my $expectedDir = expectedDirectoryForTest($base, $isText, $expectedExtension);
803     $expectedResultPaths{$base} = File::Spec->catfile($expectedDir, $expectedFileName);
804
805     unless ($readResults->{status} eq "success") {
806         my $crashed = $readResults->{status} eq "crashed";
807         testCrashedOrTimedOut($test, $base, $crashed, $actual, $error);
808         countFinishedTest($test, $base, $crashed ? "crash" : "timedout", 0);
809         last if stopRunningTestsEarlyIfNeeded();
810         next;
811     }
812
813     $durations{$test} = time - $startTime if $report10Slowest;
814
815     my $expected;
816
817     if (!$resetResults && open EXPECTED, "<", $expectedResultPaths{$base}) {
818         $expected = "";
819         while (<EXPECTED>) {
820             next if $stripEditingCallbacks && $_ =~ /^EDITING DELEGATE:/;
821             $expected .= $_;
822         }
823         close EXPECTED;
824     }
825
826     if ($ignoreMetrics && !$isText && defined $expected) {
827         ($actual, $expected) = stripMetrics($actual, $expected);
828     }
829
830     if ($shouldCheckLeaks && $testsPerDumpTool == 1) {
831         print "        $test -> ";
832     }
833
834     my $actualPNG = "";
835     my $diffPNG = "";
836     my $diffPercentage = 0;
837     my $diffResult = "passed";
838
839     my $actualHash = "";
840     my $expectedHash = "";
841     my $actualPNGSize = 0;
842
843     while (<IN>) {
844         last if /#EOF/;
845         if (/ActualHash: ([a-f0-9]{32})/) {
846             $actualHash = $1;
847         } elsif (/ExpectedHash: ([a-f0-9]{32})/) {
848             $expectedHash = $1;
849         } elsif (/Content-Length: (\d+)\s*/) {
850             $actualPNGSize = $1;
851             read(IN, $actualPNG, $actualPNGSize);
852         }
853     }
854
855     if ($verbose && $pixelTests && !$resetResults && $actualPNGSize) {
856         if ($actualHash eq "" && $expectedHash eq "") {
857             printFailureMessageForTest($test, "WARNING: actual & expected pixel hashes are missing!");
858         } elsif ($actualHash eq "") {
859             printFailureMessageForTest($test, "WARNING: actual pixel hash is missing!");
860         } elsif ($expectedHash eq "") {
861             printFailureMessageForTest($test, "WARNING: expected pixel hash is missing!");
862         }
863     }
864
865     if ($actualPNGSize > 0) {
866         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
867         my $expectedPNGPath = File::Spec->catfile($expectedPixelDir, "$base-$expectedTag.png");
868
869         if (!$resetResults && ($expectedHash ne $actualHash || ($actualHash eq "" && $expectedHash eq ""))) {
870             if (-f $expectedPNGPath) {
871                 my $expectedPNGSize = -s $expectedPNGPath;
872                 my $expectedPNG = "";
873                 open EXPECTEDPNG, $expectedPNGPath;
874                 read(EXPECTEDPNG, $expectedPNG, $expectedPNGSize);
875
876                 openDiffTool();
877                 print DIFFOUT "Content-Length: $actualPNGSize\n";
878                 print DIFFOUT $actualPNG;
879
880                 print DIFFOUT "Content-Length: $expectedPNGSize\n";
881                 print DIFFOUT $expectedPNG;
882
883                 while (<DIFFIN>) {
884                     last if /^error/ || /^diff:/;
885                     if (/Content-Length: (\d+)\s*/) {
886                         read(DIFFIN, $diffPNG, $1);
887                     }
888                 }
889
890                 if (/^diff: (.+)% (passed|failed)/) {
891                     $diffPercentage = $1 + 0;
892                     $imageDifferences{$base} = $diffPercentage;
893                     $diffResult = $2;
894                 }
895                 
896                 if (!$diffPercentage) {
897                     printFailureMessageForTest($test, "pixel hash failed (but pixel test still passes)");
898                 }
899             } elsif ($verbose) {
900                 printFailureMessageForTest($test, "WARNING: expected image is missing!");
901             }
902         }
903
904         if ($resetResults || !-f $expectedPNGPath) {
905             mkpath catfile($expectedPixelDir, dirname($base)) if $testDirectory ne $expectedPixelDir;
906             writeToFile($expectedPNGPath, $actualPNG);
907         }
908
909         my $expectedChecksumPath = File::Spec->catfile($expectedPixelDir, "$base-$expectedTag.checksum");
910         if ($actualHash ne "" && ($resetResults || !-f $expectedChecksumPath)) {
911             writeToFile($expectedChecksumPath, $actualHash);
912         }
913     }
914
915     if (dumpToolDidCrash()) {
916         $result = "crash";
917         testCrashedOrTimedOut($test, $base, 1, $actual, $error);
918     } elsif (!defined $expected) {
919         if ($verbose) {
920             print "new " . ($resetResults ? "result" : "test");
921         }
922         $result = "new";
923
924         if ($generateNewResults || $resetResults) {
925             mkpath catfile($expectedDir, dirname($base)) if $testDirectory ne $expectedDir;
926             writeToFile("$expectedDir/$expectedFileName", $actual);
927         }
928         deleteExpectedAndActualResults($base);
929         recordActualResultsAndDiff($base, $actual);
930         if (!$resetResults) {
931             # Always print the file name for new tests, as they will probably need some manual inspection.
932             # in verbose mode we already printed the test case, so no need to do it again.
933             unless ($verbose) {
934                 print "\n" unless $atLineStart;
935                 print "$test -> ";
936             }
937             my $resultsDir = catdir($expectedDir, dirname($base));
938             if (!$verbose) {
939                 print "new";
940             }
941             if ($generateNewResults) {
942                 print " (results generated in $resultsDir)";
943             }
944             print "\n" unless $atLineStart;
945             $atLineStart = 1;
946         }
947     } elsif ($actual eq $expected && $diffResult eq "passed") {
948         if ($verbose) {
949             print "succeeded\n";
950             $atLineStart = 1;
951         }
952         $result = "match";
953         deleteExpectedAndActualResults($base);
954     } else {
955         $result = "mismatch";
956
957         my $pixelTestFailed = $pixelTests && $diffPNG && $diffPNG ne "";
958         my $testFailed = $actual ne $expected;
959
960         my $message = !$testFailed ? "pixel test failed" : "failed";
961
962         if (($testFailed || $pixelTestFailed) && $addPlatformExceptions) {
963             my $testBase = catfile($testDirectory, $base);
964             my $expectedBase = catfile($expectedDir, $base);
965             my $testIsMaximallyPlatformSpecific = $testBase =~ m|^\Q$platformTestDirectory\E/|;
966             my $expectedResultIsMaximallyPlatformSpecific = $expectedBase =~ m|^\Q$platformTestDirectory\E/|;
967             if (!$testIsMaximallyPlatformSpecific && !$expectedResultIsMaximallyPlatformSpecific) {
968                 mkpath catfile($platformTestDirectory, dirname($base));
969                 if ($testFailed) {
970                     my $expectedFile = catfile($platformTestDirectory, "$expectedFileName");
971                     writeToFile("$expectedFile", $actual);
972                 }
973                 if ($pixelTestFailed) {
974                     my $expectedFile = catfile($platformTestDirectory, "$base-$expectedTag.checksum");
975                     writeToFile("$expectedFile", $actualHash);
976
977                     $expectedFile = catfile($platformTestDirectory, "$base-$expectedTag.png");
978                     writeToFile("$expectedFile", $actualPNG);
979                 }
980                 $message .= " (results generated in $platformTestDirectory)";
981             }
982         }
983
984         printFailureMessageForTest($test, $message);
985
986         my $dir = "$testResultsDirectory/$base";
987         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
988         my $testName = $1;
989         mkpath $dir;
990
991         deleteExpectedAndActualResults($base);
992         recordActualResultsAndDiff($base, $actual);
993
994         if ($pixelTestFailed) {
995             $imagesPresent{$base} = 1;
996
997             writeToFile("$testResultsDirectory/$base-$actualTag.png", $actualPNG);
998             writeToFile("$testResultsDirectory/$base-$diffsTag.png", $diffPNG);
999
1000             my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
1001             copy("$expectedPixelDir/$base-$expectedTag.png", "$testResultsDirectory/$base-$expectedTag.png");
1002
1003             open DIFFHTML, ">$testResultsDirectory/$base-$diffsTag.html" or die;
1004             print DIFFHTML "<html>\n";
1005             print DIFFHTML "<head>\n";
1006             print DIFFHTML "<title>$base Image Compare</title>\n";
1007             print DIFFHTML "<script language=\"Javascript\" type=\"text/javascript\">\n";
1008             print DIFFHTML "var currentImage = 0;\n";
1009             print DIFFHTML "var imageNames = new Array(\"Actual\", \"Expected\");\n";
1010             print DIFFHTML "var imagePaths = new Array(\"$testName-$actualTag.png\", \"$testName-$expectedTag.png\");\n";
1011             if (-f "$testDirectory/$base-w3c.png") {
1012                 copy("$testDirectory/$base-w3c.png", "$testResultsDirectory/$base-w3c.png");
1013                 print DIFFHTML "imageNames.push(\"W3C\");\n";
1014                 print DIFFHTML "imagePaths.push(\"$testName-w3c.png\");\n";
1015             }
1016             print DIFFHTML "function animateImage() {\n";
1017             print DIFFHTML "    var image = document.getElementById(\"animatedImage\");\n";
1018             print DIFFHTML "    var imageText = document.getElementById(\"imageText\");\n";
1019             print DIFFHTML "    image.src = imagePaths[currentImage];\n";
1020             print DIFFHTML "    imageText.innerHTML = imageNames[currentImage] + \" Image\";\n";
1021             print DIFFHTML "    currentImage = (currentImage + 1) % imageNames.length;\n";
1022             print DIFFHTML "    setTimeout('animateImage()',2000);\n";
1023             print DIFFHTML "}\n";
1024             print DIFFHTML "</script>\n";
1025             print DIFFHTML "</head>\n";
1026             print DIFFHTML "<body onLoad=\"animateImage();\">\n";
1027             print DIFFHTML "<table>\n";
1028             if ($diffPercentage) {
1029                 print DIFFHTML "<tr>\n";
1030                 print DIFFHTML "<td>Difference between images: <a href=\"$testName-$diffsTag.png\">$diffPercentage%</a></td>\n";
1031                 print DIFFHTML "</tr>\n";
1032             }
1033             print DIFFHTML "<tr>\n";
1034             print DIFFHTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">test file</a></td>\n";
1035             print DIFFHTML "</tr>\n";
1036             print DIFFHTML "<tr>\n";
1037             print DIFFHTML "<td id=\"imageText\" style=\"text-weight: bold;\">Actual Image</td>\n";
1038             print DIFFHTML "</tr>\n";
1039             print DIFFHTML "<tr>\n";
1040             print DIFFHTML "<td><img src=\"$testName-$actualTag.png\" id=\"animatedImage\"></td>\n";
1041             print DIFFHTML "</tr>\n";
1042             print DIFFHTML "</table>\n";
1043             print DIFFHTML "</body>\n";
1044             print DIFFHTML "</html>\n";
1045         }
1046     }
1047
1048     if ($error) {
1049         my $dir = dirname(File::Spec->catdir($testResultsDirectory, $base));
1050         mkpath $dir;
1051         
1052         writeToFile(File::Spec->catfile($testResultsDirectory, "$base-$errorTag.txt"), $error);
1053         
1054         $counts{error}++;
1055         push @{$tests{error}}, $test;
1056     }
1057
1058     countFinishedTest($test, $base, $result, $isText);
1059     last if stopRunningTestsEarlyIfNeeded();
1060 }
1061
1062 my $totalTestingTime = time - $overallStartTime;
1063 my $waitTime = getWaitTime();
1064 if ($waitTime > 0.1) {
1065     my $normalizedTestingTime = $totalTestingTime - $waitTime;
1066     printf "\n%0.2fs HTTPD waiting time\n", $waitTime . "";
1067     printf "%0.2fs normalized testing time", $normalizedTestingTime . "";
1068 }
1069 printf "\n%0.2fs total testing time\n", $totalTestingTime . "";
1070
1071 !$isDumpToolOpen || die "Failed to close $dumpToolName.\n";
1072
1073 $isHttpdOpen = !closeHTTPD();
1074 closeWebSocketServer();
1075
1076 # Because multiple instances of this script are running concurrently we cannot 
1077 # safely delete this symlink.
1078 # system "rm /tmp/LayoutTests";
1079
1080 # FIXME: Do we really want to check the image-comparison tool for leaks every time?
1081 if ($isDiffToolOpen && $shouldCheckLeaks) {
1082     $totalLeaks += countAndPrintLeaks("ImageDiff", $imageDiffToolPID, "$testResultsDirectory/ImageDiff-leaks.txt");
1083 }
1084
1085 if ($totalLeaks) {
1086     if ($mergeDepth) {
1087         parseLeaksandPrintUniqueLeaks();
1088     } else { 
1089         print "\nWARNING: $totalLeaks total leaks found!\n";
1090         print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
1091     }
1092 }
1093
1094 close IN;
1095 close OUT;
1096 close ERROR;
1097
1098 if ($report10Slowest) {
1099     print "\n\nThe 10 slowest tests:\n\n";
1100     my $count = 0;
1101     for my $test (sort slowestcmp keys %durations) {
1102         printf "%0.2f secs: %s\n", $durations{$test}, $test;
1103         last if ++$count == 10;
1104     }
1105 }
1106
1107 print "\n";
1108
1109 if ($skippedOnly && $counts{"match"}) {
1110     print "The following tests are in the Skipped file (" . File::Spec->abs2rel("$platformTestDirectory/Skipped", $testDirectory) . "), but succeeded:\n";
1111     foreach my $test (@{$tests{"match"}}) {
1112         print "  $test\n";
1113     }
1114 }
1115
1116 if ($resetResults || ($counts{match} && $counts{match} == $count)) {
1117     print "all $count test cases succeeded\n";
1118     unlink $testResults;
1119     exit;
1120 }
1121
1122 printResults();
1123
1124 mkpath $testResultsDirectory;
1125
1126 open HTML, ">", $testResults or die "Failed to open $testResults. $!";
1127 print HTML "<html>\n";
1128 print HTML "<head>\n";
1129 print HTML "<title>Layout Test Results</title>\n";
1130 print HTML "</head>\n";
1131 print HTML "<body>\n";
1132
1133 if ($ignoreMetrics) {
1134     print HTML "<h4>Tested with metrics ignored.</h4>";
1135 }
1136
1137 print HTML htmlForResultsSection(@{$tests{mismatch}}, "Tests where results did not match expected results", \&linksForMismatchTest);
1138 print HTML htmlForResultsSection(@{$tests{timedout}}, "Tests that timed out", \&linksForErrorTest);
1139 print HTML htmlForResultsSection(@{$tests{crash}}, "Tests that caused the DumpRenderTree tool to crash", \&linksForErrorTest);
1140 print HTML htmlForResultsSection(@{$tests{error}}, "Tests that had stderr output", \&linksForErrorTest);
1141 print HTML htmlForResultsSection(@{$tests{new}}, "Tests that had no expected results (probably new)", \&linksForNewTest);
1142
1143 print HTML "</body>\n";
1144 print HTML "</html>\n";
1145 close HTML;
1146
1147 my @configurationArgs = argumentsForConfiguration();
1148
1149 if (isGtk()) {
1150   system "Tools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1151 } elsif (isQt()) {
1152   unshift @configurationArgs, qw(-graphicssystem raster -style windows);
1153   if (isCygwin()) {
1154     $testResults = "/" . toWindowsPath($testResults);
1155     $testResults =~ s/\\/\//g;
1156   }
1157   system "Tools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1158 } elsif (isCygwin()) {
1159   system "cygstart", $testResults if $launchSafari;
1160 } elsif (isWindows()) {
1161   system "start", $testResults if $launchSafari;
1162 } else {
1163   system "Tools/Scripts/run-safari", @configurationArgs, "-NSOpen", $testResults if $launchSafari;
1164 }
1165
1166 closeCygpaths() if isCygwin();
1167
1168 exit 1;
1169
1170 sub countAndPrintLeaks($$$)
1171 {
1172     my ($dumpToolName, $dumpToolPID, $leaksFilePath) = @_;
1173
1174     print "\n" unless $atLineStart;
1175     $atLineStart = 1;
1176
1177     # We are excluding the following reported leaks so they don't get in our way when looking for WebKit leaks:
1178     # This allows us ignore known leaks and only be alerted when new leaks occur. Some leaks are in the old
1179     # versions of the system frameworks that are being used by the leaks bots. Even though a leak has been
1180     # fixed, it will be listed here until the bot has been updated with the newer frameworks.
1181
1182     my @typesToExclude = (
1183     );
1184
1185     my @callStacksToExclude = (
1186         "Flash_EnforceLocalSecurity" # leaks in Flash plug-in code, rdar://problem/4449747
1187     );
1188
1189     if (isTiger()) {
1190         # Leak list for the version of Tiger used on the build bot.
1191         push @callStacksToExclude, (
1192             "CFRunLoopRunSpecific \\| malloc_zone_malloc", "CFRunLoopRunSpecific \\| CFAllocatorAllocate ", # leak in CFRunLoopRunSpecific, rdar://problem/4670839
1193             "CGImageSourceGetPropertiesAtIndex", # leak in ImageIO, rdar://problem/4628809
1194             "FOGetCoveredUnicodeChars", # leak in ATS, rdar://problem/3943604
1195             "GetLineDirectionPreference", "InitUnicodeUtilities", # leaks tool falsely reporting leak in CFNotificationCenterAddObserver, rdar://problem/4964790
1196             "ICCFPrefWrapper::GetPrefDictionary", # leaks in Internet Config. code, rdar://problem/4449794
1197             "NSHTTPURLProtocol setResponseHeader:", # leak in multipart/mixed-replace handling in Foundation, no Radar, but fixed in Leopard
1198             "NSURLCache cachedResponseForRequest", # leak in CFURL cache, rdar://problem/4768430
1199             "PCFragPrepareClosureFromFile", # leak in Code Fragment Manager, rdar://problem/3426998
1200             "WebCore::Selection::toRange", # bug in 'leaks', rdar://problem/4967949
1201             "WebCore::SubresourceLoader::create", # bug in 'leaks', rdar://problem/4985806
1202             "_CFPreferencesDomainDeepCopyDictionary", # leak in CFPreferences, rdar://problem/4220786
1203             "_objc_msgForward", # leak in NSSpellChecker, rdar://problem/4965278
1204             "gldGetString", # leak in OpenGL, rdar://problem/5013699
1205             "_setDefaultUserInfoFromURL", # leak in NSHTTPAuthenticator, rdar://problem/5546453 
1206             "SSLHandshake", # leak in SSL, rdar://problem/5546440 
1207             "SecCertificateCreateFromData", # leak in SSL code, rdar://problem/4464397
1208         );
1209         push @typesToExclude, (
1210             "THRD", # bug in 'leaks', rdar://problem/3387783
1211             "DRHT", # ditto (endian little hate i)
1212         );
1213     }
1214
1215     if (isLeopard()) {
1216         # Leak list for the version of Leopard used on the build bot.
1217         push @callStacksToExclude, (
1218             "CFHTTPMessageAppendBytes", # leak in CFNetwork, rdar://problem/5435912
1219             "sendDidReceiveDataCallback", # leak in CFNetwork, rdar://problem/5441619
1220             "_CFHTTPReadStreamReadMark", # leak in CFNetwork, rdar://problem/5441468
1221             "httpProtocolStart", # leak in CFNetwork, rdar://problem/5468837
1222             "_CFURLConnectionSendCallbacks", # leak in CFNetwork, rdar://problem/5441600
1223             "DispatchQTMsg", # leak in QuickTime, PPC only, rdar://problem/5667132
1224             "QTMovieContentView createVisualContext", # leak in QuickTime, PPC only, rdar://problem/5667132
1225             "_CopyArchitecturesForJVMVersion", # leak in Java, rdar://problem/5910823
1226         );
1227     }
1228
1229     if (isSnowLeopard()) {
1230         push @callStacksToExclude, (
1231             "readMakerNoteProps", # <rdar://problem/7156432> leak in ImageIO
1232             "QTKitMovieControllerView completeUISetup", # <rdar://problem/7155156> leak in QTKit
1233             "getVMInitArgs", # <rdar://problem/7714444> leak in Java
1234             "Java_java_lang_System_initProperties", # <rdar://problem/7714465> leak in Java
1235             "glrCompExecuteKernel", # <rdar://problem/7815391> leak in graphics driver while using OpenGL
1236         );
1237     }
1238
1239     if (isDarwin() && !isTiger() && !isLeopard() && !isSnowLeopard()) {
1240         push @callStacksToExclude, (
1241             "CGGradientCreateWithColorComponents", # leak in CoreGraphics, <rdar://problem/7888492>
1242         );
1243     }
1244
1245     my $leaksTool = sourceDir() . "/Tools/Scripts/run-leaks";
1246     my $excludeString = "--exclude-callstack '" . (join "' --exclude-callstack '", @callStacksToExclude) . "'";
1247     $excludeString .= " --exclude-type '" . (join "' --exclude-type '", @typesToExclude) . "'" if @typesToExclude;
1248
1249     print " ? checking for leaks in $dumpToolName\n";
1250     my $leaksOutput = `$leaksTool $excludeString $dumpToolPID`;
1251     my ($count, $bytes) = $leaksOutput =~ /Process $dumpToolPID: (\d+) leaks? for (\d+) total/;
1252     my ($excluded) = $leaksOutput =~ /(\d+) leaks? excluded/;
1253
1254     my $adjustedCount = $count;
1255     $adjustedCount -= $excluded if $excluded;
1256
1257     if (!$adjustedCount) {
1258         print " - no leaks found\n";
1259         unlink $leaksFilePath;
1260         return 0;
1261     } else {
1262         my $dir = $leaksFilePath;
1263         $dir =~ s|/[^/]+$|| or die;
1264         mkpath $dir;
1265
1266         if ($excluded) {
1267             print " + $adjustedCount leaks ($bytes bytes including $excluded excluded leaks) were found, details in $leaksFilePath\n";
1268         } else {
1269             print " + $count leaks ($bytes bytes) were found, details in $leaksFilePath\n";
1270         }
1271
1272         writeToFile($leaksFilePath, $leaksOutput);
1273         
1274         push @leaksFilenames, $leaksFilePath;
1275     }
1276
1277     return $adjustedCount;
1278 }
1279
1280 sub writeToFile($$)
1281 {
1282     my ($filePath, $contents) = @_;
1283     open NEWFILE, ">", "$filePath" or die "Could not create $filePath. $!\n";
1284     print NEWFILE $contents;
1285     close NEWFILE;
1286 }
1287
1288 # Break up a path into the directory (with slash) and base name.
1289 sub splitpath($)
1290 {
1291     my ($path) = @_;
1292
1293     my $pathSeparator = "/";
1294     my $dirname = dirname($path) . $pathSeparator;
1295     $dirname = "" if $dirname eq "." . $pathSeparator;
1296
1297     return ($dirname, basename($path));
1298 }
1299
1300 # Sort first by directory, then by file, so all paths in one directory are grouped
1301 # rather than being interspersed with items from subdirectories.
1302 # Use numericcmp to sort directory and filenames to make order logical.
1303 sub pathcmp($$)
1304 {
1305     my ($patha, $pathb) = @_;
1306
1307     my ($dira, $namea) = splitpath($patha);
1308     my ($dirb, $nameb) = splitpath($pathb);
1309
1310     return numericcmp($dira, $dirb) if $dira ne $dirb;
1311     return numericcmp($namea, $nameb);
1312 }
1313
1314 # Sort numeric parts of strings as numbers, other parts as strings.
1315 # Makes 1.33 come after 1.3, which is cool.
1316 sub numericcmp($$)
1317 {
1318     my ($aa, $bb) = @_;
1319
1320     my @a = split /(\d+)/, $aa;
1321     my @b = split /(\d+)/, $bb;
1322
1323     # Compare one chunk at a time.
1324     # Each chunk is either all numeric digits, or all not numeric digits.
1325     while (@a && @b) {
1326         my $a = shift @a;
1327         my $b = shift @b;
1328         
1329         # Use numeric comparison if chunks are non-equal numbers.
1330         return $a <=> $b if $a =~ /^\d/ && $b =~ /^\d/ && $a != $b;
1331
1332         # Use string comparison if chunks are any other kind of non-equal string.
1333         return $a cmp $b if $a ne $b;
1334     }
1335     
1336     # One of the two is now empty; compare lengths for result in this case.
1337     return @a <=> @b;
1338 }
1339
1340 # Sort slowest tests first.
1341 sub slowestcmp($$)
1342 {
1343     my ($testa, $testb) = @_;
1344
1345     my $dura = $durations{$testa};
1346     my $durb = $durations{$testb};
1347     return $durb <=> $dura if $dura != $durb;
1348     return pathcmp($testa, $testb);
1349 }
1350
1351 sub launchWithEnv(\@\%)
1352 {
1353     my ($args, $env) = @_;
1354
1355     # Dump the current environment as perl code and then put it in quotes so it is one parameter.
1356     my $environmentDumper = Data::Dumper->new([\%{$env}], [qw(*ENV)]);
1357     $environmentDumper->Indent(0);
1358     $environmentDumper->Purity(1);
1359     my $allEnvVars = $environmentDumper->Dump();
1360     unshift @{$args}, "\"$allEnvVars\"";
1361
1362     my $execScript = File::Spec->catfile(sourceDir(), qw(Tools Scripts execAppWithEnv));
1363     unshift @{$args}, $perlInterpreter, $execScript;
1364     return @{$args};
1365 }
1366
1367 sub resolveAndMakeTestResultsDirectory()
1368 {
1369     my $absTestResultsDirectory = File::Spec->rel2abs(glob $testResultsDirectory);
1370     mkpath $absTestResultsDirectory;
1371     return $absTestResultsDirectory;
1372 }
1373
1374 sub openDiffTool()
1375 {
1376     return if $isDiffToolOpen;
1377     return if !$pixelTests;
1378
1379     my %CLEAN_ENV;
1380     $CLEAN_ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1381     $imageDiffToolPID = open2(\*DIFFIN, \*DIFFOUT, $imageDiffTool, launchWithEnv(@diffToolArgs, %CLEAN_ENV)) or die "unable to open $imageDiffTool\n";
1382     $isDiffToolOpen = 1;
1383 }
1384
1385 sub buildDumpTool($)
1386 {
1387     my ($dumpToolName) = @_;
1388
1389     my $dumpToolBuildScript =  "build-" . lc($dumpToolName);
1390     print STDERR "Running $dumpToolBuildScript\n";
1391
1392     local *DEVNULL;
1393     my ($childIn, $childOut, $childErr);
1394     if ($quiet) {
1395         open(DEVNULL, ">", File::Spec->devnull()) or die "Failed to open /dev/null";
1396         $childOut = ">&DEVNULL";
1397         $childErr = ">&DEVNULL";
1398     } else {
1399         # When not quiet, let the child use our stdout/stderr.
1400         $childOut = ">&STDOUT";
1401         $childErr = ">&STDERR";
1402     }
1403
1404     my @args = argumentsForConfiguration();
1405     my $buildProcess = open3($childIn, $childOut, $childErr, $perlInterpreter, File::Spec->catfile(qw(Tools Scripts), $dumpToolBuildScript), @args) or die "Failed to run build-dumprendertree";
1406     close($childIn);
1407     waitpid $buildProcess, 0;
1408     my $buildResult = $?;
1409     close($childOut);
1410     close($childErr);
1411
1412     close DEVNULL if ($quiet);
1413
1414     if ($buildResult) {
1415         print STDERR "Compiling $dumpToolName failed!\n";
1416         exit exitStatus($buildResult);
1417     }
1418 }
1419
1420 sub openDumpTool()
1421 {
1422     return if $isDumpToolOpen;
1423
1424     if ($verbose && $testsPerDumpTool != 1) {
1425         print "| Opening DumpTool |\n";
1426     }
1427
1428     my %CLEAN_ENV;
1429
1430     # Generic environment variables
1431     if (defined $ENV{'WEBKIT_TESTFONTS'}) {
1432         $CLEAN_ENV{WEBKIT_TESTFONTS} = $ENV{'WEBKIT_TESTFONTS'};
1433     }
1434
1435     # unique temporary directory for each DumpRendertree - needed for running more DumpRenderTree in parallel
1436     $CLEAN_ENV{DUMPRENDERTREE_TEMP} = File::Temp::tempdir('DumpRenderTree-XXXXXX', TMPDIR => 1, CLEANUP => 1);
1437     $CLEAN_ENV{XML_CATALOG_FILES} = ""; # work around missing /etc/catalog <rdar://problem/4292995>
1438
1439     # Platform spesifics
1440     if (isLinux()) {
1441         if (defined $ENV{'DISPLAY'}) {
1442             $CLEAN_ENV{DISPLAY} = $ENV{'DISPLAY'};
1443         } else {
1444             $CLEAN_ENV{DISPLAY} = ":1";
1445         }
1446         if (defined $ENV{'XAUTHORITY'}) {
1447             $CLEAN_ENV{XAUTHORITY} = $ENV{'XAUTHORITY'};
1448         }
1449
1450         $CLEAN_ENV{HOME} = $ENV{'HOME'};
1451
1452         if (defined $ENV{'LD_LIBRARY_PATH'}) {
1453             $CLEAN_ENV{LD_LIBRARY_PATH} = $ENV{'LD_LIBRARY_PATH'};
1454         }
1455         if (defined $ENV{'DBUS_SESSION_BUS_ADDRESS'}) {
1456             $CLEAN_ENV{DBUS_SESSION_BUS_ADDRESS} = $ENV{'DBUS_SESSION_BUS_ADDRESS'};
1457         }
1458     } elsif (isDarwin()) {
1459         if (defined $ENV{'DYLD_LIBRARY_PATH'}) {
1460             $CLEAN_ENV{DYLD_LIBRARY_PATH} = $ENV{'DYLD_LIBRARY_PATH'};
1461         }
1462
1463         $CLEAN_ENV{DYLD_FRAMEWORK_PATH} = $productDir;
1464         $CLEAN_ENV{DYLD_INSERT_LIBRARIES} = "/usr/lib/libgmalloc.dylib" if $guardMalloc;
1465     } elsif (isCygwin()) {
1466         $CLEAN_ENV{HOMEDRIVE} = $ENV{'HOMEDRIVE'};
1467         $CLEAN_ENV{HOMEPATH} = $ENV{'HOMEPATH'};
1468         $CLEAN_ENV{_NT_SYMBOL_PATH} = $ENV{_NT_SYMBOL_PATH};
1469
1470         setPathForRunningWebKitApp(\%CLEAN_ENV);
1471     }
1472
1473     # Port specifics
1474     if (isGtk()) {
1475         $CLEAN_ENV{GTK_MODULES} = "gail";
1476         $CLEAN_ENV{WEBKIT_INSPECTOR_PATH} = "$productDir/resources/inspector";
1477     }
1478
1479     if (isQt()) {
1480         $CLEAN_ENV{QTWEBKIT_PLUGIN_PATH} = productDir() . "/lib/plugins";
1481         $CLEAN_ENV{QT_DRT_WEBVIEW_MODE} = $ENV{"QT_DRT_WEBVIEW_MODE"};
1482     }
1483     
1484     my @args = ($dumpTool, @toolArgs);
1485     if (isAppleMacWebKit() and !isTiger()) { 
1486         unshift @args, "arch", "-" . architecture();             
1487     }
1488
1489     if ($useValgrind) {
1490         unshift @args, "valgrind", "--suppressions=$platformBaseDirectory/qt/SuppressedValgrindErrors";
1491     } 
1492
1493     if ($useWebKitTestRunner) {
1494         # Make WebKitTestRunner use a similar timeout. We don't use the exact same timeout to avoid
1495         # race conditions.
1496         push @args, "--timeout", $timeoutSeconds - 5;
1497     }
1498
1499     $CLEAN_ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1500
1501     $dumpToolPID = open3(\*OUT, \*IN, \*ERROR, launchWithEnv(@args, %CLEAN_ENV)) or die "Failed to start tool: $dumpTool\n";
1502     $isDumpToolOpen = 1;
1503     $dumpToolCrashed = 0;
1504 }
1505
1506 sub closeDumpTool()
1507 {
1508     return if !$isDumpToolOpen;
1509
1510     if ($verbose && $testsPerDumpTool != 1) {
1511         print "| Closing DumpTool |\n";
1512     }
1513
1514     close IN;
1515     close OUT;
1516     waitpid $dumpToolPID, 0;
1517     
1518     # check for WebCore counter leaks.
1519     if ($shouldCheckLeaks) {
1520         while (<ERROR>) {
1521             print;
1522         }
1523     }
1524     close ERROR;
1525     $isDumpToolOpen = 0;
1526 }
1527
1528 sub dumpToolDidCrash()
1529 {
1530     return 1 if $dumpToolCrashed;
1531     return 0 unless $isDumpToolOpen;
1532     my $pid = waitpid(-1, WNOHANG);
1533     return 1 if ($pid == $dumpToolPID);
1534
1535     # On Mac OS X, crashing may be significantly delayed by crash reporter.
1536     return 0 unless isAppleMacWebKit();
1537
1538     return DumpRenderTreeSupport::processIsCrashing($dumpToolPID);
1539 }
1540
1541 sub configureAndOpenHTTPDIfNeeded()
1542 {
1543     return if $isHttpdOpen;
1544     my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
1545     my $listen = "127.0.0.1:$httpdPort";
1546     my @args = (
1547         "-c", "CustomLog \"$absTestResultsDirectory/access_log.txt\" common",
1548         "-c", "ErrorLog \"$absTestResultsDirectory/error_log.txt\"",
1549         "-C", "Listen $listen"
1550     );
1551
1552     my @defaultArgs = getDefaultConfigForTestDirectory($testDirectory);
1553     @args = (@defaultArgs, @args);
1554
1555     waitForHTTPDLock() if $shouldWaitForHTTPD;
1556     $isHttpdOpen = openHTTPD(@args);
1557 }
1558
1559 sub checkPythonVersion()
1560 {
1561     # we have not chdir to sourceDir yet.
1562     system $perlInterpreter, File::Spec->catfile(sourceDir(), qw(Tools Scripts ensure-valid-python)), "--check-only";
1563     return exitStatus($?) == 0;
1564 }
1565
1566 sub openWebSocketServerIfNeeded()
1567 {
1568     return 1 if $isWebSocketServerOpen;
1569     return 0 if $failedToStartWebSocketServer;
1570
1571     my $webSocketHandlerDir = "$testDirectory";
1572     my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
1573     $webSocketServerPidFile = "$absTestResultsDirectory/websocket.pid";
1574
1575     my @args = (
1576         "Tools/Scripts/new-run-webkit-websocketserver",
1577         "--server", "start",
1578         "--port", "$webSocketPort",
1579         "--root", "$webSocketHandlerDir",
1580         "--output-dir", "$absTestResultsDirectory",
1581         "--pidfile", "$webSocketServerPidFile"
1582     );
1583     system "/usr/bin/python", @args;
1584
1585     $isWebSocketServerOpen = 1;
1586     return 1;
1587 }
1588
1589 sub closeWebSocketServer()
1590 {
1591     return if !$isWebSocketServerOpen;
1592
1593     my @args = (
1594         "Tools/Scripts/new-run-webkit-websocketserver",
1595         "--server", "stop",
1596         "--pidfile", "$webSocketServerPidFile"
1597     );
1598     system "/usr/bin/python", @args;
1599     unlink "$webSocketServerPidFile";
1600
1601     # wss is disabled until all platforms support pyOpenSSL.
1602     $isWebSocketServerOpen = 0;
1603 }
1604
1605 sub fileNameWithNumber($$)
1606 {
1607     my ($base, $number) = @_;
1608     return "$base$number" if ($number > 1);
1609     return $base;
1610 }
1611
1612 sub processIgnoreTests($$)
1613 {
1614     my @ignoreList = split(/\s*,\s*/, shift);
1615     my $listName = shift;
1616
1617     my $disabledSuffix = "-disabled";
1618
1619     my $addIgnoredDirectories = sub {
1620         return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
1621         $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)} = 1;
1622         return @_;
1623     };
1624     foreach my $item (@ignoreList) {
1625         my $path = catfile($testDirectory, $item); 
1626         if (-d $path) {
1627             $ignoredDirectories{$item} = 1;
1628             find({ preprocess => $addIgnoredDirectories, wanted => sub {} }, $path);
1629         }
1630         elsif (-f $path) {
1631             $ignoredFiles{$item} = 1;
1632         } elsif (-f $path . $disabledSuffix) {
1633             # The test is disabled, so do nothing.
1634         } else {
1635             print "$listName list contained '$item', but no file of that name could be found\n";
1636         }
1637     }
1638 }
1639
1640 sub stripExtension($)
1641 {
1642     my ($test) = @_;
1643
1644     $test =~ s/\.[a-zA-Z]+$//;
1645     return $test;
1646 }
1647
1648 sub isTextOnlyTest($)
1649 {
1650     my ($actual) = @_;
1651     my $isText;
1652     if ($actual =~ /^layer at/ms) {
1653         $isText = 0;
1654     } else {
1655         $isText = 1;
1656     }
1657     return $isText;
1658 }
1659
1660 sub expectedDirectoryForTest($;$;$)
1661 {
1662     my ($base, $isText, $expectedExtension) = @_;
1663
1664     my @directories = @platformResultHierarchy;
1665     push @directories, map { catdir($platformBaseDirectory, $_) } qw(mac-snowleopard mac) if isAppleWinWebKit();
1666     push @directories, $expectedDirectory;
1667
1668     # If we already have expected results, just return their location.
1669     foreach my $directory (@directories) {
1670         return $directory if -f File::Spec->catfile($directory, "$base-$expectedTag.$expectedExtension");
1671     }
1672
1673     # For cross-platform tests, text-only results should go in the cross-platform directory,
1674     # while render tree dumps should go in the least-specific platform directory.
1675     return $isText ? $expectedDirectory : $platformResultHierarchy[$#platformResultHierarchy];
1676 }
1677
1678 sub countFinishedTest($$$$)
1679 {
1680     my ($test, $base, $result, $isText) = @_;
1681
1682     if (($count + 1) % $testsPerDumpTool == 0 || $count == $#tests) {
1683         if ($shouldCheckLeaks) {
1684             my $fileName;
1685             if ($testsPerDumpTool == 1) {
1686                 $fileName = File::Spec->catfile($testResultsDirectory, "$base-leaks.txt");
1687             } else {
1688                 $fileName = File::Spec->catfile($testResultsDirectory, fileNameWithNumber($dumpToolName, $leaksOutputFileNumber) . "-leaks.txt");
1689             }
1690             my $leakCount = countAndPrintLeaks($dumpToolName, $dumpToolPID, $fileName);
1691             $totalLeaks += $leakCount;
1692             $leaksOutputFileNumber++ if ($leakCount);
1693         }
1694
1695         closeDumpTool();
1696     }
1697     
1698     $count++;
1699     $counts{$result}++;
1700     push @{$tests{$result}}, $test;
1701 }
1702
1703 sub testCrashedOrTimedOut($$$$$)
1704 {
1705     my ($test, $base, $didCrash, $actual, $error) = @_;
1706
1707     printFailureMessageForTest($test, $didCrash ? "crashed" : "timed out");
1708
1709     sampleDumpTool() unless $didCrash;
1710
1711     my $dir = dirname(File::Spec->catdir($testResultsDirectory, $base));
1712     mkpath $dir;
1713
1714     deleteExpectedAndActualResults($base);
1715
1716     if (defined($error) && length($error)) {
1717         writeToFile(File::Spec->catfile($testResultsDirectory, "$base-$errorTag.txt"), $error);
1718     }
1719
1720     recordActualResultsAndDiff($base, $actual);
1721
1722     kill 9, $dumpToolPID unless $didCrash;
1723
1724     closeDumpTool();
1725     
1726     return unless isCygwin() && !$didCrash && $base =~ /^http/;
1727     # On Cygwin, http tests timing out can be a symptom of a non-responsive httpd.
1728     # If we timed out running an http test, try restarting httpd.
1729     $isHttpdOpen = !closeHTTPD();
1730     configureAndOpenHTTPDIfNeeded();
1731 }
1732
1733 sub printFailureMessageForTest($$)
1734 {
1735     my ($test, $description) = @_;
1736
1737     unless ($verbose) {
1738         print "\n" unless $atLineStart;
1739         print "$test -> ";
1740     }
1741     print "$description\n";
1742     $atLineStart = 1;
1743 }
1744
1745 my %cygpaths = ();
1746
1747 sub openCygpathIfNeeded($)
1748 {
1749     my ($options) = @_;
1750
1751     return unless isCygwin();
1752     return $cygpaths{$options} if $cygpaths{$options} && $cygpaths{$options}->{"open"};
1753
1754     local (*CYGPATHIN, *CYGPATHOUT);
1755     my $pid = open2(\*CYGPATHIN, \*CYGPATHOUT, "cygpath -f - $options");
1756     my $cygpath =  {
1757         "pid" => $pid,
1758         "in" => *CYGPATHIN,
1759         "out" => *CYGPATHOUT,
1760         "open" => 1
1761     };
1762
1763     $cygpaths{$options} = $cygpath;
1764
1765     return $cygpath;
1766 }
1767
1768 sub closeCygpaths()
1769 {
1770     return unless isCygwin();
1771
1772     foreach my $cygpath (values(%cygpaths)) {
1773         close $cygpath->{"in"};
1774         close $cygpath->{"out"};
1775         waitpid($cygpath->{"pid"}, 0);
1776         $cygpath->{"open"} = 0;
1777
1778     }
1779 }
1780
1781 sub convertPathUsingCygpath($$)
1782 {
1783     my ($path, $options) = @_;
1784
1785     # cygpath -f (at least in Cygwin 1.7) converts spaces into newlines. We remove spaces here and
1786     # add them back in after conversion to work around this.
1787     my $spaceSubstitute = "__NOTASPACE__";
1788     $path =~ s/ /\Q$spaceSubstitute\E/g;
1789
1790     my $cygpath = openCygpathIfNeeded($options);
1791     local *inFH = $cygpath->{"in"};
1792     local *outFH = $cygpath->{"out"};
1793     print outFH $path . "\n";
1794     my $convertedPath = <inFH>;
1795     chomp($convertedPath) if defined $convertedPath;
1796
1797     $convertedPath =~ s/\Q$spaceSubstitute\E/ /g;
1798     return $convertedPath;
1799 }
1800
1801 sub toCygwinPath($)
1802 {
1803     my ($path) = @_;
1804     return unless isCygwin();
1805
1806     return convertPathUsingCygpath($path, "-u");
1807 }
1808
1809 sub toWindowsPath($)
1810 {
1811     my ($path) = @_;
1812     return unless isCygwin();
1813
1814     return convertPathUsingCygpath($path, "-w");
1815 }
1816
1817 sub toURL($)
1818 {
1819     my ($path) = @_;
1820
1821     if ($useRemoteLinksToTests) {
1822         my $relativePath = File::Spec->abs2rel($path, $testDirectory);
1823
1824         # If the file is below the test directory then convert it into a link to the file in SVN
1825         if ($relativePath !~ /^\.\.\//) {
1826             my $revision = svnRevisionForDirectory($testDirectory);
1827             my $svnPath = pathRelativeToSVNRepositoryRootForPath($path);
1828             return "http://trac.webkit.org/export/$revision/$svnPath";
1829         }
1830     }
1831
1832     return $path unless isCygwin();
1833
1834     return "file:///" . convertPathUsingCygpath($path, "-m");
1835 }
1836
1837 sub validateSkippedArg($$;$)
1838 {
1839     my ($option, $value, $value2) = @_;
1840     my %validSkippedValues = map { $_ => 1 } qw(default ignore only);
1841     $value = lc($value);
1842     die "Invalid argument '" . $value . "' for option $option" unless $validSkippedValues{$value};
1843     $treatSkipped = $value;
1844 }
1845
1846 sub htmlForResultsSection(\@$&)
1847 {
1848     my ($tests, $description, $linkGetter) = @_;
1849
1850     my @html = ();
1851     return join("\n", @html) unless @{$tests};
1852
1853     push @html, "<p>$description:</p>";
1854     push @html, "<table>";
1855     foreach my $test (@{$tests}) {
1856         push @html, "<tr>";
1857         push @html, "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$test</a></td>";
1858         foreach my $link (@{&{$linkGetter}($test)}) {
1859             push @html, "<td><a href=\"$link->{href}\">$link->{text}</a></td>";
1860         }
1861         push @html, "</tr>";
1862     }
1863     push @html, "</table>";
1864
1865     return join("\n", @html);
1866 }
1867
1868 sub linksForExpectedAndActualResults($)
1869 {
1870     my ($base) = @_;
1871
1872     my @links = ();
1873
1874     return \@links unless -s "$testResultsDirectory/$base-$diffsTag.txt";
1875     
1876     my $expectedResultPath = $expectedResultPaths{$base};
1877     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1878
1879     push @links, { href => "$base-$expectedTag$expectedResultExtension", text => "expected" };
1880     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "actual" };
1881     push @links, { href => "$base-$diffsTag.txt", text => "diff" };
1882     push @links, { href => "$base-$prettyDiffTag.html", text => "pretty diff" };
1883
1884     return \@links;
1885 }
1886
1887 sub linksForMismatchTest
1888 {
1889     my ($test) = @_;
1890
1891     my @links = ();
1892
1893     my $base = stripExtension($test);
1894
1895     push @links, @{linksForExpectedAndActualResults($base)};
1896     return \@links unless $pixelTests && $imagesPresent{$base};
1897
1898     push @links, { href => "$base-$expectedTag.png", text => "expected image" };
1899     push @links, { href => "$base-$diffsTag.html", text => "image diffs" };
1900     push @links, { href => "$base-$diffsTag.png", text => "$imageDifferences{$base}%" };
1901
1902     return \@links;
1903 }
1904
1905 sub linksForErrorTest
1906 {
1907     my ($test) = @_;
1908
1909     my @links = ();
1910
1911     my $base = stripExtension($test);
1912
1913     push @links, @{linksForExpectedAndActualResults($base)};
1914     push @links, { href => "$base-$errorTag.txt", text => "stderr" };
1915
1916     return \@links;
1917 }
1918
1919 sub linksForNewTest
1920 {
1921     my ($test) = @_;
1922
1923     my @links = ();
1924
1925     my $base = stripExtension($test);
1926
1927     my $expectedResultPath = $expectedResultPaths{$base};
1928     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1929
1930     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "result" };
1931     if ($pixelTests && $imagesPresent{$base}) {
1932         push @links, { href => "$base-$expectedTag.png", text => "image" };
1933     }
1934
1935     return \@links;
1936 }
1937
1938 sub deleteExpectedAndActualResults($)
1939 {
1940     my ($base) = @_;
1941
1942     unlink "$testResultsDirectory/$base-$actualTag.txt";
1943     unlink "$testResultsDirectory/$base-$diffsTag.txt";
1944     unlink "$testResultsDirectory/$base-$errorTag.txt";
1945 }
1946
1947 sub recordActualResultsAndDiff($$)
1948 {
1949     my ($base, $actualResults) = @_;
1950
1951     return unless defined($actualResults) && length($actualResults);
1952
1953     my $expectedResultPath = $expectedResultPaths{$base};
1954     my ($expectedResultFileNameMinusExtension, $expectedResultDirectoryPath, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1955     my $actualResultsPath = File::Spec->catfile($testResultsDirectory, "$base-$actualTag$expectedResultExtension");
1956     my $copiedExpectedResultsPath = File::Spec->catfile($testResultsDirectory, "$base-$expectedTag$expectedResultExtension");
1957
1958     mkpath(dirname($actualResultsPath));
1959     writeToFile("$actualResultsPath", $actualResults);
1960
1961     if (-f $expectedResultPath) {
1962         copy("$expectedResultPath", "$copiedExpectedResultsPath");
1963     } else {
1964         open EMPTY, ">$copiedExpectedResultsPath";
1965         close EMPTY;
1966     }
1967
1968     my $diffOuputBasePath = File::Spec->catfile($testResultsDirectory, $base);
1969     my $diffOutputPath = "$diffOuputBasePath-$diffsTag.txt";
1970     system "diff -u \"$copiedExpectedResultsPath\" \"$actualResultsPath\" > \"$diffOutputPath\"";
1971
1972     my $prettyDiffOutputPath = "$diffOuputBasePath-$prettyDiffTag.html";
1973     my $prettyPatchPath = "BugsSite/PrettyPatch/";
1974     my $prettifyPath = "$prettyPatchPath/prettify.rb";
1975     system "ruby -I \"$prettyPatchPath\" \"$prettifyPath\" \"$diffOutputPath\" > \"$prettyDiffOutputPath\"";
1976 }
1977
1978 sub buildPlatformResultHierarchy()
1979 {
1980     mkpath($platformTestDirectory) if ($platform eq "undefined" && !-d "$platformTestDirectory");
1981
1982     my @platforms;
1983     
1984     my $isMac = $platform =~ /^mac/;
1985     my $isWin = $platform =~ /^win/;
1986     if ($isMac || $isWin) {
1987         my $effectivePlatform = $platform;
1988         if ($platform eq "mac-wk2" || $platform eq "win-wk2") {
1989             push @platforms, $platform;
1990             $effectivePlatform = $realPlatform;
1991         }
1992
1993         my @platformList = $isMac ? @macPlatforms : @winPlatforms;
1994         my $i;
1995         for ($i = 0; $i < @platformList; $i++) {
1996             last if $platformList[$i] eq $effectivePlatform;
1997         }
1998         for (; $i < @platformList; $i++) {
1999             push @platforms, $platformList[$i];
2000         }
2001     } elsif ($platform =~ /^qt-/) {
2002         push @platforms, $platform;
2003         push @platforms, "qt";
2004     } else {
2005         @platforms = $platform;
2006     }
2007
2008     my @hierarchy;
2009     for (my $i = 0; $i < @platforms; $i++) {
2010         my $scoped = catdir($platformBaseDirectory, $platforms[$i]);
2011         push(@hierarchy, $scoped) if (-d $scoped);
2012     }
2013     
2014     return @hierarchy;
2015 }
2016
2017 sub buildPlatformTestHierarchy(@)
2018 {
2019     my (@platformHierarchy) = @_;
2020     return @platformHierarchy if (@platformHierarchy < 2);
2021     if ($platformHierarchy[0] =~ /mac-wk2/) {
2022         return ($platformHierarchy[0], $platformHierarchy[1], $platformHierarchy[$#platformHierarchy]);
2023     }
2024     return ($platformHierarchy[0], $platformHierarchy[$#platformHierarchy]);
2025 }
2026
2027 sub epiloguesAndPrologues($$)
2028 {
2029     my ($lastDirectory, $directory) = @_;
2030     my @lastComponents = split('/', $lastDirectory);
2031     my @components = split('/', $directory);
2032
2033     while (@lastComponents) {
2034         if (!defined($components[0]) || $lastComponents[0] ne $components[0]) {
2035             last;
2036         }
2037         shift @components;
2038         shift @lastComponents;
2039     }
2040
2041     my @result;
2042     my $leaving = $lastDirectory;
2043     foreach (@lastComponents) {
2044         my $epilogue = $leaving . "/resources/run-webkit-tests-epilogue.html";
2045         foreach (@platformResultHierarchy) {
2046             push @result, catdir($_, $epilogue) if (stat(catdir($_, $epilogue)));
2047         }
2048         push @result, catdir($testDirectory, $epilogue) if (stat(catdir($testDirectory, $epilogue)));
2049         $leaving =~ s|(^\|/)[^/]+$||;
2050     }
2051
2052     my $entering = $leaving;
2053     foreach (@components) {
2054         $entering .= '/' . $_;
2055         my $prologue = $entering . "/resources/run-webkit-tests-prologue.html";
2056         push @result, catdir($testDirectory, $prologue) if (stat(catdir($testDirectory, $prologue)));
2057         foreach (reverse @platformResultHierarchy) {
2058             push @result, catdir($_, $prologue) if (stat(catdir($_, $prologue)));
2059         }
2060     }
2061     return @result;
2062 }
2063     
2064 sub parseLeaksandPrintUniqueLeaks()
2065 {
2066     return unless @leaksFilenames;
2067      
2068     my $mergedFilenames = join " ", @leaksFilenames;
2069     my $parseMallocHistoryTool = sourceDir() . "/Tools/Scripts/parse-malloc-history";
2070     
2071     open MERGED_LEAKS, "cat $mergedFilenames | $parseMallocHistoryTool --merge-depth $mergeDepth  - |" ;
2072     my @leakLines = <MERGED_LEAKS>;
2073     close MERGED_LEAKS;
2074     
2075     my $uniqueLeakCount = 0;
2076     my $totalBytes;
2077     foreach my $line (@leakLines) {
2078         ++$uniqueLeakCount if ($line =~ /^(\d*)\scalls/);
2079         $totalBytes = $1 if $line =~ /^total\:\s(.*)\s\(/;
2080     }
2081     
2082     print "\nWARNING: $totalLeaks total leaks found for a total of $totalBytes!\n";
2083     print "WARNING: $uniqueLeakCount unique leaks found!\n";
2084     print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
2085     
2086 }
2087
2088 sub extensionForMimeType($)
2089 {
2090     my ($mimeType) = @_;
2091
2092     if ($mimeType eq "application/x-webarchive") {
2093         return "webarchive";
2094     } elsif ($mimeType eq "application/pdf") {
2095         return "pdf";
2096     }
2097     return "txt";
2098 }
2099
2100 # Read up to the first #EOF (the content block of the test), or until detecting crashes or timeouts.
2101 sub readFromDumpToolWithTimer(**)
2102 {
2103     my ($fhIn, $fhError) = @_;
2104
2105     setFileHandleNonBlocking($fhIn, 1);
2106     setFileHandleNonBlocking($fhError, 1);
2107
2108     my $maximumSecondsWithoutOutput = $timeoutSeconds;
2109     my $microsecondsToWaitBeforeReadingAgain = 1000;
2110
2111     my $timeOfLastSuccessfulRead = time;
2112
2113     my @output = ();
2114     my @error = ();
2115     my $status = "success";
2116     my $mimeType = "text/plain";
2117     # We don't have a very good way to know when the "headers" stop
2118     # and the content starts, so we use this as a hack:
2119     my $haveSeenContentType = 0;
2120     my $haveSeenEofIn = 0;
2121     my $haveSeenEofError = 0;
2122
2123     while (1) {
2124         if (time - $timeOfLastSuccessfulRead > $maximumSecondsWithoutOutput) {
2125             $status = dumpToolDidCrash() ? "crashed" : "timedOut";
2126             last;
2127         }
2128
2129         # Once we've seen the EOF, we must not read anymore.
2130         my $lineIn = readline($fhIn) unless $haveSeenEofIn;
2131         my $lineError = readline($fhError) unless $haveSeenEofError;
2132         if (!defined($lineIn) && !defined($lineError)) {
2133             last if ($haveSeenEofIn && $haveSeenEofError);
2134
2135             if ($! != EAGAIN) {
2136                 $status = "crashed";
2137                 last;
2138             }
2139
2140             # No data ready
2141             usleep($microsecondsToWaitBeforeReadingAgain);
2142             next;
2143         }
2144
2145         $timeOfLastSuccessfulRead = time;
2146
2147         if (defined($lineIn)) {
2148             if (!$haveSeenContentType && $lineIn =~ /^Content-Type: (\S+)$/) {
2149                 $mimeType = $1;
2150                 $haveSeenContentType = 1;
2151             } elsif ($lineIn =~ /#EOF/) {
2152                 $haveSeenEofIn = 1;
2153             } else {
2154                 push @output, $lineIn;
2155             }
2156         }
2157         if (defined($lineError)) {
2158             if ($lineError =~ /#CRASHED/) {
2159                 $status = "crashed";
2160                 last;
2161             }
2162             if ($lineError =~ /#EOF/) {
2163                 $haveSeenEofError = 1;
2164             } else {
2165                 push @error, $lineError;
2166             }
2167         }
2168     }
2169
2170     setFileHandleNonBlocking($fhIn, 0);
2171     setFileHandleNonBlocking($fhError, 0);
2172     return {
2173         output => join("", @output),
2174         error => join("", @error),
2175         status => $status,
2176         mimeType => $mimeType,
2177         extension => extensionForMimeType($mimeType)
2178     };
2179 }
2180
2181 sub setFileHandleNonBlocking(*$)
2182 {
2183     my ($fh, $nonBlocking) = @_;
2184
2185     my $flags = fcntl($fh, F_GETFL, 0) or die "Couldn't get filehandle flags";
2186
2187     if ($nonBlocking) {
2188         $flags |= O_NONBLOCK;
2189     } else {
2190         $flags &= ~O_NONBLOCK;
2191     }
2192
2193     fcntl($fh, F_SETFL, $flags) or die "Couldn't set filehandle flags";
2194
2195     return 1;
2196 }
2197
2198 sub sampleDumpTool()
2199 {
2200     return unless isAppleMacWebKit();
2201     return unless $runSample;
2202
2203     my $outputDirectory = "$ENV{HOME}/Library/Logs/DumpRenderTree";
2204     -d $outputDirectory or mkdir $outputDirectory;
2205
2206     my $outputFile = "$outputDirectory/HangReport.txt";
2207     system "/usr/bin/sample", $dumpToolPID, qw(10 10 -file), $outputFile;
2208 }
2209
2210 sub stripMetrics($$)
2211 {
2212     my ($actual, $expected) = @_;
2213
2214     foreach my $result ($actual, $expected) {
2215         $result =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
2216         $result =~ s/size -?[0-9]+x-?[0-9]+ *//g;
2217         $result =~ s/text run width -?[0-9]+: //g;
2218         $result =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
2219         $result =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
2220         $result =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
2221         $result =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
2222         $result =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
2223         $result =~ s/\([0-9]+px/px/g;
2224         $result =~ s/ *" *\n +" */ /g;
2225         $result =~ s/" +$/"/g;
2226
2227         $result =~ s/- /-/g;
2228         $result =~ s/\n( *)"\s+/\n$1"/g;
2229         $result =~ s/\s+"\n/"\n/g;
2230         $result =~ s/scrollWidth [0-9]+/scrollWidth/g;
2231         $result =~ s/scrollHeight [0-9]+/scrollHeight/g;
2232     }
2233
2234     return ($actual, $expected);
2235 }
2236
2237 sub fileShouldBeIgnored
2238 {
2239     my ($filePath) = @_;
2240     foreach my $ignoredDir (keys %ignoredDirectories) {
2241         if ($filePath =~ m/^$ignoredDir/) {
2242             return 1;
2243         }
2244     }
2245     return 0;
2246 }
2247
2248 sub readSkippedFiles($)
2249 {
2250     my ($constraintPath) = @_;
2251
2252     my @skippedFileDirectories = @platformTestHierarchy;
2253
2254     # Because nearly all of the skipped tests for WebKit 2 on Mac are due to
2255     # cross-platform issues, Windows will use both the Mac and Windows skipped
2256     # lists to avoid maintaining separate lists.
2257     push(@skippedFileDirectories, catdir($platformBaseDirectory, "mac-wk2")) if $platform eq "win-wk2";
2258
2259     foreach my $level (@skippedFileDirectories) {
2260         if (open SKIPPED, "<", "$level/Skipped") {
2261             if ($verbose) {
2262                 my ($dir, $name) = splitpath($level);
2263                 print "Skipped tests in $name:\n";
2264             }
2265
2266             while (<SKIPPED>) {
2267                 my $skipped = $_;
2268                 chomp $skipped;
2269                 $skipped =~ s/^[ \n\r]+//;
2270                 $skipped =~ s/[ \n\r]+$//;
2271                 if ($skipped && $skipped !~ /^#/) {
2272                     if ($skippedOnly) {
2273                         if (!fileShouldBeIgnored($skipped)) {
2274                             if (!$constraintPath) {
2275                                 # Always add $skipped since no constraint path was specified on the command line.
2276                                 push(@ARGV, $skipped);
2277                             } elsif ($skipped =~ /^($constraintPath)/) {
2278                                 # Add $skipped only if it matches the current path constraint, e.g.,
2279                                 # "--skipped=only dir1" with "dir1/file1.html" on the skipped list.
2280                                 push(@ARGV, $skipped);
2281                             } elsif ($constraintPath =~ /^($skipped)/) {
2282                                 # Add current path constraint if it is more specific than the skip list entry,
2283                                 # e.g., "--skipped=only dir1/dir2/dir3" with "dir1" on the skipped list.
2284                                 push(@ARGV, $constraintPath);
2285                             }
2286                         } elsif ($verbose) {
2287                             print "    $skipped\n";
2288                         }
2289                     } else {
2290                         if ($verbose) {
2291                             print "    $skipped\n";
2292                         }
2293                         processIgnoreTests($skipped, "Skipped");
2294                     }
2295                 }
2296             }
2297             close SKIPPED;
2298         }
2299     }
2300 }
2301
2302 my @testsFound;
2303
2304 sub directoryFilter
2305 {
2306     return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
2307     return () if exists $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)};
2308     return @_;
2309 }
2310
2311 sub fileFilter
2312 {
2313     my $filename = $_;
2314     if ($filename =~ /\.([^.]+)$/) {
2315         if (exists $supportedFileExtensions{$1}) {
2316             my $path = File::Spec->abs2rel(catfile($File::Find::dir, $filename), $testDirectory);
2317             push @testsFound, $path if !exists $ignoredFiles{$path};
2318         }
2319     }
2320 }
2321
2322 sub findTestsToRun
2323 {
2324     my @testsToRun = ();
2325
2326     for my $test (@ARGV) {
2327         $test =~ s/^(\Q$layoutTestsName\E|\Q$testDirectory\E)\///;
2328         my $fullPath = catfile($testDirectory, $test);
2329         if (file_name_is_absolute($test)) {
2330             print "can't run test $test outside $testDirectory\n";
2331         } elsif (-f $fullPath) {
2332             my ($filename, $pathname, $fileExtension) = fileparse($test, qr{\.[^.]+$});
2333             if (!exists $supportedFileExtensions{substr($fileExtension, 1)}) {
2334                 print "test $test does not have a supported extension\n";
2335             } elsif ($testHTTP || $pathname !~ /^http\//) {
2336                 push @testsToRun, $test;
2337             }
2338         } elsif (-d $fullPath) {
2339             @testsFound = ();
2340             find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $fullPath);
2341             for my $level (@platformTestHierarchy) {
2342                 my $platformPath = catfile($level, $test);
2343                 find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $platformPath) if (-d $platformPath);
2344             }
2345             push @testsToRun, sort pathcmp @testsFound;
2346             @testsFound = ();
2347         } else {
2348             print "test $test not found\n";
2349         }
2350     }
2351
2352     if (!scalar @ARGV) {
2353         @testsFound = ();
2354         find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $testDirectory);
2355         for my $level (@platformTestHierarchy) {
2356             find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $level);
2357         }
2358         push @testsToRun, sort pathcmp @testsFound;
2359         @testsFound = ();
2360
2361         # We need to minimize the time when Apache and WebSocketServer is locked by tests
2362         # so run them last if no explicit order was specified in the argument list.
2363         my @httpTests;
2364         my @websocketTests;
2365         my @otherTests;
2366         foreach my $test (@testsToRun) {
2367             if ($test =~ /^http\//) {
2368                 push(@httpTests, $test);
2369             } elsif ($test =~ /^websocket\//) {
2370                 push(@websocketTests, $test);
2371             } else {
2372                 push(@otherTests, $test);
2373             }
2374         }
2375         @testsToRun = (@otherTests, @httpTests, @websocketTests);
2376     }
2377
2378     # Reverse the tests
2379     @testsToRun = reverse @testsToRun if $reverseTests;
2380
2381     # Shuffle the array
2382     @testsToRun = shuffle(@testsToRun) if $randomizeTests;
2383
2384     return @testsToRun;
2385 }
2386
2387 sub printResults
2388 {
2389     my %text = (
2390         match => "succeeded",
2391         mismatch => "had incorrect layout",
2392         new => "were new",
2393         timedout => "timed out",
2394         crash => "crashed",
2395         error => "had stderr output"
2396     );
2397
2398     for my $type ("match", "mismatch", "new", "timedout", "crash", "error") {
2399         my $typeCount = $counts{$type};
2400         next unless $typeCount;
2401         my $typeText = $text{$type};
2402         my $message;
2403         if ($typeCount == 1) {
2404             $typeText =~ s/were/was/;
2405             $message = sprintf "1 test case (%d%%) %s\n", 1 * 100 / $count, $typeText;
2406         } else {
2407             $message = sprintf "%d test cases (%d%%) %s\n", $typeCount, $typeCount * 100 / $count, $typeText;
2408         }
2409         $message =~ s-\(0%\)-(<1%)-;
2410         print $message;
2411     }
2412 }
2413
2414 sub stopRunningTestsEarlyIfNeeded()
2415 {
2416     # --reset-results does not check pass vs. fail, so exitAfterNFailures makes no sense with --reset-results.
2417     return 0 if $resetResults;
2418
2419     my $passCount = $counts{match} || 0; # $counts{match} will be undefined if we've not yet passed a test (e.g. the first test fails).
2420     my $newCount = $counts{new} || 0;
2421     my $failureCount = $count - $passCount - $newCount; # "Failure" here includes timeouts, crashes, etc.
2422     if ($exitAfterNFailures && $failureCount >= $exitAfterNFailures) {
2423         print "\nExiting early after $failureCount failures. $count tests run.";
2424         closeDumpTool();
2425         return 1;
2426     }
2427
2428     my $crashCount = $counts{crash} || 0;
2429     my $timeoutCount = $counts{timedout} || 0;
2430     if ($exitAfterNCrashesOrTimeouts && $crashCount + $timeoutCount >= $exitAfterNCrashesOrTimeouts) {
2431         print "\nExiting early after $crashCount crashes and $timeoutCount timeouts. $count tests run.";
2432         closeDumpTool();
2433         return 1;
2434     }
2435
2436     return 0;
2437 }
2438
2439 sub setUpWindowsCrashLogSaving()
2440 {
2441     return unless isCygwin();
2442
2443     unless (defined $ENV{_NT_SYMBOL_PATH}) {
2444         print "The _NT_SYMBOL_PATH environment variable is not set. Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2445         return;
2446     }
2447
2448     my $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{PROGRAMFILES}), "Debugging Tools for Windows (x86)", "ntsd.exe");
2449     unless (-f $ntsdPath) {
2450         $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{SYSTEMROOT}), "system32", "ntsd.exe");
2451         unless (-f $ntsdPath) {
2452             print STDERR "Can't find ntsd.exe. Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2453             return;
2454         }
2455     }
2456
2457     my %values = (
2458         Debugger => '"' . toWindowsPath($ntsdPath) . '" -p %ld -e %ld -g -lines -c ".logopen /t \"' . toWindowsPath($testResultsDirectory) . '\CrashLog.txt\";!analyze -vv;~*kpn;q"',
2459         Auto => 1
2460     );
2461
2462     foreach my $value (keys %values) {
2463         chomp($previousWindowsPostMortemDebuggerValues{$value} = `regtool get "$windowsPostMortemDebuggerKey/$value"`);
2464         my $result = system "regtool", "set", "-s", "$windowsPostMortemDebuggerKey/$value", $values{$value};
2465         next unless $result;
2466
2467         print "Failed to set \"$windowsPostMortemDebuggerKey/$value\". Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2468         return;
2469     }
2470
2471     print "Crash logs will be saved to $testResultsDirectory.\n";
2472 }
2473
2474 END {
2475     return unless isCygwin();
2476
2477     foreach my $value (keys %previousWindowsPostMortemDebuggerValues) {
2478         my $result = system "regtool", "set", "-s", "$windowsPostMortemDebuggerKey/$value", $previousWindowsPostMortemDebuggerValues{$value};
2479         !$result or print "Failed to restore \"$windowsPostMortemDebuggerKey/$value\" to its previous value \"$previousWindowsPostMortemDebuggerValues{$value}\"\n.";
2480     }
2481 }