670670733af7c74aac3d99bd53677a304944e1b6
[WebKit-https.git] / Tools / Scripts / build-webkit
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012, 2013, 2014 Apple Inc. All rights reserved.
4 # Copyright (C) 2009 Google Inc. All rights reserved.
5 # Copyright (C) 2010 moiji-mobile.com All rights reserved.
6 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
7 # Copyright (C) 2013 Nokia Corporation and/or its subsidiary(-ies).
8 #
9 # Redistribution and use in source and binary forms, with or without
10 # modification, are permitted provided that the following conditions
11 # are met:
12 #
13 # 1.  Redistributions of source code must retain the above copyright
14 #     notice, this list of conditions and the following disclaimer. 
15 # 2.  Redistributions in binary form must reproduce the above copyright
16 #     notice, this list of conditions and the following disclaimer in the
17 #     documentation and/or other materials provided with the distribution. 
18 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
19 #     its contributors may be used to endorse or promote products derived
20 #     from this software without specific prior written permission. 
21 #
22 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
23 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
24 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
25 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
26 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
27 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
28 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
29 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
32
33 # Build script wrapper for the WebKit Open Source Project.
34
35 use strict;
36 use File::Basename;
37 use File::Find;
38 use File::Spec;
39 use FindBin;
40 use Getopt::Long qw(:config pass_through no_auto_abbrev);
41 use lib $FindBin::Bin;
42 use webkitdirs;
43 use List::Util qw(first);
44 use webkitperl::FeatureList qw(getFeatureOptionList);
45 use POSIX;
46
47 sub cMakeArgsFromFeatures();
48 sub writeCongrats();
49
50 my $originalWorkingDirectory = getcwd();
51 chdirWebKit();
52
53 my $showHelp = 0;
54 my $clean = 0;
55 my $minimal = 0;
56 my $installHeaders;
57 my $installLibs;
58 my $prefixPath;
59 my $makeArgs = "";
60 my @cmakeArgs;
61 my $onlyWebKitProject = 0;
62 my $coverageSupport = 0;
63 my $shouldRunStaticAnalyzer = 0;
64 my $startTime = time();
65
66 my @features = getFeatureOptionList();
67
68 # Additional environment parameters
69 push @ARGV, split(/ /, $ENV{'BUILD_WEBKIT_ARGS'}) if ($ENV{'BUILD_WEBKIT_ARGS'});
70
71 # Initialize values from defaults
72 foreach (@ARGV) {
73     if ($_ eq '--minimal') {
74         $minimal = 1;
75     }
76 }
77
78 # Initialize values from defaults
79 foreach (@features) {
80     ${$_->{value}} = ($minimal ? 0 : $_->{default});
81 }
82
83 my $programName = basename($0);
84 my $usage = <<EOF;
85 Usage: $programName [options] [options to pass to build system]
86   --help                            Show this help message
87   --clean                           Cleanup the build directory
88   --debug                           Compile with Debug configuration
89   --release                         Compile with Release configuration
90   --sdk=<sdk>                       Use a specific Xcode SDK (iOS and Mac only)
91   --device                          Use "iphoneos.internal" SDK if installed, else "iphoneos" SDK (iOS only)
92   --ios-simulator                   Use the current iphonesimulator SDK (iOS only)
93   --coverage                        Enable code coverage support (Mac only)
94   --analyze                         Enable static anaylsis (iOS and Mac only)
95
96   --efl                             Build the EFL port
97   --gtk                             Build the GTK+ port
98   --wincairo                        Build using Cairo (rather than CoreGraphics) on Windows
99
100   --inspector-frontend              Copy Web Inspector user interface resources to the build directory
101
102   --prefix=<path>                   Set installation prefix to the given path (Gtk/Efl only)
103   --makeargs=<arguments>            Optional Makefile flags
104   --cmakeargs=<arguments>           One or more optional CMake flags (e.g. --cmakeargs="-DFOO=bar -DCMAKE_PREFIX_PATH=/usr/local")
105
106   --minimal                         No optional features, unless explicitly enabled
107
108   --only-webkit                     Build only the WebKit project
109
110 EOF
111
112 my %options = (
113     'help' => \$showHelp,
114     'clean' => \$clean,
115     'install-headers=s' => \$installHeaders,
116     'install-libs=s' => \$installLibs,
117     'prefix=s' => \$prefixPath,
118     'makeargs=s' => \$makeArgs,
119     'cmakeargs=s' => \@cmakeArgs,
120     'minimal' => \$minimal,
121     'only-webkit' => \$onlyWebKitProject,
122     'coverage' => \$coverageSupport,
123     'analyze' => \$shouldRunStaticAnalyzer,
124 );
125
126 # Build usage text and options list from features
127 foreach (@features) {
128     my $opt = sprintf("%-35s", "  --[no-]$_->{option}");
129     $usage .= "$opt $_->{desc} (default: $_->{default})\n";
130     $options{"$_->{option}!"} = $_->{value};
131 }
132
133 GetOptions(%options);
134
135 if ($showHelp) {
136    print STDERR $usage;
137    exit 1;
138 }
139
140 checkRequiredSystemConfig();
141 setConfiguration();
142
143 my $productDir = productDir();
144
145 # Check that all the project directories are there.
146 my @projects = ("Source/JavaScriptCore", "Source/WebCore", "Source/WebKit");
147
148 # Build WTF as a separate static library on ports which support it.
149 splice @projects, 0, 0, "Source/WTF" if isAppleMacWebKit() or isAppleWinWebKit() or isWinCairo();
150
151 splice @projects, 0, 0, "Source/bmalloc" if isAppleMacWebKit();
152
153 for my $dir (@projects) {
154     if (! -d $dir) {
155         die "Error: No $dir directory found. Please do a fresh checkout.\n";
156     }
157 }
158
159 if ((isAppleWebKit() || isWinCairo()) && !-d "WebKitLibraries") {
160     die "Error: No WebKitLibraries directory found. Please do a fresh checkout.\n";
161 }
162
163 my @options = ();
164
165 if (isAppleMacWebKit()) {
166     push @options, XcodeOptions();
167     sub option($$$)
168     {
169         my ($feature, $isEnabled, $defaultValue) = @_;
170         return "" if $defaultValue == $isEnabled;
171         return $feature . "=" . ($isEnabled ? $feature : "");
172     }
173
174     foreach (@features) {
175         my $option = option($_->{define}, ${$_->{value}}, $_->{default});
176         push @options, $option unless $option eq "";
177     }
178
179     # ANGLE must come before WebCore
180     splice @projects, 0, 0, "Source/ThirdParty/ANGLE";
181
182     push @projects, ("Source/WebKit2");
183
184     if (!isIOSWebKit()) {
185         push @projects, ("Tools/MiniBrowser");
186
187         # WebInspectorUI must come after JavaScriptCore and WebCore but before WebKit and WebKit2
188         my $webKitIndex = first { $projects[$_] eq "Source/WebKit" } 0..$#projects;
189         splice(@projects, $webKitIndex, 0, "Source/WebInspectorUI");
190
191         # Copy library and header from WebKitLibraries to a findable place in the product directory.
192         my @copyLibrariesArgs = ("perl", "Tools/Scripts/copy-webkitlibraries-to-product-directory", "--wksi",  productDir());
193         print(join(" ", @copyLibrariesArgs) . "\n");
194         (system(@copyLibrariesArgs) == 0) or die;
195     } else {
196         my @copyLibrariesArgs = ("perl", "Tools/Scripts/copy-webkitlibraries-to-product-directory", "--sdk", xcodeSDK(), "--wksi");
197         push @copyLibrariesArgs, productDir();
198         print(join(" ", @copyLibrariesArgs) . "\n");
199         (system(@copyLibrariesArgs) == 0) or die;
200
201         if (willUseIOSSimulatorSDK()) {
202             (system("perl", "Tools/Scripts/build-layouttestrelay", argumentsForConfiguration()) == 0) or die;
203         }
204     }
205
206     # Build Tools needed for Apple ports
207     push @projects, ("Tools/DumpRenderTree", "Tools/WebKitTestRunner", "Source/ThirdParty/gtest", "Tools/TestWebKitAPI");
208
209 } elsif (isWinCairo()) {
210     (system("perl Tools/Scripts/update-webkit-wincairo-libs") == 0) or die;
211 } elsif (isAppleWinWebKit()) {
212     # Copy WebKitSupportLibrary to the correct location in WebKitLibraries so it can be found.
213     # Will fail if WebKitSupportLibrary.zip is not in source root.
214     (system("perl Tools/Scripts/update-webkit-support-libs") == 0) or die;
215 }
216
217 # If asked to build just the WebKit project, overwrite the projects
218 # list after all of the port specific tweaks have been made to
219 # build options, etc.
220 @projects = ("Source/WebKit") if $onlyWebKitProject;
221
222 my $result = 0;
223
224 if (isInspectorFrontend()) {
225     die "The --inspector-frontend option is not supported for CMake-based builds." if isCMakeBuild();
226     @projects = ("Source/WebInspectorUI");
227 }
228
229 if (isCMakeBuild() && !isAnyWindows()) {
230
231     # By default we build using all of the available CPUs.
232     $makeArgs .= ($makeArgs ? " " : "") . "-j" . numberOfCPUs() if $makeArgs !~ /-j\s*\d+/;
233     my $maxCPULoad = maxCPULoad() if $makeArgs !~ /-l\s*\d+\.?\d*/;
234     $makeArgs .= " -l" . maxCPULoad() if defined $maxCPULoad;
235
236     # We remove CMakeCache to avoid the bots to reuse cached flags when
237     # we enable new features. This forces a reconfiguration.
238     my @featureArgs = cMakeArgsFromFeatures();
239     removeCMakeCache(@featureArgs);
240
241     buildCMakeProjectOrExit($clean, $prefixPath, $makeArgs, (cmakeBasedPortArguments(), @featureArgs), @cmakeArgs);
242 }
243
244 my $baseProductDir = baseProductDir();
245 if (isAppleWinWebKit() || isWinCairo()) {
246     my @featureArgs = cMakeArgsFromFeatures();
247     removeCMakeCache(@featureArgs);
248
249     chdirWebKit();
250     if (exitStatus(generateBuildSystemFromCMakeProject())) {
251         die "Run \"C:/Program Files (x86)/Microsoft Visual Studio 14.0/VC/vcvarsall.bat\" before build-webkit when using ninja";
252     }
253     chdirWebKit();
254     if (canUseNinja()) {
255         chdir File::Spec->catdir($baseProductDir, configuration());
256         $result = system("ninja");
257     } else {
258         $result = buildVisualStudioProject(File::Spec->catfile("WebKitBuild", configuration(), "WebKit.sln"), $clean);
259     }
260     if (exitStatus($result)) {
261         my $scriptDir = relativeScriptsDir();
262         if (isAppleWinWebKit() || isWinCairo()) {
263             print "\n\n===== BUILD FAILED ======\n\n";
264             print "Please ensure you have run $scriptDir/update-webkit to install dependencies.\n\n";
265             print "You can view build errors by checking the BuildLog.htm files located at:\n$baseProductDir/obj/<project>/<config>.\n";
266         }
267         exit exitStatus($result);
268     }
269 } elsif (isAppleMacWebKit() && !isCMakeBuild()) {
270     # Build, and abort if the build fails.
271     for my $dir (@projects) {
272         chdir $dir or die;
273         $result = 0;
274
275         my $project = basename($dir);
276         
277         my @local_options = @options;
278         push @local_options, XcodeCoverageSupportOptions() if $coverageSupport;
279         push @local_options, XcodeStaticAnalyzerOption() if $shouldRunStaticAnalyzer;
280         my $projectPath = $project =~ /gtest/ ? "xcode/gtest" : $project;
281         $result = buildXCodeProject($projectPath, $clean, @local_options, @ARGV);
282
283         # Various build* calls above may change the CWD.
284         chdirWebKit();
285
286         if (exitStatus($result)) {
287             exit exitStatus($result);
288         }
289     }
290 }
291
292 # Don't report the "WebKit is now built" message after a clean operation.
293 exit if $clean;
294
295 # Don't report congrats message if build was interrupted by the user.
296 exit if ($result & 127) == SIGINT;
297
298 # Explicitly chdir back to where exit will take us anyway, since the following "launcher"
299 # message is relative to that directory.
300 chdir $originalWorkingDirectory;
301
302 # Write out congratulations message.
303 writeCongrats();
304
305 exit 0;
306
307 sub cMakeArgsFromFeatures()
308 {
309     my @args;
310     foreach (@features) {
311         my $featureName = $_->{define};
312         if ($featureName) {
313             my $featureEnabled = ${$_->{value}} ? "ON" : "OFF";
314             push @args, "-D$featureName=$featureEnabled";
315         }
316     }
317     return @args;
318 }
319
320 sub writeCongrats()
321 {
322     my $launcherPath = launcherPath();
323     my $launcherName = launcherName();
324     my $endTime = time();
325     my $buildTime = formatBuildTime($endTime - $startTime);
326
327     print "\n";
328     print "====================================================================\n";
329     print " WebKit is now built ($buildTime). \n";
330     if ($launcherPath && $launcherName) {
331         print " To run $launcherName with this newly-built code, use the\n";
332         print " \"$launcherPath\" script.\n";
333     }
334     print "====================================================================\n";
335 }