8674beb3efc13a870d962c69aee478edbc5bef63
[WebKit-https.git] / Tools / MiniBrowser / DerivedSources.pro
1 # DerivedSources - qmake build info
2
3 CONFIG -= debug_and_release
4
5 TEMPLATE = lib
6 TARGET = dummy
7
8 QMAKE_EXTRA_TARGETS += generated_files
9
10 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../..
11 SRC_ROOT_DIR = $$replace(PWD, "/Tools/MiniBrowser", "")
12
13 !exists($$OUTPUT_DIR/MiniBrowser/qt): system($$QMAKE_MKDIR $$OUTPUT_DIR/MiniBrowser/qt)
14
15 ualist_copier.input = $$SRC_ROOT_DIR/Tools/QtTestBrowser/useragentlist.txt
16 ualist_copier.output = $$OUTPUT_DIR/MiniBrowser/qt/useragentlist.txt
17 ualist_copier.tempNames = $$ualist_copier.input $$ualist_copier.output
18 ualist_copier.commands = $$QMAKE_COPY $$replace(ualist_copier.tempNames, "/", $$QMAKE_DIR_SEP)
19 ualist_copier.depends = $$ualist_copier.input
20 generated_files.depends += ualist_copier
21 QMAKE_EXTRA_TARGETS += ualist_copier
22
23 # We have to copy the resource file to the build directory
24 # to use the useragentlist.txt file of QtTestBrowser without
25 # polluting the source tree.
26
27 qrc_copier.input = $$SRC_ROOT_DIR/Tools/MiniBrowser/MiniBrowser.qrc
28 qrc_copier.output = $$OUTPUT_DIR/MiniBrowser/qt/MiniBrowser.qrc
29 qrc_copier.tempNames = $$qrc_copier.input $$qrc_copier.output
30 qrc_copier.commands = $$QMAKE_COPY $$replace(qrc_copier.tempNames, "/", $$QMAKE_DIR_SEP)
31 qrc_copier.depends = ualist_copier $$qrc_copier.input
32 generated_files.depends += qrc_copier
33 QMAKE_EXTRA_TARGETS += qrc_copier