filter-build-webkit: Don't filter out the location of the missing symbol when linking...
[WebKit-https.git] / Tools / Scripts / filter-build-webkit
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2011, 2012, 2013 Apple Inc. All rights reserved.
4
5 # Redistribution and use in source and binary forms, with or without
6 # modification, are permitted provided that the following conditions
7 # are met:
8 # 1.  Redistributions of source code must retain the above copyright
9 #     notice, this list of conditions and the following disclaimer.
10 # 2.  Redistributions in binary form must reproduce the above copyright
11 #     notice, this list of conditions and the following disclaimer in the
12 #     documentation and/or other materials provided with the distribution.
13
14 # THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS'' AND ANY
15 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
16 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
17 # DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS BE LIABLE FOR ANY
18 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
19 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
20 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
21 # ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
22 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
23 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
24
25 # Filters the output of build-webkit into a more human-readable format.
26
27 use strict;
28 use warnings;
29
30 use CGI qw(escapeHTML);
31 use File::Basename;
32 use FindBin;
33 use lib $FindBin::Bin;
34 use Getopt::Long;
35 use VCSUtils;
36
37 use constant {
38     STYLE_PLAIN => 0,
39     STYLE_HEADER => 1,
40     STYLE_SUCCESS => 2,
41     STYLE_ALERT => 3,
42
43     HTML_HEADER =><<HTMLHEADER,
44 <html>
45     <head>
46         <title>Build Log</title>
47         <style>
48             body { font-family: Monaco, monospace; font-size: 10px; color: #666; line-height: 1.5em; }
49             h2 { margin: 1.5em 0 0 0; font-size: 1.0em; font-weight: bold; color: blue; }
50             p { margin: 0; padding-left: 1.5em; border-left: 3px solid #fff; }
51             p.alert { border-left-color: red; color: red; margin: 1.5em 0 0 0; }
52             p.alert + p { margin: 1.5em 0 0 0; }
53             p.alert + p.alert { margin: 0; }
54             p.success { color: green; }
55         </style>
56     </head>
57     <body>
58 HTMLHEADER
59
60     HTML_FOOTER =><<HTMLFOOTER,
61     </body>
62 </html>
63 HTMLFOOTER
64 };
65
66 sub printLine($$);
67 sub setLogfileOption($$);
68 sub setOutputFormatOption($$);
69 sub shouldIgnoreLine($$);
70 sub usageAndExit();
71
72 # Defined in VCSUtils.
73 sub possiblyColored($$);
74
75 # Global variables used only in global scope.
76 my $outputPath = "&STDOUT";
77 my $showHelp;
78
79 # Global variables used in global and subroutine scope.
80 our $logUnfilteredOutput;
81 our $outputFormat = "text";
82 our $unfilteredOutputPath = "build.log";
83 our $useColor = -t STDOUT;
84
85 sub usageAndExit()
86 {
87     print STDERR <<__END__;
88 Usage: @{[ basename($0) ]} [options] buildlog1 [buildlog2 ...]
89        build-webkit | @{[ basename($0) ]} [options]
90   -h|--help     Show this help message
91 Output Options:
92   -o|--output   Path for output (default: STDOUT)
93   -f|--format   Output format (default: $outputFormat)
94                   text: Plain text
95                   html: Standalone HTML document
96   --[no-]color  ANSI color output for text (default: on, if -o is STDOUT)
97 Unfiltered Logging Options:
98   -l|--log      Save unfiltered output to file (see --log-file)
99   --logfile     Path to save unfiltered output (implies --log, default: $unfilteredOutputPath)
100 __END__
101     exit 1;
102 }
103
104 my $getOptionsResult = GetOptions(
105     'h|help'                => \$showHelp,
106     'o|output=s'            => \$outputPath,
107     'f|format=s'            => \&setOutputFormatOption,
108     'color!'                => \$useColor,
109     'l|log'                 => \$logUnfilteredOutput,
110     'logfile=s'             => \&setLogfileOption,
111 );
112
113 if (-t STDIN || $showHelp || !$getOptionsResult) {
114     usageAndExit();
115 }
116
117 open(OUTPUT_HANDLE, ">$outputPath") or die "Failed to open $outputPath : $!";
118 if ($logUnfilteredOutput) {
119     open(UNFILTERED_OUTPUT_HANDLE, ">$unfilteredOutputPath") or die "Failed to open $unfilteredOutputPath : $!";
120 }
121
122 print OUTPUT_HANDLE HTML_HEADER if ($outputFormat eq "html");
123
124 my $buildFinished;
125 my $buildFailed = 0;
126 for (my $previousLine = "", my $line = <>; $line; $previousLine = $line, $line = <>) {
127     print UNFILTERED_OUTPUT_HANDLE $line if $logUnfilteredOutput;
128
129     chomp($line);
130
131     next if shouldIgnoreLine($previousLine, $line);
132
133     if ($line =~ /^={10}/) {
134         printLine($line, STYLE_SUCCESS);
135         $buildFinished = 1;
136     } elsif ($line =~ /^===/) {
137         printLine($line, STYLE_HEADER);
138     } elsif ($line =~ /Checking Dependencies|Check dependencies/) {
139         printLine($line, STYLE_PLAIN);
140     } elsif ($line =~ /\*\* BUILD SUCCEEDED \*\*/) {
141         printLine("Build Succeeded", STYLE_SUCCESS);
142     } elsif ($line =~ /^(PhaseScriptExecution|CompileC|Distributed-CompileC|Ld|PBXCp|CpResource|CopyPNGFile|CopyTiffFile|CpHeader|Processing|ProcessInfoPlistFile|ProcessPCH|ProcessPCH\+\+|Touch|Libtool|CopyStringsFile|Mig|CreateUniversalBinary|Analyze|ProcessProductPackaging|CodeSign|SymLink|Updating|CompileXIB|StripNIB|CopyPlistFile|GenerateDSYMFile) ("[^"]+"|\S+)?/) {
143         my ($command, $path) = ($1, basename($2));
144         $path =~ s/"//g;
145         printLine("$command $path", STYLE_PLAIN);
146     } elsif ($line =~ /^\/\S+?(strip|WebCoreExportFileGenerator) .*?(\/|\> )(\S+)/) {
147         my ($command, $path) = (basename($1), basename($3));
148         printLine("$command $path", STYLE_PLAIN);
149     } elsif ($line =~ /^offlineasm\: /) {
150         printLine($line, STYLE_PLAIN);
151     } elsif ($line =~ /^Generating message.*(header|receiver) for (\S+)\.\.\./) {
152         my ($command, $path) = ($1, basename($2));
153         printLine("Generating message $command $path", STYLE_PLAIN);
154     } elsif ($line =~ /^(\S+\/cc).*?(\S+)\.(out|exp)/) {
155         my ($command, $path) = (basename($1), basename($2));
156         printLine("$command $path", STYLE_PLAIN);
157     } else {
158         # This only gets hit if stderr is redirected to stdout.
159         if ($line =~ /\*\* BUILD FAILED \*\*/) {
160             $buildFailed = 1;
161         }
162         printLine($line, $buildFinished ? STYLE_SUCCESS : STYLE_ALERT);
163     }
164 }
165
166 print OUTPUT_HANDLE HTML_FOOTER if ($outputFormat eq "html");
167
168 close(OUTPUT_HANDLE);
169 close(UNFILTERED_OUTPUT_HANDLE) if ($logUnfilteredOutput);
170
171 exit $buildFailed;
172
173 sub printLine($$)
174 {
175     my ($line, $style) = @_;
176
177     if ($outputFormat eq "html") {
178         $line = escapeHTML($line);
179         if    ($style == STYLE_HEADER)  { print OUTPUT_HANDLE "<h2>$line</h2>"; }
180         elsif ($style == STYLE_SUCCESS) { print OUTPUT_HANDLE "<p class=\"success\">$line</p>"; }
181         elsif ($style == STYLE_ALERT)   { print OUTPUT_HANDLE "<p class=\"alert\">$line</p>"; }
182         else                            { print OUTPUT_HANDLE "<p>$line</p>"; }
183     } else {
184         if ($useColor) {
185             my $colors = "reset";
186             if ($style == STYLE_HEADER)  { $colors = "blue"; }
187             if ($style == STYLE_SUCCESS) { $colors = "green"; }
188             if ($style == STYLE_ALERT)   { $colors = "red"; }
189             print OUTPUT_HANDLE possiblyColored($colors, $line);
190         } else {
191             print OUTPUT_HANDLE $line;
192         }
193     }
194     print OUTPUT_HANDLE "\n";
195 }
196
197 sub setLogfileOption($$)
198 {
199     my ($opt, $value) = @_;
200     $unfilteredOutputPath = $value;
201     $logUnfilteredOutput = 1;
202 }
203
204 sub setOutputFormatOption($$)
205 {
206     my ($opt, $value) = @_;
207     $value = lc($value);
208     if ($value ne "html" && $value ne "text") {
209         die "The $opt option must be either \"html\" or \"text\"";
210     }
211     $outputFormat = $value;
212 }
213
214 sub shouldIgnoreLine($$)
215 {
216     my ($previousLine, $line) = @_;
217
218     return 1 if $line =~ /^\s*$/;
219     return 1 if $line =~ /^Build settings from command line:/;
220     return 1 if $line =~ /make: Nothing to be done for `all'\./;
221     return 1 if $line =~ /^JavaScriptCore\/create_hash_table/;
222     return 1 if $line =~ /JavaScriptCore.framework\/PrivateHeaders\/create_hash_table/;
223     return 1 if $line =~ /^JavaScriptCore\/pcre\/dftables/;
224     return 1 if $line =~ /^Creating hashtable for /;
225     return 1 if $line =~ /^Wrote output to /;
226     return 1 if $line =~ /^(touch|perl|cat|rm -f|bison|flex|python|\/usr\/bin\/g\+\+|gperf|echo|sed|if \[ \-f|WebCore\/generate-export-file) /;
227     return 1 if $line =~ /^UNDOCUMENTED: /;
228     return 1 if $line =~ /libtool.*has no symbols/;
229     return 1 if $line =~ /^# Lower case all the values, as CSS values are case-insensitive$/;
230     return 1 if $line =~ /^if sort /;
231     return 1 if $line =~ /^    / && $previousLine !~ /referenced from:$/;
232     return 1 if $line =~ /^printf /;
233     return 1 if $line =~ /^offlineasm: Nothing changed/;
234     return 1 if $line =~ /^Showing first/;
235
236     return 0;
237 }