Add standalone script that filters the output of build-webkit to be more human-readable
[WebKit-https.git] / Tools / Scripts / filter-build-webkit
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2011 Apple Inc. All rights reserved.
4
5 # Redistribution and use in source and binary forms, with or without
6 # modification, are permitted provided that the following conditions
7 # are met:
8 # 1.  Redistributions of source code must retain the above copyright
9 #     notice, this list of conditions and the following disclaimer.
10 # 2.  Redistributions in binary form must reproduce the above copyright
11 #     notice, this list of conditions and the following disclaimer in the
12 #     documentation and/or other materials provided with the distribution.
13
14 # THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS'' AND ANY
15 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
16 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
17 # DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS BE LIABLE FOR ANY
18 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
19 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
20 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
21 # ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
22 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
23 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
24
25 # Filters the output of build-webkit into a more human-readable format.
26
27 use strict;
28 use warnings;
29
30 use CGI qw(escapeHTML);
31 use File::Basename;
32 use FindBin;
33 use lib $FindBin::Bin;
34 use Getopt::Long;
35 use VCSUtils;
36
37 use constant {    
38     STYLE_PLAIN => 0,
39     STYLE_HEADER => 1,
40     STYLE_SUCCESS => 2,
41     STYLE_ALERT => 3,
42     
43     HTML_HEADER =><<HTMLHEADER,
44 <html>
45     <head>
46         <title>Build Log</title>
47         <style>
48             body { font-family: Monaco, monospace; font-size: 10px; color: #666; line-height: 1.5em; }
49             h2 { margin: 1.5em 0 0 0; font-size: 1.0em; font-weight: bold; color: blue; }
50             p { margin: 0; padding-left: 1.5em; border-left: 3px solid #fff; }
51             p.alert { border-left-color: red; color: red; margin: 1.5em 0 0 0; }
52             p.alert + p { margin: 1.5em 0 0 0; }
53             p.alert + p.alert { margin: 0; }
54             p.success { color: green; }
55         </style>
56     </head>
57     <body>
58 HTMLHEADER
59
60     HTML_FOOTER =><<HTMLFOOTER,
61     </body>
62 </html>
63 HTMLFOOTER
64 };
65
66 sub printLine($$);
67 sub setLogfileOption($$);
68 sub setOutputFormatOption($$);
69 sub usageAndExit();
70
71 # Defined in VCSUtils.
72 sub possiblyColored($$);
73
74 my $showHelp;
75 my $outputPath = "&STDOUT";
76 my $outputFormat = "text";
77 my $useColor = -t STDOUT;
78 my $unfilteredOutputPath = "build.log";
79 my $logUnfilteredOutput;
80
81 sub usageAndExit()
82 {
83     print STDERR <<__END__;
84 Usage: @{[ basename($0) ]} [options] buildlog1 [buildlog2 ...]
85        build-webkit | @{[ basename($0) ]} [options]
86   -h|--help     Show this help message
87 Output Options:
88   -o|--output   Path for output (default: STDOUT)
89   -f|--format   Output format (default: $outputFormat)
90                   text: Plain text
91                   html: Standalone HTML document
92   --[no-]color  ANSI color output for text (default: on, if -o is STDOUT)
93 Unfiltered Logging Options:
94   -l|--log      Save unfiltered output to file (see --log-file)
95   --logfile     Path to save unfiltered output (implies --log, default: $unfilteredOutputPath)
96 __END__
97     exit 1;
98 }
99
100 my $getOptionsResult = GetOptions(
101     'h|help'                => \$showHelp,
102     'o|output=s'            => \$outputPath,
103     'f|format=s'            => \&setOutputFormatOption,
104     'color!'                => \$useColor,
105     'l|log'                 => \$logUnfilteredOutput,
106     'logfile=s'             => \&setLogfileOption,
107 );
108
109 if (-t STDIN || $showHelp || !$getOptionsResult) {
110     usageAndExit();
111 }
112
113 open(OUTPUT_HANDLE, ">$outputPath") or die "Failed to open $outputPath : $!";
114 if ($logUnfilteredOutput) {
115     open(UNFILTERED_OUTPUT_HANDLE, ">$unfilteredOutputPath") or die "Failed to open $unfilteredOutputPath : $!";
116 }
117
118 print OUTPUT_HANDLE HTML_HEADER if ($outputFormat eq "html");
119
120 my $buildFinished;
121 while (my $line = <>) {
122     print UNFILTERED_OUTPUT_HANDLE $line if $logUnfilteredOutput;
123     
124     chomp($line);
125
126     next if $line =~ /^\s*$/;
127     next if $line =~ /^Build settings from command line:/;
128     next if $line =~ /make: Nothing to be done for `all'\./;
129     next if $line =~ /^JavaScriptCore\/create_hash_table/;
130     next if $line =~ /JavaScriptCore.framework\/PrivateHeaders\/create_hash_table/;
131     next if $line =~ /^JavaScriptCore\/pcre\/dftables/;
132     next if $line =~ /^Creating hashtable for /;
133     next if $line =~ /^Wrote output to /;
134     next if $line =~ /^(touch|perl|cat|rm -f|bison|flex|python|\/usr\/bin\/g\+\+|gperf|echo|sed|if \[ \-f|WebCore\/generate-export-file) /;
135     next if $line =~ /^UNDOCUMENTED: /;
136     next if $line =~ /libtool.*has no symbols/;
137     next if $line =~ /^# Lower case all the values, as CSS values are case-insensitive$/;
138     next if $line =~ /^if sort /;
139     next if $line =~ /^    /;
140
141     if ($line =~ /^={10}/) {
142         printLine($line, STYLE_SUCCESS);
143         $buildFinished = 1;
144     } elsif ($line =~ /^===/) {
145         printLine($line, STYLE_HEADER);
146     } elsif ($line =~ /Checking Dependencies|Check dependencies/) {
147         printLine($line, STYLE_PLAIN);
148     } elsif ($line =~ /\*\* BUILD SUCCEEDED \*\*/) {
149         printLine("Build Succeeded", STYLE_SUCCESS);
150     } elsif ($line =~ /^(PhaseScriptExecution|CompileC|Ld|PBXCp|CpResource|CopyPNGFile|CopyTiffFile|CpHeader|Processing|ProcessInfoPlistFile|ProcessPCH|ProcessPCH\+\+|Touch|Libtool|CopyStringsFile|Mig|CreateUniversalBinary|Analyze) ("[^"]+"|\S+)/) {
151         my ($command, $path) = ($1, basename($2));
152         printLine("$command $path", STYLE_PLAIN);
153     } else {
154         printLine($line, $buildFinished ? STYLE_SUCCESS : STYLE_ALERT);
155     }
156 }
157
158 print OUTPUT_HANDLE HTML_FOOTER if ($outputFormat eq "html");
159
160 close(OUTPUT_HANDLE);
161 close(UNFILTERED_OUTPUT_HANDLE) if ($logUnfilteredOutput);
162
163 exit 0;
164
165 sub printLine($$)
166 {
167     my ($line, $style) = @_;
168     
169     if ($outputFormat eq "html") {
170         $line = escapeHTML($line);
171         if    ($style == STYLE_HEADER)  { print OUTPUT_HANDLE "<h2>$line</h2>"; }
172         elsif ($style == STYLE_SUCCESS) { print OUTPUT_HANDLE "<p class=\"success\">$line</p>"; }
173         elsif ($style == STYLE_ALERT)   { print OUTPUT_HANDLE "<p class=\"alert\">$line</p>"; }
174         else                            { print OUTPUT_HANDLE "<p>$line</p>"; }
175     } else {
176         my $colors = "reset";
177         if ($useColor) {
178             if ($style == STYLE_HEADER)  { $colors = "blue"; }
179             if ($style == STYLE_SUCCESS) { $colors = "green"; }
180             if ($style == STYLE_ALERT)   { $colors = "red"; }
181         }
182         print OUTPUT_HANDLE possiblyColored($colors, $line);
183     }
184     print OUTPUT_HANDLE "\n";
185 }
186
187 sub setLogfileOption($$)
188 {
189     my ($opt, $value) = @_;
190     $unfilteredOutputPath = $value;
191     $logUnfilteredOutput = 1;
192 }
193
194 sub setOutputFormatOption($$)
195 {
196     my ($opt, $value) = @_;
197     $value = lc($value);
198     if ($value ne "html" && $value ne "text") {
199         die "The $opt option must be either \"html\" or \"text\"";
200     }
201     $outputFormat = $value;
202 }