Add CMake build infrastructure for the BlackBerry port
[WebKit-https.git] / Tools / Scripts / build-webkit
1 #!/usr/bin/perl -w
2
3 # Copyright (C) 2005, 2006, 2007, 2008, 2009, 2010 Apple Inc. All rights reserved.
4 # Copyright (C) 2009 Google Inc. All rights reserved.
5 # Copyright (C) 2010 moiji-mobile.com All rights reserved.
6 # Copyright (C) 2011 Research In Motion Limited. All rights reserved.
7 #
8 # Redistribution and use in source and binary forms, with or without
9 # modification, are permitted provided that the following conditions
10 # are met:
11 #
12 # 1.  Redistributions of source code must retain the above copyright
13 #     notice, this list of conditions and the following disclaimer. 
14 # 2.  Redistributions in binary form must reproduce the above copyright
15 #     notice, this list of conditions and the following disclaimer in the
16 #     documentation and/or other materials provided with the distribution. 
17 # 3.  Neither the name of Apple Computer, Inc. ("Apple") nor the names of
18 #     its contributors may be used to endorse or promote products derived
19 #     from this software without specific prior written permission. 
20 #
21 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
22 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
23 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
24 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
25 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
26 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
27 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
28 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
31
32 # Build script wrapper for the WebKit Open Source Project.
33
34 use strict;
35 use File::Basename;
36 use File::Find;
37 use File::Spec;
38 use FindBin;
39 use Getopt::Long qw(:config pass_through);
40 use lib $FindBin::Bin;
41 use webkitdirs;
42 use webkitperl::features;
43 use POSIX;
44
45 sub cMakeArgsFromFeatures();
46 sub checkForJavaSDK();
47 sub formatBuildTime($);
48 sub writeCongrats();
49
50 my $originalWorkingDirectory = getcwd();
51 chdirWebKit();
52
53 my $showHelp = 0;
54 my $clean = 0;
55 my $useGYP = 0;
56 my $minimal = 0;
57 my $v8 = 0;
58 my $installHeaders;
59 my $installLibs;
60 my $prefixPath;
61 my $makeArgs = "";
62 my $cmakeArgs;
63 my $onlyWebKitProject = 0;
64 my $noWebKit2 = 0;
65 my $startTime = time();
66
67 my (
68     $requestAnimationFrameSupport,
69     $threeDCanvasSupport,
70     $threeDRenderingSupport,
71     $accelerated2dCanvasSupport,
72     $animationAPISupport,
73     $blobSupport,
74     $channelMessagingSupport,
75     $clientBasedGeolocationSupport,
76     $coverageSupport,
77     $cssFiltersSupport,
78     $cssGridLayoutSupport,
79     $cssShadersSupport,
80     $sqlDatabaseSupport,
81     $datalistSupport,
82     $dataTransferItemsSupport,
83     $detailsSupport,
84     $deviceOrientationSupport,
85     $directoryUploadSupport,
86     $fileSystemSupport,
87     $filtersSupport,
88     $fullscreenAPISupport,
89     $gamepadSupport,
90     $geolocationSupport,
91     $iconDatabaseSupport,
92     $imageResizerSupport,
93     $indexedDatabaseSupport,
94     $inputColorSupport,
95     $inputSpeechSupport,
96     $inputTypeDateSupport,
97     $inputTypeDatetimeSupport,
98     $inputTypeDatetimelocalSupport,
99     $inputTypeMonthSupport,
100     $inputTypeTimeSupport,
101     $inputTypeWeekSupport,
102     $javaScriptDebuggerSupport,
103     $linkPrefetchSupport,
104     $mathmlSupport,
105     $mediaSourceSupport,
106     $mediaStatisticsSupport,
107     $mediaStreamSupport,
108     $meterTagSupport,
109     $mhtmlSupport,
110     $microdataSupport,
111     $mutationObserversSupport,
112     $netscapePluginSupport,
113     $notificationsSupport,
114     $orientationEventsSupport,
115     $pageVisibilityApiSupport,
116     $progressTagSupport,
117     $quotaSupport,
118     $registerProtocolHandlerSupport,
119     $sharedWorkersSupport,
120     $svgSupport,
121     $svgDOMObjCBindingsSupport,
122     $svgFontsSupport,
123     $systemMallocSupport,
124     $tiledBackingStoreSupport,
125     $touchEventsSupport,
126     $touchIconLoadingSupport,
127     $videoSupport,
128     $webAudioSupport,
129     $webInspectorSupport,
130     $webSocketsSupport,
131     $webTimingSupport,
132     $workersSupport,
133     $xsltSupport,
134 );
135
136 my @features = (
137     { option => "request-animation-frame", desc => "Toggle requestAnimationFrame support",
138       define => "ENABLE_REQUEST_ANIMATION_FRAME", default => (isAppleMacWebKit()), value => \$requestAnimationFrameSupport },
139
140     { option => "3d-canvas", desc => "Toggle 3D canvas (WebGL) support",
141       define => "ENABLE_WEBGL", default => (isAppleMacWebKit() && !isLeopard()), value => \$threeDCanvasSupport },
142
143     { option => "3d-rendering", desc => "Toggle 3D rendering support",
144       define => "ENABLE_3D_RENDERING", default => (isAppleMacWebKit() || isQt()), value => \$threeDRenderingSupport },
145
146     { option => "accelerated-2d-canvas", desc => "Toggle accelerated 2D canvas support",
147       define => "ENABLE_ACCELERATED_2D_CANVAS", default => 0, value => \$accelerated2dCanvasSupport },
148
149     { option => "animation-api", desc => "Toggle animation API support",
150       define => "ENABLE_ANIMATION_API", default => isBlackBerry(), value => \$animationAPISupport },
151
152     { option => "blob", desc => "Toggle Blob support",
153       define => "ENABLE_BLOB", default => (isAppleMacWebKit() || isGtk() || isChromium()), value => \$blobSupport },
154
155     { option => "channel-messaging", desc => "Toggle MessageChannel and MessagePort support",
156       define => "ENABLE_CHANNEL_MESSAGING", default => 1, value => \$channelMessagingSupport },
157
158     { option => "client-based-geolocation", desc => "Toggle client-based Geolocation support",
159       define => "ENABLE_CLIENT_BASED_GEOLOCATION", default => (isAppleWebKit() || isGtk() || isBlackBerry()), value => \$clientBasedGeolocationSupport },
160
161     { option => "css-filters", desc => "Toggle CSS Filters support",
162       define => "ENABLE_CSS_FILTERS", default => isAppleWebKit(), value => \$cssFiltersSupport },
163
164     { option => "css-grid-layout", desc => "Toggle CSS Grid Layout support",
165       define => "ENABLE_CSS_GRID_LAYOUT", default => 0, value => \$cssGridLayoutSupport },
166
167     { option => "css-shaders", desc => "Toggle CSS Shaders (within CSS Filters) support",
168       define => "ENABLE_CSS_SHADERS", default => isAppleWebKit(), value => \$cssShadersSupport },
169
170     { option => "coverage", desc => "Toggle code coverage support",
171       define => "", default => 0, value => \$coverageSupport },
172
173     { option => "sql-database", desc => "Toggle SQL Database Support",
174       define => "ENABLE_SQL_DATABASE", default => 1, value => \$sqlDatabaseSupport },
175
176     { option => "datalist", desc => "Toggle HTML5 datalist support",
177       define => "ENABLE_DATALIST", default => 1, value => \$datalistSupport },
178
179     { option => "data-transfer-items", desc => "Toggle HTML5 data transfer items support",
180       define => "ENABLE_DATA_TRANSFER_ITEMS", default => 0, value => \$dataTransferItemsSupport },
181
182     { option => "details", desc => "Toggle HTML5 details support",
183       define => "ENABLE_DETAILS", default => 1, value => \$detailsSupport },
184
185     { option => "device-orientation", desc => "Toggle DeviceOrientation support",
186       define => "ENABLE_DEVICE_ORIENTATION", default => isBlackBerry(), value => \$deviceOrientationSupport },
187
188     { option => "directory-upload", desc => "Toogle Directory upload support",
189       define => "ENABLE_DIRECTORY_UPLOAD", default => 0, value => \$directoryUploadSupport },
190
191     { option => "mutation-observers", desc => "Toggle DOM mutation observer support",
192       define => "ENABLE_MUTATION_OBSERVERS", default => 0, value => \$mutationObserversSupport },
193
194     { option => "file-system", desc => "Toggle FileSystem support",
195       define => "ENABLE_FILE_SYSTEM", default => 0, value => \$fileSystemSupport },
196
197     { option => "filters", desc => "Toggle SVG Filters support",
198       define => "ENABLE_FILTERS", default => (isAppleWebKit() || isGtk() || isQt() || isEfl() || isBlackBerry()), value => \$filtersSupport },
199
200     { option => "fullscreen-api", desc => "Toggle Fullscreen API support",
201       define => "ENABLE_FULLSCREEN_API", default => (isAppleMacWebKit() || isGtk()), value => \$fullscreenAPISupport },
202
203     { option => "gamepad", desc => "Toggle Gamepad support",
204       define => "ENABLE_GAMEPAD", default => 0, value => \$gamepadSupport },
205
206     { option => "geolocation", desc => "Toggle Geolocation support",
207       define => "ENABLE_GEOLOCATION", default => (isAppleWebKit() || isGtk() || isBlackBerry()), value => \$geolocationSupport },
208
209     { option => "icon-database", desc => "Toggle Icon database support",
210       define => "ENABLE_ICONDATABASE", default => 1, value => \$iconDatabaseSupport },
211
212     { option => "indexed-database", desc => "Toggle Indexed Database API support",
213       define => "ENABLE_INDEXED_DATABASE", default => 0, value => \$indexedDatabaseSupport },
214
215     { option => "input-color", desc => "Color Input support",
216       define => "ENABLE_INPUT_COLOR", default => isBlackBerry(), value => \$inputColorSupport },
217
218     { option => "input-speech", desc => "Speech Input API support",
219       define => "ENABLE_INPUT_SPEECH", default => 0, value => \$inputSpeechSupport },
220
221     { option => "input-type-date", desc => "Toggle date type <input> support",
222       define => "ENABLE_INPUT_TYPE_DATE", default => 0, value => \$inputTypeDateSupport },
223
224     { option => "input-type-datetime", desc => "Toggle datetime type <input> support",
225       define => "ENABLE_INPUT_TYPE_DATETIME", default => 0, value => \$inputTypeDatetimeSupport },
226
227     { option => "input-type-datetimelocal", desc => "Toggle datetime-local type <input> support",
228       define => "ENABLE_INPUT_TYPE_DATETIMELOCAL", default => 0, value => \$inputTypeDatetimelocalSupport },
229
230     { option => "input-type-month", desc => "Toggle month type <input> support",
231       define => "ENABLE_INPUT_TYPE_MONTH", default => 0, value => \$inputTypeMonthSupport },
232
233     { option => "input-type-time", desc => "Toggle time type <input> support",
234       define => "ENABLE_INPUT_TYPE_TIME", default => 0, value => \$inputTypeTimeSupport },
235
236     { option => "input-type-week", desc => "Toggle week type <input> support",
237       define => "ENABLE_INPUT_TYPE_WEEK", default => 0, value => \$inputTypeWeekSupport },
238
239     { option => "inspector", desc => "Toggle Web Inspector support",
240       define => "ENABLE_INSPECTOR", default => 1, value => \$webInspectorSupport },
241
242     { option => "javascript-debugger", desc => "Toggle JavaScript Debugger/Profiler support",
243       define => "ENABLE_JAVASCRIPT_DEBUGGER", default => 1, value => \$javaScriptDebuggerSupport },
244
245     { option => "link-prefetch", desc => "Toggle pre fetching support",
246       define => "ENABLE_LINK_PREFETCH", default => 0, value => \$linkPrefetchSupport },
247
248     { option => "mathml", desc => "Toggle MathML support",
249       define => "ENABLE_MATHML", default => 1, value => \$mathmlSupport },
250
251     { option => "media-source", desc => "Toggle Media Source support",
252       define => "ENABLE_MEDIA_SOURCE", default => 0, value => \$mediaSourceSupport },
253
254     { option => "media-statistics", desc => "Toggle Media Statistics support",
255       define => "ENABLE_MEDIA_STATISTICS", default => 0, value => \$mediaStatisticsSupport },
256
257     { option => "media-stream", desc => "Toggle Media Stream API support (implies Blob support, currently Chromium and GTK only)",
258       define => "ENABLE_MEDIA_STREAM", default => (isChromium() || isGtk()), value => \$mediaStreamSupport },
259
260     { option => "meter-tag", desc => "Meter Tag support",
261       define => "ENABLE_METER_TAG", default => !isAppleWinWebKit(), value => \$meterTagSupport },
262
263     { option => "mhtml", desc => "Toggle MHTML support",
264       define => "ENABLE_MHTML", default => 0, value => \$mhtmlSupport },
265
266     { option => "microdata", desc => "Toggle Microdata support",
267       define => "ENABLE_MICRODATA", default => 0, value => \$microdataSupport },
268
269     { option => "netscape-plugin", desc => "Netscape Plugin support",
270       define => "ENABLE_NETSCAPE_PLUGIN_API", default => !isEfl(), value => \$netscapePluginSupport },
271
272     { option => "notifications", desc => "Toggle Desktop Notifications Support",
273       define => "ENABLE_NOTIFICATIONS", default => isBlackBerry(), value => \$notificationsSupport },
274
275     { option => "orientation-events", desc => "Toggle Orientation Events support",
276       define => "ENABLE_ORIENTATION_EVENTS", default => isBlackBerry(), value => \$orientationEventsSupport },
277
278     { option => "page-visibility-api", desc => "Page Visibility API support",
279       define => "ENABLE_PAGE_VISIBILITY_API", default => 0, value => \$pageVisibilityApiSupport },
280
281     { option => "progress-tag", desc => "Progress Tag support",
282       define => "ENABLE_PROGRESS_TAG", default => 1, value => \$progressTagSupport },
283
284     { option => "quota", desc => "Toggle Quota support",
285       define => "ENABLE_QUOTA", default => 0, value => \$quotaSupport },
286
287     { option => "register-protocol-handler", desc => "Register Protocol Handler support",
288       define => "ENABLE_REGISTER_PROTOCOL_HANDLER", default => 0, value => \$registerProtocolHandlerSupport },
289
290     { option => "system-malloc", desc => "Toggle system allocator instead of TCmalloc",
291       define => "USE_SYSTEM_MALLOC", default => 0, value => \$systemMallocSupport },
292
293     { option => "shared-workers", desc => "Toggle SharedWorkers support",
294       define => "ENABLE_SHARED_WORKERS", default => (isAppleWebKit() || isGtk() || isBlackBerry()), value => \$sharedWorkersSupport },
295
296     { option => "svg", desc => "Toggle SVG support",
297       define => "ENABLE_SVG", default => 1, value => \$svgSupport },
298
299     { option => "svg-dom-objc-bindings", desc => "Toggle SVG DOM Objective-C bindings support (implies SVG support)",
300       define => "ENABLE_SVG_DOM_OBJC_BINDINGS", default => isAppleMacWebKit(), value => \$svgDOMObjCBindingsSupport },
301
302     { option => "svg-fonts", desc => "Toggle SVG fonts support (imples SVG support)",
303       define => "ENABLE_SVG_FONTS", default => 1, value => \$svgFontsSupport },
304
305     { option => "tiled-backing-store", desc => "Toggle Tiled Backing Store support",
306       define => "WTF_USE_TILED_BACKING_STORE", default => isQt(), value => \$tiledBackingStoreSupport },
307
308     { option => "touch-events", desc => "Toggle Touch Events support",
309       define => "ENABLE_TOUCH_EVENTS", default => (isQt() || isBlackBerry()), value => \$touchEventsSupport },
310
311     { option => "touch-icon-loading", desc => "Toggle Touch Icon Loading Support",
312       define => "ENABLE_TOUCH_ICON_LOADING", default => 0, value => \$touchIconLoadingSupport },
313
314     { option => "video", desc => "Toggle Video support",
315       define => "ENABLE_VIDEO", default => (isAppleWebKit() || isGtk() || isBlackBerry()), value => \$videoSupport },
316
317     { option => "web-audio", desc => "Toggle Web Audio support",
318       define => "ENABLE_WEB_AUDIO", default => 0, value=> \$webAudioSupport },
319
320     { option => "web-sockets", desc => "Toggle Web Sockets support",
321       define => "ENABLE_WEB_SOCKETS", default => 1, value=> \$webSocketsSupport },
322
323     { option => "web-timing", desc => "Toggle Web Timing support",
324       define => "ENABLE_WEB_TIMING", default => 0, value=> \$webTimingSupport },
325
326     { option => "workers", desc => "Toggle Web Workers support",
327       define => "ENABLE_WORKERS", default => (isAppleWebKit() || isGtk() || isBlackBerry()), value => \$workersSupport },
328
329     { option => "xslt", desc => "Toggle XSLT support",
330       define => "ENABLE_XSLT", default => 1, value => \$xsltSupport },
331 );
332
333 # Update defaults from Qt's project file
334 if (isQt()) {
335     # Take a sneek peek at the arguments, since we will need the qmake binary early
336     # on to do profile parsing. We also need to know if we're showing the help-text.
337     foreach (@ARGV) {
338         if (/^--qmake=(.*)/) {
339             setQmakeBinaryPath($1);
340         } elsif (/^--help$/) {
341             $showHelp = 1;
342         }
343     }
344
345     my %qtDefaults;
346     if ($showHelp) {
347         %qtDefaults = qtFeatureDefaults();
348     }
349
350     foreach (@features) {
351         $_->{default} = (%qtDefaults ? $qtDefaults{$_->{define}} || 0 : -1);
352     }
353 }
354
355 # Additional environment parameters
356 push @ARGV, split(/ /, $ENV{'BUILD_WEBKIT_ARGS'}) if ($ENV{'BUILD_WEBKIT_ARGS'});
357
358 # Initialize values from defaults
359 foreach (@ARGV) {
360     if ($_ eq '--minimal') {
361         $minimal = 1;
362     } elsif ($_ eq '--v8') {
363         $v8 = 1;
364     }
365 }
366
367 # Initialize values from defaults
368 foreach (@features) {
369     ${$_->{value}} = ($minimal ? 0 : $_->{default});
370 }
371
372 $svgSupport = $svgSupport || $svgDOMObjCBindingsSupport || $svgFontsSupport;
373
374 $blobSupport = $blobSupport || $mediaStreamSupport;
375
376 my $programName = basename($0);
377 my $usage = <<EOF;
378 Usage: $programName [options] [options to pass to build system]
379   --help                            Show this help message
380   --clean                           Cleanup the build directory
381   --debug                           Compile in debug mode
382   --gyp                             Use GYP-generated project files
383   --dsym                            Change debugging format to dwarf-with-dsym (Mac only)
384
385   --blackberry                      Build the BlackBerry port on Mac/Linux
386   --chromium                        Build the Chromium port on Mac/Win/Linux
387   --chromium-android                Build the Chromium port on Android
388   --efl                             Build the EFL port
389   --gtk                             Build the GTK+ port
390   --qt                              Build the Qt port
391   --wincairo                        Build using Cairo (rather than CoreGraphics) on Windows
392   --wince                           Build the WinCE port
393
394   --inspector-frontend              Copy changes to the inspector front-end files to the build directory
395
396   --install-headers=<path>          Set installation path for the headers (Qt only)
397   --install-libs=<path>             Set installation path for the libraries (Qt only)
398   --v8                              Use V8 as JavaScript engine (Qt only)
399
400   --prefix=<path>                   Set installation prefix to the given path (Gtk/Efl/BlackBerry only)
401   --makeargs=<arguments>            Optional Makefile flags
402   --qmakearg=<arguments>            Optional qmake flags (Qt only, e.g. --qmakearg="CONFIG+=webkit2" to build WebKit2)
403   --cmakearg=<arguments>            Optional CMake flags (e.g. --cmakearg="-DFOO=bar -DCMAKE_PREFIX_PATH=/usr/local")
404
405   --minimal                         No optional features, unless explicitly enabled
406
407   --only-webkit                     Build only the WebKit project
408   --no-webkit2                      Omit WebKit2 code from the build
409
410 EOF
411
412 my %options = (
413     'help' => \$showHelp,
414     'clean' => \$clean,
415     'gyp' => \$useGYP,
416     'install-headers=s' => \$installHeaders,
417     'install-libs=s' => \$installLibs,
418     'prefix=s' => \$prefixPath,
419     'makeargs=s' => \$makeArgs,
420     'cmakeargs=s' => \$cmakeArgs,
421     'minimal' => \$minimal,
422     'v8' => \$v8,
423     'only-webkit' => \$onlyWebKitProject,
424     'no-webkit2' => \$noWebKit2,
425 );
426
427 # Build usage text and options list from features
428 foreach (@features) {
429     my $opt = sprintf("%-35s", "  --[no-]$_->{option}");
430     $usage .= "$opt $_->{desc} (default: $_->{default})\n";
431     $options{"$_->{option}!"} = $_->{value};
432 }
433
434 GetOptions(%options);
435
436 if ($showHelp) {
437    print STDERR $usage;
438    exit 1;
439 }
440
441 checkRequiredSystemConfig();
442 setConfiguration();
443
444 my $productDir = productDir();
445
446 # Remove 0 byte sized files from productDir after slave lost for Qt buildbots.
447 File::Find::find(\&unlinkZeroFiles, $productDir) if (isQt() && -e $productDir);
448
449 sub unlinkZeroFiles()
450 {
451     my $file = $File::Find::name;
452     # Remove 0 size files, except .d files used for dependency tracking
453     if (! -s $file && $file !~ m/\.d$/) {
454         unlink $file;
455         print "0 byte sized file removed from build directory: $file\n";
456     }
457 }
458
459 # Check that all the project directories are there.
460 my @projects = ("Source/JavaScriptCore", "Source/WebCore", "Source/WebKit");
461
462 for my $dir (@projects) {
463     if (! -d $dir) {
464         die "Error: No $dir directory found. Please do a fresh checkout.\n";
465     }
466 }
467
468 if (!isQt() && !-d "WebKitLibraries") {
469     die "Error: No WebKitLibraries directory found. Please do a fresh checkout.\n";
470 }
471
472 # Generate the generate project files from .gyp files
473 if ($useGYP) {
474     system("perl", "Tools/Scripts/generate-project-files") == 0 or die "Failed to run generate-project-files";
475 }
476
477 my @options = ();
478
479 # enable autotool options accordingly
480 if (isGtk()) {
481     @options = @ARGV;
482     foreach (@features) {
483         push @options, autotoolsFlag(${$_->{value}}, $_->{option});
484     }
485
486     push @options, "--prefix=" . $prefixPath if defined($prefixPath);
487     push @options, "--makeargs=" . $makeArgs if $makeArgs;
488 } elsif (isAppleMacWebKit()) {
489     checkForJavaSDK();
490     push @options, XcodeOptions();
491
492     sub option($$$)
493     {
494         my ($feature, $isEnabled, $defaultValue) = @_;
495         return "" if $defaultValue == $isEnabled;
496         return $feature . "=" . ($isEnabled ? $feature : "");
497     }
498
499     foreach (@features) {
500         if ($_->{option} ne "coverage") {
501             my $option = option($_->{define}, ${$_->{value}}, $_->{default});
502             push @options, $option unless $option eq "";
503         }
504     }
505
506     # Apple builds JavaScriptGlue, and only on the Mac.
507     splice @projects, 1, 0, "Source/JavaScriptGlue";
508
509     # ANGLE must come before WebCore
510     splice @projects, 0, 0, "Source/ThirdParty/ANGLE";
511
512     # WebKit2 is only supported in SnowLeopard and later at present.
513     push @projects, ("Source/WebKit2", "Tools/MiniBrowser") if osXVersion()->{"minor"} >= 6 and !$noWebKit2;
514
515     # Copy library and header from WebKitLibraries to a findable place in the product directory.
516     my @librariesToCopy = (
517         "libWebKitSystemInterfaceLeopard.a",
518         "libWebKitSystemInterfaceSnowLeopard.a",
519         "libWebKitSystemInterfaceLion.a",
520         "libWebCoreSQLite3.a",
521     );
522     foreach my $libName (@librariesToCopy) {
523         my $srcLib = "WebKitLibraries/" . $libName;
524         my $lib = "$productDir/" . $libName;
525         if (!-e $lib || -M $lib > -M $srcLib) {
526             print "Updating $lib\n";
527             system "ditto", $srcLib, $lib;
528             system "ranlib", $lib;
529         }
530     }
531
532     # FIXME: This code should be abstracted to not be copy/paste.
533     my $srcHeader = "WebKitLibraries/WebKitSystemInterface.h";
534     my $header = "$productDir/usr/local/include/WebKitSystemInterface.h";
535     if (!-e $header || -M $header > -M $srcHeader) {
536         print "Updating $header\n";
537         system "mkdir", "-p", "$productDir/usr/local/include";
538         system "ditto", $srcHeader, $header;
539     }
540
541     my $srcHeaderDir = "WebKitLibraries/WebCoreSQLite3";
542     my $headerDir = "$productDir/WebCoreSQLite3";
543     if (!-e $headerDir || -M $headerDir > -M $srcHeaderDir) {
544         print "Updating $headerDir\n";
545         system "ditto", $srcHeaderDir, $headerDir;
546     }
547 } elsif (isWinCairo()) {
548     (system("perl Tools/Scripts/update-webkit-wincairo-libs") == 0) or die;
549 } elsif (isAppleWinWebKit()) {
550     # Copy WebKitSupportLibrary to the correct location in WebKitLibraries so it can be found.
551     # Will fail if WebKitSupportLibrary.zip is not in source root.
552     (system("perl Tools/Scripts/update-webkit-support-libs") == 0) or die;
553 } elsif (isQt()) {
554     push @options, "--install-headers=" . $installHeaders if defined($installHeaders);
555     push @options, "--install-libs=" . $installLibs if defined($installLibs);
556     push @options, "--makeargs=" . $makeArgs if $makeArgs;
557     push @options, "--qmakearg=CONFIG+=no_webkit2" if $noWebKit2;
558
559     if (checkForArgumentAndRemoveFromARGV("-2")) {
560         print "Note: WebKit2 is now built by default, you don't need to passs -2. Disable using --no-webkit2\n";
561     }
562
563     @options = (@ARGV, @options);
564
565     foreach (@features) {
566         push @options, "DEFINES+=$_->{define}=${$_->{value}}" if $_->{define} && ${$_->{value}} != $_->{default};
567     }
568
569     if ($minimal) {
570         push @options, "CONFIG+=minimal";
571     }
572
573     if ($v8) {
574         push @options, "CONFIG+=v8";
575     }
576 }
577
578 # If asked to build just the WebKit project, overwrite the projects
579 # list after all of the port specific tweaks have been made to
580 # build options, etc.
581 @projects = ("Source/WebKit") if $onlyWebKitProject;
582
583 # Force re-link of existing libraries if different than expected
584 removeLibraryDependingOnFeature("WebCore", "SVG", $svgSupport);
585
586 if (isInspectorFrontend()) {
587     exit exitStatus(copyInspectorFrontendFiles());
588 }
589
590 if (isWx()) {
591     $makeArgs .= " --port=wx";
592
593     downloadWafIfNeeded();
594     @options = split(/ /, $makeArgs);
595     @projects = ();
596     my $result = buildWafProject('.', $clean, @options);
597     exit exitStatus($result) if exitStatus($result);
598 }
599
600 if (isChromium()) {
601     # Currently chromium does not honour the features passed to build-webkit.
602     # Until this is solved, we issue a warning about that.
603     foreach (@features) {
604         if (${$_->{value}} ne $_->{default}) {
605             print "\n";
606             print "===========================================================\n";
607             print " Chromium does not honor the features passed to build-webkit.\n";
608             print " The preferred way is to set up your overrides in ~/.gyp/include.gypi.\n";
609             print " See https://trac.webkit.org/wiki/Chromium#Buildingwithfeaturedefines\n";
610             print " on how to do that.\n";
611             print "===========================================================\n";
612             last;
613         }
614     }
615
616     @options = @ARGV;
617     # Chromium doesn't build by project directories.
618     @projects = ();
619     push @options, "--makeargs=" . $makeArgs if $makeArgs;
620     my $result = buildChromium($clean, @options);
621     exit exitStatus($result) if exitStatus($result);
622 }
623
624 if (isEfl()) {
625     # By default we build using all of the available CPUs.
626     $makeArgs .= ($makeArgs ? " " : "") . "-j" . numberOfCPUs() if $makeArgs !~ /-j\s*\d+/;
627     buildCMakeProjectOrExit($clean, "Efl", $prefixPath, $makeArgs, cMakeArgsFromFeatures(), $cmakeArgs);
628 }
629
630 if (isWinCE()) {
631     buildCMakeProjectOrExit($clean, "WinCE", $prefixPath, $makeArgs, ("-DCMAKE_WINCE_SDK=\"STANDARDSDK_500 (ARMV4I)\"", cMakeArgsFromFeatures()), $cmakeArgs);
632 }
633
634 if (isBlackBerry()) {
635     my %archInfo = blackberryTargetArchitecture();
636     my $arch = $archInfo{"arch"};
637     my $cpu = $archInfo{"cpu"};
638     my $cpuDir = $archInfo{"cpuDir"};
639     my $buSuffix = $archInfo{"buSuffix"};
640
641     my @cmakeExtraOptions;
642     if ($cpu eq "a9") {
643         $cpu = $arch . "v7le";
644         push @cmakeExtraOptions, '-DTARGETING_PLAYBOOK=1';
645     }
646
647     my $stageDir = $ENV{"STAGE_DIR"};
648     my $stageLib = File::Spec->catdir($stageDir, $cpuDir, "lib");
649     my $stageUsrLib = File::Spec->catdir($stageDir, $cpuDir, "usr", "lib");
650     my $stageInc = File::Spec->catdir($stageDir, "usr", "include");
651
652     my $qnxHost = $ENV{"QNX_HOST"};
653     my $numberOfJobs;
654     my $ccCommand;
655     my $cxxCommand;
656     if ($ENV{"USE_ICECC"}) {
657         chomp($ccCommand = `which icecc`);
658         $cxxCommand = $ccCommand;
659         $numberOfJobs = 50; # 50 is the number we choose for internal development
660     } else {
661         $ccCommand = File::Spec->catfile($qnxHost, "usr", "bin", "qcc");
662         $cxxCommand = $ccCommand;
663         $numberOfJobs = numberOfCPUs();
664     }
665     $makeArgs .= ($makeArgs ? " " : "") . "-j" . $numberOfJobs if $makeArgs !~ /-j\s*\d+/;
666
667     if ($ENV{"CCWRAP"}) {
668         $ccCommand = $ENV{"CCWRAP"};
669         push @cmakeExtraOptions, "-DCMAKE_C_COMPILER_ARG1=qcc";
670         push @cmakeExtraOptions, "-DCMAKE_CXX_COMPILER_ARG1=qcc";
671     }
672
673     push @cmakeExtraOptions, "-DCMAKE_SKIP_RPATH='ON'" if isDarwin();
674     push @cmakeExtraOptions, "-DENABLE_DRT=1" if $ENV{"ENABLE_DRT"};
675
676     my @includeSystemDirectories;
677     push @includeSystemDirectories, File::Spec->catdir($stageInc, "grskia", "skia");
678     push @includeSystemDirectories, File::Spec->catdir($stageInc, "grskia");
679     push @includeSystemDirectories, File::Spec->catdir($stageInc, "harfbuzz");
680     push @includeSystemDirectories, File::Spec->catdir($stageInc, "imf");
681     push @includeSystemDirectories, $stageInc;
682     push @includeSystemDirectories, File::Spec->catdir($stageInc, "browser", "platform");
683     push @includeSystemDirectories, File::Spec->catdir($stageInc, "browser", "qsk");
684
685     my @cxxFlags;
686     push @cxxFlags, "-Wl,-rpath-link,$stageLib";
687     push @cxxFlags, "-Wl,-rpath-link," . File::Spec->catfile($stageUsrLib, "torch-webkit");
688     push @cxxFlags, "-Wl,-rpath-link,$stageUsrLib";
689     push @cxxFlags, "-L$stageLib";
690     push @cxxFlags, "-L$stageUsrLib";
691
692     if ($ENV{"PROFILE"}) {
693         push @cmakeExtraOptions, "-DPROFILING=1";
694         push @cxxFlags, "-p";
695     }
696
697     my @cmakeArgs;
698     push @cmakeArgs, "-DPUBLIC_BUILD=0";
699     push @cmakeArgs, '-DCMAKE_SYSTEM_NAME="QNX"';
700     push @cmakeArgs, "-DCMAKE_SYSTEM_PROCESSOR=\"$cpuDir\"";
701     push @cmakeArgs, '-DCMAKE_SYSTEM_VERSION="1"';
702     push @cmakeArgs, "-DCMAKE_C_COMPILER=\"$ccCommand\"";
703     push @cmakeArgs, "-DCMAKE_CXX_COMPILER=\"$cxxCommand\"";
704     push @cmakeArgs, "-DCMAKE_C_FLAGS=\"-Vgcc_nto${cpu} -g @cxxFlags\"";
705     push @cmakeArgs, "-DCMAKE_CXX_FLAGS=\"-Vgcc_nto${cpu}_cpp-ne -g -lang-c++ @cxxFlags\"";
706
707     # We cannot use CMAKE_INCLUDE_PATH since this describes the search path for header files in user directories.
708     # And the QNX system headers are in user directories on the host OS (i.e. they aren't installed in the host OS's
709     # system header search path). So, we need to inform g++ that these user directories (@includeSystemDirectories)
710     # are to be taken as the host OS's system header directories when building our port.
711     #
712     # Also, we cannot use CMAKE_SYSTEM_INCLUDE_PATH since that will override the entire system header path.
713     # So, we define the additional system include paths in ADDITIONAL_SYSTEM_INCLUDE_PATH. This list will
714     # be processed in OptionsBlackBerry.cmake.
715     push @cmakeArgs, '-DADDITIONAL_SYSTEM_INCLUDE_PATH="' . join(';', @includeSystemDirectories) . '"';
716
717     # FIXME: Make this more general purpose such that we can pass a list of directories and files.
718     push @cmakeArgs, '-DTHIRD_PARTY_ICU_DIR="' . File::Spec->catdir($stageInc, "unicode") . '"';
719     push @cmakeArgs, '-DTHIRD_PARTY_UNICODE_FILE="' . File::Spec->catfile($stageInc, "unicode.h") . '"';
720
721     push @cmakeArgs, "-DCMAKE_LIBRARY_PATH=\"$stageLib;$stageUsrLib\"";
722     push @cmakeArgs, '-DCMAKE_AR="' . File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ar") . '"';
723     push @cmakeArgs, '-DCMAKE_RANLIB="' . File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ranlib") . '"';
724     push @cmakeArgs, '-DCMAKE_LD="'. File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ld") . '"';
725     push @cmakeArgs, '-DCMAKE_LINKER="' . File::Spec->catfile($qnxHost, "usr", "bin", "nto${buSuffix}-ld") . '"';
726     push @cmakeArgs, "-DECLIPSE_CDT4_GENERATE_SOURCE_PROJECT=TRUE";
727     push @cmakeArgs, '-G"Eclipse CDT4 - Unix Makefiles"';
728     push @cmakeArgs, @cmakeExtraOptions;
729
730     $prefixPath = $stageDir unless $prefixPath;
731
732     buildCMakeProjectOrExit($clean, "BlackBerry", $prefixPath, $makeArgs, (@cmakeArgs, cMakeArgsFromFeatures()));
733 }
734
735 # Build, and abort if the build fails.
736 for my $dir (@projects) {
737     chdir $dir or die;
738     my $result = 0;
739
740     # For Gtk and Qt the WebKit project builds all others
741     if ((isGtk() || isQt()) && $dir ne "Source/WebKit") {
742         chdirWebKit();
743         next;
744     }
745
746     my $project = basename($dir);
747     if (isGtk()) {
748         $result = buildGtkProject($project, $clean, !$noWebKit2, @options);
749     } elsif (isQt()) {
750         #FIXME: $dir should probably be $project.
751         $result = buildQMakeQtProject($dir, $clean, @options);
752     } elsif (isAppleMacWebKit()) {
753         my @local_options = @options;
754         push @local_options, XcodeCoverageSupportOptions() if $coverageSupport && $project ne "ANGLE";
755         my $useGYPProject = $useGYP && ($project =~ "WebCore|JavaScriptCore|JavaScriptGlue");
756         my $projectPath = $useGYPProject ? "gyp/$project" : $project;
757         $result = buildXCodeProject($projectPath, $clean, @local_options, @ARGV);
758     } elsif (isAppleWinWebKit()) {
759         if ($project eq "WebKit") {
760             $result = buildVisualStudioProject("win/WebKit.vcproj/WebKit.sln", $clean);
761         }
762     }
763     # Various build* calls above may change the CWD.
764     chdirWebKit();
765
766     if (exitStatus($result)) {
767         my $scriptDir = relativeScriptsDir();
768         if (usingVisualStudioExpress()) {
769             # Visual Studio Express is so lame it can't stdout build failures.
770             # So we find its logs and dump them to the console ourselves.
771             system(File::Spec->catfile($scriptDir, "print-vse-failure-logs"));
772         }
773         if (isAppleWinWebKit()) {
774             print "\n\n===== BUILD FAILED ======\n\n";
775             print "Please ensure you have run $scriptDir/update-webkit to install dependencies.\n\n";
776             my $baseProductDir = baseProductDir();
777             print "You can view build errors by checking the BuildLog.htm files located at:\n$baseProductDir/obj/<project>/<config>.\n";
778         }
779         exit exitStatus($result);
780     }
781 }
782
783 # Don't report the "WebKit is now built" message after a clean operation.
784 exit if $clean;
785
786 # Write out congratulations message.
787 writeCongrats();
788
789 exit 0;
790
791 sub cMakeArgsFromFeatures()
792 {
793     my @args;
794     foreach (@features) {
795         my $featureName = $_->{define};
796         if ($featureName) {
797             my $featureEnabled = ${$_->{value}} ? "ON" : "OFF";
798             push @args, "-D$featureName=$featureEnabled";
799         }
800     }
801     return @args;
802 }
803
804 sub checkForJavaSDK()
805 {
806     my $jniHeader = "/System/Library/Frameworks/JavaVM.framework/Headers/jni.h";
807     if (-e $jniHeader) {
808         return;
809     }
810     print "\nCan't find required $jniHeader, build will fail.\n\n";
811     print "After installing \"Java for Mac OS X 10.6 Update 3\", the Java Developer Package is required to build WebKit.\n";
812     print "Please install the package from http://connect.apple.com (found under Downloads > Java).\n\n";
813     print "For more information, see:\n";
814     print "https://lists.webkit.org/pipermail/webkit-dev/2010-October/014867.html\n";
815     print "https://webkit.org/building/tools.html\n\n";
816     exit 1;
817 }
818
819 sub formatBuildTime($)
820 {
821     my ($buildTime) = @_;
822
823     my $buildHours = int($buildTime / 3600);
824     my $buildMins = int(($buildTime - $buildHours * 3600) / 60);
825     my $buildSecs = $buildTime - $buildHours * 3600 - $buildMins * 60;
826
827     if ($buildHours) {
828         return sprintf("%dh:%02dm:%02ds", $buildHours, $buildMins, $buildSecs);
829     }
830     return sprintf("%02dm:%02ds", $buildMins, $buildSecs);
831 }
832
833 sub writeCongrats()
834 {
835     my $launcherPath = launcherPath();
836     my $launcherName = launcherName();
837     my $endTime = time();
838     my $buildTime = formatBuildTime($endTime - $startTime);
839
840     print "\n";
841     print "===========================================================\n";
842     print " WebKit is now built ($buildTime). \n";
843     if (!isChromium()) {
844         print " To run $launcherName with this newly-built code, use the\n";
845         print " \"$launcherPath\" script.\n";
846     }
847     print "===========================================================\n";
848 }