cfe6d6111d3a7974df63c19a456f20ae6d7f1e7e
[WebKit-https.git] / Tools / Scripts / old-run-webkit-tests
1 #!/usr/bin/perl
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009, 2010 Apple Inc. All rights reserved.
4 # Copyright (C) 2006 Alexey Proskuryakov (ap@nypop.com)
5 # Copyright (C) 2007 Matt Lilek (pewtermoose@gmail.com)
6 # Copyright (C) 2007 Eric Seidel <eric@webkit.org>
7 # Copyright (C) 2009 Google Inc. All rights reserved.
8 # Copyright (C) 2009 Andras Becsi (becsi.andras@stud.u-szeged.hu), University of Szeged
9 #
10 # Redistribution and use in source and binary forms, with or without
11 # modification, are permitted provided that the following conditions
12 # are met:
13 #
14 # 1.  Redistributions of source code must retain the above copyright
15 #     notice, this list of conditions and the following disclaimer. 
16 # 2.  Redistributions in binary form must reproduce the above copyright
17 #     notice, this list of conditions and the following disclaimer in the
18 #     documentation and/or other materials provided with the distribution. 
19 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
20 #     its contributors may be used to endorse or promote products derived
21 #     from this software without specific prior written permission. 
22 #
23 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
24 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
25 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
26 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
27 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
28 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
29 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
30 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
31 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
32 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
33
34 # Script to run the WebKit Open Source Project layout tests.
35
36 # Run all the tests passed in on the command line.
37 # If no tests are passed, find all the .html, .shtml, .xml, .xhtml, .xhtmlmp, .pl, .php (and svg) files in the test directory.
38
39 # Run each text.
40 # Compare against the existing file xxx-expected.txt.
41 # If there is a mismatch, generate xxx-actual.txt and xxx-diffs.txt.
42
43 # At the end, report:
44 #   the number of tests that got the expected results
45 #   the number of tests that ran, but did not get the expected results
46 #   the number of tests that failed to run
47 #   the number of tests that were run but had no expected results to compare against
48
49 use strict;
50 use warnings;
51
52 use CGI;
53 use Config;
54 use Cwd;
55 use Data::Dumper;
56 use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
57 use File::Basename;
58 use File::Copy;
59 use File::Find;
60 use File::Path;
61 use File::Spec;
62 use File::Spec::Functions;
63 use File::Temp;
64 use FindBin;
65 use Getopt::Long;
66 use IPC::Open2;
67 use IPC::Open3;
68 use Time::HiRes qw(time usleep);
69
70 use List::Util 'shuffle';
71
72 use lib $FindBin::Bin;
73 use webkitperl::features;
74 use webkitperl::httpd;
75 use webkitdirs;
76 use VCSUtils;
77 use POSIX;
78
79 sub buildPlatformResultHierarchy();
80 sub buildPlatformTestHierarchy(@);
81 sub captureSavedCrashLog($$);
82 sub checkPythonVersion();
83 sub closeCygpaths();
84 sub closeDumpTool();
85 sub closeWebSocketServer();
86 sub configureAndOpenHTTPDIfNeeded();
87 sub countAndPrintLeaks($$$);
88 sub countFinishedTest($$$$);
89 sub deleteExpectedAndActualResults($);
90 sub dumpToolDidCrash();
91 sub epiloguesAndPrologues($$);
92 sub expectedDirectoryForTest($;$;$);
93 sub fileNameWithNumber($$);
94 sub findNewestFileMatchingGlob($);
95 sub htmlForResultsSection(\@$&);
96 sub isTextOnlyTest($);
97 sub launchWithEnv(\@\%);
98 sub resolveAndMakeTestResultsDirectory();
99 sub numericcmp($$);
100 sub openDiffTool();
101 sub buildDumpTool($);
102 sub openDumpTool();
103 sub parseLeaksandPrintUniqueLeaks();
104 sub openWebSocketServerIfNeeded();
105 sub pathcmp($$);
106 sub printFailureMessageForTest($$);
107 sub processIgnoreTests($$);
108 sub readChecksumFromPng($);
109 sub readFromDumpToolWithTimer(**);
110 sub readSkippedFiles($);
111 sub recordActualResultsAndDiff($$);
112 sub sampleDumpTool();
113 sub setFileHandleNonBlocking(*$);
114 sub setUpWindowsCrashLogSaving();
115 sub slowestcmp($$);
116 sub splitpath($);
117 sub stopRunningTestsEarlyIfNeeded();
118 sub stripExtension($);
119 sub stripMetrics($$);
120 sub testCrashedOrTimedOut($$$$$$);
121 sub toCygwinPath($);
122 sub toURL($);
123 sub toWindowsPath($);
124 sub validateSkippedArg($$;$);
125 sub writeToFile($$);
126
127 # Argument handling
128 my $addPlatformExceptions = 0;
129 my @additionalPlatformDirectories = ();
130 my $complexText = 0;
131 my $exitAfterNFailures = 0;
132 my $exitAfterNCrashesOrTimeouts = 0;
133 my $generateNewResults = isAppleMacWebKit() ? 1 : 0;
134 my $guardMalloc = '';
135 # FIXME: Dynamic HTTP-port configuration in this file is wrong.  The various
136 # apache config files in LayoutTests/http/config govern the port numbers.
137 # Dynamic configuration as-written will also cause random failures in
138 # an IPv6 environment.  See https://bugs.webkit.org/show_bug.cgi?id=37104.
139 my $httpdPort = 8000;
140 my $httpdSSLPort = 8443;
141 my $ignoreMetrics = 0;
142 my $webSocketPort = 8880;
143 # wss is disabled until all platforms support pyOpenSSL.
144 # my $webSocketSecurePort = 9323;
145 my @ignoreTests;
146 my $iterations = 1;
147 my $launchSafari = 1;
148 my $mergeDepth;
149 my $pixelTests = '';
150 my $platform;
151 my $quiet = '';
152 my $randomizeTests = 0;
153 my $repeatEach = 1;
154 my $report10Slowest = 0;
155 my $resetResults = 0;
156 my $reverseTests = 0;
157 my $root;
158 my $runSample = 1;
159 my $shouldCheckLeaks = 0;
160 my $showHelp = 0;
161 my $stripEditingCallbacks;
162 my $testHTTP = 1;
163 my $testWebSocket = 1;
164 my $testMedia = 1;
165 my $tmpDir = "/tmp";
166 my $testResultsDirectory = File::Spec->catdir($tmpDir, "layout-test-results");
167 my $testsPerDumpTool = 1000;
168 my $threaded = 0;
169 my $gcBetweenTests = 0;
170 # DumpRenderTree has an internal timeout of 30 seconds, so this must be > 30.
171 my $timeoutSeconds = 35;
172 my $tolerance = 0;
173 my $treatSkipped = "default";
174 my $useRemoteLinksToTests = 0;
175 my $useValgrind = 0;
176 my $verbose = 0;
177 my $shouldWaitForHTTPD = 0;
178 my $useWebKitTestRunner = 0;
179 my $noBuildDumpTool = 0;
180
181 my @leaksFilenames;
182
183 if (isWindows() || isMsys()) {
184     print "This script has to be run under Cygwin to function correctly.\n";
185     exit 1;
186 }
187
188 # Default to --no-http for wx for now.
189 $testHTTP = 0 if (isWx());
190
191 my $perlInterpreter = "perl";
192
193 my $expectedTag = "expected";
194 my $mismatchTag = "mismatch";
195 my $actualTag = "actual";
196 my $prettyDiffTag = "pretty-diff";
197 my $diffsTag = "diffs";
198 my $errorTag = "stderr";
199 my $crashLogTag = "crash-log";
200
201 my $windowsCrashLogFilePrefix = "CrashLog";
202
203 # These are defined here instead of closer to where they are used so that they
204 # will always be accessible from the END block that uses them, even if the user
205 # presses Ctrl-C before Perl has finished evaluating this whole file.
206 my $windowsPostMortemDebuggerKey = "/HKLM/SOFTWARE/Microsoft/Windows NT/CurrentVersion/AeDebug";
207 my %previousWindowsPostMortemDebuggerValues;
208
209 my $realPlatform;
210
211 my @macPlatforms = ("mac-leopard", "mac-snowleopard", "mac");
212 my @winPlatforms = ("win-xp", "win-vista", "win-7sp0", "win");
213
214 if (isAppleMacWebKit()) {
215     if (isLeopard()) {
216         $platform = "mac-leopard";
217         $tolerance = 0.1;
218     } elsif (isSnowLeopard()) {
219         $platform = "mac-snowleopard";
220         $tolerance = 0.1;
221     } else {
222         $platform = "mac";
223     }
224 } elsif (isQt()) {
225     if (isDarwin()) {
226         $platform = "qt-mac";
227     } elsif (isARM()) {
228         $platform = "qt-arm";
229     } elsif (getQtVersion() eq "4.8") {
230         $platform = "qt-4.8";
231     } elsif (isLinux()) {
232         $platform = "qt-linux";
233     } elsif (isWindows() || isCygwin()) {
234         $platform = "qt-win";
235     } else {
236         $platform = "qt";
237     }
238 } elsif (isGtk()) {
239     $platform = "gtk";
240 } elsif (isWx()) {
241     $platform = "wx";
242 } elsif (isCygwin() || isWindows()) {
243     if (isWindowsXP()) {
244         $platform = "win-xp";
245     } elsif (isWindowsVista()) {
246         $platform = "win-vista";
247     } elsif (isWindows7SP0()) {
248         $platform = "win-7sp0";
249     } else {
250         $platform = "win";
251     }
252 }
253
254 if (isQt() || isAppleWinWebKit()) {
255     my $testfontPath = $ENV{"WEBKIT_TESTFONTS"};
256     if (!$testfontPath || !-d "$testfontPath") {
257         print "The WEBKIT_TESTFONTS environment variable is not defined or not set properly\n";
258         print "You must set it before running the tests.\n";
259         print "Use git to grab the actual fonts from http://gitorious.org/qtwebkit/testfonts\n";
260         exit 1;
261     }
262 }
263
264 if (!defined($platform)) {
265     print "WARNING: Your platform is not recognized. Any platform-specific results will be generated in platform/undefined.\n";
266     $platform = "undefined";
267 }
268
269 if (!checkPythonVersion()) {
270     print "WARNING: Your platform does not have Python 2.5+, which is required to run websocket server, so disabling websocket/tests.\n";
271     $testWebSocket = 0;
272 }
273
274 my $programName = basename($0);
275 my $launchSafariDefault = $launchSafari ? "launch" : "do not launch";
276 my $httpDefault = $testHTTP ? "run" : "do not run";
277 my $sampleDefault = $runSample ? "run" : "do not run";
278
279 my $usage = <<EOF;
280 Usage: $programName [options] [testdir|testpath ...]
281   --add-platform-exceptions       Put new results for non-platform-specific failing tests into the platform-specific results directory
282   --additional-platform-directory path/to/directory
283                                   Look in the specified directory before looking in any of the default platform-specific directories
284   --complex-text                  Use the complex text code path for all text (Mac OS X and Windows only)
285   -c|--configuration config       Set DumpRenderTree build configuration
286   --gc-between-tests              Force garbage collection between each test
287   -g|--guard-malloc               Enable malloc guard
288   --exit-after-n-failures N       Exit after the first N failures (includes crashes) instead of running all tests
289   --exit-after-n-crashes-or-timeouts N
290                                   Exit after the first N crashes instead of running all tests
291   -h|--help                       Show this help message
292   --[no-]http                     Run (or do not run) http tests (default: $httpDefault)
293   --[no-]wait-for-httpd           Wait for httpd if some other test session is using it already (same as WEBKIT_WAIT_FOR_HTTPD=1). (default: $shouldWaitForHTTPD) 
294   -i|--ignore-tests               Comma-separated list of directories or tests to ignore
295   --iterations n                  Number of times to run the set of tests (e.g. ABCABCABC)
296   --[no-]launch-safari            Launch (or do not launch) Safari to display test results (default: $launchSafariDefault)
297   -l|--leaks                      Enable leaks checking
298   --[no-]new-test-results         Generate results for new tests
299   --nthly n                       Restart DumpRenderTree every n tests (default: $testsPerDumpTool)
300   -p|--pixel-tests                Enable pixel tests
301   --tolerance t                   Ignore image differences less than this percentage (default: $tolerance)
302   --platform                      Override the detected platform to use for tests and results (default: $platform)
303   --port                          Web server port to use with http tests
304   -q|--quiet                      Less verbose output
305   --reset-results                 Reset ALL results (including pixel tests if --pixel-tests is set)
306   -o|--results-directory          Output results directory (default: $testResultsDirectory)
307   --random                        Run the tests in a random order
308   --repeat-each n                 Number of times to run each test (e.g. AAABBBCCC)
309   --reverse                       Run the tests in reverse alphabetical order
310   --root                          Path to root tools build
311   --[no-]sample-on-timeout        Run sample on timeout (default: $sampleDefault) (Mac OS X only)
312   -1|--singly                     Isolate each test case run (implies --nthly 1 --verbose)
313   --skipped=[default|ignore|only] Specifies how to treat the Skipped file
314                                      default: Tests/directories listed in the Skipped file are not tested
315                                      ignore:  The Skipped file is ignored
316                                      only:    Only those tests/directories listed in the Skipped file will be run
317   --slowest                       Report the 10 slowest tests
318   --ignore-metrics                Ignore metrics in tests
319   --[no-]strip-editing-callbacks  Remove editing callbacks from expected results
320   -t|--threaded                   Run a concurrent JavaScript thead with each test
321   --timeout t                     Sets the number of seconds before a test times out (default: $timeoutSeconds)
322   --valgrind                      Run DumpRenderTree inside valgrind (Qt/Linux only)
323   -v|--verbose                    More verbose output (overrides --quiet)
324   -m|--merge-leak-depth arg       Merges leak callStacks and prints the number of unique leaks beneath a callstack depth of arg.  Defaults to 5.
325   --use-remote-links-to-tests     Link to test files within the SVN repository in the results.
326   -2|--webkit-test-runner         Use WebKitTestRunner rather than DumpRenderTree.
327 EOF
328
329 setConfiguration();
330
331 my $getOptionsResult = GetOptions(
332     'add-platform-exceptions' => \$addPlatformExceptions,
333     'additional-platform-directory=s' => \@additionalPlatformDirectories,
334     'complex-text' => \$complexText,
335     'exit-after-n-failures=i' => \$exitAfterNFailures,
336     'exit-after-n-crashes-or-timeouts=i' => \$exitAfterNCrashesOrTimeouts,
337     'gc-between-tests' => \$gcBetweenTests,
338     'guard-malloc|g' => \$guardMalloc,
339     'help|h' => \$showHelp,
340     'http!' => \$testHTTP,
341     'wait-for-httpd!' => \$shouldWaitForHTTPD,
342     'ignore-metrics!' => \$ignoreMetrics,
343     'ignore-tests|i=s' => \@ignoreTests,
344     'iterations=i' => \$iterations,
345     'launch-safari!' => \$launchSafari,
346     'leaks|l' => \$shouldCheckLeaks,
347     'merge-leak-depth|m:5' => \$mergeDepth,
348     'new-test-results!' => \$generateNewResults,
349     'no-build' => \$noBuildDumpTool,
350     'nthly=i' => \$testsPerDumpTool,
351     'pixel-tests|p' => \$pixelTests,
352     'platform=s' => \$platform,
353     'port=i' => \$httpdPort,
354     'quiet|q' => \$quiet,
355     'random' => \$randomizeTests,
356     'repeat-each=i' => \$repeatEach,
357     'reset-results' => \$resetResults,
358     'results-directory|o=s' => \$testResultsDirectory,
359     'reverse' => \$reverseTests,
360     'root=s' => \$root,
361     'sample-on-timeout!' => \$runSample,
362     'singly|1' => sub { $testsPerDumpTool = 1; },
363     'skipped=s' => \&validateSkippedArg,
364     'slowest' => \$report10Slowest,
365     'strip-editing-callbacks!' => \$stripEditingCallbacks,
366     'threaded|t' => \$threaded,
367     'timeout=i' => \$timeoutSeconds,
368     'tolerance=f' => \$tolerance,
369     'use-remote-links-to-tests' => \$useRemoteLinksToTests,
370     'valgrind' => \$useValgrind,
371     'verbose|v' => \$verbose,
372     'webkit-test-runner|2' => \$useWebKitTestRunner,
373 );
374
375 if (!$getOptionsResult || $showHelp) {
376     print STDERR $usage;
377     exit 1;
378 }
379
380 if ($useWebKitTestRunner) {
381     if (isAppleMacWebKit()) {
382         $realPlatform = $platform;
383         $platform = "mac-wk2";
384     } elsif (isAppleWinWebKit()) {
385         $stripEditingCallbacks = 0 unless defined $stripEditingCallbacks;
386         $realPlatform = $platform;
387         $platform = "win-wk2";
388     } elsif (isQt()) {
389         $realPlatform = $platform;
390         $platform = "qt-wk2";
391     }
392 }
393
394 $timeoutSeconds *= 10 if $guardMalloc;
395
396 $stripEditingCallbacks = isCygwin() unless defined $stripEditingCallbacks;
397
398 my $ignoreSkipped = $treatSkipped eq "ignore";
399 my $skippedOnly = $treatSkipped eq "only";
400
401 my $configuration = configuration();
402
403 # We need an environment variable to be able to enable the feature per-slave
404 $shouldWaitForHTTPD = $ENV{"WEBKIT_WAIT_FOR_HTTPD"} unless ($shouldWaitForHTTPD);
405 $verbose = 1 if $testsPerDumpTool == 1;
406
407 if ($shouldCheckLeaks && $testsPerDumpTool > 1000) {
408     print STDERR "\nWARNING: Running more than 1000 tests at a time with MallocStackLogging enabled may cause a crash.\n\n";
409 }
410
411 # Generating remote links causes a lot of unnecessary spew on GTK build bot
412 $useRemoteLinksToTests = 0 if isGtk();
413
414 setConfigurationProductDir(Cwd::abs_path($root)) if (defined($root));
415 my $productDir = productDir();
416 $productDir .= "/bin" if isQt();
417 $productDir .= "/Programs" if isGtk();
418
419 chdirWebKit();
420
421 if (!defined($root) && !$noBuildDumpTool) {
422     # FIXME: We build both DumpRenderTree and WebKitTestRunner for
423     # WebKitTestRunner runs becuase DumpRenderTree still includes
424     # the DumpRenderTreeSupport module and the TestNetscapePlugin.
425     # These two projects should be factored out into their own
426     # projects.
427     buildDumpTool("DumpRenderTree");
428     buildDumpTool("WebKitTestRunner") if $useWebKitTestRunner;
429 }
430
431 my $dumpToolName = $useWebKitTestRunner ? "WebKitTestRunner" : "DumpRenderTree";
432
433 if (isAppleWinWebKit()) {
434     $dumpToolName .= "_debug" if configurationForVisualStudio() eq "Debug_All";
435     $dumpToolName .= "_debug" if configurationForVisualStudio() eq "Debug_Cairo_CFLite";
436     $dumpToolName .= $Config{_exe};
437 }
438 my $dumpTool = File::Spec->catfile($productDir, $dumpToolName);
439 die "can't find executable $dumpToolName (looked in $productDir)\n" unless -x $dumpTool;
440
441 my $imageDiffTool = "$productDir/ImageDiff";
442 $imageDiffTool .= "_debug" if isCygwin() && configurationForVisualStudio() eq "Debug_All";
443 $imageDiffTool .= "_debug" if isCygwin() && configurationForVisualStudio() eq "Debug_Cairo_CFLite";
444 die "can't find executable $imageDiffTool (looked in $productDir)\n" if $pixelTests && !-x $imageDiffTool;
445
446 checkFrameworks() unless isCygwin();
447
448 if (isAppleMacWebKit()) {
449     push @INC, $productDir;
450     require DumpRenderTreeSupport;
451 }
452
453 my $layoutTestsName = "LayoutTests";
454 my $testDirectory = File::Spec->rel2abs($layoutTestsName);
455 my $expectedDirectory = $testDirectory;
456 my $platformBaseDirectory = catdir($testDirectory, "platform");
457 my $platformTestDirectory = catdir($platformBaseDirectory, $platform);
458 my @platformResultHierarchy = buildPlatformResultHierarchy();
459 my @platformTestHierarchy = buildPlatformTestHierarchy(@platformResultHierarchy);
460
461 $expectedDirectory = $ENV{"WebKitExpectedTestResultsDirectory"} if $ENV{"WebKitExpectedTestResultsDirectory"};
462
463 $testResultsDirectory = File::Spec->rel2abs($testResultsDirectory);
464 # $testResultsDirectory must be empty before testing.
465 rmtree $testResultsDirectory;
466 my $testResults = File::Spec->catfile($testResultsDirectory, "results.html");
467
468 if (isAppleMacWebKit()) {
469     print STDERR "Compiling Java tests\n";
470     my $javaTestsDirectory = catdir($testDirectory, "java");
471
472     if (system("/usr/bin/make", "-C", "$javaTestsDirectory")) {
473         exit 1;
474     }
475 } elsif (isCygwin()) {
476     setUpWindowsCrashLogSaving();
477 }
478
479 print "Running tests from $testDirectory\n";
480 if ($pixelTests) {
481     print "Enabling pixel tests with a tolerance of $tolerance%\n";
482     if (isDarwin()) {
483         if (!$useWebKitTestRunner) {
484             print "WARNING: Temporarily changing the main display color profile:\n";
485             print "\tThe colors on your screen will change for the duration of the testing.\n";
486             print "\tThis allows the pixel tests to have consistent color values across all machines.\n";
487         }
488
489         if (isPerianInstalled()) {
490             print "WARNING: Perian's QuickTime component is installed and this may affect pixel test results!\n";
491             print "\tYou should avoid generating new pixel results in this environment.\n";
492             print "\tSee https://bugs.webkit.org/show_bug.cgi?id=22615 for details.\n";
493         }
494     }
495 }
496
497 system "ln", "-s", $testDirectory, "/tmp/LayoutTests" unless -x "/tmp/LayoutTests";
498
499 my %ignoredFiles = ( "results.html" => 1 );
500 my %ignoredDirectories = map { $_ => 1 } qw(platform);
501 my %ignoredLocalDirectories = map { $_ => 1 } qw(.svn _svn resources script-tests);
502 my %supportedFileExtensions = map { $_ => 1 } qw(html shtml xml xhtml xhtmlmp pl php);
503
504 if (!checkWebCoreFeatureSupport("MathML", 0)) {
505     $ignoredDirectories{'mathml'} = 1;
506 }
507
508 # FIXME: We should fix webkitperl/features.pm:hasFeature() to do the correct feature detection for Cygwin.
509 if (checkWebCoreFeatureSupport("SVG", 0)) {
510     $supportedFileExtensions{'svg'} = 1;
511 } elsif (isCygwin()) {
512     $supportedFileExtensions{'svg'} = 1;
513 } else {
514     $ignoredLocalDirectories{'svg'} = 1;
515 }
516
517 if (!$testHTTP) {
518     $ignoredDirectories{'http'} = 1;
519     $ignoredDirectories{'websocket'} = 1;
520 }
521 if (!$testWebSocket) {
522     $ignoredDirectories{'websocket'} = 1;
523 }
524
525 if (!$testMedia) {
526     $ignoredDirectories{'media'} = 1;
527     $ignoredDirectories{'http/tests/media'} = 1;
528 }
529
530 my $supportedFeaturesResult = "";
531
532 if (isCygwin()) {
533     # Collect supported features list
534     setPathForRunningWebKitApp(\%ENV);
535     my $supportedFeaturesCommand = "\"$dumpTool\" --print-supported-features 2>&1";
536     $supportedFeaturesResult = `$supportedFeaturesCommand 2>&1`;
537 }
538
539 my $hasAcceleratedCompositing = 0;
540 my $has3DRendering = 0;
541
542 if (isCygwin()) {
543     $hasAcceleratedCompositing = $supportedFeaturesResult =~ /AcceleratedCompositing/;
544     $has3DRendering = $supportedFeaturesResult =~ /3DRendering/;
545 } else {
546     $hasAcceleratedCompositing = checkWebCoreFeatureSupport("Accelerated Compositing", 0);
547     $has3DRendering = checkWebCoreFeatureSupport("3D Rendering", 0);
548 }
549
550 if (!$hasAcceleratedCompositing) {
551     $ignoredDirectories{'compositing'} = 1;
552
553     # This test has slightly different floating-point rounding when accelerated
554     # compositing is enabled.
555     $ignoredFiles{'svg/custom/use-on-symbol-inside-pattern.svg'} = 1;
556
557     # This test has an iframe that is put in a layer only in compositing mode.
558     $ignoredFiles{'media/media-document-audio-repaint.html'} = 1;
559
560     if (isAppleWebKit()) {
561         # In Apple's ports, the default controls for <video> contain a "full
562         # screen" button only if accelerated compositing is enabled.
563         $ignoredFiles{'media/controls-after-reload.html'} = 1;
564         $ignoredFiles{'media/controls-drag-timebar.html'} = 1;
565         $ignoredFiles{'media/controls-strict.html'} = 1;
566         $ignoredFiles{'media/controls-styling.html'} = 1;
567         $ignoredFiles{'media/controls-without-preload.html'} = 1;
568         $ignoredFiles{'media/video-controls-rendering.html'} = 1;
569         $ignoredFiles{'media/video-display-toggle.html'} = 1;
570         $ignoredFiles{'media/video-no-audio.html'} = 1;
571     }
572
573     # Here we're using !$hasAcceleratedCompositing as a proxy for "is a headless XP machine" (like
574     # our test slaves). Headless XP machines can neither support accelerated compositing nor pass
575     # this test, so skipping the test here is expedient, if a little sloppy. See
576     # <http://webkit.org/b/48333>.
577     $ignoredFiles{'platform/win/plugins/npn-invalidate-rect-invalidates-window.html'} = 1 if isAppleWinWebKit();
578 }
579
580 if (!$has3DRendering) {
581     $ignoredDirectories{'animations/3d'} = 1;
582     $ignoredDirectories{'transforms/3d'} = 1;
583
584     # These tests use the -webkit-transform-3d media query.
585     $ignoredFiles{'fast/media/mq-transform-02.html'} = 1;
586     $ignoredFiles{'fast/media/mq-transform-03.html'} = 1;
587 }
588
589 if (!checkWebCoreFeatureSupport("3D Canvas", 0)) {
590     $ignoredDirectories{'fast/canvas/webgl'} = 1;
591     $ignoredDirectories{'compositing/webgl'} = 1;
592     $ignoredDirectories{'http/tests/canvas/webgl'} = 1;
593 }
594
595 if (!checkWebCoreFeatureSupport("WCSS", 0)) {
596     $ignoredDirectories{'fast/wcss'} = 1;
597 }
598
599 if (!checkWebCoreFeatureSupport("XHTMLMP", 0)) {
600     $ignoredDirectories{'fast/xhtmlmp'} = 1;
601 }
602
603 if (isAppleMacWebKit() && $platform ne "mac-wk2" && osXVersion()->{minor} >= 6 && architecture() =~ /x86_64/) {
604     # This test relies on executing JavaScript during NPP_Destroy, which isn't supported with
605     # out-of-process plugins in WebKit1. See <http://webkit.org/b/58077>.
606     $ignoredFiles{'plugins/npp-set-window-called-during-destruction.html'} = 1;
607 }
608
609 processIgnoreTests(join(',', @ignoreTests), "ignore-tests") if @ignoreTests;
610 if (!$ignoreSkipped) {
611     if (!$skippedOnly || @ARGV == 0) {
612         readSkippedFiles("");
613     } else {
614         # Since readSkippedFiles() appends to @ARGV, we must use a foreach
615         # loop so that we only iterate over the original argument list.
616         foreach my $argnum (0 .. $#ARGV) {
617             readSkippedFiles(shift @ARGV);
618         }
619     }
620 }
621
622 my @tests = findTestsToRun();
623
624 die "no tests to run\n" if !@tests;
625
626 my %counts;
627 my %tests;
628 my %imagesPresent;
629 my %imageDifferences;
630 my %durations;
631 my $count = 0;
632 my $leaksOutputFileNumber = 1;
633 my $totalLeaks = 0;
634
635 my @toolArgs = ();
636 push @toolArgs, "--pixel-tests" if $pixelTests;
637 push @toolArgs, "--threaded" if $threaded;
638 push @toolArgs, "--complex-text" if $complexText;
639 push @toolArgs, "--gc-between-tests" if $gcBetweenTests;
640 push @toolArgs, "-";
641
642 my @diffToolArgs = ();
643 push @diffToolArgs, "--tolerance", $tolerance;
644
645 $| = 1;
646
647 my $dumpToolPID;
648 my $isDumpToolOpen = 0;
649 my $dumpToolCrashed = 0;
650 my $imageDiffToolPID;
651 my $isDiffToolOpen = 0;
652
653 my $atLineStart = 1;
654 my $lastDirectory = "";
655
656 my $isHttpdOpen = 0;
657 my $isWebSocketServerOpen = 0;
658 my $webSocketServerPidFile = 0;
659 my $failedToStartWebSocketServer = 0;
660 # wss is disabled until all platforms support pyOpenSSL.
661 # my $webSocketSecureServerPID = 0;
662
663 sub catch_pipe { $dumpToolCrashed = 1; }
664 $SIG{"PIPE"} = "catch_pipe";
665
666 print "Testing ", scalar @tests, " test cases";
667 print " $iterations times" if ($iterations > 1);
668 print ", repeating each test $repeatEach times" if ($repeatEach > 1);
669 print ".\n";
670
671 my $overallStartTime = time;
672
673 my %expectedResultPaths;
674
675 my @originalTests = @tests;
676 # Add individual test repetitions
677 if ($repeatEach > 1) {
678     @tests = ();
679     foreach my $test (@originalTests) {
680         for (my $i = 0; $i < $repeatEach; $i++) {
681             push(@tests, $test);
682         }
683     }
684 }
685 # Add test set repetitions
686 for (my $i = 1; $i < $iterations; $i++) {
687     push(@tests, @originalTests);
688 }
689
690 my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
691 open my $tests_run_fh, '>', "$absTestResultsDirectory/tests_run.txt" or die $!;
692
693 for my $test (@tests) {
694     my $newDumpTool = not $isDumpToolOpen;
695     openDumpTool();
696
697     my $base = stripExtension($test);
698     my $expectedExtension = ".txt";
699     
700     my $dir = $base;
701     $dir =~ s|/[^/]+$||;
702
703     if ($newDumpTool || $dir ne $lastDirectory) {
704         foreach my $logue (epiloguesAndPrologues($newDumpTool ? "" : $lastDirectory, $dir)) {
705             if (isCygwin()) {
706                 $logue = toWindowsPath($logue);
707             } else {
708                 $logue = canonpath($logue);
709             }
710             if ($verbose) {
711                 print "running epilogue or prologue $logue\n";
712             }
713             print OUT "$logue\n";
714             # Throw away output from DumpRenderTree.
715             # Once for the test output and once for pixel results (empty)
716             while (<IN>) {
717                 last if /#EOF/;
718             }
719             while (<IN>) {
720                 last if /#EOF/;
721             }
722         }
723     }
724
725     if ($verbose) {
726         print "running $test -> ";
727         $atLineStart = 0;
728     } elsif (!$quiet) {
729         if ($dir ne $lastDirectory) {
730             print "\n" unless $atLineStart;
731             print "$dir ";
732         }
733         print ".";
734         $atLineStart = 0;
735     }
736
737     $lastDirectory = $dir;
738
739     my $result;
740
741     my $startTime = time if $report10Slowest;
742
743     print $tests_run_fh "$testDirectory/$test\n";
744
745     # Try to read expected hash file for pixel tests
746     my $suffixExpectedHash = "";
747     if ($pixelTests && !$resetResults) {
748         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
749         if (my $expectedHash = readChecksumFromPng(File::Spec->catfile($expectedPixelDir, "$base-$expectedTag.png"))) {
750             # Format expected hash into a suffix string that is appended to the path / URL passed to DRT.
751             $suffixExpectedHash = "'$expectedHash";
752         }
753     }
754
755     if ($test =~ /^http\//) {
756         configureAndOpenHTTPDIfNeeded();
757         if ($test =~ /^http\/tests\/websocket\//) {
758             if ($test =~ /^websocket\/tests\/local\//) {
759                 my $testPath = "$testDirectory/$test";
760                 if (isCygwin()) {
761                     $testPath = toWindowsPath($testPath);
762                 } else {
763                     $testPath = canonpath($testPath);
764                 }
765                 print OUT "$testPath\n";
766             } else {
767                 if (openWebSocketServerIfNeeded()) {
768                     my $path = canonpath($test);
769                     if ($test =~ /^http\/tests\/websocket\/tests\/ssl\//) {
770                         # wss is disabled until all platforms support pyOpenSSL.
771                         print STDERR "Error: wss is disabled until all platforms support pyOpenSSL.";
772                     } else {
773                         $path =~ s/^http\/tests\///;
774                         print OUT "http://127.0.0.1:$httpdPort/$path\n";
775                     }
776                 } else {
777                     # We failed to launch the WebSocket server.  Display a useful error message rather than attempting
778                     # to run tests that expect the server to be available.
779                     my $errorMessagePath = "$testDirectory/http/tests/websocket/resources/server-failed-to-start.html";
780                     $errorMessagePath = isCygwin() ? toWindowsPath($errorMessagePath) : canonpath($errorMessagePath);
781                     print OUT "$errorMessagePath\n";
782                 }
783             }
784         } elsif ($test !~ /^http\/tests\/local\// && $test !~ /^http\/tests\/ssl\//) {
785             my $path = canonpath($test);
786             $path =~ s/^http\/tests\///;
787             print OUT "http://127.0.0.1:$httpdPort/$path$suffixExpectedHash\n";
788         } elsif ($test =~ /^http\/tests\/ssl\//) {
789             my $path = canonpath($test);
790             $path =~ s/^http\/tests\///;
791             print OUT "https://127.0.0.1:$httpdSSLPort/$path$suffixExpectedHash\n";
792         } else {
793             my $testPath = "$testDirectory/$test";
794             if (isCygwin()) {
795                 $testPath = toWindowsPath($testPath);
796             } else {
797                 $testPath = canonpath($testPath);
798             }
799             print OUT "$testPath$suffixExpectedHash\n";
800         }
801     } else {
802         my $testPath = "$testDirectory/$test";
803         if (isCygwin()) {
804             $testPath = toWindowsPath($testPath);
805         } else {
806             $testPath = canonpath($testPath);
807         }
808         print OUT "$testPath$suffixExpectedHash\n" if defined $testPath;
809     }
810
811     # DumpRenderTree is expected to dump two "blocks" to stdout for each test.
812     # Each block is terminated by a #EOF on a line by itself.
813     # The first block is the output of the test (in text, RenderTree or other formats).
814     # The second block is for optional pixel data in PNG format, and may be empty if
815     # pixel tests are not being run, or the test does not dump pixels (e.g. text tests).
816     my $readResults = readFromDumpToolWithTimer(IN, ERROR);
817
818     my $actual = $readResults->{output};
819     my $error = $readResults->{error};
820
821     $expectedExtension = $readResults->{extension};
822     my $expectedFileName = "$base-$expectedTag.$expectedExtension";
823
824     my $isText = isTextOnlyTest($actual);
825
826     my $expectedDir = expectedDirectoryForTest($base, $isText, $expectedExtension);
827     $expectedResultPaths{$base} = File::Spec->catfile($expectedDir, $expectedFileName);
828
829     unless ($readResults->{status} eq "success") {
830         my $crashed = $readResults->{status} eq "crashed";
831         my $webProcessCrashed = $readResults->{status} eq "webProcessCrashed";
832         testCrashedOrTimedOut($test, $base, $crashed, $webProcessCrashed, $actual, $error);
833         countFinishedTest($test, $base, $webProcessCrashed ? "webProcessCrash" : $crashed ? "crash" : "timedout", 0);
834         last if stopRunningTestsEarlyIfNeeded();
835         next;
836     }
837
838     $durations{$test} = time - $startTime if $report10Slowest;
839
840     my $expected;
841
842     if (!$resetResults && open EXPECTED, "<", $expectedResultPaths{$base}) {
843         $expected = "";
844         while (<EXPECTED>) {
845             next if $stripEditingCallbacks && $_ =~ /^EDITING DELEGATE:/;
846             $expected .= $_;
847         }
848         close EXPECTED;
849     }
850
851     if ($ignoreMetrics && !$isText && defined $expected) {
852         ($actual, $expected) = stripMetrics($actual, $expected);
853     }
854
855     if ($shouldCheckLeaks && $testsPerDumpTool == 1) {
856         print "        $test -> ";
857     }
858
859     my $actualPNG = "";
860     my $diffPNG = "";
861     my $diffPercentage = 0;
862     my $diffResult = "passed";
863
864     my $actualHash = "";
865     my $expectedHash = "";
866     my $actualPNGSize = 0;
867
868     while (<IN>) {
869         last if /#EOF/;
870         if (/ActualHash: ([a-f0-9]{32})/) {
871             $actualHash = $1;
872         } elsif (/ExpectedHash: ([a-f0-9]{32})/) {
873             $expectedHash = $1;
874         } elsif (/Content-Length: (\d+)\s*/) {
875             $actualPNGSize = $1;
876             read(IN, $actualPNG, $actualPNGSize);
877         }
878     }
879
880     if ($verbose && $pixelTests && !$resetResults && $actualPNGSize) {
881         if ($actualHash eq "" && $expectedHash eq "") {
882             printFailureMessageForTest($test, "WARNING: actual & expected pixel hashes are missing!");
883         } elsif ($actualHash eq "") {
884             printFailureMessageForTest($test, "WARNING: actual pixel hash is missing!");
885         } elsif ($expectedHash eq "") {
886             printFailureMessageForTest($test, "WARNING: expected pixel hash is missing!");
887         }
888     }
889
890     if ($actualPNGSize > 0) {
891         my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
892         my $expectedPNGPath = File::Spec->catfile($expectedPixelDir, "$base-$expectedTag.png");
893
894         if (!$resetResults && ($expectedHash ne $actualHash || ($actualHash eq "" && $expectedHash eq ""))) {
895             if (-f $expectedPNGPath) {
896                 my $expectedPNGSize = -s $expectedPNGPath;
897                 my $expectedPNG = "";
898                 open EXPECTEDPNG, $expectedPNGPath;
899                 read(EXPECTEDPNG, $expectedPNG, $expectedPNGSize);
900
901                 openDiffTool();
902                 print DIFFOUT "Content-Length: $actualPNGSize\n";
903                 print DIFFOUT $actualPNG;
904
905                 print DIFFOUT "Content-Length: $expectedPNGSize\n";
906                 print DIFFOUT $expectedPNG;
907
908                 while (<DIFFIN>) {
909                     last if /^error/ || /^diff:/;
910                     if (/Content-Length: (\d+)\s*/) {
911                         read(DIFFIN, $diffPNG, $1);
912                     }
913                 }
914
915                 if (/^diff: (.+)% (passed|failed)/) {
916                     $diffPercentage = $1 + 0;
917                     $imageDifferences{$base} = $diffPercentage;
918                     $diffResult = $2;
919                 }
920                 
921                 if (!$diffPercentage) {
922                     printFailureMessageForTest($test, "pixel hash failed (but pixel test still passes)");
923                 }
924             } elsif ($verbose) {
925                 printFailureMessageForTest($test, "WARNING: expected image is missing!");
926             }
927         }
928
929         if ($resetResults || !-f $expectedPNGPath) {
930             mkpath catfile($expectedPixelDir, dirname($base)) if $testDirectory ne $expectedPixelDir;
931             writeToFile($expectedPNGPath, $actualPNG);
932         }
933     }
934
935     if (dumpToolDidCrash()) {
936         $result = "crash";
937         testCrashedOrTimedOut($test, $base, 1, 0, $actual, $error);
938     } elsif (!defined $expected) {
939         if ($verbose) {
940             print "new " . ($resetResults ? "result" : "test");
941         }
942         $result = "new";
943
944         if ($generateNewResults || $resetResults) {
945             mkpath catfile($expectedDir, dirname($base)) if $testDirectory ne $expectedDir;
946             writeToFile("$expectedDir/$expectedFileName", $actual);
947         }
948         deleteExpectedAndActualResults($base);
949         recordActualResultsAndDiff($base, $actual);
950         if (!$resetResults) {
951             # Always print the file name for new tests, as they will probably need some manual inspection.
952             # in verbose mode we already printed the test case, so no need to do it again.
953             unless ($verbose) {
954                 print "\n" unless $atLineStart;
955                 print "$test -> ";
956             }
957             my $resultsDir = catdir($expectedDir, dirname($base));
958             if (!$verbose) {
959                 print "new";
960             }
961             if ($generateNewResults) {
962                 print " (results generated in $resultsDir)";
963             }
964             print "\n" unless $atLineStart;
965             $atLineStart = 1;
966         }
967     } elsif ($actual eq $expected && $diffResult eq "passed") {
968         if ($verbose) {
969             print "succeeded\n";
970             $atLineStart = 1;
971         }
972         $result = "match";
973         deleteExpectedAndActualResults($base);
974     } else {
975         $result = "mismatch";
976
977         my $pixelTestFailed = $pixelTests && $diffPNG && $diffPNG ne "";
978         my $testFailed = $actual ne $expected;
979
980         my $message = !$testFailed ? "pixel test failed" : "failed";
981
982         if (($testFailed || $pixelTestFailed) && $addPlatformExceptions) {
983             my $testBase = catfile($testDirectory, $base);
984             my $expectedBase = catfile($expectedDir, $base);
985             my $testIsMaximallyPlatformSpecific = $testBase =~ m|^\Q$platformTestDirectory\E/|;
986             my $expectedResultIsMaximallyPlatformSpecific = $expectedBase =~ m|^\Q$platformTestDirectory\E/|;
987             if (!$testIsMaximallyPlatformSpecific && !$expectedResultIsMaximallyPlatformSpecific) {
988                 mkpath catfile($platformTestDirectory, dirname($base));
989                 if ($testFailed) {
990                     my $expectedFile = catfile($platformTestDirectory, "$expectedFileName");
991                     writeToFile("$expectedFile", $actual);
992                 }
993                 if ($pixelTestFailed) {
994                     my $expectedFile = catfile($platformTestDirectory, "$base-$expectedTag.png");
995                     writeToFile("$expectedFile", $actualPNG);
996                 }
997                 $message .= " (results generated in $platformTestDirectory)";
998             }
999         }
1000
1001         printFailureMessageForTest($test, $message);
1002
1003         my $dir = "$testResultsDirectory/$base";
1004         $dir =~ s|/([^/]+)$|| or die "Failed to find test name from base\n";
1005         my $testName = $1;
1006         mkpath $dir;
1007
1008         deleteExpectedAndActualResults($base);
1009         recordActualResultsAndDiff($base, $actual);
1010
1011         if ($pixelTestFailed) {
1012             $imagesPresent{$base} = 1;
1013
1014             writeToFile("$testResultsDirectory/$base-$actualTag.png", $actualPNG);
1015             writeToFile("$testResultsDirectory/$base-$diffsTag.png", $diffPNG);
1016
1017             my $expectedPixelDir = expectedDirectoryForTest($base, 0, "png");
1018             copy("$expectedPixelDir/$base-$expectedTag.png", "$testResultsDirectory/$base-$expectedTag.png");
1019
1020             open DIFFHTML, ">$testResultsDirectory/$base-$diffsTag.html" or die;
1021             print DIFFHTML "<html>\n";
1022             print DIFFHTML "<head>\n";
1023             print DIFFHTML "<title>$base Image Compare</title>\n";
1024             print DIFFHTML "<script language=\"Javascript\" type=\"text/javascript\">\n";
1025             print DIFFHTML "var currentImage = 0;\n";
1026             print DIFFHTML "var imageNames = new Array(\"Actual\", \"Expected\");\n";
1027             print DIFFHTML "var imagePaths = new Array(\"$testName-$actualTag.png\", \"$testName-$expectedTag.png\");\n";
1028             if (-f "$testDirectory/$base-w3c.png") {
1029                 copy("$testDirectory/$base-w3c.png", "$testResultsDirectory/$base-w3c.png");
1030                 print DIFFHTML "imageNames.push(\"W3C\");\n";
1031                 print DIFFHTML "imagePaths.push(\"$testName-w3c.png\");\n";
1032             }
1033             print DIFFHTML "function animateImage() {\n";
1034             print DIFFHTML "    var image = document.getElementById(\"animatedImage\");\n";
1035             print DIFFHTML "    var imageText = document.getElementById(\"imageText\");\n";
1036             print DIFFHTML "    image.src = imagePaths[currentImage];\n";
1037             print DIFFHTML "    imageText.innerHTML = imageNames[currentImage] + \" Image\";\n";
1038             print DIFFHTML "    currentImage = (currentImage + 1) % imageNames.length;\n";
1039             print DIFFHTML "    setTimeout('animateImage()',2000);\n";
1040             print DIFFHTML "}\n";
1041             print DIFFHTML "</script>\n";
1042             print DIFFHTML "</head>\n";
1043             print DIFFHTML "<body onLoad=\"animateImage();\">\n";
1044             print DIFFHTML "<table>\n";
1045             if ($diffPercentage) {
1046                 print DIFFHTML "<tr>\n";
1047                 print DIFFHTML "<td>Difference between images: <a href=\"$testName-$diffsTag.png\">$diffPercentage%</a></td>\n";
1048                 print DIFFHTML "</tr>\n";
1049             }
1050             print DIFFHTML "<tr>\n";
1051             print DIFFHTML "<td><a href=\"" . toURL("$testDirectory/$test") . "\">test file</a></td>\n";
1052             print DIFFHTML "</tr>\n";
1053             print DIFFHTML "<tr>\n";
1054             print DIFFHTML "<td id=\"imageText\" style=\"text-weight: bold;\">Actual Image</td>\n";
1055             print DIFFHTML "</tr>\n";
1056             print DIFFHTML "<tr>\n";
1057             print DIFFHTML "<td><img src=\"$testName-$actualTag.png\" id=\"animatedImage\"></td>\n";
1058             print DIFFHTML "</tr>\n";
1059             print DIFFHTML "</table>\n";
1060             print DIFFHTML "</body>\n";
1061             print DIFFHTML "</html>\n";
1062         }
1063     }
1064
1065     if ($error) {
1066         my $dir = dirname(File::Spec->catdir($testResultsDirectory, $base));
1067         mkpath $dir;
1068         
1069         writeToFile(File::Spec->catfile($testResultsDirectory, "$base-$errorTag.txt"), $error);
1070         
1071         $counts{error}++;
1072         push @{$tests{error}}, $test;
1073     }
1074
1075     countFinishedTest($test, $base, $result, $isText);
1076     last if stopRunningTestsEarlyIfNeeded();
1077 }
1078
1079 close($tests_run_fh);
1080
1081 my $totalTestingTime = time - $overallStartTime;
1082 my $waitTime = getWaitTime();
1083 if ($waitTime > 0.1) {
1084     my $normalizedTestingTime = $totalTestingTime - $waitTime;
1085     printf "\n%0.2fs HTTPD waiting time\n", $waitTime . "";
1086     printf "%0.2fs normalized testing time", $normalizedTestingTime . "";
1087 }
1088 printf "\n%0.2fs total testing time\n", $totalTestingTime . "";
1089
1090 !$isDumpToolOpen || die "Failed to close $dumpToolName.\n";
1091
1092 $isHttpdOpen = !closeHTTPD();
1093 closeWebSocketServer();
1094
1095 # Because multiple instances of this script are running concurrently we cannot 
1096 # safely delete this symlink.
1097 # system "rm /tmp/LayoutTests";
1098
1099 # FIXME: Do we really want to check the image-comparison tool for leaks every time?
1100 if ($isDiffToolOpen && $shouldCheckLeaks) {
1101     $totalLeaks += countAndPrintLeaks("ImageDiff", $imageDiffToolPID, "$testResultsDirectory/ImageDiff-leaks.txt");
1102 }
1103
1104 if ($totalLeaks) {
1105     if ($mergeDepth) {
1106         parseLeaksandPrintUniqueLeaks();
1107     } else { 
1108         print "\nWARNING: $totalLeaks total leaks found!\n";
1109         print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
1110     }
1111 }
1112
1113 close IN;
1114 close OUT;
1115 close ERROR;
1116
1117 if ($report10Slowest) {
1118     print "\n\nThe 10 slowest tests:\n\n";
1119     my $count = 0;
1120     for my $test (sort slowestcmp keys %durations) {
1121         printf "%0.2f secs: %s\n", $durations{$test}, $test;
1122         last if ++$count == 10;
1123     }
1124 }
1125
1126 print "\n";
1127
1128 if ($skippedOnly && $counts{"match"}) {
1129     print "The following tests are in the Skipped file (" . File::Spec->abs2rel("$platformTestDirectory/Skipped", $testDirectory) . "), but succeeded:\n";
1130     foreach my $test (@{$tests{"match"}}) {
1131         print "  $test\n";
1132     }
1133 }
1134
1135 if ($resetResults || ($counts{match} && $counts{match} == $count)) {
1136     print "all $count test cases succeeded\n";
1137     unlink $testResults;
1138     exit;
1139 }
1140
1141 printResults();
1142
1143 mkpath $testResultsDirectory;
1144
1145 open HTML, ">", $testResults or die "Failed to open $testResults. $!";
1146 print HTML "<html>\n";
1147 print HTML "<head>\n";
1148 print HTML "<title>Layout Test Results</title>\n";
1149 print HTML "</head>\n";
1150 print HTML "<body>\n";
1151
1152 if ($ignoreMetrics) {
1153     print HTML "<h4>Tested with metrics ignored.</h4>";
1154 }
1155
1156 print HTML htmlForResultsSection(@{$tests{mismatch}}, "Tests where results did not match expected results", \&linksForMismatchTest);
1157 print HTML htmlForResultsSection(@{$tests{timedout}}, "Tests that timed out", \&linksForErrorTest);
1158 print HTML htmlForResultsSection(@{$tests{crash}}, "Tests that caused the DumpRenderTree tool to crash", \&linksForErrorTest);
1159 print HTML htmlForResultsSection(@{$tests{webProcessCrash}}, "Tests that caused the Web process to crash", \&linksForErrorTest);
1160 print HTML htmlForResultsSection(@{$tests{error}}, "Tests that had stderr output", \&linksForErrorTest);
1161 print HTML htmlForResultsSection(@{$tests{new}}, "Tests that had no expected results (probably new)", \&linksForNewTest);
1162
1163 print HTML "<p>httpd access log: <a href=\"access_log.txt\">access_log.txt</a></p>\n";
1164 print HTML "<p>httpd error log: <a href=\"error_log.txt\">error_log.txt</a></p>\n";
1165
1166 print HTML "</body>\n";
1167 print HTML "</html>\n";
1168 close HTML;
1169
1170 my @configurationArgs = argumentsForConfiguration();
1171
1172 if (isGtk()) {
1173   system "Tools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1174 } elsif (isQt()) {
1175   unshift @configurationArgs, qw(-graphicssystem raster -style windows);
1176   if (isCygwin()) {
1177     $testResults = "/" . toWindowsPath($testResults);
1178     $testResults =~ s/\\/\//g;
1179   }
1180   push(@configurationArgs, '-2') if $useWebKitTestRunner;
1181   system "Tools/Scripts/run-launcher", @configurationArgs, "file://".$testResults if $launchSafari;
1182 } elsif (isCygwin()) {
1183   system "cygstart", $testResults if $launchSafari;
1184 } elsif (isWindows()) {
1185   system "start", $testResults if $launchSafari;
1186 } else {
1187   system "Tools/Scripts/run-safari", @configurationArgs, "-NSOpen", $testResults if $launchSafari;
1188 }
1189
1190 closeCygpaths() if isCygwin();
1191
1192 exit 1;
1193
1194 sub countAndPrintLeaks($$$)
1195 {
1196     my ($dumpToolName, $dumpToolPID, $leaksFilePath) = @_;
1197
1198     print "\n" unless $atLineStart;
1199     $atLineStart = 1;
1200
1201     # We are excluding the following reported leaks so they don't get in our way when looking for WebKit leaks:
1202     # This allows us ignore known leaks and only be alerted when new leaks occur. Some leaks are in the old
1203     # versions of the system frameworks that are being used by the leaks bots. Even though a leak has been
1204     # fixed, it will be listed here until the bot has been updated with the newer frameworks.
1205
1206     my @typesToExclude = (
1207     );
1208
1209     my @callStacksToExclude = (
1210         "Flash_EnforceLocalSecurity" # leaks in Flash plug-in code, rdar://problem/4449747
1211     );
1212
1213     if (isLeopard()) {
1214         # Leak list for the version of Leopard used on the build bot.
1215         push @callStacksToExclude, (
1216             "CFHTTPMessageAppendBytes", # leak in CFNetwork, rdar://problem/5435912
1217             "sendDidReceiveDataCallback", # leak in CFNetwork, rdar://problem/5441619
1218             "_CFHTTPReadStreamReadMark", # leak in CFNetwork, rdar://problem/5441468
1219             "httpProtocolStart", # leak in CFNetwork, rdar://problem/5468837
1220             "_CFURLConnectionSendCallbacks", # leak in CFNetwork, rdar://problem/5441600
1221             "DispatchQTMsg", # leak in QuickTime, PPC only, rdar://problem/5667132
1222             "QTMovieContentView createVisualContext", # leak in QuickTime, PPC only, rdar://problem/5667132
1223             "_CopyArchitecturesForJVMVersion", # leak in Java, rdar://problem/5910823
1224         );
1225     }
1226
1227     if (isSnowLeopard()) {
1228         push @callStacksToExclude, (
1229             "readMakerNoteProps", # <rdar://problem/7156432> leak in ImageIO
1230             "QTKitMovieControllerView completeUISetup", # <rdar://problem/7155156> leak in QTKit
1231             "getVMInitArgs", # <rdar://problem/7714444> leak in Java
1232             "Java_java_lang_System_initProperties", # <rdar://problem/7714465> leak in Java
1233             "glrCompExecuteKernel", # <rdar://problem/7815391> leak in graphics driver while using OpenGL
1234             "NSNumberFormatter getObjectValue:forString:errorDescription:", # <rdar://problem/7149350> Leak in NSNumberFormatter
1235         );
1236     }
1237
1238     my $leaksTool = sourceDir() . "/Tools/Scripts/run-leaks";
1239     my $excludeString = "--exclude-callstack '" . (join "' --exclude-callstack '", @callStacksToExclude) . "'";
1240     $excludeString .= " --exclude-type '" . (join "' --exclude-type '", @typesToExclude) . "'" if @typesToExclude;
1241
1242     print " ? checking for leaks in $dumpToolName\n";
1243     my $leaksOutput = `$leaksTool $excludeString $dumpToolPID`;
1244     my ($count, $bytes) = $leaksOutput =~ /Process $dumpToolPID: (\d+) leaks? for (\d+) total/;
1245     my ($excluded) = $leaksOutput =~ /(\d+) leaks? excluded/;
1246
1247     my $adjustedCount = $count;
1248     $adjustedCount -= $excluded if $excluded;
1249
1250     if (!$adjustedCount) {
1251         print " - no leaks found\n";
1252         unlink $leaksFilePath;
1253         return 0;
1254     } else {
1255         my $dir = $leaksFilePath;
1256         $dir =~ s|/[^/]+$|| or die;
1257         mkpath $dir;
1258
1259         if ($excluded) {
1260             print " + $adjustedCount leaks ($bytes bytes including $excluded excluded leaks) were found, details in $leaksFilePath\n";
1261         } else {
1262             print " + $count leaks ($bytes bytes) were found, details in $leaksFilePath\n";
1263         }
1264
1265         writeToFile($leaksFilePath, $leaksOutput);
1266         
1267         push @leaksFilenames, $leaksFilePath;
1268     }
1269
1270     return $adjustedCount;
1271 }
1272
1273 sub writeToFile($$)
1274 {
1275     my ($filePath, $contents) = @_;
1276     open NEWFILE, ">", "$filePath" or die "Could not create $filePath. $!\n";
1277     print NEWFILE $contents;
1278     close NEWFILE;
1279 }
1280
1281 # Break up a path into the directory (with slash) and base name.
1282 sub splitpath($)
1283 {
1284     my ($path) = @_;
1285
1286     my $pathSeparator = "/";
1287     my $dirname = dirname($path) . $pathSeparator;
1288     $dirname = "" if $dirname eq "." . $pathSeparator;
1289
1290     return ($dirname, basename($path));
1291 }
1292
1293 # Sort first by directory, then by file, so all paths in one directory are grouped
1294 # rather than being interspersed with items from subdirectories.
1295 # Use numericcmp to sort directory and filenames to make order logical.
1296 sub pathcmp($$)
1297 {
1298     my ($patha, $pathb) = @_;
1299
1300     my ($dira, $namea) = splitpath($patha);
1301     my ($dirb, $nameb) = splitpath($pathb);
1302
1303     return numericcmp($dira, $dirb) if $dira ne $dirb;
1304     return numericcmp($namea, $nameb);
1305 }
1306
1307 # Sort numeric parts of strings as numbers, other parts as strings.
1308 # Makes 1.33 come after 1.3, which is cool.
1309 sub numericcmp($$)
1310 {
1311     my ($aa, $bb) = @_;
1312
1313     my @a = split /(\d+)/, $aa;
1314     my @b = split /(\d+)/, $bb;
1315
1316     # Compare one chunk at a time.
1317     # Each chunk is either all numeric digits, or all not numeric digits.
1318     while (@a && @b) {
1319         my $a = shift @a;
1320         my $b = shift @b;
1321         
1322         # Use numeric comparison if chunks are non-equal numbers.
1323         return $a <=> $b if $a =~ /^\d/ && $b =~ /^\d/ && $a != $b;
1324
1325         # Use string comparison if chunks are any other kind of non-equal string.
1326         return $a cmp $b if $a ne $b;
1327     }
1328     
1329     # One of the two is now empty; compare lengths for result in this case.
1330     return @a <=> @b;
1331 }
1332
1333 # Sort slowest tests first.
1334 sub slowestcmp($$)
1335 {
1336     my ($testa, $testb) = @_;
1337
1338     my $dura = $durations{$testa};
1339     my $durb = $durations{$testb};
1340     return $durb <=> $dura if $dura != $durb;
1341     return pathcmp($testa, $testb);
1342 }
1343
1344 sub launchWithEnv(\@\%)
1345 {
1346     my ($args, $env) = @_;
1347
1348     # Dump the current environment as perl code and then put it in quotes so it is one parameter.
1349     my $environmentDumper = Data::Dumper->new([\%{$env}], [qw(*ENV)]);
1350     $environmentDumper->Indent(0);
1351     $environmentDumper->Purity(1);
1352     my $allEnvVars = $environmentDumper->Dump();
1353     unshift @{$args}, "\"$allEnvVars\"";
1354
1355     my $execScript = File::Spec->catfile(sourceDir(), qw(Tools Scripts execAppWithEnv));
1356     unshift @{$args}, $perlInterpreter, $execScript;
1357     return @{$args};
1358 }
1359
1360 sub resolveAndMakeTestResultsDirectory()
1361 {
1362     my $absTestResultsDirectory = File::Spec->rel2abs(glob $testResultsDirectory);
1363     mkpath $absTestResultsDirectory;
1364     return $absTestResultsDirectory;
1365 }
1366
1367 sub openDiffTool()
1368 {
1369     return if $isDiffToolOpen;
1370     return if !$pixelTests;
1371
1372     my %CLEAN_ENV;
1373     $CLEAN_ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1374     $imageDiffToolPID = open2(\*DIFFIN, \*DIFFOUT, $imageDiffTool, launchWithEnv(@diffToolArgs, %CLEAN_ENV)) or die "unable to open $imageDiffTool\n";
1375     $isDiffToolOpen = 1;
1376 }
1377
1378 sub buildDumpTool($)
1379 {
1380     my ($dumpToolName) = @_;
1381
1382     my $dumpToolBuildScript =  "build-" . lc($dumpToolName);
1383     print STDERR "Running $dumpToolBuildScript\n";
1384
1385     local *DEVNULL;
1386     my ($childIn, $childOut, $childErr);
1387     if ($quiet) {
1388         open(DEVNULL, ">", File::Spec->devnull()) or die "Failed to open /dev/null";
1389         $childOut = ">&DEVNULL";
1390         $childErr = ">&DEVNULL";
1391     } else {
1392         # When not quiet, let the child use our stdout/stderr.
1393         $childOut = ">&STDOUT";
1394         $childErr = ">&STDERR";
1395     }
1396
1397     my @args = argumentsForConfiguration();
1398     my $buildProcess = open3($childIn, $childOut, $childErr, $perlInterpreter, File::Spec->catfile(qw(Tools Scripts), $dumpToolBuildScript), @args) or die "Failed to run build-dumprendertree";
1399     close($childIn);
1400     waitpid $buildProcess, 0;
1401     my $buildResult = $?;
1402     close($childOut);
1403     close($childErr);
1404
1405     close DEVNULL if ($quiet);
1406
1407     if ($buildResult) {
1408         print STDERR "Compiling $dumpToolName failed!\n";
1409         exit exitStatus($buildResult);
1410     }
1411 }
1412
1413 sub openDumpTool()
1414 {
1415     return if $isDumpToolOpen;
1416
1417     if ($verbose && $testsPerDumpTool != 1) {
1418         print "| Opening DumpTool |\n";
1419     }
1420
1421     my %CLEAN_ENV;
1422
1423     # Generic environment variables
1424     if (defined $ENV{'WEBKIT_TESTFONTS'}) {
1425         $CLEAN_ENV{WEBKIT_TESTFONTS} = $ENV{'WEBKIT_TESTFONTS'};
1426     }
1427
1428     # unique temporary directory for each DumpRendertree - needed for running more DumpRenderTree in parallel
1429     $CLEAN_ENV{DUMPRENDERTREE_TEMP} = File::Temp::tempdir('DumpRenderTree-XXXXXX', TMPDIR => 1, CLEANUP => 1);
1430     $CLEAN_ENV{XML_CATALOG_FILES} = ""; # work around missing /etc/catalog <rdar://problem/4292995>
1431
1432     # Platform spesifics
1433     if (isLinux()) {
1434         if (defined $ENV{'DISPLAY'}) {
1435             $CLEAN_ENV{DISPLAY} = $ENV{'DISPLAY'};
1436         } else {
1437             $CLEAN_ENV{DISPLAY} = ":1";
1438         }
1439         if (defined $ENV{'XAUTHORITY'}) {
1440             $CLEAN_ENV{XAUTHORITY} = $ENV{'XAUTHORITY'};
1441         }
1442
1443         $CLEAN_ENV{HOME} = $ENV{'HOME'};
1444         $CLEAN_ENV{LANG} = $ENV{'LANG'};
1445
1446         if (defined $ENV{'LD_LIBRARY_PATH'}) {
1447             $CLEAN_ENV{LD_LIBRARY_PATH} = $ENV{'LD_LIBRARY_PATH'};
1448         }
1449         if (defined $ENV{'DBUS_SESSION_BUS_ADDRESS'}) {
1450             $CLEAN_ENV{DBUS_SESSION_BUS_ADDRESS} = $ENV{'DBUS_SESSION_BUS_ADDRESS'};
1451         }
1452     } elsif (isDarwin()) {
1453         if (defined $ENV{'DYLD_LIBRARY_PATH'}) {
1454             $CLEAN_ENV{DYLD_LIBRARY_PATH} = $ENV{'DYLD_LIBRARY_PATH'};
1455         }
1456         if (defined $ENV{'HOME'}) {
1457             $CLEAN_ENV{HOME} = $ENV{'HOME'};
1458         }
1459
1460         $CLEAN_ENV{DYLD_FRAMEWORK_PATH} = $productDir;
1461         $CLEAN_ENV{DYLD_INSERT_LIBRARIES} = "/usr/lib/libgmalloc.dylib" if $guardMalloc;
1462     } elsif (isCygwin()) {
1463         $CLEAN_ENV{HOMEDRIVE} = $ENV{'HOMEDRIVE'};
1464         $CLEAN_ENV{HOMEPATH} = $ENV{'HOMEPATH'};
1465         $CLEAN_ENV{_NT_SYMBOL_PATH} = $ENV{_NT_SYMBOL_PATH};
1466
1467         setPathForRunningWebKitApp(\%CLEAN_ENV);
1468     }
1469
1470     # Port specifics
1471     if (isGtk()) {
1472         $CLEAN_ENV{LIBOVERLAY_SCROLLBAR} = "0";
1473         $CLEAN_ENV{GTK_MODULES} = "gail";
1474         $CLEAN_ENV{WEBKIT_INSPECTOR_PATH} = "$productDir/resources/inspector";
1475     }
1476
1477     if (isQt()) {
1478         $CLEAN_ENV{QTWEBKIT_PLUGIN_PATH} = productDir() . "/lib/plugins";
1479         $CLEAN_ENV{QT_DRT_WEBVIEW_MODE} = $ENV{"QT_DRT_WEBVIEW_MODE"};
1480     }
1481     
1482     my @args = ($dumpTool, @toolArgs);
1483     if (isAppleMacWebKit()) { 
1484         unshift @args, "arch", "-" . architecture();             
1485     }
1486
1487     if ($useValgrind) {
1488         unshift @args, "valgrind", "--suppressions=$platformBaseDirectory/qt/SuppressedValgrindErrors";
1489     } 
1490
1491     if ($useWebKitTestRunner) {
1492         # Make WebKitTestRunner use a similar timeout. We don't use the exact same timeout to avoid
1493         # race conditions.
1494         push @args, "--timeout", $timeoutSeconds - 5;
1495     }
1496
1497     $CLEAN_ENV{MallocStackLogging} = 1 if $shouldCheckLeaks;
1498
1499     $dumpToolPID = open3(\*OUT, \*IN, \*ERROR, launchWithEnv(@args, %CLEAN_ENV)) or die "Failed to start tool: $dumpTool\n";
1500     $isDumpToolOpen = 1;
1501     $dumpToolCrashed = 0;
1502 }
1503
1504 sub closeDumpTool()
1505 {
1506     return if !$isDumpToolOpen;
1507
1508     if ($verbose && $testsPerDumpTool != 1) {
1509         print "| Closing DumpTool |\n";
1510     }
1511
1512     close IN;
1513     close OUT;
1514     waitpid $dumpToolPID, 0;
1515     
1516     # check for WebCore counter leaks.
1517     if ($shouldCheckLeaks) {
1518         while (<ERROR>) {
1519             print;
1520         }
1521     }
1522     close ERROR;
1523     $isDumpToolOpen = 0;
1524 }
1525
1526 sub dumpToolDidCrash()
1527 {
1528     return 1 if $dumpToolCrashed;
1529     return 0 unless $isDumpToolOpen;
1530     my $pid = waitpid(-1, WNOHANG);
1531     return 1 if ($pid == $dumpToolPID);
1532
1533     # On Mac OS X, crashing may be significantly delayed by crash reporter.
1534     return 0 unless isAppleMacWebKit();
1535
1536     return DumpRenderTreeSupport::processIsCrashing($dumpToolPID);
1537 }
1538
1539 sub configureAndOpenHTTPDIfNeeded()
1540 {
1541     return if $isHttpdOpen;
1542     my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
1543     my $listen = "127.0.0.1:$httpdPort";
1544     my @args = (
1545         "-c", "CustomLog \"$absTestResultsDirectory/access_log.txt\" common",
1546         "-c", "ErrorLog \"$absTestResultsDirectory/error_log.txt\"",
1547         "-C", "Listen $listen"
1548     );
1549
1550     my @defaultArgs = getDefaultConfigForTestDirectory($testDirectory);
1551     @args = (@defaultArgs, @args);
1552
1553     waitForHTTPDLock() if $shouldWaitForHTTPD;
1554     $isHttpdOpen = openHTTPD(@args);
1555 }
1556
1557 sub checkPythonVersion()
1558 {
1559     # we have not chdir to sourceDir yet.
1560     system $perlInterpreter, File::Spec->catfile(sourceDir(), qw(Tools Scripts ensure-valid-python)), "--check-only";
1561     return exitStatus($?) == 0;
1562 }
1563
1564 sub openWebSocketServerIfNeeded()
1565 {
1566     return 1 if $isWebSocketServerOpen;
1567     return 0 if $failedToStartWebSocketServer;
1568
1569     my $webSocketHandlerDir = "$testDirectory";
1570     my $absTestResultsDirectory = resolveAndMakeTestResultsDirectory();
1571     $webSocketServerPidFile = "$absTestResultsDirectory/websocket.pid";
1572
1573     my @args = (
1574         "Tools/Scripts/new-run-webkit-websocketserver",
1575         "--server", "start",
1576         "--port", "$webSocketPort",
1577         "--root", "$webSocketHandlerDir",
1578         "--output-dir", "$absTestResultsDirectory",
1579         "--pidfile", "$webSocketServerPidFile"
1580     );
1581     system "/usr/bin/python", @args;
1582
1583     $isWebSocketServerOpen = 1;
1584     return 1;
1585 }
1586
1587 sub closeWebSocketServer()
1588 {
1589     return if !$isWebSocketServerOpen;
1590
1591     my @args = (
1592         "Tools/Scripts/new-run-webkit-websocketserver",
1593         "--server", "stop",
1594         "--pidfile", "$webSocketServerPidFile"
1595     );
1596     system "/usr/bin/python", @args;
1597     unlink "$webSocketServerPidFile";
1598
1599     # wss is disabled until all platforms support pyOpenSSL.
1600     $isWebSocketServerOpen = 0;
1601 }
1602
1603 sub fileNameWithNumber($$)
1604 {
1605     my ($base, $number) = @_;
1606     return "$base$number" if ($number > 1);
1607     return $base;
1608 }
1609
1610 sub processIgnoreTests($$)
1611 {
1612     my @ignoreList = split(/\s*,\s*/, shift);
1613     my $listName = shift;
1614
1615     my $disabledSuffix = "-disabled";
1616
1617     my $addIgnoredDirectories = sub {
1618         return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
1619         $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)} = 1;
1620         return @_;
1621     };
1622     foreach my $item (@ignoreList) {
1623         my $path = catfile($testDirectory, $item); 
1624         if (-d $path) {
1625             $ignoredDirectories{$item} = 1;
1626             find({ preprocess => $addIgnoredDirectories, wanted => sub {} }, $path);
1627         }
1628         elsif (-f $path) {
1629             $ignoredFiles{$item} = 1;
1630         } elsif (-f $path . $disabledSuffix) {
1631             # The test is disabled, so do nothing.
1632         } else {
1633             print "$listName list contained '$item', but no file of that name could be found\n";
1634         }
1635     }
1636 }
1637
1638 sub stripExtension($)
1639 {
1640     my ($test) = @_;
1641
1642     $test =~ s/\.[a-zA-Z]+$//;
1643     return $test;
1644 }
1645
1646 sub isTextOnlyTest($)
1647 {
1648     my ($actual) = @_;
1649     my $isText;
1650     if ($actual =~ /^layer at/ms) {
1651         $isText = 0;
1652     } else {
1653         $isText = 1;
1654     }
1655     return $isText;
1656 }
1657
1658 sub expectedDirectoryForTest($;$;$)
1659 {
1660     my ($base, $isText, $expectedExtension) = @_;
1661
1662     my @directories = @platformResultHierarchy;
1663
1664     my @extraPlatforms = ();
1665     if (isAppleWinWebKit()) {
1666         push @extraPlatforms, "mac-wk2" if $platform eq "win-wk2";
1667         push @extraPlatforms, qw(mac-snowleopard mac);
1668     }
1669   
1670     push @directories, map { catdir($platformBaseDirectory, $_) } @extraPlatforms;
1671     push @directories, $expectedDirectory;
1672
1673     # If we already have expected results, just return their location.
1674     foreach my $directory (@directories) {
1675         return $directory if -f File::Spec->catfile($directory, "$base-$expectedTag.$expectedExtension");
1676     }
1677
1678     # For cross-platform tests, text-only results should go in the cross-platform directory,
1679     # while render tree dumps should go in the least-specific platform directory.
1680     return $isText ? $expectedDirectory : $platformResultHierarchy[$#platformResultHierarchy];
1681 }
1682
1683 sub countFinishedTest($$$$)
1684 {
1685     my ($test, $base, $result, $isText) = @_;
1686
1687     if (($count + 1) % $testsPerDumpTool == 0 || $count == $#tests) {
1688         if ($shouldCheckLeaks) {
1689             my $fileName;
1690             if ($testsPerDumpTool == 1) {
1691                 $fileName = File::Spec->catfile($testResultsDirectory, "$base-leaks.txt");
1692             } else {
1693                 $fileName = File::Spec->catfile($testResultsDirectory, fileNameWithNumber($dumpToolName, $leaksOutputFileNumber) . "-leaks.txt");
1694             }
1695             my $leakCount = countAndPrintLeaks($dumpToolName, $dumpToolPID, $fileName);
1696             $totalLeaks += $leakCount;
1697             $leaksOutputFileNumber++ if ($leakCount);
1698         }
1699
1700         closeDumpTool();
1701     }
1702     
1703     $count++;
1704     $counts{$result}++;
1705     push @{$tests{$result}}, $test;
1706 }
1707
1708 sub testCrashedOrTimedOut($$$$$$)
1709 {
1710     my ($test, $base, $didCrash, $webProcessCrashed, $actual, $error) = @_;
1711
1712     printFailureMessageForTest($test, $webProcessCrashed ? "Web process crashed" : $didCrash ? "crashed" : "timed out");
1713
1714     sampleDumpTool() unless $didCrash || $webProcessCrashed;
1715
1716     my $dir = dirname(File::Spec->catdir($testResultsDirectory, $base));
1717     mkpath $dir;
1718
1719     deleteExpectedAndActualResults($base);
1720
1721     if (defined($error) && length($error)) {
1722         writeToFile(File::Spec->catfile($testResultsDirectory, "$base-$errorTag.txt"), $error);
1723     }
1724
1725     recordActualResultsAndDiff($base, $actual);
1726
1727     # There's no point in killing the dump tool when it's crashed. And it will kill itself when the
1728     # web process crashes.
1729     kill 9, $dumpToolPID unless $didCrash || $webProcessCrashed;
1730
1731     closeDumpTool();
1732
1733     captureSavedCrashLog($base, $webProcessCrashed) if $didCrash || $webProcessCrashed;
1734
1735     return unless isCygwin() && !$didCrash && $base =~ /^http/;
1736     # On Cygwin, http tests timing out can be a symptom of a non-responsive httpd.
1737     # If we timed out running an http test, try restarting httpd.
1738     $isHttpdOpen = !closeHTTPD();
1739     configureAndOpenHTTPDIfNeeded();
1740 }
1741
1742 sub captureSavedCrashLog($$)
1743 {
1744     my ($base, $webProcessCrashed) = @_;
1745
1746     my $crashLog;
1747
1748     my $glob;
1749     if (isCygwin()) {
1750         $glob = File::Spec->catfile($testResultsDirectory, $windowsCrashLogFilePrefix . "*.txt");
1751     } elsif (isAppleMacWebKit()) {
1752         my $crashLogDirectoryName;
1753         if (isLeopard()) {
1754             $crashLogDirectoryName = "CrashReporter";
1755         } else {
1756             $crashLogDirectoryName = "DiagnosticReports";
1757         }
1758
1759         $glob = File::Spec->catfile("~", "Library", "Logs", $crashLogDirectoryName, ($webProcessCrashed ? "WebProcess" : $dumpToolName) . "_*.crash");
1760
1761         # Even though the dump tool has exited, CrashReporter might still be running. We need to
1762         # wait for it to exit to ensure it has saved its crash log to disk. For simplicitly, we'll
1763         # assume that the ReportCrash process with the highest PID is the one we want.
1764         if (my @reportCrashPIDs = sort map { /^\s*(\d+)/; $1 } grep { /ReportCrash/ } `/bin/ps x`) {
1765             my $reportCrashPID = $reportCrashPIDs[$#reportCrashPIDs];
1766             # We use kill instead of waitpid because ReportCrash is not one of our child processes.
1767             usleep(250000) while kill(0, $reportCrashPID) > 0;
1768         }
1769     }
1770
1771     return unless $glob;
1772
1773     # We assume that the newest crash log in matching the glob is the one that corresponds to the crash that just occurred.
1774     if (my $newestCrashLog = findNewestFileMatchingGlob($glob)) {
1775         # The crash log must have been created after this script started running.
1776         $crashLog = $newestCrashLog if -M $newestCrashLog < 0;
1777     }
1778
1779     return unless $crashLog;
1780
1781     move($crashLog, File::Spec->catfile($testResultsDirectory, "$base-$crashLogTag.txt"));
1782 }
1783
1784 sub findNewestFileMatchingGlob($)
1785 {
1786     my ($glob) = @_;
1787
1788     my @paths = glob $glob;
1789     return unless scalar(@paths);
1790
1791     my @pathsAndTimes = map { [$_, -M $_] } @paths;
1792     @pathsAndTimes = sort { $b->[1] <=> $a->[1] } @pathsAndTimes;
1793     return $pathsAndTimes[$#pathsAndTimes]->[0];
1794 }
1795
1796 sub printFailureMessageForTest($$)
1797 {
1798     my ($test, $description) = @_;
1799
1800     unless ($verbose) {
1801         print "\n" unless $atLineStart;
1802         print "$test -> ";
1803     }
1804     print "$description\n";
1805     $atLineStart = 1;
1806 }
1807
1808 my %cygpaths = ();
1809
1810 sub openCygpathIfNeeded($)
1811 {
1812     my ($options) = @_;
1813
1814     return unless isCygwin();
1815     return $cygpaths{$options} if $cygpaths{$options} && $cygpaths{$options}->{"open"};
1816
1817     local (*CYGPATHIN, *CYGPATHOUT);
1818     my $pid = open2(\*CYGPATHIN, \*CYGPATHOUT, "cygpath -f - $options");
1819     my $cygpath =  {
1820         "pid" => $pid,
1821         "in" => *CYGPATHIN,
1822         "out" => *CYGPATHOUT,
1823         "open" => 1
1824     };
1825
1826     $cygpaths{$options} = $cygpath;
1827
1828     return $cygpath;
1829 }
1830
1831 sub closeCygpaths()
1832 {
1833     return unless isCygwin();
1834
1835     foreach my $cygpath (values(%cygpaths)) {
1836         close $cygpath->{"in"};
1837         close $cygpath->{"out"};
1838         waitpid($cygpath->{"pid"}, 0);
1839         $cygpath->{"open"} = 0;
1840
1841     }
1842 }
1843
1844 sub convertPathUsingCygpath($$)
1845 {
1846     my ($path, $options) = @_;
1847
1848     # cygpath -f (at least in Cygwin 1.7) converts spaces into newlines. We remove spaces here and
1849     # add them back in after conversion to work around this.
1850     my $spaceSubstitute = "__NOTASPACE__";
1851     $path =~ s/ /\Q$spaceSubstitute\E/g;
1852
1853     my $cygpath = openCygpathIfNeeded($options);
1854     local *inFH = $cygpath->{"in"};
1855     local *outFH = $cygpath->{"out"};
1856     print outFH $path . "\n";
1857     my $convertedPath = <inFH>;
1858     chomp($convertedPath) if defined $convertedPath;
1859
1860     $convertedPath =~ s/\Q$spaceSubstitute\E/ /g;
1861     return $convertedPath;
1862 }
1863
1864 sub toCygwinPath($)
1865 {
1866     my ($path) = @_;
1867     return unless isCygwin();
1868
1869     return convertPathUsingCygpath($path, "-u");
1870 }
1871
1872 sub toWindowsPath($)
1873 {
1874     my ($path) = @_;
1875     return unless isCygwin();
1876
1877     return convertPathUsingCygpath($path, "-w");
1878 }
1879
1880 sub toURL($)
1881 {
1882     my ($path) = @_;
1883
1884     if ($useRemoteLinksToTests) {
1885         my $relativePath = File::Spec->abs2rel($path, $testDirectory);
1886
1887         # If the file is below the test directory then convert it into a link to the file in SVN
1888         if ($relativePath !~ /^\.\.\//) {
1889             my $revision = svnRevisionForDirectory($testDirectory);
1890             my $svnPath = pathRelativeToSVNRepositoryRootForPath($path);
1891             return "http://trac.webkit.org/export/$revision/$svnPath";
1892         }
1893     }
1894
1895     return $path unless isCygwin();
1896
1897     return "file:///" . convertPathUsingCygpath($path, "-m");
1898 }
1899
1900 sub validateSkippedArg($$;$)
1901 {
1902     my ($option, $value, $value2) = @_;
1903     my %validSkippedValues = map { $_ => 1 } qw(default ignore only);
1904     $value = lc($value);
1905     die "Invalid argument '" . $value . "' for option $option" unless $validSkippedValues{$value};
1906     $treatSkipped = $value;
1907 }
1908
1909 sub htmlForResultsSection(\@$&)
1910 {
1911     my ($tests, $description, $linkGetter) = @_;
1912
1913     my @html = ();
1914     return join("\n", @html) unless @{$tests};
1915
1916     push @html, "<p>$description:</p>";
1917     push @html, "<table>";
1918     foreach my $test (@{$tests}) {
1919         push @html, "<tr>";
1920         push @html, "<td><a href=\"" . toURL("$testDirectory/$test") . "\">$test</a></td>";
1921         foreach my $link (@{&{$linkGetter}($test)}) {
1922             push @html, "<td>";
1923             push @html, "<a href=\"$link->{href}\">$link->{text}</a>" if -f File::Spec->catfile($testResultsDirectory, $link->{href});
1924             push @html, "</td>";
1925         }
1926         push @html, "</tr>";
1927     }
1928     push @html, "</table>";
1929
1930     return join("\n", @html);
1931 }
1932
1933 sub linksForExpectedAndActualResults($)
1934 {
1935     my ($base) = @_;
1936
1937     my @links = ();
1938
1939     return \@links unless -s "$testResultsDirectory/$base-$diffsTag.txt";
1940     
1941     my $expectedResultPath = $expectedResultPaths{$base};
1942     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
1943
1944     push @links, { href => "$base-$expectedTag$expectedResultExtension", text => "expected" };
1945     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "actual" };
1946     push @links, { href => "$base-$diffsTag.txt", text => "diff" };
1947     push @links, { href => "$base-$prettyDiffTag.html", text => "pretty diff" };
1948
1949     return \@links;
1950 }
1951
1952 sub linksForMismatchTest
1953 {
1954     my ($test) = @_;
1955
1956     my @links = ();
1957
1958     my $base = stripExtension($test);
1959
1960     push @links, @{linksForExpectedAndActualResults($base)};
1961     return \@links unless $pixelTests && $imagesPresent{$base};
1962
1963     push @links, { href => "$base-$expectedTag.png", text => "expected image" };
1964     push @links, { href => "$base-$diffsTag.html", text => "image diffs" };
1965     push @links, { href => "$base-$diffsTag.png", text => "$imageDifferences{$base}%" };
1966
1967     return \@links;
1968 }
1969
1970 sub crashLocation($)
1971 {
1972     my ($base) = @_;
1973
1974     my $crashLogFile = File::Spec->catfile($testResultsDirectory, "$base-$crashLogTag.txt");
1975
1976     if (isCygwin()) {
1977         # We're looking for the following text:
1978         #
1979         # FOLLOWUP_IP:
1980         # module!function+offset [file:line]
1981         #
1982         # The second contains the function that crashed (or the function that ended up jumping to a bad
1983         # address, as in the case of a null function pointer).
1984
1985         open LOG, "<", $crashLogFile or return;
1986         while (my $line = <LOG>) {
1987             last if $line =~ /^FOLLOWUP_IP:/;
1988         }
1989         my $desiredLine = <LOG>;
1990         close LOG;
1991
1992         return unless $desiredLine;
1993
1994         # Just take everything up to the first space (which is where the file/line information should
1995         # start).
1996         $desiredLine =~ /^(\S+)/;
1997         return $1;
1998     }
1999
2000     if (isAppleMacWebKit()) {
2001         # We're looking for the following text:
2002         #
2003         # Thread M Crashed:
2004         # N   module                              address function + offset (file:line)
2005         #
2006         # Some lines might have a module of "???" if we've jumped to a bad address. We should skip
2007         # past those.
2008
2009         open LOG, "<", $crashLogFile or return;
2010         while (my $line = <LOG>) {
2011             last if $line =~ /^Thread \d+ Crashed:/;
2012         }
2013         my $location;
2014         while (my $line = <LOG>) {
2015             $line =~ /^\d+\s+(\S+)\s+\S+ (.* \+ \d+)/ or next;
2016             my $module = $1;
2017             my $functionAndOffset = $2;
2018             next if $module eq "???";
2019             $location = "$module: $functionAndOffset";
2020             last;
2021         }
2022         close LOG;
2023         return $location;
2024     }
2025 }
2026
2027 sub linksForErrorTest
2028 {
2029     my ($test) = @_;
2030
2031     my @links = ();
2032
2033     my $base = stripExtension($test);
2034
2035     my $crashLogText = "crash log";
2036     if (my $crashLocation = crashLocation($base)) {
2037         $crashLogText .= " (<code>" . CGI::escapeHTML($crashLocation) . "</code>)";
2038     }
2039
2040     push @links, @{linksForExpectedAndActualResults($base)};
2041     push @links, { href => "$base-$errorTag.txt", text => "stderr" };
2042     push @links, { href => "$base-$crashLogTag.txt", text => $crashLogText };
2043
2044     return \@links;
2045 }
2046
2047 sub linksForNewTest
2048 {
2049     my ($test) = @_;
2050
2051     my @links = ();
2052
2053     my $base = stripExtension($test);
2054
2055     my $expectedResultPath = $expectedResultPaths{$base};
2056     my ($expectedResultFileName, $expectedResultsDirectory, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
2057
2058     push @links, { href => "$base-$actualTag$expectedResultExtension", text => "result" };
2059     if ($pixelTests && $imagesPresent{$base}) {
2060         push @links, { href => "$base-$expectedTag.png", text => "image" };
2061     }
2062
2063     return \@links;
2064 }
2065
2066 sub deleteExpectedAndActualResults($)
2067 {
2068     my ($base) = @_;
2069
2070     unlink "$testResultsDirectory/$base-$actualTag.txt";
2071     unlink "$testResultsDirectory/$base-$diffsTag.txt";
2072     unlink "$testResultsDirectory/$base-$errorTag.txt";
2073     unlink "$testResultsDirectory/$base-$crashLogTag.txt";
2074 }
2075
2076 sub recordActualResultsAndDiff($$)
2077 {
2078     my ($base, $actualResults) = @_;
2079
2080     return unless defined($actualResults) && length($actualResults);
2081
2082     my $expectedResultPath = $expectedResultPaths{$base};
2083     my ($expectedResultFileNameMinusExtension, $expectedResultDirectoryPath, $expectedResultExtension) = fileparse($expectedResultPath, qr{\.[^.]+$});
2084     my $actualResultsPath = File::Spec->catfile($testResultsDirectory, "$base-$actualTag$expectedResultExtension");
2085     my $copiedExpectedResultsPath = File::Spec->catfile($testResultsDirectory, "$base-$expectedTag$expectedResultExtension");
2086
2087     mkpath(dirname($actualResultsPath));
2088     writeToFile("$actualResultsPath", $actualResults);
2089
2090     # We don't need diff and pretty diff for tests without expected file.
2091     if ( !-f $expectedResultPath) {
2092         return;
2093     }
2094
2095     copy("$expectedResultPath", "$copiedExpectedResultsPath");
2096
2097     my $diffOuputBasePath = File::Spec->catfile($testResultsDirectory, $base);
2098     my $diffOutputPath = "$diffOuputBasePath-$diffsTag.txt";
2099     system "diff -u \"$copiedExpectedResultsPath\" \"$actualResultsPath\" > \"$diffOutputPath\"";
2100
2101     my $prettyDiffOutputPath = "$diffOuputBasePath-$prettyDiffTag.html";
2102     my $prettyPatchPath = "Websites/bugs.webkit.org/PrettyPatch/";
2103     my $prettifyPath = "$prettyPatchPath/prettify.rb";
2104     system "ruby -I \"$prettyPatchPath\" \"$prettifyPath\" \"$diffOutputPath\" > \"$prettyDiffOutputPath\"";
2105 }
2106
2107 sub buildPlatformResultHierarchy()
2108 {
2109     mkpath($platformTestDirectory) if ($platform eq "undefined" && !-d "$platformTestDirectory");
2110
2111     my @platforms;
2112     
2113     my $isMac = $platform =~ /^mac/;
2114     my $isWin = $platform =~ /^win/;
2115     if ($isMac || $isWin) {
2116         my $effectivePlatform = $platform;
2117         if ($platform eq "mac-wk2" || $platform eq "win-wk2") {
2118             push @platforms, $platform;
2119             $effectivePlatform = $realPlatform;
2120         }
2121
2122         my @platformList = $isMac ? @macPlatforms : @winPlatforms;
2123         my $i;
2124         for ($i = 0; $i < @platformList; $i++) {
2125             last if $platformList[$i] eq $effectivePlatform;
2126         }
2127         for (; $i < @platformList; $i++) {
2128             push @platforms, $platformList[$i];
2129         }
2130     } elsif ($platform =~ /^qt-/) {
2131         push @platforms, $platform;
2132         push @platforms, "qt";
2133     } else {
2134         @platforms = $platform;
2135     }
2136
2137     my @hierarchy;
2138     for (my $i = 0; $i < @platforms; $i++) {
2139         my $scoped = catdir($platformBaseDirectory, $platforms[$i]);
2140         push(@hierarchy, $scoped) if (-d $scoped);
2141     }
2142     
2143     unshift @hierarchy, grep { -d $_ } @additionalPlatformDirectories;
2144
2145     return @hierarchy;
2146 }
2147
2148 sub buildPlatformTestHierarchy(@)
2149 {
2150     my (@platformHierarchy) = @_;
2151
2152     my $wk2Platform;
2153     for (my $i = 0; $i < @platformHierarchy; ++$i) {
2154         if ($platformHierarchy[$i] =~ /-wk2/) {
2155             $wk2Platform = splice @platformHierarchy, $i, 1;
2156             last;
2157         }
2158     }
2159
2160     my @result;
2161     push @result, $platformHierarchy[0];
2162     push @result, $wk2Platform if defined $wk2Platform;
2163     push @result, $platformHierarchy[$#platformHierarchy] if @platformHierarchy >= 2;
2164
2165     return @result;
2166 }
2167
2168 sub epiloguesAndPrologues($$)
2169 {
2170     my ($lastDirectory, $directory) = @_;
2171     my @lastComponents = split('/', $lastDirectory);
2172     my @components = split('/', $directory);
2173
2174     while (@lastComponents) {
2175         if (!defined($components[0]) || $lastComponents[0] ne $components[0]) {
2176             last;
2177         }
2178         shift @components;
2179         shift @lastComponents;
2180     }
2181
2182     my @result;
2183     my $leaving = $lastDirectory;
2184     foreach (@lastComponents) {
2185         my $epilogue = $leaving . "/resources/run-webkit-tests-epilogue.html";
2186         foreach (@platformResultHierarchy) {
2187             push @result, catdir($_, $epilogue) if (stat(catdir($_, $epilogue)));
2188         }
2189         push @result, catdir($testDirectory, $epilogue) if (stat(catdir($testDirectory, $epilogue)));
2190         $leaving =~ s|(^\|/)[^/]+$||;
2191     }
2192
2193     my $entering = $leaving;
2194     foreach (@components) {
2195         $entering .= '/' . $_;
2196         my $prologue = $entering . "/resources/run-webkit-tests-prologue.html";
2197         push @result, catdir($testDirectory, $prologue) if (stat(catdir($testDirectory, $prologue)));
2198         foreach (reverse @platformResultHierarchy) {
2199             push @result, catdir($_, $prologue) if (stat(catdir($_, $prologue)));
2200         }
2201     }
2202     return @result;
2203 }
2204     
2205 sub parseLeaksandPrintUniqueLeaks()
2206 {
2207     return unless @leaksFilenames;
2208      
2209     my $mergedFilenames = join " ", @leaksFilenames;
2210     my $parseMallocHistoryTool = sourceDir() . "/Tools/Scripts/parse-malloc-history";
2211     
2212     open MERGED_LEAKS, "cat $mergedFilenames | $parseMallocHistoryTool --merge-depth $mergeDepth  - |" ;
2213     my @leakLines = <MERGED_LEAKS>;
2214     close MERGED_LEAKS;
2215     
2216     my $uniqueLeakCount = 0;
2217     my $totalBytes;
2218     foreach my $line (@leakLines) {
2219         ++$uniqueLeakCount if ($line =~ /^(\d*)\scalls/);
2220         $totalBytes = $1 if $line =~ /^total\:\s(.*)\s\(/;
2221     }
2222     
2223     print "\nWARNING: $totalLeaks total leaks found for a total of $totalBytes!\n";
2224     print "WARNING: $uniqueLeakCount unique leaks found!\n";
2225     print "See above for individual leaks results.\n" if ($leaksOutputFileNumber > 2);
2226     
2227 }
2228
2229 sub extensionForMimeType($)
2230 {
2231     my ($mimeType) = @_;
2232
2233     if ($mimeType eq "application/x-webarchive") {
2234         return "webarchive";
2235     } elsif ($mimeType eq "application/pdf") {
2236         return "pdf";
2237     }
2238     return "txt";
2239 }
2240
2241 # Read up to the first #EOF (the content block of the test), or until detecting crashes or timeouts.
2242 sub readFromDumpToolWithTimer(**)
2243 {
2244     my ($fhIn, $fhError) = @_;
2245
2246     setFileHandleNonBlocking($fhIn, 1);
2247     setFileHandleNonBlocking($fhError, 1);
2248
2249     my $maximumSecondsWithoutOutput = $timeoutSeconds;
2250     my $microsecondsToWaitBeforeReadingAgain = 1000;
2251
2252     my $timeOfLastSuccessfulRead = time;
2253
2254     my @output = ();
2255     my @error = ();
2256     my $status = "success";
2257     my $mimeType = "text/plain";
2258     # We don't have a very good way to know when the "headers" stop
2259     # and the content starts, so we use this as a hack:
2260     my $haveSeenContentType = 0;
2261     my $haveSeenEofIn = 0;
2262     my $haveSeenEofError = 0;
2263
2264     while (1) {
2265         if (time - $timeOfLastSuccessfulRead > $maximumSecondsWithoutOutput) {
2266             $status = dumpToolDidCrash() ? "crashed" : "timedOut";
2267             last;
2268         }
2269
2270         # Once we've seen the EOF, we must not read anymore.
2271         my $lineIn = readline($fhIn) unless $haveSeenEofIn;
2272         my $lineError = readline($fhError) unless $haveSeenEofError;
2273         if (!defined($lineIn) && !defined($lineError)) {
2274             last if ($haveSeenEofIn && $haveSeenEofError);
2275
2276             if ($! != EAGAIN) {
2277                 $status = "crashed";
2278                 last;
2279             }
2280
2281             # No data ready
2282             usleep($microsecondsToWaitBeforeReadingAgain);
2283             next;
2284         }
2285
2286         $timeOfLastSuccessfulRead = time;
2287
2288         if (defined($lineIn)) {
2289             if (!$haveSeenContentType && $lineIn =~ /^Content-Type: (\S+)$/) {
2290                 $mimeType = $1;
2291                 $haveSeenContentType = 1;
2292             } elsif ($lineIn =~ /#EOF/) {
2293                 $haveSeenEofIn = 1;
2294             } else {
2295                 push @output, $lineIn;
2296             }
2297         }
2298         if (defined($lineError)) {
2299             if ($lineError =~ /#CRASHED - WebProcess/) {
2300                 $status = "webProcessCrashed";
2301                 last;
2302             }
2303             if ($lineError =~ /#CRASHED/) {
2304                 $status = "crashed";
2305                 last;
2306             }
2307             if ($lineError =~ /#EOF/) {
2308                 $haveSeenEofError = 1;
2309             } else {
2310                 push @error, $lineError;
2311             }
2312         }
2313     }
2314
2315     setFileHandleNonBlocking($fhIn, 0);
2316     setFileHandleNonBlocking($fhError, 0);
2317     return {
2318         output => join("", @output),
2319         error => join("", @error),
2320         status => $status,
2321         mimeType => $mimeType,
2322         extension => extensionForMimeType($mimeType)
2323     };
2324 }
2325
2326 sub setFileHandleNonBlocking(*$)
2327 {
2328     my ($fh, $nonBlocking) = @_;
2329
2330     my $flags = fcntl($fh, F_GETFL, 0) or die "Couldn't get filehandle flags";
2331
2332     if ($nonBlocking) {
2333         $flags |= O_NONBLOCK;
2334     } else {
2335         $flags &= ~O_NONBLOCK;
2336     }
2337
2338     fcntl($fh, F_SETFL, $flags) or die "Couldn't set filehandle flags";
2339
2340     return 1;
2341 }
2342
2343 sub sampleDumpTool()
2344 {
2345     return unless isAppleMacWebKit();
2346     return unless $runSample;
2347
2348     my $outputDirectory = "$ENV{HOME}/Library/Logs/DumpRenderTree";
2349     -d $outputDirectory or mkdir $outputDirectory;
2350
2351     my $outputFile = "$outputDirectory/HangReport.txt";
2352     system "/usr/bin/sample", $dumpToolPID, qw(10 10 -file), $outputFile;
2353 }
2354
2355 sub stripMetrics($$)
2356 {
2357     my ($actual, $expected) = @_;
2358
2359     foreach my $result ($actual, $expected) {
2360         $result =~ s/at \(-?[0-9]+,-?[0-9]+\) *//g;
2361         $result =~ s/size -?[0-9]+x-?[0-9]+ *//g;
2362         $result =~ s/text run width -?[0-9]+: //g;
2363         $result =~ s/text run width -?[0-9]+ [a-zA-Z ]+: //g;
2364         $result =~ s/RenderButton {BUTTON} .*/RenderButton {BUTTON}/g;
2365         $result =~ s/RenderImage {INPUT} .*/RenderImage {INPUT}/g;
2366         $result =~ s/RenderBlock {INPUT} .*/RenderBlock {INPUT}/g;
2367         $result =~ s/RenderTextControl {INPUT} .*/RenderTextControl {INPUT}/g;
2368         $result =~ s/\([0-9]+px/px/g;
2369         $result =~ s/ *" *\n +" */ /g;
2370         $result =~ s/" +$/"/g;
2371
2372         $result =~ s/- /-/g;
2373         $result =~ s/\n( *)"\s+/\n$1"/g;
2374         $result =~ s/\s+"\n/"\n/g;
2375         $result =~ s/scrollWidth [0-9]+/scrollWidth/g;
2376         $result =~ s/scrollHeight [0-9]+/scrollHeight/g;
2377     }
2378
2379     return ($actual, $expected);
2380 }
2381
2382 sub fileShouldBeIgnored
2383 {
2384     my ($filePath) = @_;
2385     foreach my $ignoredDir (keys %ignoredDirectories) {
2386         if ($filePath =~ m/^$ignoredDir/) {
2387             return 1;
2388         }
2389     }
2390     return 0;
2391 }
2392
2393 sub readSkippedFiles($)
2394 {
2395     my ($constraintPath) = @_;
2396
2397     my @skippedFileDirectories = @platformTestHierarchy;
2398
2399     # Because nearly all of the skipped tests for WebKit 2 on Mac are due to
2400     # cross-platform issues, the Windows and Qt ports use the Mac skipped list
2401     # additionally to their own to avoid maintaining separate lists.
2402     push(@skippedFileDirectories, catdir($platformBaseDirectory, "mac-wk2")) if ($platform eq "win-wk2" || $platform eq "qt-wk2");
2403
2404     foreach my $level (@skippedFileDirectories) {
2405         if (open SKIPPED, "<", "$level/Skipped") {
2406             if ($verbose) {
2407                 my ($dir, $name) = splitpath($level);
2408                 print "Skipped tests in $name:\n";
2409             }
2410
2411             while (<SKIPPED>) {
2412                 my $skipped = $_;
2413                 chomp $skipped;
2414                 $skipped =~ s/^[ \n\r]+//;
2415                 $skipped =~ s/[ \n\r]+$//;
2416                 if ($skipped && $skipped !~ /^#/) {
2417                     if ($skippedOnly) {
2418                         if (!fileShouldBeIgnored($skipped)) {
2419                             if (!$constraintPath) {
2420                                 # Always add $skipped since no constraint path was specified on the command line.
2421                                 push(@ARGV, $skipped);
2422                             } elsif ($skipped =~ /^($constraintPath)/ || ("LayoutTests/".$skipped) =~ /^($constraintPath)/ ) {
2423                                 # Add $skipped only if it matches the current path constraint, e.g.,
2424                                 # "--skipped=only dir1" with "dir1/file1.html" on the skipped list or
2425                                 # "--skipped=only LayoutTests/dir1" with "dir1/file1.html" on the skipped list
2426                                 push(@ARGV, $skipped);
2427                             } elsif ($constraintPath =~ /^("LayoutTests\/".$skipped)/ || $constraintPath =~ /^($skipped)/) {
2428                                 # Add current path constraint if it is more specific than the skip list entry,
2429                                 # e.g., "--skipped=only dir1/dir2/dir3" with "dir1" on the skipped list or
2430                                 # e.g., "--skipped=only LayoutTests/dir1/dir2/dir3" with "dir1" on the skipped list.
2431                                 push(@ARGV, $constraintPath);
2432                             }
2433                         } elsif ($verbose) {
2434                             print "    $skipped\n";
2435                         }
2436                     } else {
2437                         if ($verbose) {
2438                             print "    $skipped\n";
2439                         }
2440                         processIgnoreTests($skipped, "Skipped");
2441                     }
2442                 }
2443             }
2444             close SKIPPED;
2445         }
2446     }
2447 }
2448
2449 sub readChecksumFromPng($)
2450 {
2451     my ($path) = @_;
2452     my $data;
2453     if (open(PNGFILE, $path) && read(PNGFILE, $data, 2048) && $data =~ /tEXtchecksum\0([a-fA-F0-9]{32})/) {
2454         return $1;
2455     }
2456 }
2457
2458 my @testsFound;
2459
2460 sub isUsedInReftest
2461 {
2462     my $filename = $_;
2463     if ($filename =~ /-$expectedTag(-$mismatchTag)?\.html$/) {
2464         return 1;
2465     }
2466     my $base = stripExtension($filename);
2467     return (-f "$base-$expectedTag.html" || -f "$base-$expectedTag-$mismatchTag.html");
2468 }
2469
2470 sub directoryFilter
2471 {
2472     return () if exists $ignoredLocalDirectories{basename($File::Find::dir)};
2473     return () if exists $ignoredDirectories{File::Spec->abs2rel($File::Find::dir, $testDirectory)};
2474     return @_;
2475 }
2476
2477 sub fileFilter
2478 {
2479     my $filename = $_;
2480     if ($filename =~ /\.([^.]+)$/) {
2481         my $extension = $1;
2482         if (exists $supportedFileExtensions{$extension} && !isUsedInReftest($filename)) {
2483             my $path = File::Spec->abs2rel(catfile($File::Find::dir, $filename), $testDirectory);
2484             push @testsFound, $path if !exists $ignoredFiles{$path};
2485         }
2486     }
2487 }
2488
2489 sub findTestsToRun
2490 {
2491     my @testsToRun = ();
2492
2493     for my $test (@ARGV) {
2494         $test =~ s/^(\Q$layoutTestsName\E|\Q$testDirectory\E)\///;
2495         my $fullPath = catfile($testDirectory, $test);
2496         if (file_name_is_absolute($test)) {
2497             print "can't run test $test outside $testDirectory\n";
2498         } elsif (-f $fullPath) {
2499             my ($filename, $pathname, $fileExtension) = fileparse($test, qr{\.[^.]+$});
2500             if (!exists $supportedFileExtensions{substr($fileExtension, 1)}) {
2501                 print "test $test does not have a supported extension\n";
2502             } elsif ($testHTTP || $pathname !~ /^http\//) {
2503                 push @testsToRun, $test;
2504             }
2505         } elsif (-d $fullPath) {
2506             @testsFound = ();
2507             find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $fullPath);
2508             for my $level (@platformTestHierarchy) {
2509                 my $platformPath = catfile($level, $test);
2510                 find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $platformPath) if (-d $platformPath);
2511             }
2512             push @testsToRun, sort pathcmp @testsFound;
2513             @testsFound = ();
2514         } else {
2515             print "test $test not found\n";
2516         }
2517     }
2518
2519     if (!scalar @ARGV) {
2520         @testsFound = ();
2521         find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $testDirectory);
2522         for my $level (@platformTestHierarchy) {
2523             find({ preprocess => \&directoryFilter, wanted => \&fileFilter }, $level);
2524         }
2525         push @testsToRun, sort pathcmp @testsFound;
2526         @testsFound = ();
2527
2528         # We need to minimize the time when Apache and WebSocketServer is locked by tests
2529         # so run them last if no explicit order was specified in the argument list.
2530         my @httpTests;
2531         my @websocketTests;
2532         my @otherTests;
2533         foreach my $test (@testsToRun) {
2534             if ($test =~ /^http\//) {
2535                 push(@httpTests, $test);
2536             } elsif ($test =~ /^websocket\//) {
2537                 push(@websocketTests, $test);
2538             } else {
2539                 push(@otherTests, $test);
2540             }
2541         }
2542         @testsToRun = (@otherTests, @httpTests, @websocketTests);
2543     }
2544
2545     # Reverse the tests
2546     @testsToRun = reverse @testsToRun if $reverseTests;
2547
2548     # Shuffle the array
2549     @testsToRun = shuffle(@testsToRun) if $randomizeTests;
2550
2551     return @testsToRun;
2552 }
2553
2554 sub printResults
2555 {
2556     my %text = (
2557         match => "succeeded",
2558         mismatch => "had incorrect layout",
2559         new => "were new",
2560         timedout => "timed out",
2561         crash => "crashed",
2562         webProcessCrash => "Web process crashed",
2563         error => "had stderr output"
2564     );
2565
2566     for my $type ("match", "mismatch", "new", "timedout", "crash", "webProcessCrash", "error") {
2567         my $typeCount = $counts{$type};
2568         next unless $typeCount;
2569         my $typeText = $text{$type};
2570         my $message;
2571         if ($typeCount == 1) {
2572             $typeText =~ s/were/was/;
2573             $message = sprintf "1 test case (%d%%) %s\n", 1 * 100 / $count, $typeText;
2574         } else {
2575             $message = sprintf "%d test cases (%d%%) %s\n", $typeCount, $typeCount * 100 / $count, $typeText;
2576         }
2577         $message =~ s-\(0%\)-(<1%)-;
2578         print $message;
2579     }
2580 }
2581
2582 sub stopRunningTestsEarlyIfNeeded()
2583 {
2584     # --reset-results does not check pass vs. fail, so exitAfterNFailures makes no sense with --reset-results.
2585     return 0 if $resetResults;
2586
2587     my $passCount = $counts{match} || 0; # $counts{match} will be undefined if we've not yet passed a test (e.g. the first test fails).
2588     my $newCount = $counts{new} || 0;
2589     my $failureCount = $count - $passCount - $newCount; # "Failure" here includes timeouts, crashes, etc.
2590     if ($exitAfterNFailures && $failureCount >= $exitAfterNFailures) {
2591         print "\nExiting early after $failureCount failures. $count tests run.";
2592         closeDumpTool();
2593         return 1;
2594     }
2595
2596     my $crashCount = $counts{crash} || 0;
2597     my $webProcessCrashCount = $counts{webProcessCrash} || 0;
2598     my $timeoutCount = $counts{timedout} || 0;
2599     if ($exitAfterNCrashesOrTimeouts && $crashCount + $webProcessCrashCount + $timeoutCount >= $exitAfterNCrashesOrTimeouts) {
2600         print "\nExiting early after $crashCount crashes, $webProcessCrashCount web process crashes, and $timeoutCount timeouts. $count tests run.";
2601         closeDumpTool();
2602         return 1;
2603     }
2604
2605     return 0;
2606 }
2607
2608 # Store this at global scope so it won't be GCed (and thus unlinked) until the program exits.
2609 my $debuggerTempDirectory;
2610
2611 sub createDebuggerCommandFile()
2612 {
2613     return unless isCygwin();
2614
2615     my @commands = (
2616         '.logopen /t "' . toWindowsPath($testResultsDirectory) . "\\" . $windowsCrashLogFilePrefix . '.txt"',
2617         '.srcpath "' . toWindowsPath(sourceDir()) . '"',
2618         '!analyze -vv',
2619         '~*kpn',
2620         'q',
2621     );
2622
2623     $debuggerTempDirectory = File::Temp->newdir;
2624
2625     my $commandFile = File::Spec->catfile($debuggerTempDirectory, "debugger-commands.txt");
2626     unless (open COMMANDS, '>', $commandFile) {
2627         print "Failed to open $commandFile. Crash logs will not be saved.\n";
2628         return;
2629     }
2630     print COMMANDS join("\n", @commands), "\n";
2631     unless (close COMMANDS) {
2632         print "Failed to write to $commandFile. Crash logs will not be saved.\n";
2633         return;
2634     }
2635
2636     return $commandFile;
2637 }
2638
2639 sub readRegistryString($)
2640 {
2641     my ($valueName) = @_;
2642     chomp(my $string = `regtool --wow32 get "$valueName"`);
2643     return $string;
2644 }
2645
2646 sub writeRegistryString($$)
2647 {
2648     my ($valueName, $string) = @_;
2649
2650     my $error = system "regtool", "--wow32", "set", "-s", $valueName, $string;
2651
2652     # On Windows Vista/7 with UAC enabled, regtool will fail to modify the registry, but will still
2653     # return a successful exit code. So we double-check here that the value we tried to write to the
2654     # registry was really written.
2655     return !$error && readRegistryString($valueName) eq $string;
2656 }
2657
2658 sub setUpWindowsCrashLogSaving()
2659 {
2660     return unless isCygwin();
2661
2662     unless (defined $ENV{_NT_SYMBOL_PATH}) {
2663         print "The _NT_SYMBOL_PATH environment variable is not set. Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2664         return;
2665     }
2666
2667     my $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{PROGRAMFILES}), "Debugging Tools for Windows (x86)", "ntsd.exe");
2668     unless (-f $ntsdPath) {
2669         $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{ProgramW6432}), "Debugging Tools for Windows (x64)", "ntsd.exe");
2670         unless (-f $ntsdPath) {
2671             $ntsdPath = File::Spec->catfile(toCygwinPath($ENV{SYSTEMROOT}), "system32", "ntsd.exe");
2672             unless (-f $ntsdPath) {
2673                 print STDERR "Can't find ntsd.exe. Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2674                 return;
2675             }
2676         }
2677     }
2678
2679     # If we used -c (instead of -cf) we could pass the commands directly on the command line. But
2680     # when the commands include multiple quoted paths (e.g., for .logopen and .srcpath), Windows
2681     # fails to invoke the post-mortem debugger at all (perhaps due to a bug in Windows's command
2682     # line parsing). So we save the commands to a file instead and tell the debugger to execute them
2683     # using -cf.
2684     my $commandFile = createDebuggerCommandFile() or return;
2685
2686     my @options = (
2687         '-p %ld',
2688         '-e %ld',
2689         '-g',
2690         '-lines',
2691         '-cf "' . toWindowsPath($commandFile) . '"',
2692     );
2693
2694     my %values = (
2695         Debugger => '"' . toWindowsPath($ntsdPath) . '" ' . join(' ', @options),
2696         Auto => 1
2697     );
2698
2699     foreach my $value (keys %values) {
2700         $previousWindowsPostMortemDebuggerValues{$value} = readRegistryString("$windowsPostMortemDebuggerKey/$value");
2701         next if writeRegistryString("$windowsPostMortemDebuggerKey/$value", $values{$value});
2702
2703         print "Failed to set \"$windowsPostMortemDebuggerKey/$value\". Crash logs will not be saved.\nSee <http://trac.webkit.org/wiki/BuildingOnWindows#GettingCrashLogs>.\n";
2704         return;
2705     }
2706
2707     print "Crash logs will be saved to $testResultsDirectory.\n";
2708 }
2709
2710 END {
2711     return unless isCygwin();
2712
2713     foreach my $value (keys %previousWindowsPostMortemDebuggerValues) {
2714         next if writeRegistryString("$windowsPostMortemDebuggerKey/$value", $previousWindowsPostMortemDebuggerValues{$value});
2715         print "Failed to restore \"$windowsPostMortemDebuggerKey/$value\" to its previous value \"$previousWindowsPostMortemDebuggerValues{$value}\"\n.";
2716     }
2717 }