Unreviewed.
[WebKit-https.git] / Tools / MiniBrowser / qt / MiniBrowser.pro
1 TEMPLATE = app
2 TARGET = MiniBrowser
3
4 SOURCES += \
5     main.cpp \
6     BrowserView.cpp \
7     BrowserWindow.cpp \
8
9 HEADERS += \
10     BrowserView.h \
11     BrowserWindow.h \
12
13 CONFIG += uitools
14
15 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../..
16 include(../../../Source/WebKit.pri)
17
18 INCLUDEPATH += \
19     $$PWD/../../../Source/JavaScriptCore \
20     $$PWD/../../../Source/WebKit2/ \
21     $$PWD/../../../Source/WebKit2/UIProcess/API/cpp \
22     $$PWD/../../../Source/WebKit2/UIProcess/API/C \
23     $$PWD/../../../Source/WebKit2/UIProcess/API/qt \
24     $$OUTPUT_DIR/include
25
26
27 DESTDIR = $$OUTPUT_DIR/bin
28 !CONFIG(standalone_package): CONFIG -= app_bundle
29
30 QT += network
31 macx:QT+=xml
32
33 linux-* {
34     # From Creator's src/rpath.pri:
35     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
36     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
37     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
38     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
39
40     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\'
41     QMAKE_RPATHDIR =
42 } else {
43     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
44 }
45
46 symbian {
47     TARGET.UID3 = 0xA000E543
48     TARGET.CAPABILITY = ReadUserData WriteUserData NetworkServices
49 }
50
51 contains(QT_CONFIG, opengl) {
52     QT += opengl
53     DEFINES += QT_CONFIGURED_WITH_OPENGL
54 }
55
56 # We copy the resource file to the build directory.
57 # The copier is defined in Tools/MiniBrowser/DerivedSources.pro.
58 RESOURCES += \
59     $$OUTPUT_DIR/MiniBrowser/qt/MiniBrowser.qrc