2011-04-01 Keith Kyzivat <keith.kyzivat@nokia.com>
[WebKit-https.git] / Tools / MiniBrowser / qt / MiniBrowser.pro
1 TEMPLATE = app
2 TARGET = MiniBrowser
3
4 SOURCES += \
5     BrowserView.cpp \
6     BrowserWindow.cpp \
7     main.cpp \
8     MiniBrowserApplication.cpp \
9     UrlLoader.cpp \
10     utils.cpp \
11
12 HEADERS += \
13     BrowserView.h \
14     BrowserWindow.h \
15     MiniBrowserApplication.h \
16     UrlLoader.h \
17     utils.h \
18
19 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../../..
20 include(../../../Source/WebKit.pri)
21
22 INCLUDEPATH += \
23     $$PWD/../../../Source/WebKit2/ \
24     $$PWD/../../../Source/WebKit2/UIProcess/API/cpp \
25     $$PWD/../../../Source/WebKit2/UIProcess/API/C \
26     $$PWD/../../../Source/WebKit2/UIProcess/API/qt \
27     $$OUTPUT_DIR/include
28
29
30 DESTDIR = $$OUTPUT_DIR/bin
31 !CONFIG(standalone_package): CONFIG -= app_bundle
32
33 QT += network
34 macx:QT+=xml
35
36 linux-* {
37     # From Creator's src/rpath.pri:
38     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
39     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
40     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
41     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
42
43     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\'
44     QMAKE_RPATHDIR =
45 } else {
46     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
47 }
48
49 symbian {
50     TARGET.UID3 = 0xA000E545
51     TARGET.CAPABILITY = ReadUserData WriteUserData NetworkServices
52 }
53
54 contains(QT_CONFIG, opengl) {
55     QT += opengl
56     DEFINES += QT_CONFIGURED_WITH_OPENGL
57 }
58
59 DEFINES -= QT_ASCII_CAST_WARNINGS
60
61 # Use the MiniBrowser.qrc file from the sources.
62 RESOURCES += MiniBrowser.qrc