f1def2ad915b0a61300da0d4822c88917bad7d7d
[WebKit-https.git] / Tools / Scripts / build-jsc
1 #!/usr/bin/env perl
2
3 # Copyright (C) 2005, 2013 Apple Inc.  All rights reserved.
4 # Copyright (C) 2007 Eric Seidel <eric@webkit.org>
5 #
6 # Redistribution and use in source and binary forms, with or without
7 # modification, are permitted provided that the following conditions
8 # are met:
9 #
10 # 1.  Redistributions of source code must retain the above copyright
11 #     notice, this list of conditions and the following disclaimer. 
12 # 2.  Redistributions in binary form must reproduce the above copyright
13 #     notice, this list of conditions and the following disclaimer in the
14 #     documentation and/or other materials provided with the distribution. 
15 # 3.  Neither the name of Apple Inc. ("Apple") nor the names of
16 #     its contributors may be used to endorse or promote products derived
17 #     from this software without specific prior written permission. 
18 #
19 # THIS SOFTWARE IS PROVIDED BY APPLE AND ITS CONTRIBUTORS "AS IS" AND ANY
20 # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
21 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
22 # DISCLAIMED. IN NO EVENT SHALL APPLE OR ITS CONTRIBUTORS BE LIABLE FOR ANY
23 # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
24 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
25 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
26 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29
30
31 use strict;
32 use warnings;
33 use FindBin;
34 use Getopt::Long qw(:config pass_through);
35 use lib $FindBin::Bin;
36 use webkitdirs;
37 use webkitperl::FeatureList qw(getFeatureOptionList);
38 use POSIX;
39
40 sub cMakeArgsFromFeatures();
41 sub writeCongrats();
42
43 prohibitUnknownPort();
44
45 my $shouldRunStaticAnalyzer = 0;
46 my $minimal = 0;
47 my $coverageSupport = 0;
48 my $showHelp = 0;
49 my $ftlJIT = int(isAppleCocoaWebKit() && !willUseIOSSimulatorSDK() || ((isARM64() || isX86_64()) && (isGtk() || isJSCOnly())));
50 my $forceCLoop = 0;
51 my $cli = 0;
52 my $makeArgs = "";
53 my @cmakeArgs;
54 my $buildDir = "";
55 my $copyLibraries = 1;
56 my $startTime = time();
57
58 my @features = getFeatureOptionList();
59
60 # Initialize values from defaults
61 foreach (@ARGV) {
62     if ($_ eq '--minimal') {
63         $minimal = 1;
64     }
65 }
66
67 # Initialize values from defaults
68 foreach (@features) {
69     ${$_->{value}} = ($minimal ? 0 : $_->{default});
70 }
71
72 # Additional environment parameters
73 push @ARGV, split(/ /, $ENV{'BUILD_JSC_ARGS'}) if ($ENV{'BUILD_JSC_ARGS'});
74
75 my $programName = basename($0);
76 my $usage = <<EOF;
77 Usage: $programName [options] [options to pass to build system]
78   --help                        Show this help message
79   --[no-]analyze                Toggle code static analysis (default: $shouldRunStaticAnalyzer)
80   --[no-]coverage               Toggle code coverage support (default: $coverageSupport)
81   --[no-]ftl-jit                Toggle FTL JIT support (default: $ftlJIT)
82   --[no-]copy-libraries         Toggle whether to copy libraries (default: $copyLibraries)
83   --cloop                       Use C Loop interpreter (default: $forceCLoop)
84   --cli                         Build the new jsc command line interface (default: $cli)
85   --makeargs=<arguments>        Optional Makefile flags
86   --cmakeargs=<arguments>       One or more optional CMake flags (e.g. --cmakeargs="-DFOO=bar -DCMAKE_PREFIX_PATH=/usr/local")
87   --build-dir=<path>            Build out of tree in directory at <path>
88 EOF
89
90 my %options = (
91     'analyze!' => \$shouldRunStaticAnalyzer,
92     'coverage!' => \$coverageSupport,
93     'help' => \$showHelp,
94     'ftl-jit!' => \$ftlJIT,
95     'cloop!' => \$forceCLoop,
96     'cli!' => \$cli,
97     'copy-libraries!' => \$copyLibraries,
98     'makeargs=s' => \$makeArgs,
99     'cmakeargs=s' => \@cmakeArgs,
100     'build-dir=s' => \$buildDir
101 );
102
103 foreach (@features) {
104     if ($_->{javascript}) {
105         my $opt = sprintf("%-35s", "  --[no-]$_->{option}");
106         $usage .= "$opt $_->{desc} (default: $_->{default})\n";
107         $options{"$_->{option}!"} = $_->{value};
108     }
109 }
110
111 GetOptions(%options);
112
113 if ($showHelp) {
114    print STDERR $usage;
115    exit 1;
116 }
117
118 if (isAnyWindows()) {
119     $ftlJIT = 0;
120 }
121
122 if ($buildDir && !isCMakeBuild()) {
123     print STDERR "--build-dir is currently only supported for cmake builds";
124     exit 1;
125 }
126
127 if (isJSCOnly() && isWindows()) {
128     (system("python Tools/Scripts/update-webkit-wincairo-libs.py") == 0) or die;
129     system("python Tools/Scripts/update-vswhere.py");
130 }
131
132 checkRequiredSystemConfig();
133 setConfiguration();
134 chdirWebKit();
135 my @options = XcodeOptions();
136 my @additionalSupportOptions = ();
137 push @additionalSupportOptions, XcodeCoverageSupportOptions() if $coverageSupport;
138 push @additionalSupportOptions, XcodeStaticAnalyzerOption() if $shouldRunStaticAnalyzer;
139
140 if ($forceCLoop) {
141     $ftlJIT = 0;
142 }
143
144 if (isCMakeBuild()) {
145     push @cmakeArgs, $forceCLoop ? " -DENABLE_JIT=OFF" : " -DENABLE_JIT=ON";
146     push @cmakeArgs, $ftlJIT ? " -DENABLE_FTL_JIT=ON" : " -DENABLE_FTL_JIT=OFF";
147     if ($buildDir) {
148         push @cmakeArgs, " " . sourceDir();
149         setBaseProductDir($buildDir);
150     }
151
152     my @featureArgs = cMakeArgsFromFeatures();
153
154     my $buildTarget = "";
155     unless (isAnyWindows()) {
156         # By default we build using all of the available CPUs
157         $makeArgs .= ($makeArgs ? " " : "") . "-j" . numberOfCPUs() if $makeArgs !~ /-j\s*\d+/;
158         $buildTarget = "jsc testb3 testair testapi testmasm $makeArgs";
159     } elsif (canUseNinja()) {
160         $buildTarget .= "jsc testapi testmasm";
161     }
162
163     # This call only returns if nothing wrong happened
164     buildCMakeProjectOrExit(0, undef, $buildTarget, (cmakeBasedPortArguments(), @featureArgs, @cmakeArgs));
165     writeCongrats();
166     exit exitStatus(0);
167 }
168
169 if (isAppleCocoaWebKit()) {
170     push @options, ($forceCLoop ? "ENABLE_JIT=ENABLE_JIT=0" : "ENABLE_JIT=ENABLE_JIT");
171     push @options, ($ftlJIT ? "ENABLE_FTL_JIT=ENABLE_FTL_JIT" : "ENABLE_FTL_JIT=ENABLE_FTL_JIT=0");
172
173     sub option($$$)
174     {
175         my ($feature, $isEnabled, $defaultValue) = @_;
176         return "" if $defaultValue == $isEnabled;
177         return $feature . "=" . ($isEnabled ? $feature : "");
178     }
179
180     foreach (@features) {
181         if ($_->{javascript}) {
182             my $option = option($_->{define}, ${$_->{value}}, $_->{default});
183             push @options, $option unless $option eq "";
184         }
185     }
186
187     if ($copyLibraries) {
188         my @copyLibrariesArgs = ("perl", "Tools/Scripts/copy-webkitlibraries-to-product-directory");
189         push @copyLibrariesArgs, "--device" if willUseIOSDeviceSDK();
190         push @copyLibrariesArgs, productDir();
191         (system(@copyLibrariesArgs) == 0) or die;
192     }
193 }
194
195 sub buildMyProject
196 {
197     my ($projectDirectory, $projectName) = @_;
198     my $result;
199     chdir $projectDirectory or die "Can't find $projectName directory to build from";
200     if (isAppleCocoaWebKit()) {
201         $result = system "sh", "-c", ('xcodebuild -project ' . $projectName . '.xcodeproj "$@" | grep -v setenv && exit ${PIPESTATUS[0]}'), "xcodebuild",  @options, @ARGV, @additionalSupportOptions;
202     } elsif (isAppleWinWebKit() || isWinCairo()) {
203         # WTF is a part of JavaScriptCore.sln because jsc.exe wouldn't start otherwise.
204         if ($projectName ne "WTF") {
205             $result = buildVisualStudioProject("$projectName.vcxproj/$projectName.sln");
206         }
207     } else {
208         die "Building not defined for this platform!\n";
209     }
210     exit exitStatus($result) if exitStatus($result);
211     chdirWebKit();
212 }
213
214 sub cMakeArgsFromFeatures()
215 {
216     my @args;
217     foreach (@features) {
218         my $featureName = $_->{define};
219         if ($featureName) {
220             my $isEnabled = ${$_->{value}};
221             if ($isEnabled != $_->{default}) {
222                 my $featureEnabled = $isEnabled ? "ON" : "OFF";
223                 push @args, "-D$featureName=$featureEnabled";
224             }
225         }
226     }
227     return @args;
228 }
229
230 sub writeCongrats()
231 {
232     my $endTime = time();
233     my $buildTime = formatBuildTime($endTime - $startTime);
234
235     print "\n";
236     print "====================================================================\n";
237     print " JavaScriptCore is now built ($buildTime). \n";
238     print "====================================================================\n";
239 }
240
241 if (!isAppleWinWebKit() && !isWinCairo()) {
242     buildMyProject("Source/bmalloc", "bmalloc");
243 }
244 buildMyProject("Source/WTF", "WTF");
245 buildMyProject("Source/JavaScriptCore", "JavaScriptCore");
246 if (isAppleCocoaWebKit() && $cli) {
247     buildMyProject("Tools/jsc-cli", "jsc-cli");
248 }